PVE/Storage/LvmThinPlugin.pm

   1 package PVE::Storage::LvmThinPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7
   8 use PVE::Tools qw(run_command trim);
   9 use PVE::Storage::Plugin;
  10 use PVE::Storage::LVMPlugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 # see: man lvmthin
  14 # lvcreate -n ThinDataLV -L LargeSize VG
  15 # lvconvert --type thin-pool VG/ThinDataLV
  16 # lvcreate -n pvepool -L 20G pve
  17 # lvconvert --type thin-pool pve/pvepool
  18
  19 # NOTE: volumes which were created as linked clones of another base volume
  20 # are currently not tracking this relationship in their volume IDs. this is
  21 # generally not a problem, as LVM thin allows deletion of such base volumes
  22 # without affecting the linked clones. this leads to increased disk usage
  23 # when migrating LVM-thin volumes, which is normally prevented for linked clones.
  24
  25 use base qw(PVE::Storage::LVMPlugin);
  26
  27 sub type {
  28     return 'lvmthin';
  29 }
  30
  31 sub plugindata {
  32     return {
  33         content => [ {images => 1, rootdir => 1}, { images => 1, rootdir => 1}],
  34     };
  35 }
  36
  37 sub properties {
  38     return {
  39         thinpool => {
  40             description => "LVM thin pool LV name.",
  41             type => 'string', format => 'pve-storage-vgname',
  42         },
  43     };
  44 }
  45
  46 sub options {
  47     return {
  48         thinpool => { fixed => 1 },
  49         vgname => { fixed => 1 },
  50         nodes => { optional => 1 },
  51         disable => { optional => 1 },
  52         content => { optional => 1 },
  53         bwlimit => { optional => 1 },
  54     };
  55 }
  56
  57 # NOTE: the fourth and fifth element of the returned array are always
  58 # undef, even if the volume is a linked clone of another volume. see note
  59 # at beginning of file.
  60 sub parse_volname {
  61     my ($class, $volname) = @_;
  62
  63     PVE::Storage::Plugin::parse_lvm_name($volname);
  64
  65     if ($volname =~ m/^((vm|base)-(\d+)-\S+)$/) {
  66         return ('images', $1, $3, undef, undef, $2 eq 'base', 'raw');
  67     }
  68
  69     die "unable to parse lvm volume name '$volname'\n";
  70 }
  71
  72 sub filesystem_path {
  73     my ($class, $scfg, $volname, $snapname) = @_;
  74
  75     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
  76
  77     my $vg = $scfg->{vgname};
  78
  79     my $path = defined($snapname) ? "/dev/$vg/snap_${name}_$snapname": "/dev/$vg/$name";
  80
  81     return wantarray ? ($path, $vmid, $vtype) : $path;
  82 }
  83
  84 sub alloc_image {
  85     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
  86
  87     die "unsupported format '$fmt'" if $fmt ne 'raw';
  88
  89     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
  90         if  $name && $name !~ m/^vm-$vmid-/;
  91
  92     my $vgs = PVE::Storage::LVMPlugin::lvm_vgs();
  93
  94     my $vg = $scfg->{vgname};
  95
  96     die "no such volume group '$vg'\n" if !defined ($vgs->{$vg});
  97
  98     $name = $class->find_free_diskname($storeid, $scfg, $vmid)
  99         if !$name;
 100
 101     my $cmd = ['/sbin/lvcreate', '-aly', '-V', "${size}k", '--name', $name,
 102                '--thinpool', "$vg/$scfg->{thinpool}" ];
 103
 104     run_command($cmd, errmsg => "lvcreate '$vg/$name' error");
 105
 106     return $name;
 107 }
 108
 109 sub free_image {
 110     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 111
 112     my $vg = $scfg->{vgname};
 113
 114     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 115
 116     if (my $dat = $lvs->{$scfg->{vgname}}) {
 117
 118         # remove all volume snapshots first
 119         foreach my $lv (keys %$dat) {
 120             next if $lv !~ m/^snap_${volname}_${PVE::JSONSchema::CONFIGID_RE}$/;
 121             my $cmd = ['/sbin/lvremove', '-f', "$vg/$lv"];
 122             run_command($cmd, errmsg => "lvremove snapshot '$vg/$lv' error");
 123         }
 124
 125         # finally remove original (if exists)
 126         if ($dat->{$volname}) {
 127             my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 128             run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 129         }
 130     }
 131
 132     return undef;
 133 }
 134
 135 sub list_images {
 136     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 137
 138     my $vgname = $scfg->{vgname};
 139
 140     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 141
 142     my $res = [];
 143
 144     if (my $dat = $cache->{lvs}->{$vgname}) {
 145
 146         foreach my $volname (keys %$dat) {
 147
 148             next if $volname !~ m/^(vm|base)-(\d+)-/;
 149             my $owner = $2;
 150
 151             my $info = $dat->{$volname};
 152
 153             next if $info->{lv_type} ne 'V';
 154
 155             next if $info->{pool_lv} ne $scfg->{thinpool};
 156
 157             my $volid = "$storeid:$volname";
 158
 159             if ($vollist) {
 160                 my $found = grep { $_ eq $volid } @$vollist;
 161                 next if !$found;
 162             } else {
 163                 next if defined($vmid) && ($owner ne $vmid);
 164             }
 165
 166             push @$res, {
 167                 volid => $volid, format => 'raw', size => $info->{lv_size}, vmid => $owner,
 168                 ctime => $info->{ctime},
 169             };
 170         }
 171     }
 172
 173     return $res;
 174 }
 175
 176 sub list_thinpools {
 177     my ($vg) = @_;
 178
 179     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 180     my $thinpools = [];
 181
 182     foreach my $vg (keys %$lvs) {
 183         foreach my $lvname (keys %{$lvs->{$vg}}) {
 184             next if $lvs->{$vg}->{$lvname}->{lv_type} ne 't';
 185             my $lv = $lvs->{$vg}->{$lvname};
 186             $lv->{lv} = $lvname;
 187             $lv->{vg} = $vg;
 188             push @$thinpools, $lv;
 189         }
 190     }
 191
 192     return $thinpools;
 193 }
 194
 195 sub status {
 196     my ($class, $storeid, $scfg, $cache) = @_;
 197
 198     my $lvname = "$scfg->{vgname}/$scfg->{thinpool}";
 199
 200     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 201
 202     my $lvs = $cache->{lvs};
 203
 204     return undef if !$lvs->{$scfg->{vgname}};
 205
 206     my $info = $lvs->{$scfg->{vgname}}->{$scfg->{thinpool}};
 207
 208     return undef if !$info;
 209
 210     return undef if $info->{lv_type} ne 't';
 211
 212     return ($info->{lv_size}, $info->{lv_size} - $info->{used}, $info->{used}, 1) if $info->{lv_size};
 213
 214     return undef;
 215 }
 216
 217 sub activate_volume {
 218     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 219
 220     my $vg = $scfg->{vgname};
 221
 222     # only snapshot volumes needs activation
 223     if ($snapname) {
 224         my $snapvol = "snap_${volname}_$snapname";
 225         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$snapvol"];
 226         run_command($cmd, errmsg => "activate_volume '$vg/$snapvol' error");
 227     } elsif ($volname =~ /^base-/) {
 228         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$volname"];
 229         run_command($cmd, errmsg => "activate_volume '$vg/$volname' error");
 230     } else {
 231         # other volumes are active by default
 232     }
 233 }
 234
 235 sub deactivate_volume {
 236     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 237
 238     my $vg = $scfg->{vgname};
 239
 240     # we only deactivate snapshot volumes
 241     if ($snapname) {
 242         my $snapvol = "snap_${volname}_$snapname";
 243         my $cmd = ['/sbin/lvchange', '-an', "$vg/$snapvol"];
 244         run_command($cmd, errmsg => "deactivate_volume '$vg/$snapvol' error");
 245     } elsif ($volname =~ /^base-/) {
 246         my $cmd = ['/sbin/lvchange', '-an', "$vg/$volname"];
 247         run_command($cmd, errmsg => "deactivate_volume '$vg/$volname' error");
 248     } else {
 249         # other volumes are kept active
 250     }
 251 }
 252
 253 sub clone_image {
 254     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 255
 256     my $vg = $scfg->{vgname};
 257
 258     my $lv;
 259
 260     if ($snap) {
 261         $lv = "$vg/snap_${volname}_$snap";
 262     } else {
 263         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
 264             $class->parse_volname($volname);
 265
 266         die "clone_image only works on base images\n" if !$isBase;
 267
 268         $lv = "$vg/$volname";
 269     }
 270
 271     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 272
 273     my $cmd = ['/sbin/lvcreate', '-n', $name, '-prw', '-kn', '-s', $lv];
 274     run_command($cmd, errmsg => "clone image '$lv' error");
 275
 276     return $name;
 277 }
 278
 279 sub create_base {
 280     my ($class, $storeid, $scfg, $volname) = @_;
 281
 282     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 283         $class->parse_volname($volname);
 284
 285     die "create_base not possible with base image\n" if $isBase;
 286
 287     my $vg = $scfg->{vgname};
 288     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 289
 290     if (my $dat = $lvs->{$vg}) {
 291         # to avoid confusion, reject if we find volume snapshots
 292         foreach my $lv (keys %$dat) {
 293             die "unable to create base volume - found snaphost '$lv'\n"
 294                 if $lv =~ m/^snap_${volname}_(\w+)$/;
 295         }
 296     }
 297
 298     my $newname = $name;
 299     $newname =~ s/^vm-/base-/;
 300
 301     my $cmd = ['/sbin/lvrename', $vg, $volname, $newname];
 302     run_command($cmd, errmsg => "lvrename '$vg/$volname' => '$vg/$newname' error");
 303
 304     # set inactive, read-only and activationskip flags
 305     $cmd = ['/sbin/lvchange', '-an', '-pr', '-ky', "$vg/$newname"];
 306     eval { run_command($cmd); };
 307     warn $@ if $@;
 308
 309     my $newvolname = $newname;
 310
 311     return $newvolname;
 312 }
 313
 314 # sub volume_resize {} reuse code from parent class
 315
 316 sub volume_snapshot {
 317     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 318
 319     my $vg = $scfg->{vgname};
 320     my $snapvol = "snap_${volname}_$snap";
 321
 322     my $cmd = ['/sbin/lvcreate', '-n', $snapvol, '-pr', '-s', "$vg/$volname"];
 323     run_command($cmd, errmsg => "lvcreate snapshot '$vg/$snapvol' error");
 324
 325 }
 326
 327 sub volume_snapshot_rollback {
 328     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 329
 330     my $vg = $scfg->{vgname};
 331     my $snapvol = "snap_${volname}_$snap";
 332
 333     my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 334     run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 335
 336     $cmd = ['/sbin/lvcreate', '-kn', '-n', $volname, '-s', "$vg/$snapvol"];
 337     run_command($cmd, errmsg => "lvm rollback '$vg/$snapvol' error");
 338 }
 339
 340 sub volume_snapshot_delete {
 341     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 342
 343     my $vg = $scfg->{vgname};
 344     my $snapvol = "snap_${volname}_$snap";
 345
 346     my $cmd = ['/sbin/lvremove', '-f', "$vg/$snapvol"];
 347     run_command($cmd, errmsg => "lvremove snapshot '$vg/$snapvol' error");
 348 }
 349
 350 sub volume_has_feature {
 351     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 352
 353     my $features = {
 354         snapshot => { current => 1 },
 355         clone => { base => 1, snap => 1},
 356         template => { current => 1},
 357         copy => { base => 1, current => 1, snap => 1},
 358         sparseinit => { base => 1, current => 1},
 359         rename => {current => 1},
 360     };
 361
 362     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 363         $class->parse_volname($volname);
 364
 365     my $key = undef;
 366     if($snapname){
 367         $key = 'snap';
 368     }else{
 369         $key =  $isBase ? 'base' : 'current';
 370     }
 371     return 1 if $features->{$feature}->{$key};
 372
 373     return undef;
 374 }
 375
 376 # used in LVMPlugin->volume_import
 377 sub volume_import_write {
 378     my ($class, $input_fh, $output_file) = @_;
 379     run_command(['dd', "of=$output_file", 'conv=sparse', 'bs=64k'],
 380         input => '<&'.fileno($input_fh));
 381 }
 382
 383 1;