PVE/Storage/NFSPlugin.pm

   1 package PVE::Storage::NFSPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use File::Path;
   8 use PVE::Tools qw(run_command);
   9 use PVE::ProcFSTools;
  10 use PVE::Storage::Plugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 # NFS helper functions
  16
  17 sub nfs_is_mounted {
  18     my ($server, $export, $mountpoint, $mountdata) = @_;
  19
  20     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  21     my $source = "$server:$export";
  22
  23     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  24     return $mountpoint if grep {
  25         $_->[2] =~ /^nfs/ &&
  26         $_->[0] =~ m|^\Q$source\E/?$| &&
  27         $_->[1] eq $mountpoint
  28     } @$mountdata;
  29     return undef;
  30 }
  31
  32 sub nfs_mount {
  33     my ($server, $export, $mountpoint, $options) = @_;
  34
  35     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  36     my $source = "$server:$export";
  37
  38     my $cmd = ['/bin/mount', '-t', 'nfs', $source, $mountpoint];
  39     if ($options) {
  40         push @$cmd, '-o', $options;
  41     }
  42
  43     run_command($cmd, errmsg => "mount error");
  44 }
  45
  46 # Configuration
  47
  48 sub type {
  49     return 'nfs';
  50 }
  51
  52 sub plugindata {
  53     return {
  54         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1, backup => 1},
  55                      { images => 1 }],
  56         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
  57     };
  58 }
  59
  60 sub properties {
  61     return {
  62         export => {
  63             description => "NFS export path.",
  64             type => 'string', format => 'pve-storage-path',
  65         },
  66         server => {
  67             description => "Server IP or DNS name.",
  68             type => 'string', format => 'pve-storage-server',
  69         },
  70         options => {
  71             description => "NFS mount options (see 'man nfs')",
  72             type => 'string',  format => 'pve-storage-options',
  73         },
  74     };
  75 }
  76
  77 sub options {
  78     return {
  79         path => { fixed => 1 },
  80         server => { fixed => 1 },
  81         export => { fixed => 1 },
  82         nodes => { optional => 1 },
  83         disable => { optional => 1 },
  84         maxfiles => { optional => 1 },
  85         options => { optional => 1 },
  86         content => { optional => 1 },
  87         format => { optional => 1 },
  88     };
  89 }
  90
  91
  92 sub check_config {
  93     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
  94
  95     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
  96
  97     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
  98 }
  99
 100 # Storage implementation
 101
 102 sub status {
 103     my ($class, $storeid, $scfg, $cache) = @_;
 104
 105     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 106         if !$cache->{mountdata};
 107
 108     my $path = $scfg->{path};
 109     my $server = $scfg->{server};
 110     my $export = $scfg->{export};
 111
 112     return undef if !nfs_is_mounted($server, $export, $path, $cache->{mountdata});
 113
 114     return $class->SUPER::status($storeid, $scfg, $cache);
 115 }
 116
 117 sub activate_storage {
 118     my ($class, $storeid, $scfg, $cache) = @_;
 119
 120     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 121         if !$cache->{mountdata};
 122
 123     my $path = $scfg->{path};
 124     my $server = $scfg->{server};
 125     my $export = $scfg->{export};
 126
 127     if (!nfs_is_mounted($server, $export, $path, $cache->{mountdata})) {
 128
 129         # NOTE: only call mkpath when not mounted (avoid hang
 130         # when NFS server is offline
 131
 132         mkpath $path;
 133
 134         die "unable to activate storage '$storeid' - " .
 135             "directory '$path' does not exist\n" if ! -d $path;
 136
 137         nfs_mount($server, $export, $path, $scfg->{options});
 138     }
 139
 140     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 141 }
 142
 143 sub deactivate_storage {
 144     my ($class, $storeid, $scfg, $cache) = @_;
 145
 146     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 147         if !$cache->{mountdata};
 148
 149     my $path = $scfg->{path};
 150     my $server = $scfg->{server};
 151     my $export = $scfg->{export};
 152
 153     if (nfs_is_mounted($server, $export, $path, $cache->{mountdata})) {
 154         my $cmd = ['/bin/umount', $path];
 155         run_command($cmd, errmsg => 'umount error');
 156     }
 157 }
 158
 159 sub check_connection {
 160     my ($class, $storeid, $scfg) = @_;
 161
 162     my $server = $scfg->{server};
 163
 164     my $cmd = ['/sbin/showmount', '--no-headers', '--exports', $server];
 165
 166     eval {
 167         run_command($cmd, timeout => 2, outfunc => sub {}, errfunc => sub {});
 168     };
 169     if (my $err = $@) {
 170         return 0;
 171     }
 172
 173     return 1;
 174 }
 175
 176 1;