PVE/Storage/PBSPlugin.pm

   1 package PVE::Storage::PBSPlugin;
   2
   3 # Plugin to access Proxmox Backup Server
   4
   5 use strict;
   6 use warnings;
   7
   8 use Fcntl qw(F_GETFD F_SETFD FD_CLOEXEC);
   9 use HTTP::Request;
  10 use IO::File;
  11 use JSON;
  12 use LWP::UserAgent;
  13 use POSIX qw(strftime ENOENT);
  14
  15 use PVE::JSONSchema qw(get_standard_option);
  16 use PVE::Network;
  17 use PVE::Storage::Plugin;
  18 use PVE::Tools qw(run_command file_read_firstline trim dir_glob_regex dir_glob_foreach $IPV6RE);
  19
  20 use base qw(PVE::Storage::Plugin);
  21
  22 # Configuration
  23
  24 sub type {
  25     return 'pbs';
  26 }
  27
  28 sub plugindata {
  29     return {
  30         content => [ {backup => 1, none => 1}, { backup => 1 }],
  31     };
  32 }
  33
  34 sub properties {
  35     return {
  36         datastore => {
  37             description => "Proxmox Backup Server datastore name.",
  38             type => 'string',
  39         },
  40         # openssl s_client -connect <host>:8007 2>&1 |openssl x509 -fingerprint -sha256
  41         fingerprint => get_standard_option('fingerprint-sha256'),
  42         'encryption-key' => {
  43             description => "Encryption key. Use 'autogen' to generate one automatically without passphrase.",
  44             type => 'string',
  45         },
  46         port => {
  47             description => "For non default port.",
  48             type => 'integer',
  49             minimum => 1,
  50             maximum => 65535,
  51             default => 8007,
  52         }
  53     };
  54 }
  55
  56 sub options {
  57     return {
  58         server => { fixed => 1 },
  59         datastore => { fixed => 1 },
  60         port => { optional => 1 },
  61         nodes => { optional => 1},
  62         disable => { optional => 1},
  63         content => { optional => 1},
  64         username => { optional => 1 },
  65         password => { optional => 1 },
  66         'encryption-key' => { optional => 1 },
  67         maxfiles => { optional => 1 },
  68         'prune-backups' => { optional => 1 },
  69         fingerprint => { optional => 1 },
  70     };
  71 }
  72
  73 # Helpers
  74
  75 sub pbs_password_file_name {
  76     my ($scfg, $storeid) = @_;
  77
  78     return "/etc/pve/priv/storage/${storeid}.pw";
  79 }
  80
  81 sub pbs_set_password {
  82     my ($scfg, $storeid, $password) = @_;
  83
  84     my $pwfile = pbs_password_file_name($scfg, $storeid);
  85     mkdir "/etc/pve/priv/storage";
  86
  87     PVE::Tools::file_set_contents($pwfile, "$password\n");
  88 }
  89
  90 sub pbs_delete_password {
  91     my ($scfg, $storeid) = @_;
  92
  93     my $pwfile = pbs_password_file_name($scfg, $storeid);
  94
  95     unlink $pwfile;
  96 }
  97
  98 sub pbs_get_password {
  99     my ($scfg, $storeid) = @_;
 100
 101     my $pwfile = pbs_password_file_name($scfg, $storeid);
 102
 103     return PVE::Tools::file_read_firstline($pwfile);
 104 }
 105
 106 sub pbs_encryption_key_file_name {
 107     my ($scfg, $storeid) = @_;
 108
 109     return "/etc/pve/priv/storage/${storeid}.enc";
 110 }
 111
 112 sub pbs_set_encryption_key {
 113     my ($scfg, $storeid, $key) = @_;
 114
 115     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 116     mkdir "/etc/pve/priv/storage";
 117
 118     PVE::Tools::file_set_contents($pwfile, "$key\n");
 119 }
 120
 121 sub pbs_delete_encryption_key {
 122     my ($scfg, $storeid) = @_;
 123
 124     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 125
 126     if (!unlink $pwfile) {
 127         return if $! == ENOENT;
 128         die "failed to delete encryption key! $!\n";
 129     }
 130     delete $scfg->{'encryption-key'};
 131 }
 132
 133 sub pbs_get_encryption_key {
 134     my ($scfg, $storeid) = @_;
 135
 136     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 137
 138     return PVE::Tools::file_get_contents($pwfile);
 139 }
 140
 141 # Returns a file handle if there is an encryption key, or `undef` if there is not. Dies on error.
 142 sub pbs_open_encryption_key {
 143     my ($scfg, $storeid) = @_;
 144
 145     my $encryption_key_file = pbs_encryption_key_file_name($scfg, $storeid);
 146
 147     my $keyfd;
 148     if (!open($keyfd, '<', $encryption_key_file)) {
 149         return undef if $! == ENOENT;
 150         die "failed to open encryption key: $encryption_key_file: $!\n";
 151     }
 152
 153     return $keyfd;
 154 }
 155
 156 sub print_volid {
 157     my ($storeid, $btype, $bid, $btime) = @_;
 158
 159     my $time_str = strftime("%FT%TZ", gmtime($btime));
 160     my $volname = "backup/${btype}/${bid}/${time_str}";
 161
 162     return "${storeid}:${volname}";
 163 }
 164
 165 my sub get_server_with_port {
 166     my ($scfg) = @_;
 167
 168     my $server = $scfg->{server};
 169     $server = "[$server]" if $server =~ /^$IPV6RE$/;
 170
 171     if (my $port = $scfg->{port}) {
 172         $server .= ":$port" if $port != 8007;
 173     }
 174     return $server;
 175 }
 176
 177 my $USE_CRYPT_PARAMS = {
 178     backup => 1,
 179     restore => 1,
 180     'upload-log' => 1,
 181 };
 182
 183 my sub do_raw_client_cmd {
 184     my ($scfg, $storeid, $client_cmd, $param, %opts) = @_;
 185
 186     my $use_crypto = $USE_CRYPT_PARAMS->{$client_cmd};
 187
 188     my $client_exe = '/usr/bin/proxmox-backup-client';
 189     die "executable not found '$client_exe'! Proxmox backup client not installed?\n"
 190         if ! -x $client_exe;
 191
 192     my $server = get_server_with_port($scfg);
 193     my $datastore = $scfg->{datastore};
 194     my $username = $scfg->{username} // 'root@pam';
 195
 196     my $userns_cmd = delete $opts{userns_cmd};
 197
 198     my $cmd = [];
 199
 200     push @$cmd, @$userns_cmd if defined($userns_cmd);
 201
 202     push @$cmd, $client_exe, $client_cmd;
 203
 204     # This must live in the top scope to not get closed before the `run_command`
 205     my $keyfd;
 206     if ($use_crypto) {
 207         if (defined($keyfd = pbs_open_encryption_key($scfg, $storeid))) {
 208             my $flags = fcntl($keyfd, F_GETFD, 0)
 209                 // die "failed to get file descriptor flags: $!\n";
 210             fcntl($keyfd, F_SETFD, $flags & ~FD_CLOEXEC)
 211                 or die "failed to remove FD_CLOEXEC from encryption key file descriptor\n";
 212             push @$cmd, '--crypt-mode=encrypt', '--keyfd='.fileno($keyfd);
 213         } else {
 214             push @$cmd, '--crypt-mode=none';
 215         }
 216     }
 217
 218     push @$cmd, @$param if defined($param);
 219
 220     push @$cmd, "--repository", "$username\@$server:$datastore";
 221
 222     local $ENV{PBS_PASSWORD} = pbs_get_password($scfg, $storeid);
 223
 224     local $ENV{PBS_FINGERPRINT} = $scfg->{fingerprint};
 225
 226     # no ascii-art on task logs
 227     local $ENV{PROXMOX_OUTPUT_NO_BORDER} = 1;
 228     local $ENV{PROXMOX_OUTPUT_NO_HEADER} = 1;
 229
 230     if (my $logfunc = $opts{logfunc}) {
 231         $logfunc->("run: " . join(' ', @$cmd));
 232     }
 233
 234     run_command($cmd, %opts);
 235 }
 236
 237 # FIXME: External perl code should NOT have access to this.
 238 #
 239 # There should be separate functions to
 240 # - make backups
 241 # - restore backups
 242 # - restore files
 243 # with a sane API
 244 sub run_raw_client_cmd {
 245     my ($scfg, $storeid, $client_cmd, $param, %opts) = @_;
 246     return do_raw_client_cmd($scfg, $storeid, $client_cmd, $param, %opts);
 247 }
 248
 249 sub run_client_cmd {
 250     my ($scfg, $storeid, $client_cmd, $param, $no_output) = @_;
 251
 252     my $json_str = '';
 253     my $outfunc = sub { $json_str .= "$_[0]\n" };
 254
 255     $param = [] if !defined($param);
 256     $param = [ $param ] if !ref($param);
 257
 258     $param = [@$param, '--output-format=json'] if !$no_output;
 259
 260     do_raw_client_cmd($scfg, $storeid, $client_cmd, $param,
 261                       outfunc => $outfunc, errmsg => 'proxmox-backup-client failed');
 262
 263     return undef if $no_output;
 264
 265     my $res = decode_json($json_str);
 266
 267     return $res;
 268 }
 269
 270 # Storage implementation
 271
 272 sub extract_vzdump_config {
 273     my ($class, $scfg, $volname, $storeid) = @_;
 274
 275     my ($vtype, $name, $vmid, undef, undef, undef, $format) = $class->parse_volname($volname);
 276
 277     my $config = '';
 278     my $outfunc = sub { $config .= "$_[0]\n" };
 279
 280     my $config_name;
 281     if ($format eq 'pbs-vm') {
 282         $config_name = 'qemu-server.conf';
 283     } elsif  ($format eq 'pbs-ct') {
 284         $config_name = 'pct.conf';
 285     } else {
 286         die "unable to extract configuration for backup format '$format'\n";
 287     }
 288
 289     do_raw_client_cmd($scfg, $storeid, 'restore', [ $name, $config_name, '-' ],
 290                       outfunc => $outfunc, errmsg => 'proxmox-backup-client failed');
 291
 292     return $config;
 293 }
 294
 295 sub prune_backups {
 296     my ($class, $scfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc) = @_;
 297
 298     $logfunc //= sub { print "$_[1]\n" };
 299
 300     my $backups = $class->list_volumes($storeid, $scfg, $vmid, ['backup']);
 301
 302     $type = 'vm' if defined($type) && $type eq 'qemu';
 303     $type = 'ct' if defined($type) && $type eq 'lxc';
 304
 305     my $backup_groups = {};
 306     foreach my $backup (@{$backups}) {
 307         (my $backup_type = $backup->{format}) =~ s/^pbs-//;
 308
 309         next if defined($type) && $backup_type ne $type;
 310
 311         my $backup_group = "$backup_type/$backup->{vmid}";
 312         $backup_groups->{$backup_group} = 1;
 313     }
 314
 315     my @param;
 316     foreach my $opt (keys %{$keep}) {
 317         next if $keep->{$opt} == 0;
 318         push @param, "--$opt";
 319         push @param, "$keep->{$opt}";
 320     }
 321
 322     push @param, '--dry-run' if $dryrun;
 323
 324     my $prune_list = [];
 325     my $failed;
 326
 327     foreach my $backup_group (keys %{$backup_groups}) {
 328         $logfunc->('info', "running 'proxmox-backup-client prune' for '$backup_group'")
 329             if !$dryrun;
 330         eval {
 331             my $res = run_client_cmd($scfg, $storeid, 'prune', [ $backup_group, @param ]);
 332
 333             foreach my $backup (@{$res}) {
 334                 die "result from proxmox-backup-client is not as expected\n"
 335                     if !defined($backup->{'backup-time'})
 336                     || !defined($backup->{'backup-type'})
 337                     || !defined($backup->{'backup-id'})
 338                     || !defined($backup->{'keep'});
 339
 340                 my $ctime = $backup->{'backup-time'};
 341                 my $type = $backup->{'backup-type'};
 342                 my $vmid = $backup->{'backup-id'};
 343                 my $volid = print_volid($storeid, $type, $vmid, $ctime);
 344
 345                 push @{$prune_list}, {
 346                     ctime => $ctime,
 347                     mark => $backup->{keep} ? 'keep' : 'remove',
 348                     type => $type eq 'vm' ? 'qemu' : 'lxc',
 349                     vmid => $vmid,
 350                     volid => $volid,
 351                 };
 352             }
 353         };
 354         if (my $err = $@) {
 355             $logfunc->('err', "prune '$backup_group': $err\n");
 356             $failed = 1;
 357         }
 358     }
 359     die "error pruning backups - check log\n" if $failed;
 360
 361     return $prune_list;
 362 }
 363
 364 my $autogen_encryption_key = sub {
 365     my ($scfg, $storeid) = @_;
 366     my $encfile = pbs_encryption_key_file_name($scfg, $storeid);
 367     my $cmd = ['proxmox-backup-client', 'key', 'create', '--kdf', 'none', $encfile];
 368     run_command($cmd, errmsg => 'failed to create encryption key');
 369     return PVE::Tools::file_get_contents($encfile);
 370 };
 371
 372 sub on_add_hook {
 373     my ($class, $storeid, $scfg, %param) = @_;
 374
 375     my $res = {};
 376
 377     if (defined(my $password = $param{password})) {
 378         pbs_set_password($scfg, $storeid, $password);
 379     } else {
 380         pbs_delete_password($scfg, $storeid);
 381     }
 382
 383     if (defined(my $encryption_key = $param{'encryption-key'})) {
 384         if ($encryption_key eq 'autogen') {
 385             $res->{'encryption-key'} = $autogen_encryption_key->($scfg, $storeid);
 386         } else {
 387             pbs_set_encryption_key($scfg, $storeid, $encryption_key);
 388             $res->{'encryption-key'} = $encryption_key;
 389         }
 390         $scfg->{'encryption-key'} = 1;
 391     } else {
 392         pbs_delete_encryption_key($scfg, $storeid);
 393     }
 394
 395     return $res;
 396 }
 397
 398 sub on_update_hook {
 399     my ($class, $storeid, $scfg, %param) = @_;
 400
 401     my $res = {};
 402
 403     if (exists($param{password})) {
 404         if (defined($param{password})) {
 405             pbs_set_password($scfg, $storeid, $param{password});
 406         } else {
 407             pbs_delete_password($scfg, $storeid);
 408         }
 409     }
 410
 411     if (exists($param{'encryption-key'})) {
 412         if (defined(my $encryption_key = delete($param{'encryption-key'}))) {
 413             if ($encryption_key eq 'autogen') {
 414                 $res->{'encryption-key'} = $autogen_encryption_key->($scfg, $storeid);
 415             } else {
 416                 pbs_set_encryption_key($scfg, $storeid, $encryption_key);
 417                 $res->{'encryption-key'} = $encryption_key;
 418             }
 419             $scfg->{'encryption-key'} = 1;
 420         } else {
 421             pbs_delete_encryption_key($scfg, $storeid);
 422         }
 423     }
 424
 425     return $res;
 426 }
 427
 428 sub on_delete_hook {
 429     my ($class, $storeid, $scfg) = @_;
 430
 431     pbs_delete_password($scfg, $storeid);
 432     pbs_delete_encryption_key($scfg, $storeid);
 433 }
 434
 435 sub parse_volname {
 436     my ($class, $volname) = @_;
 437
 438     if ($volname =~ m!^backup/([^\s_]+)/([^\s_]+)/([0-9]{4}-[0-9]{2}-[0-9]{2}T[0-9]{2}:[0-9]{2}:[0-9]{2}Z)$!) {
 439         my $btype = $1;
 440         my $bid = $2;
 441         my $btime = $3;
 442         my $format = "pbs-$btype";
 443
 444         my $name = "$btype/$bid/$btime";
 445
 446         if ($bid =~ m/^\d+$/) {
 447             return ('backup', $name, $bid, undef, undef, undef, $format);
 448         } else {
 449             return ('backup', $name, undef, undef, undef, undef, $format);
 450         }
 451     }
 452
 453     die "unable to parse PBS volume name '$volname'\n";
 454 }
 455
 456 sub path {
 457     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 458
 459     die "volume snapshot is not possible on pbs storage"
 460         if defined($snapname);
 461
 462     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 463
 464     my $server = get_server_with_port($scfg);
 465     my $datastore = $scfg->{datastore};
 466     my $username = $scfg->{username} // 'root@pam';
 467
 468     # artifical url - we currently do not use that anywhere
 469     my $path = "pbs://$username\@$server:$datastore/$name";
 470
 471     return ($path, $vmid, $vtype);
 472 }
 473
 474 sub create_base {
 475     my ($class, $storeid, $scfg, $volname) = @_;
 476
 477     die "can't create base images in pbs storage\n";
 478 }
 479
 480 sub clone_image {
 481     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 482
 483     die "can't clone images in pbs storage\n";
 484 }
 485
 486 sub alloc_image {
 487     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 488
 489     die "can't allocate space in pbs storage\n";
 490 }
 491
 492 sub free_image {
 493     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 494
 495     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 496
 497     run_client_cmd($scfg, $storeid, "forget", [ $name ], 1);
 498 }
 499
 500
 501 sub list_images {
 502     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 503
 504     my $res = [];
 505
 506     return $res;
 507 }
 508
 509 sub list_volumes {
 510     my ($class, $storeid, $scfg, $vmid, $content_types) = @_;
 511
 512     my $res = [];
 513
 514     return $res if !grep { $_ eq 'backup' } @$content_types;
 515
 516     my $data = run_client_cmd($scfg, $storeid, "snapshots");
 517
 518     foreach my $item (@$data) {
 519         my $btype = $item->{"backup-type"};
 520         my $bid = $item->{"backup-id"};
 521         my $epoch = $item->{"backup-time"};
 522         my $size = $item->{size} // 1;
 523
 524         next if !($btype eq 'vm' || $btype eq 'ct');
 525         next if $bid !~ m/^\d+$/;
 526         next if defined($vmid) && $bid ne $vmid;
 527
 528         my $volid = print_volid($storeid, $btype, $bid, $epoch);
 529
 530         my $info = {
 531             volid => $volid,
 532             format => "pbs-$btype",
 533             size => $size,
 534             content => 'backup',
 535             vmid => int($bid),
 536             ctime => $epoch,
 537         };
 538
 539         $info->{verification} = $item->{verification} if defined($item->{verification});
 540         $info->{comment} = $item->{comment} if defined($item->{comment});
 541
 542         push @$res, $info;
 543     }
 544
 545     return $res;
 546 }
 547
 548 sub status {
 549     my ($class, $storeid, $scfg, $cache) = @_;
 550
 551     my $total = 0;
 552     my $free = 0;
 553     my $used = 0;
 554     my $active = 0;
 555
 556     eval {
 557         my $res = run_client_cmd($scfg, $storeid, "status");
 558
 559         $active = 1;
 560         $total = $res->{total};
 561         $used = $res->{used};
 562         $free = $res->{avail};
 563     };
 564     if (my $err = $@) {
 565         warn $err;
 566     }
 567
 568     return ($total, $free, $used, $active);
 569 }
 570
 571 sub activate_storage {
 572     my ($class, $storeid, $scfg, $cache) = @_;
 573
 574     # a 'status' client command is to expensive here
 575     # TODO: use a dummy ping API call to ensure the PBS API daemon is available for real
 576     my $server = $scfg->{server};
 577     my $port = $scfg->{port} // 8007;
 578     PVE::Network::tcp_ping($server, $port, 2);
 579
 580     return 1;
 581 }
 582
 583 sub deactivate_storage {
 584     my ($class, $storeid, $scfg, $cache) = @_;
 585     return 1;
 586 }
 587
 588 sub activate_volume {
 589     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 590
 591     die "volume snapshot is not possible on pbs device" if $snapname;
 592
 593     return 1;
 594 }
 595
 596 sub deactivate_volume {
 597     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 598
 599     die "volume snapshot is not possible on pbs device" if $snapname;
 600
 601     return 1;
 602 }
 603
 604 sub volume_size_info {
 605     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 606
 607     my ($vtype, $name,  undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 608
 609     my $data = run_client_cmd($scfg, $storeid, "files", [ $name ]);
 610
 611     my $size = 0;
 612     foreach my $info (@$data) {
 613         $size += $info->{size} if $info->{size};
 614     }
 615
 616     my $used = $size;
 617
 618     return wantarray ? ($size, $format, $used, undef) : $size;
 619 }
 620
 621 sub volume_resize {
 622     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 623     die "volume resize is not possible on pbs device";
 624 }
 625
 626 sub volume_snapshot {
 627     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 628     die "volume snapshot is not possible on pbs device";
 629 }
 630
 631 sub volume_snapshot_rollback {
 632     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 633     die "volume snapshot rollback is not possible on pbs device";
 634 }
 635
 636 sub volume_snapshot_delete {
 637     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 638     die "volume snapshot delete is not possible on pbs device";
 639 }
 640
 641 sub volume_has_feature {
 642     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 643
 644     return undef;
 645 }
 646
 647 1;