PVE/Storage/PBSPlugin.pm

   1 package PVE::Storage::PBSPlugin;
   2
   3 # Plugin to access Proxmox Backup Server
   4
   5 use strict;
   6 use warnings;
   7
   8 use Fcntl qw(F_GETFD F_SETFD FD_CLOEXEC);
   9 use HTTP::Request;
  10 use IO::File;
  11 use JSON;
  12 use LWP::UserAgent;
  13 use POSIX qw(strftime ENOENT);
  14
  15 use PVE::JSONSchema qw(get_standard_option);
  16 use PVE::Network;
  17 use PVE::Storage::Plugin;
  18 use PVE::Tools qw(run_command file_read_firstline trim dir_glob_regex dir_glob_foreach $IPV6RE);
  19
  20 use base qw(PVE::Storage::Plugin);
  21
  22 # Configuration
  23
  24 sub type {
  25     return 'pbs';
  26 }
  27
  28 sub plugindata {
  29     return {
  30         content => [ {backup => 1, none => 1}, { backup => 1 }],
  31     };
  32 }
  33
  34 sub properties {
  35     return {
  36         datastore => {
  37             description => "Proxmox Backup Server datastore name.",
  38             type => 'string',
  39         },
  40         # openssl s_client -connect <host>:8007 2>&1 |openssl x509 -fingerprint -sha256
  41         fingerprint => get_standard_option('fingerprint-sha256'),
  42         'encryption-key' => {
  43             description => "Encryption key. Use 'autogen' to generate one automatically without passphrase.",
  44             type => 'string',
  45         },
  46         port => {
  47             description => "For non default port.",
  48             type => 'integer',
  49             minimum => 1,
  50             maximum => 65535,
  51             default => 8007,
  52         }
  53     };
  54 }
  55
  56 sub options {
  57     return {
  58         server => { fixed => 1 },
  59         datastore => { fixed => 1 },
  60         port => { optional => 1 },
  61         nodes => { optional => 1},
  62         disable => { optional => 1},
  63         content => { optional => 1},
  64         username => { optional => 1 },
  65         password => { optional => 1 },
  66         'encryption-key' => { optional => 1 },
  67         maxfiles => { optional => 1 },
  68         'prune-backups' => { optional => 1 },
  69         fingerprint => { optional => 1 },
  70     };
  71 }
  72
  73 # Helpers
  74
  75 sub pbs_password_file_name {
  76     my ($scfg, $storeid) = @_;
  77
  78     return "/etc/pve/priv/storage/${storeid}.pw";
  79 }
  80
  81 sub pbs_set_password {
  82     my ($scfg, $storeid, $password) = @_;
  83
  84     my $pwfile = pbs_password_file_name($scfg, $storeid);
  85     mkdir "/etc/pve/priv/storage";
  86
  87     PVE::Tools::file_set_contents($pwfile, "$password\n");
  88 }
  89
  90 sub pbs_delete_password {
  91     my ($scfg, $storeid) = @_;
  92
  93     my $pwfile = pbs_password_file_name($scfg, $storeid);
  94
  95     unlink $pwfile;
  96 }
  97
  98 sub pbs_get_password {
  99     my ($scfg, $storeid) = @_;
 100
 101     my $pwfile = pbs_password_file_name($scfg, $storeid);
 102
 103     return PVE::Tools::file_read_firstline($pwfile);
 104 }
 105
 106 sub pbs_encryption_key_file_name {
 107     my ($scfg, $storeid) = @_;
 108
 109     return "/etc/pve/priv/storage/${storeid}.enc";
 110 }
 111
 112 sub pbs_set_encryption_key {
 113     my ($scfg, $storeid, $key) = @_;
 114
 115     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 116     mkdir "/etc/pve/priv/storage";
 117
 118     PVE::Tools::file_set_contents($pwfile, "$key\n");
 119 }
 120
 121 sub pbs_delete_encryption_key {
 122     my ($scfg, $storeid) = @_;
 123
 124     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 125
 126     if (!unlink $pwfile) {
 127         return if $! == ENOENT;
 128         die "failed to delete encryption key! $!\n";
 129     }
 130     delete $scfg->{'encryption-key'};
 131 }
 132
 133 sub pbs_get_encryption_key {
 134     my ($scfg, $storeid) = @_;
 135
 136     my $pwfile = pbs_encryption_key_file_name($scfg, $storeid);
 137
 138     return PVE::Tools::file_get_contents($pwfile);
 139 }
 140
 141 # Returns a file handle if there is an encryption key, or `undef` if there is not. Dies on error.
 142 sub pbs_open_encryption_key {
 143     my ($scfg, $storeid) = @_;
 144
 145     my $encryption_key_file = pbs_encryption_key_file_name($scfg, $storeid);
 146
 147     my $keyfd;
 148     if (!open($keyfd, '<', $encryption_key_file)) {
 149         return undef if $! == ENOENT;
 150         die "failed to open encryption key: $encryption_key_file: $!\n";
 151     }
 152
 153     return $keyfd;
 154 }
 155
 156 sub print_volid {
 157     my ($storeid, $btype, $bid, $btime) = @_;
 158
 159     my $time_str = strftime("%FT%TZ", gmtime($btime));
 160     my $volname = "backup/${btype}/${bid}/${time_str}";
 161
 162     return "${storeid}:${volname}";
 163 }
 164
 165 my sub get_server_with_port {
 166     my ($scfg) = @_;
 167
 168     my $server = $scfg->{server};
 169     $server = "[$server]" if $server =~ /^$IPV6RE$/;
 170
 171     if (my $port = $scfg->{port}) {
 172         $server .= ":$port" if $port != 8007;
 173     }
 174     return $server;
 175 }
 176
 177 my $USE_CRYPT_PARAMS = {
 178     backup => 1,
 179     restore => 1,
 180     'upload-log' => 1,
 181 };
 182
 183 my sub do_raw_client_cmd {
 184     my ($scfg, $storeid, $client_cmd, $param, %opts) = @_;
 185
 186     my $use_crypto = $USE_CRYPT_PARAMS->{$client_cmd};
 187
 188     my $client_exe = '/usr/bin/proxmox-backup-client';
 189     die "executable not found '$client_exe'! Proxmox backup client not installed?\n"
 190         if ! -x $client_exe;
 191
 192     my $server = get_server_with_port($scfg);
 193     my $datastore = $scfg->{datastore};
 194     my $username = $scfg->{username} // 'root@pam';
 195
 196     my $userns_cmd = delete $opts{userns_cmd};
 197
 198     my $cmd = [];
 199
 200     push @$cmd, @$userns_cmd if defined($userns_cmd);
 201
 202     push @$cmd, $client_exe, $client_cmd;
 203
 204     # This must live in the top scope to not get closed before the `run_command`
 205     my $keyfd;
 206     if ($use_crypto) {
 207         if (defined($keyfd = pbs_open_encryption_key($scfg, $storeid))) {
 208             my $flags = fcntl($keyfd, F_GETFD, 0)
 209                 // die "failed to get file descriptor flags: $!\n";
 210             fcntl($keyfd, F_SETFD, $flags & ~FD_CLOEXEC)
 211                 or die "failed to remove FD_CLOEXEC from encryption key file descriptor\n";
 212             push @$cmd, '--crypt-mode=encrypt', '--keyfd='.fileno($keyfd);
 213         } else {
 214             push @$cmd, '--crypt-mode=none';
 215         }
 216     }
 217
 218     push @$cmd, @$param if defined($param);
 219
 220     push @$cmd, "--repository", "$username\@$server:$datastore";
 221
 222     local $ENV{PBS_PASSWORD} = pbs_get_password($scfg, $storeid);
 223
 224     local $ENV{PBS_FINGERPRINT} = $scfg->{fingerprint};
 225
 226     # no ascii-art on task logs
 227     local $ENV{PROXMOX_OUTPUT_NO_BORDER} = 1;
 228     local $ENV{PROXMOX_OUTPUT_NO_HEADER} = 1;
 229
 230     if (my $logfunc = $opts{logfunc}) {
 231         $logfunc->("run: " . join(' ', @$cmd));
 232     }
 233
 234     run_command($cmd, %opts);
 235 }
 236
 237 # FIXME: External perl code should NOT have access to this.
 238 #
 239 # There should be separate functions to
 240 # - make backups
 241 # - restore backups
 242 # - restore files
 243 # with a sane API
 244 sub run_raw_client_cmd {
 245     my ($scfg, $storeid, $client_cmd, $param, %opts) = @_;
 246     return do_raw_client_cmd($scfg, $storeid, $client_cmd, $param, %opts);
 247 }
 248
 249 sub run_client_cmd {
 250     my ($scfg, $storeid, $client_cmd, $param, $no_output) = @_;
 251
 252     my $json_str = '';
 253     my $outfunc = sub { $json_str .= "$_[0]\n" };
 254
 255     $param = [] if !defined($param);
 256     $param = [ $param ] if !ref($param);
 257
 258     $param = [@$param, '--output-format=json'] if !$no_output;
 259
 260     do_raw_client_cmd($scfg, $storeid, $client_cmd, $param,
 261                       outfunc => $outfunc, errmsg => 'proxmox-backup-client failed');
 262
 263     return undef if $no_output;
 264
 265     my $res = decode_json($json_str);
 266
 267     return $res;
 268 }
 269
 270 # Storage implementation
 271
 272 sub extract_vzdump_config {
 273     my ($class, $scfg, $volname, $storeid) = @_;
 274
 275     my ($vtype, $name, $vmid, undef, undef, undef, $format) = $class->parse_volname($volname);
 276
 277     my $config = '';
 278     my $outfunc = sub { $config .= "$_[0]\n" };
 279
 280     my $config_name;
 281     if ($format eq 'pbs-vm') {
 282         $config_name = 'qemu-server.conf';
 283     } elsif  ($format eq 'pbs-ct') {
 284         $config_name = 'pct.conf';
 285     } else {
 286         die "unable to extract configuration for backup format '$format'\n";
 287     }
 288
 289     do_raw_client_cmd($scfg, $storeid, 'restore', [ $name, $config_name, '-' ],
 290                       outfunc => $outfunc, errmsg => 'proxmox-backup-client failed');
 291
 292     return $config;
 293 }
 294
 295 sub prune_backups {
 296     my ($class, $scfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc) = @_;
 297
 298     $logfunc //= sub { print "$_[1]\n" };
 299
 300     my $backups = $class->list_volumes($storeid, $scfg, $vmid, ['backup']);
 301
 302     $type = 'vm' if defined($type) && $type eq 'qemu';
 303     $type = 'ct' if defined($type) && $type eq 'lxc';
 304
 305     my $backup_groups = {};
 306     foreach my $backup (@{$backups}) {
 307         (my $backup_type = $backup->{format}) =~ s/^pbs-//;
 308
 309         next if defined($type) && $backup_type ne $type;
 310
 311         my $backup_group = "$backup_type/$backup->{vmid}";
 312         $backup_groups->{$backup_group} = 1;
 313     }
 314
 315     my @param;
 316
 317     my $keep_all = delete $keep->{'keep-all'};
 318
 319     if (!$keep_all) {
 320         foreach my $opt (keys %{$keep}) {
 321             next if $keep->{$opt} == 0;
 322             push @param, "--$opt";
 323             push @param, "$keep->{$opt}";
 324         }
 325     } else { # no need to pass anything to PBS
 326         $keep = { 'keep-all' => 1 };
 327     }
 328
 329     push @param, '--dry-run' if $dryrun;
 330
 331     my $prune_list = [];
 332     my $failed;
 333
 334     foreach my $backup_group (keys %{$backup_groups}) {
 335         $logfunc->('info', "running 'proxmox-backup-client prune' for '$backup_group'")
 336             if !$dryrun;
 337         eval {
 338             my $res = run_client_cmd($scfg, $storeid, 'prune', [ $backup_group, @param ]);
 339
 340             foreach my $backup (@{$res}) {
 341                 die "result from proxmox-backup-client is not as expected\n"
 342                     if !defined($backup->{'backup-time'})
 343                     || !defined($backup->{'backup-type'})
 344                     || !defined($backup->{'backup-id'})
 345                     || !defined($backup->{'keep'});
 346
 347                 my $ctime = $backup->{'backup-time'};
 348                 my $type = $backup->{'backup-type'};
 349                 my $vmid = $backup->{'backup-id'};
 350                 my $volid = print_volid($storeid, $type, $vmid, $ctime);
 351
 352                 push @{$prune_list}, {
 353                     ctime => $ctime,
 354                     mark => $backup->{keep} ? 'keep' : 'remove',
 355                     type => $type eq 'vm' ? 'qemu' : 'lxc',
 356                     vmid => $vmid,
 357                     volid => $volid,
 358                 };
 359             }
 360         };
 361         if (my $err = $@) {
 362             $logfunc->('err', "prune '$backup_group': $err\n");
 363             $failed = 1;
 364         }
 365     }
 366     die "error pruning backups - check log\n" if $failed;
 367
 368     return $prune_list;
 369 }
 370
 371 my $autogen_encryption_key = sub {
 372     my ($scfg, $storeid) = @_;
 373     my $encfile = pbs_encryption_key_file_name($scfg, $storeid);
 374     my $cmd = ['proxmox-backup-client', 'key', 'create', '--kdf', 'none', $encfile];
 375     run_command($cmd, errmsg => 'failed to create encryption key');
 376     return PVE::Tools::file_get_contents($encfile);
 377 };
 378
 379 sub on_add_hook {
 380     my ($class, $storeid, $scfg, %param) = @_;
 381
 382     my $res = {};
 383
 384     if (defined(my $password = $param{password})) {
 385         pbs_set_password($scfg, $storeid, $password);
 386     } else {
 387         pbs_delete_password($scfg, $storeid);
 388     }
 389
 390     if (defined(my $encryption_key = $param{'encryption-key'})) {
 391         if ($encryption_key eq 'autogen') {
 392             $res->{'encryption-key'} = $autogen_encryption_key->($scfg, $storeid);
 393         } else {
 394             pbs_set_encryption_key($scfg, $storeid, $encryption_key);
 395             $res->{'encryption-key'} = $encryption_key;
 396         }
 397         $scfg->{'encryption-key'} = 1;
 398     } else {
 399         pbs_delete_encryption_key($scfg, $storeid);
 400     }
 401
 402     return $res;
 403 }
 404
 405 sub on_update_hook {
 406     my ($class, $storeid, $scfg, %param) = @_;
 407
 408     my $res = {};
 409
 410     if (exists($param{password})) {
 411         if (defined($param{password})) {
 412             pbs_set_password($scfg, $storeid, $param{password});
 413         } else {
 414             pbs_delete_password($scfg, $storeid);
 415         }
 416     }
 417
 418     if (exists($param{'encryption-key'})) {
 419         if (defined(my $encryption_key = delete($param{'encryption-key'}))) {
 420             if ($encryption_key eq 'autogen') {
 421                 $res->{'encryption-key'} = $autogen_encryption_key->($scfg, $storeid);
 422             } else {
 423                 pbs_set_encryption_key($scfg, $storeid, $encryption_key);
 424                 $res->{'encryption-key'} = $encryption_key;
 425             }
 426             $scfg->{'encryption-key'} = 1;
 427         } else {
 428             pbs_delete_encryption_key($scfg, $storeid);
 429         }
 430     }
 431
 432     return $res;
 433 }
 434
 435 sub on_delete_hook {
 436     my ($class, $storeid, $scfg) = @_;
 437
 438     pbs_delete_password($scfg, $storeid);
 439     pbs_delete_encryption_key($scfg, $storeid);
 440 }
 441
 442 sub parse_volname {
 443     my ($class, $volname) = @_;
 444
 445     if ($volname =~ m!^backup/([^\s_]+)/([^\s_]+)/([0-9]{4}-[0-9]{2}-[0-9]{2}T[0-9]{2}:[0-9]{2}:[0-9]{2}Z)$!) {
 446         my $btype = $1;
 447         my $bid = $2;
 448         my $btime = $3;
 449         my $format = "pbs-$btype";
 450
 451         my $name = "$btype/$bid/$btime";
 452
 453         if ($bid =~ m/^\d+$/) {
 454             return ('backup', $name, $bid, undef, undef, undef, $format);
 455         } else {
 456             return ('backup', $name, undef, undef, undef, undef, $format);
 457         }
 458     }
 459
 460     die "unable to parse PBS volume name '$volname'\n";
 461 }
 462
 463 sub path {
 464     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 465
 466     die "volume snapshot is not possible on pbs storage"
 467         if defined($snapname);
 468
 469     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 470
 471     my $server = get_server_with_port($scfg);
 472     my $datastore = $scfg->{datastore};
 473     my $username = $scfg->{username} // 'root@pam';
 474
 475     # artifical url - we currently do not use that anywhere
 476     my $path = "pbs://$username\@$server:$datastore/$name";
 477
 478     return ($path, $vmid, $vtype);
 479 }
 480
 481 sub create_base {
 482     my ($class, $storeid, $scfg, $volname) = @_;
 483
 484     die "can't create base images in pbs storage\n";
 485 }
 486
 487 sub clone_image {
 488     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 489
 490     die "can't clone images in pbs storage\n";
 491 }
 492
 493 sub alloc_image {
 494     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 495
 496     die "can't allocate space in pbs storage\n";
 497 }
 498
 499 sub free_image {
 500     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 501
 502     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 503
 504     run_client_cmd($scfg, $storeid, "forget", [ $name ], 1);
 505 }
 506
 507
 508 sub list_images {
 509     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 510
 511     my $res = [];
 512
 513     return $res;
 514 }
 515
 516 sub list_volumes {
 517     my ($class, $storeid, $scfg, $vmid, $content_types) = @_;
 518
 519     my $res = [];
 520
 521     return $res if !grep { $_ eq 'backup' } @$content_types;
 522
 523     my $data = run_client_cmd($scfg, $storeid, "snapshots");
 524
 525     foreach my $item (@$data) {
 526         my $btype = $item->{"backup-type"};
 527         my $bid = $item->{"backup-id"};
 528         my $epoch = $item->{"backup-time"};
 529         my $size = $item->{size} // 1;
 530
 531         next if !($btype eq 'vm' || $btype eq 'ct');
 532         next if $bid !~ m/^\d+$/;
 533         next if defined($vmid) && $bid ne $vmid;
 534
 535         my $volid = print_volid($storeid, $btype, $bid, $epoch);
 536
 537         my $info = {
 538             volid => $volid,
 539             format => "pbs-$btype",
 540             size => $size,
 541             content => 'backup',
 542             vmid => int($bid),
 543             ctime => $epoch,
 544         };
 545
 546         $info->{verification} = $item->{verification} if defined($item->{verification});
 547         $info->{notes} = $item->{comment} if defined($item->{comment});
 548
 549         push @$res, $info;
 550     }
 551
 552     return $res;
 553 }
 554
 555 sub status {
 556     my ($class, $storeid, $scfg, $cache) = @_;
 557
 558     my $total = 0;
 559     my $free = 0;
 560     my $used = 0;
 561     my $active = 0;
 562
 563     eval {
 564         my $res = run_client_cmd($scfg, $storeid, "status");
 565
 566         $active = 1;
 567         $total = $res->{total};
 568         $used = $res->{used};
 569         $free = $res->{avail};
 570     };
 571     if (my $err = $@) {
 572         warn $err;
 573     }
 574
 575     return ($total, $free, $used, $active);
 576 }
 577
 578 sub activate_storage {
 579     my ($class, $storeid, $scfg, $cache) = @_;
 580
 581     # a 'status' client command is to expensive here
 582     # TODO: use a dummy ping API call to ensure the PBS API daemon is available for real
 583     my $server = $scfg->{server};
 584     my $port = $scfg->{port} // 8007;
 585     PVE::Network::tcp_ping($server, $port, 2);
 586
 587     return 1;
 588 }
 589
 590 sub deactivate_storage {
 591     my ($class, $storeid, $scfg, $cache) = @_;
 592     return 1;
 593 }
 594
 595 sub activate_volume {
 596     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 597
 598     die "volume snapshot is not possible on pbs device" if $snapname;
 599
 600     return 1;
 601 }
 602
 603 sub deactivate_volume {
 604     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 605
 606     die "volume snapshot is not possible on pbs device" if $snapname;
 607
 608     return 1;
 609 }
 610
 611 sub volume_size_info {
 612     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 613
 614     my ($vtype, $name,  undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 615
 616     my $data = run_client_cmd($scfg, $storeid, "files", [ $name ]);
 617
 618     my $size = 0;
 619     foreach my $info (@$data) {
 620         $size += $info->{size} if $info->{size};
 621     }
 622
 623     my $used = $size;
 624
 625     return wantarray ? ($size, $format, $used, undef) : $size;
 626 }
 627
 628 sub volume_resize {
 629     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 630     die "volume resize is not possible on pbs device";
 631 }
 632
 633 sub volume_snapshot {
 634     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 635     die "volume snapshot is not possible on pbs device";
 636 }
 637
 638 sub volume_snapshot_rollback {
 639     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 640     die "volume snapshot rollback is not possible on pbs device";
 641 }
 642
 643 sub volume_snapshot_delete {
 644     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 645     die "volume snapshot delete is not possible on pbs device";
 646 }
 647
 648 sub volume_has_feature {
 649     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 650
 651     return undef;
 652 }
 653
 654 1;