PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use JSON;
   8 use Net::IP;
   9
  10 use PVE::CephConfig;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::ProcFSTools;
  13 use PVE::RADOS;
  14 use PVE::Storage::Plugin;
  15 use PVE::Tools qw(run_command trim);
  16
  17 use base qw(PVE::Storage::Plugin);
  18
  19 my $get_parent_image_name = sub {
  20     my ($parent) = @_;
  21     return undef if !$parent;
  22     return $parent->{image} . "@" . $parent->{snapshot};
  23 };
  24
  25 my $get_rbd_path = sub {
  26     my ($scfg, $volume) = @_;
  27     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  28     return "${pool}/${volume}";
  29 };
  30
  31 my $build_cmd = sub {
  32     my ($binary, $scfg, $storeid, $op, @options) = @_;
  33
  34     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  35     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  36
  37     my $cmd = [$binary, '-p', $pool];
  38
  39     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  40     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  41     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  42     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  43     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  44
  45     push @$cmd, $op;
  46
  47     push @$cmd, @options if scalar(@options);
  48
  49     return $cmd;
  50 };
  51
  52 my $rbd_cmd = sub {
  53     my ($scfg, $storeid, $op, @options) = @_;
  54
  55     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  56 };
  57
  58 my $rados_cmd = sub {
  59     my ($scfg, $storeid, $op, @options) = @_;
  60
  61     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  62 };
  63
  64 my $librados_connect = sub {
  65     my ($scfg, $storeid, $options) = @_;
  66
  67     my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  68
  69     my $rados = PVE::RADOS->new(%$librados_config);
  70
  71     return $rados;
  72 };
  73
  74 # needed for volumes created using ceph jewel (or higher)
  75 my $krbd_feature_update = sub {
  76     my ($scfg, $storeid, $name) = @_;
  77
  78     my (@disable, @enable);
  79     my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version();
  80
  81     if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) {
  82         # 'deep-flatten' can only be disabled, not enabled after image creation
  83         push @enable, 'fast-diff', 'object-map';
  84     } else {
  85         push @disable, 'fast-diff', 'object-map', 'deep-flatten';
  86     }
  87
  88     if ($kmajor >= 5) {
  89         push @enable, 'exclusive-lock';
  90     } else {
  91         push @disable, 'exclusive-lock';
  92     }
  93
  94     my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4];
  95     my $active_features = { map { $_ => 1 } @$active_features_list };
  96
  97     my $to_disable = join(',', grep {  $active_features->{$_} } @disable);
  98     my $to_enable  = join(',', grep { !$active_features->{$_} } @enable );
  99
 100     if ($to_disable) {
 101         print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n";
 102         my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable);
 103         run_rbd_command(
 104             $cmd,
 105             errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name",
 106         );
 107     }
 108     if ($to_enable) {
 109         print "enable RBD image features this kernel RBD drivers supports: $to_enable\n";
 110         eval {
 111             my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable);
 112             run_rbd_command(
 113                 $cmd,
 114                 errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name",
 115             );
 116         };
 117         warn "$@" if $@;
 118     }
 119 };
 120
 121 sub run_rbd_command {
 122     my ($cmd, %args) = @_;
 123
 124     my $lasterr;
 125     my $errmsg = $args{errmsg} . ": " || "";
 126     if (!exists($args{errfunc})) {
 127         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 128         # at least 1 child(ren) in pool cephstor1
 129         $args{errfunc} = sub {
 130             my $line = shift;
 131             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 132                 $lasterr = "$1\n";
 133             } else {
 134                 $lasterr = $line;
 135             }
 136             print STDERR $lasterr;
 137             *STDERR->flush();
 138         };
 139     }
 140
 141     eval { run_command($cmd, %args); };
 142     if (my $err = $@) {
 143         die $errmsg . $lasterr if length($lasterr);
 144         die $err;
 145     }
 146
 147     return undef;
 148 }
 149
 150 sub rbd_ls {
 151     my ($scfg, $storeid) = @_;
 152
 153     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 154     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 155
 156     my $raw = '';
 157     my $parser = sub { $raw .= shift };
 158
 159     eval {
 160         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 161     };
 162     my $err = $@;
 163
 164     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 165
 166     my $result;
 167     if ($raw eq '') {
 168         $result = [];
 169     } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint
 170         $result = JSON::decode_json($1);
 171     } else {
 172         die "got unexpected data from rbd ls: '$raw'\n";
 173     }
 174
 175     my $list = {};
 176
 177     foreach my $el (@$result) {
 178         next if defined($el->{snapshot});
 179
 180         my $image = $el->{image};
 181
 182         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 183         next if !defined($owner);
 184
 185         $list->{$pool}->{$image} = {
 186             name => $image,
 187             size => $el->{size},
 188             parent => $get_parent_image_name->($el->{parent}),
 189             vmid => $owner
 190         };
 191     }
 192
 193     return $list;
 194 }
 195
 196 sub rbd_ls_snap {
 197     my ($scfg, $storeid, $name) = @_;
 198
 199     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'ls', $name, '--format', 'json');
 200
 201     my $raw = '';
 202     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => sub { $raw .= shift; });
 203
 204     my $list;
 205     if ($raw =~ m/^(\[.*\])$/s) { # untaint
 206         $list = eval { JSON::decode_json($1) };
 207         die "invalid JSON output from 'rbd snap ls $name': $@\n" if $@;
 208     } else {
 209         die "got unexpected data from 'rbd snap ls $name': '$raw'\n";
 210     }
 211
 212     $list = [] if !defined($list);
 213
 214     my $res = {};
 215     foreach my $el (@$list) {
 216         my $snap = $el->{name};
 217         my $protected = defined($el->{protected}) && $el->{protected} eq "true" ? 1 : undef;
 218         $res->{$snap} = {
 219             name => $snap,
 220             id => $el->{id} // undef,
 221             size => $el->{size} // 0,
 222             protected => $protected,
 223         };
 224     }
 225     return $res;
 226 }
 227
 228 sub rbd_volume_info {
 229     my ($scfg, $storeid, $volname, $snap) = @_;
 230
 231     my $cmd = undef;
 232
 233     my @options = ('info', $volname, '--format', 'json');
 234     if ($snap) {
 235         push @options, '--snap', $snap;
 236     }
 237
 238     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 239
 240     my $raw = '';
 241     my $parser = sub { $raw .= shift };
 242
 243     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 244
 245     my $volume;
 246     if ($raw eq '') {
 247         $volume = {};
 248     } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint
 249         $volume = JSON::decode_json($1);
 250     } else {
 251         die "got unexpected data from rbd info: '$raw'\n";
 252     }
 253
 254     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 255     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 256
 257     return $volume->@{qw(size parent format protected features)};
 258 }
 259
 260 # Configuration
 261
 262 sub type {
 263     return 'rbd';
 264 }
 265
 266 sub plugindata {
 267     return {
 268         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 269     };
 270 }
 271
 272 sub properties {
 273     return {
 274         monhost => {
 275             description => "IP addresses of monitors (for external clusters).",
 276             type => 'string', format => 'pve-storage-portal-dns-list',
 277         },
 278         pool => {
 279             description => "Pool.",
 280             type => 'string',
 281         },
 282         username => {
 283             description => "RBD Id.",
 284             type => 'string',
 285         },
 286         authsupported => {
 287             description => "Authsupported.",
 288             type => 'string',
 289         },
 290         krbd => {
 291             description => "Always access rbd through krbd kernel module.",
 292             type => 'boolean',
 293         },
 294     };
 295 }
 296
 297 sub options {
 298     return {
 299         nodes => { optional => 1 },
 300         disable => { optional => 1 },
 301         monhost => { optional => 1},
 302         pool => { optional => 1 },
 303         username => { optional => 1 },
 304         content => { optional => 1 },
 305         krbd => { optional => 1 },
 306         bwlimit => { optional => 1 },
 307     };
 308 }
 309
 310 # Storage implementation
 311
 312 sub on_add_hook {
 313     my ($class, $storeid, $scfg, %param) = @_;
 314
 315     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 316
 317     PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
 318
 319     return;
 320 }
 321
 322 sub on_delete_hook {
 323     my ($class, $storeid, $scfg) = @_;
 324
 325     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 326
 327     PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
 328
 329     return;
 330 }
 331
 332 sub parse_volname {
 333     my ($class, $volname) = @_;
 334
 335     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 336         return ('images', $4, $7, $2, $3, $5, 'raw');
 337     }
 338
 339     die "unable to parse rbd volume name '$volname'\n";
 340 }
 341
 342 sub path {
 343     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 344
 345     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
 346     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 347     $name .= '@'.$snapname if $snapname;
 348
 349     my $rbd_path = &$get_rbd_path($scfg, $name);
 350     return ("/dev/rbd/${rbd_path}", $vmid, $vtype) if $scfg->{krbd};
 351
 352     my $path = "rbd:${rbd_path}";
 353
 354     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 355     if (defined($scfg->{monhost})) {
 356         my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';');
 357         $monhost =~ s/:/\\:/g;
 358         $path .= ":mon_host=$monhost";
 359         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 360     }
 361
 362     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 363
 364     return ($path, $vmid, $vtype);
 365 }
 366
 367 sub find_free_diskname {
 368     my ($class, $storeid, $scfg, $vmid, $fmt, $add_fmt_suffix) = @_;
 369
 370     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 371     my $disk_list = [];
 372
 373     my $parser = sub {
 374         my $line = shift;
 375         if ($line =~ m/^(.*)$/) { # untaint
 376             push @$disk_list, $1;
 377         }
 378     };
 379
 380     eval {
 381         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 382     };
 383     my $err = $@;
 384
 385     die $err if $err && $err !~ m/doesn't contain rbd images/;
 386
 387     return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg);
 388 }
 389
 390 sub create_base {
 391     my ($class, $storeid, $scfg, $volname) = @_;
 392
 393     my $snap = '__base__';
 394
 395     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 396         $class->parse_volname($volname);
 397
 398     die "create_base not possible with base image\n" if $isBase;
 399
 400     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 401     die "rbd volume info on '$name' failed\n" if !($size);
 402
 403     die "rbd image must be at format V2" if $format ne "2";
 404
 405     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 406         if $basename && (!$parent || $parent ne $basename."@".$snap);
 407
 408     my $newname = $name;
 409     $newname =~ s/^vm-/base-/;
 410
 411     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 412
 413     my $cmd = &$rbd_cmd(
 414         $scfg,
 415         $storeid,
 416         'rename',
 417         &$get_rbd_path($scfg, $name),
 418         &$get_rbd_path($scfg, $newname),
 419     );
 420     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 421
 422     my $running  = undef; #fixme : is create_base always offline ?
 423
 424     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 425
 426     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 427
 428     if (!$protected){
 429         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 430         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 431     }
 432
 433     return $newvolname;
 434
 435 }
 436
 437 sub clone_image {
 438     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 439
 440     my $snap = '__base__';
 441     $snap = $snapname if length $snapname;
 442
 443     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 444         $class->parse_volname($volname);
 445
 446     die "$volname is not a base image and snapname is not provided\n"
 447         if !$isBase && !length($snapname);
 448
 449     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 450
 451     warn "clone $volname: $basename snapname $snap to $name\n";
 452
 453     if (length($snapname)) {
 454         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 455
 456         if (!$protected) {
 457             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 458             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 459         }
 460     }
 461
 462     my $newvol = "$basename/$name";
 463     $newvol = $name if length($snapname);
 464
 465     my $cmd = &$rbd_cmd(
 466         $scfg,
 467         $storeid,
 468         'clone',
 469         &$get_rbd_path($scfg, $basename),
 470         '--snap',
 471         $snap,
 472         &$get_rbd_path($scfg, $name),
 473     );
 474
 475     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 476
 477     return $newvol;
 478 }
 479
 480 sub alloc_image {
 481     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 482
 483
 484     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 485         if  $name && $name !~ m/^vm-$vmid-/;
 486
 487     $name = $class->find_free_diskname($storeid, $scfg, $vmid) if !$name;
 488
 489     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 490     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 491
 492     return $name;
 493 }
 494
 495 sub free_image {
 496     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 497
 498     my ($vtype, $name, $vmid, undef, undef, undef) =
 499         $class->parse_volname($volname);
 500
 501     my $snaps = rbd_ls_snap($scfg, $storeid, $name);
 502     foreach my $snap (keys %$snaps) {
 503         if ($snaps->{$snap}->{protected}) {
 504             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 505             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 506         }
 507     }
 508
 509     $class->deactivate_volume($storeid, $scfg, $volname);
 510
 511     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 512     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 513
 514     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 515     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 516
 517     return undef;
 518 }
 519
 520 sub list_images {
 521     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 522
 523     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 524     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 525
 526     my $res = [];
 527
 528     if (my $dat = $cache->{rbd}->{$pool}) {
 529         foreach my $image (keys %$dat) {
 530
 531             my $info = $dat->{$image};
 532
 533             my $volname = $info->{name};
 534             my $parent = $info->{parent};
 535             my $owner = $info->{vmid};
 536
 537             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 538                 $info->{volid} = "$storeid:$1/$volname";
 539             } else {
 540                 $info->{volid} = "$storeid:$volname";
 541             }
 542
 543             if ($vollist) {
 544                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 545                 next if !$found;
 546             } else {
 547                 next if defined ($vmid) && ($owner ne $vmid);
 548             }
 549
 550             $info->{format} = 'raw';
 551
 552             push @$res, $info;
 553         }
 554     }
 555
 556     return $res;
 557 }
 558
 559 sub status {
 560     my ($class, $storeid, $scfg, $cache) = @_;
 561
 562
 563     my $rados = &$librados_connect($scfg, $storeid);
 564     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 565
 566     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 567
 568     # max_avail -> max available space for data w/o replication in the pool
 569     # bytes_used -> data w/o replication in the pool
 570     my $free = $d->{stats}->{max_avail};
 571     my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used};
 572     my $total = $used + $free;
 573     my $active = 1;
 574
 575     return ($total, $free, $used, $active);
 576 }
 577
 578 sub activate_storage {
 579     my ($class, $storeid, $scfg, $cache) = @_;
 580     return 1;
 581 }
 582
 583 sub deactivate_storage {
 584     my ($class, $storeid, $scfg, $cache) = @_;
 585     return 1;
 586 }
 587
 588 my $get_kernel_device_name = sub {
 589     my ($scfg, $name) = @_;
 590
 591     my $rbd_path = &$get_rbd_path($scfg, $name);
 592     return "/dev/rbd/${rbd_path}";
 593 };
 594
 595 sub map_volume {
 596     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 597
 598     my ($vtype, $img_name, $vmid) = $class->parse_volname($volname);
 599
 600     my $name = $img_name;
 601     $name .= '@'.$snapname if $snapname;
 602
 603     my $kerneldev = $get_kernel_device_name->($scfg, $name);
 604
 605     return $kerneldev if -b $kerneldev; # already mapped
 606
 607     # features can only be enabled/disabled for image, not for snapshot!
 608     $krbd_feature_update->($scfg, $storeid, $img_name);
 609
 610     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 611     run_rbd_command($cmd, errmsg => "can't map rbd volume $name");
 612
 613     return $kerneldev;
 614 }
 615
 616 sub unmap_volume {
 617     my ($class, $storeid, $scfg, $volname, $snapname) = @_;
 618
 619     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 620     $name .= '@'.$snapname if $snapname;
 621
 622     my $kerneldev = $get_kernel_device_name->($scfg, $name);
 623
 624     if (-b $kerneldev) {
 625         my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $kerneldev);
 626         run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev");
 627     }
 628
 629     return 1;
 630 }
 631
 632 sub activate_volume {
 633     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 634
 635     $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd};
 636
 637     return 1;
 638 }
 639
 640 sub deactivate_volume {
 641     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 642
 643     $class->unmap_volume($storeid, $scfg, $volname, $snapname);
 644
 645     return 1;
 646 }
 647
 648 sub volume_size_info {
 649     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 650
 651     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 652     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 653     return $size;
 654 }
 655
 656 sub volume_resize {
 657     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 658
 659     return 1 if $running && !$scfg->{krbd}; # FIXME???
 660
 661     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 662
 663     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 664     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 665     return undef;
 666 }
 667
 668 sub volume_snapshot {
 669     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 670
 671     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 672
 673     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 674     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 675     return undef;
 676 }
 677
 678 sub volume_snapshot_rollback {
 679     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 680
 681     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 682
 683     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 684     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 685 }
 686
 687 sub volume_snapshot_delete {
 688     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 689
 690     return 1 if $running && !$scfg->{krbd}; # FIXME: ????
 691
 692     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 693
 694     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 695
 696     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 697     if ($protected){
 698         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 699         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 700     }
 701
 702     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 703
 704     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 705
 706     return undef;
 707 }
 708
 709 sub volume_snapshot_needs_fsfreeze {
 710
 711     return 1;
 712 }
 713
 714 sub volume_has_feature {
 715     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 716
 717    my $features = {
 718         snapshot => { current => 1, snap => 1},
 719         clone => { base => 1, snap => 1},
 720         template => { current => 1},
 721         copy => { base => 1, current => 1, snap => 1},
 722         sparseinit => { base => 1, current => 1},
 723     };
 724
 725     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 726         $class->parse_volname($volname);
 727
 728     my $key = undef;
 729     if($snapname){
 730         $key = 'snap';
 731     }else{
 732         $key =  $isBase ? 'base' : 'current';
 733     }
 734     return 1 if $features->{$feature}->{$key};
 735
 736     return undef;
 737 }
 738
 739 1;