PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use Net::IP;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::JSONSchema qw(get_standard_option);
  10 use PVE::RADOS;
  11 use PVE::Storage::CephTools;
  12 use JSON;
  13
  14 use base qw(PVE::Storage::Plugin);
  15
  16 my $get_parent_image_name = sub {
  17     my ($parent) = @_;
  18     return undef if !$parent;
  19     return $parent->{image} . "@" . $parent->{snapshot};
  20 };
  21
  22 my $add_pool_to_disk = sub {
  23     my ($scfg, $disk) = @_;
  24
  25     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  26
  27     return "$pool/$disk";
  28 };
  29
  30 my $build_cmd = sub {
  31     my ($binary, $scfg, $storeid, $op, @options) = @_;
  32
  33     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  34     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  35
  36     my $cmd = [$binary, '-p', $pool];
  37
  38     push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
  39     push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
  40     push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
  41     push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
  42     push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
  43
  44     push @$cmd, $op;
  45
  46     push @$cmd, @options if scalar(@options);
  47
  48     return $cmd;
  49 };
  50
  51 my $rbd_cmd = sub {
  52     my ($scfg, $storeid, $op, @options) = @_;
  53
  54     return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
  55 };
  56
  57 my $rados_cmd = sub {
  58     my ($scfg, $storeid, $op, @options) = @_;
  59
  60     return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
  61 };
  62
  63 my $librados_connect = sub {
  64     my ($scfg, $storeid, $options) = @_;
  65
  66     my $librados_config = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
  67
  68     my $rados = PVE::RADOS->new(%$librados_config);
  69
  70     return $rados;
  71 };
  72
  73 # needed for volumes created using ceph jewel (or higher)
  74 my $krbd_feature_disable = sub {
  75     my ($scfg, $storeid, $name) = @_;
  76
  77     return 1 if !$scfg->{krbd};
  78
  79     my ($major, undef, undef, undef) = ceph_version();
  80     return 1 if $major < 10;
  81
  82     my $krbd_feature_blacklist = ['deep-flatten', 'fast-diff', 'object-map', 'exclusive-lock'];
  83     my (undef, undef, undef, undef, $features) = rbd_volume_info($scfg, $storeid, $name);
  84
  85     my $active_features = { map { $_ => 1 } $features };
  86     my $incompatible_features = join(',', grep { %$active_features{$_} } @$krbd_feature_blacklist);
  87
  88     if ($incompatible_features) {
  89         my $feature_cmd = &$rbd_cmd($scfg, $storeid, 'feature', 'disable', $name, $incompatible_features);
  90         run_rbd_command($feature_cmd, errmsg => "could not disable krbd-incompatible image features of rbd volume $name");
  91     }
  92 };
  93
  94 my $ceph_version_parser = sub {
  95     my $line = shift;
  96     if ($line =~ m/^ceph version ((\d+)\.(\d+)\.(\d+))(?: \([a-fA-F0-9]+\))/) {
  97         return ($2, $3, $4, $1);
  98     } else {
  99         warn "Could not parse Ceph version: '$line'\n";
 100     }
 101 };
 102
 103 sub ceph_version {
 104     my ($cache) = @_;
 105
 106     my $version_string = $cache;
 107
 108     my $major;
 109     my $minor;
 110     my $bugfix;
 111
 112     if (defined($version_string)) {
 113         ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($version_string);
 114     } else {
 115         run_command('ceph --version', outfunc => sub {
 116             my $line = shift;
 117             ($major, $minor, $bugfix, $version_string) = &$ceph_version_parser($line);
 118         });
 119     }
 120     return undef if !defined($version_string);
 121     return wantarray ? ($major, $minor, $bugfix, $version_string) : $version_string;
 122 }
 123
 124 sub run_rbd_command {
 125     my ($cmd, %args) = @_;
 126
 127     my $lasterr;
 128     my $errmsg = $args{errmsg} . ": " || "";
 129     if (!exists($args{errfunc})) {
 130         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
 131         # at least 1 child(ren) in pool cephstor1
 132         $args{errfunc} = sub {
 133             my $line = shift;
 134             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
 135                 $lasterr = "$1\n";
 136             } else {
 137                 $lasterr = $line;
 138             }
 139             print STDERR $lasterr;
 140             *STDERR->flush();
 141         };
 142     }
 143
 144     eval { run_command($cmd, %args); };
 145     if (my $err = $@) {
 146         die $errmsg . $lasterr if length($lasterr);
 147         die $err;
 148     }
 149
 150     return undef;
 151 }
 152
 153 sub rbd_ls {
 154     my ($scfg, $storeid) = @_;
 155
 156     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l', '--format', 'json');
 157     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 158
 159     my $raw = '';
 160     my $parser = sub { $raw .= shift };
 161
 162     eval {
 163         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 164     };
 165     my $err = $@;
 166
 167     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 168
 169     my $result = $raw ne '' ? JSON::decode_json($raw) : [];
 170
 171     my $list = {};
 172
 173     foreach my $el (@$result) {
 174         next if defined($el->{snapshot});
 175
 176         my $image = $el->{image};
 177
 178         my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
 179         next if !defined($owner);
 180
 181         $list->{$pool}->{$image} = {
 182             name => $image,
 183             size => $el->{size},
 184             parent => $get_parent_image_name->($el->{parent}),
 185             vmid => $owner
 186         };
 187     }
 188
 189     return $list;
 190 }
 191
 192 sub rbd_volume_info {
 193     my ($scfg, $storeid, $volname, $snap) = @_;
 194
 195     my $cmd = undef;
 196
 197     my @options = ('info', $volname, '--format', 'json');
 198     if ($snap) {
 199         push @options, '--snap', $snap;
 200     }
 201
 202     $cmd = &$rbd_cmd($scfg, $storeid, @options);
 203
 204     my $raw = '';
 205     my $parser = sub { $raw .= shift };
 206
 207     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 208
 209     my $volume = $raw ne '' ? JSON::decode_json($raw) : {};
 210
 211     $volume->{parent} = $get_parent_image_name->($volume->{parent});
 212     $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
 213
 214     return $volume->@{qw(size parent format protected features)};
 215 }
 216
 217 # Configuration
 218
 219 sub type {
 220     return 'rbd';
 221 }
 222
 223 sub plugindata {
 224     return {
 225         content => [ {images => 1, rootdir => 1}, { images => 1 }],
 226     };
 227 }
 228
 229 sub properties {
 230     return {
 231         monhost => {
 232             description => "IP addresses of monitors (for external clusters).",
 233             type => 'string', format => 'pve-storage-portal-dns-list',
 234         },
 235         pool => {
 236             description => "Pool.",
 237             type => 'string',
 238         },
 239         username => {
 240             description => "RBD Id.",
 241             type => 'string',
 242         },
 243         authsupported => {
 244             description => "Authsupported.",
 245             type => 'string',
 246         },
 247         krbd => {
 248             description => "Access rbd through krbd kernel module.",
 249             type => 'boolean',
 250         },
 251     };
 252 }
 253
 254 sub options {
 255     return {
 256         nodes => { optional => 1 },
 257         disable => { optional => 1 },
 258         monhost => { optional => 1},
 259         pool => { optional => 1 },
 260         username => { optional => 1 },
 261         content => { optional => 1 },
 262         krbd => { optional => 1 },
 263         bwlimit => { optional => 1 },
 264     };
 265 }
 266
 267 # Storage implementation
 268
 269 sub on_add_hook {
 270     my ($class, $storeid, $scfg, %param) = @_;
 271
 272     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 273
 274     PVE::Storage::CephTools::ceph_create_keyfile($scfg->{type}, $storeid);
 275 }
 276
 277 sub on_delete_hook {
 278     my ($class, $storeid, $scfg) = @_;
 279
 280     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 281
 282     PVE::Storage::CephTools::ceph_remove_keyfile($scfg->{type}, $storeid);
 283 }
 284
 285 sub parse_volname {
 286     my ($class, $volname) = @_;
 287
 288     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 289         return ('images', $4, $7, $2, $3, $5, 'raw');
 290     }
 291
 292     die "unable to parse rbd volume name '$volname'\n";
 293 }
 294
 295 sub path {
 296     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 297
 298     my $cmd_option = PVE::Storage::CephTools::ceph_connect_option($scfg, $storeid);
 299     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 300     $name .= '@'.$snapname if $snapname;
 301
 302     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 303     return ("/dev/rbd/$pool/$name", $vmid, $vtype) if $scfg->{krbd};
 304
 305     my $path = "rbd:$pool/$name";
 306
 307     $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
 308     if (defined($scfg->{monhost})) {
 309         my $monhost = PVE::Storage::CephTools::hostlist($scfg->{monhost}, ';');
 310         $monhost =~ s/:/\\:/g;
 311         $path .= ":mon_host=$monhost";
 312         $path .= ":auth_supported=$cmd_option->{auth_supported}";
 313     }
 314
 315     $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
 316
 317     return ($path, $vmid, $vtype);
 318 }
 319
 320 my $find_free_diskname = sub {
 321     my ($storeid, $scfg, $vmid) = @_;
 322
 323     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls');
 324     my $disk_ids = {};
 325
 326     my $parser = sub {
 327         my $line = shift;
 328
 329         if ($line =~  m/^(vm|base)-\Q$vmid\E+-disk-(\d+)$/) {
 330             $disk_ids->{$2} = 1;
 331         }
 332     };
 333
 334     eval {
 335         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 336     };
 337     my $err = $@;
 338
 339     die $err if $err && $err !~ m/doesn't contain rbd images/;
 340
 341     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 342     for (my $i = 1; $i < 100; $i++) {
 343         if (!$disk_ids->{$i}) {
 344             return "vm-$vmid-disk-$i";
 345         }
 346     }
 347
 348     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 349 };
 350
 351 sub create_base {
 352     my ($class, $storeid, $scfg, $volname) = @_;
 353
 354     my $snap = '__base__';
 355
 356     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 357         $class->parse_volname($volname);
 358
 359     die "create_base not possible with base image\n" if $isBase;
 360
 361     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 362     die "rbd volume info on '$name' failed\n" if !($size);
 363
 364     die "rbd image must be at format V2" if $format ne "2";
 365
 366     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 367         if $basename && (!$parent || $parent ne $basename."@".$snap);
 368
 369     my $newname = $name;
 370     $newname =~ s/^vm-/base-/;
 371
 372     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 373
 374     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 375     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 376
 377     my $running  = undef; #fixme : is create_base always offline ?
 378
 379     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 380
 381     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 382
 383     if (!$protected){
 384         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 385         run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
 386     }
 387
 388     return $newvolname;
 389
 390 }
 391
 392 sub clone_image {
 393     my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
 394
 395     my $snap = '__base__';
 396     $snap = $snapname if length $snapname;
 397
 398     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 399         $class->parse_volname($volname);
 400
 401     die "$volname is not a base image and snapname is not provided\n"
 402         if !$isBase && !length($snapname);
 403
 404     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 405
 406     warn "clone $volname: $basename snapname $snap to $name\n";
 407
 408     if (length($snapname)) {
 409         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
 410
 411         if (!$protected) {
 412             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
 413             run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
 414         }
 415     }
 416
 417     my $newvol = "$basename/$name";
 418     $newvol = $name if length($snapname);
 419
 420     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename),
 421                         '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 422
 423     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 424
 425     &$krbd_feature_disable($scfg, $storeid, $name);
 426
 427     return $newvol;
 428 }
 429
 430 sub alloc_image {
 431     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 432
 433
 434     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
 435         if  $name && $name !~ m/^vm-$vmid-/;
 436
 437     $name = &$find_free_diskname($storeid, $scfg, $vmid) if !$name;
 438
 439     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 440     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 441
 442     &$krbd_feature_disable($scfg, $storeid, $name);
 443
 444     return $name;
 445 }
 446
 447 sub free_image {
 448     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 449
 450     my ($vtype, $name, $vmid, undef, undef, undef) =
 451         $class->parse_volname($volname);
 452
 453     if ($isBase) {
 454         my $snap = '__base__';
 455         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 456         if ($protected){
 457             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 458             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 459         }
 460     }
 461
 462     $class->deactivate_volume($storeid, $scfg, $volname);
 463
 464     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 465     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 466
 467     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 468     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 469
 470     return undef;
 471 }
 472
 473 sub list_images {
 474     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 475
 476     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 477     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 478
 479     my $res = [];
 480
 481     if (my $dat = $cache->{rbd}->{$pool}) {
 482         foreach my $image (keys %$dat) {
 483
 484             my $info = $dat->{$image};
 485
 486             my $volname = $info->{name};
 487             my $parent = $info->{parent};
 488             my $owner = $info->{vmid};
 489
 490             if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
 491                 $info->{volid} = "$storeid:$1/$volname";
 492             } else {
 493                 $info->{volid} = "$storeid:$volname";
 494             }
 495
 496             if ($vollist) {
 497                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 498                 next if !$found;
 499             } else {
 500                 next if defined ($vmid) && ($owner ne $vmid);
 501             }
 502
 503             $info->{format} = 'raw';
 504
 505             push @$res, $info;
 506         }
 507     }
 508
 509     return $res;
 510 }
 511
 512 sub status {
 513     my ($class, $storeid, $scfg, $cache) = @_;
 514
 515
 516     my $rados = &$librados_connect($scfg, $storeid);
 517     my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
 518
 519     my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
 520
 521     # max_avail -> max available space for data w/o replication in the pool
 522     # bytes_used -> data w/o replication in the pool
 523     my $free = $d->{stats}->{max_avail};
 524     my $used = $d->{stats}->{bytes_used};
 525     my $total = $used + $free;
 526     my $active = 1;
 527
 528     return ($total, $free, $used, $active);
 529 }
 530
 531 sub activate_storage {
 532     my ($class, $storeid, $scfg, $cache) = @_;
 533     return 1;
 534 }
 535
 536 sub deactivate_storage {
 537     my ($class, $storeid, $scfg, $cache) = @_;
 538     return 1;
 539 }
 540
 541 sub activate_volume {
 542     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 543
 544     return 1 if !$scfg->{krbd};
 545
 546     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 547     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 548
 549     my $path = "/dev/rbd/$pool/$name";
 550     $path .= '@'.$snapname if $snapname;
 551     return if -b $path;
 552
 553     $name .= '@'.$snapname if $snapname;
 554     my $cmd = &$rbd_cmd($scfg, $storeid, 'map', $name);
 555     run_rbd_command($cmd, errmsg => "can't mount rbd volume $name");
 556
 557     return 1;
 558 }
 559
 560 sub deactivate_volume {
 561     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 562
 563     return 1 if !$scfg->{krbd};
 564
 565     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 566     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 567
 568     my $path = "/dev/rbd/$pool/$name";
 569     $path .= '@'.$snapname if $snapname;
 570     return if ! -b $path;
 571
 572     my $cmd = &$rbd_cmd($scfg, $storeid, 'unmap', $path);
 573     run_rbd_command($cmd, errmsg => "can't unmap rbd volume $name");
 574
 575     return 1;
 576 }
 577
 578 sub volume_size_info {
 579     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 580
 581     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 582     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 583     return $size;
 584 }
 585
 586 sub volume_resize {
 587     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 588
 589     return 1 if $running && !$scfg->{krbd};
 590
 591     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 592
 593     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
 594     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 595     return undef;
 596 }
 597
 598 sub volume_snapshot {
 599     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 600
 601     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 602
 603     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 604     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 605     return undef;
 606 }
 607
 608 sub volume_snapshot_rollback {
 609     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 610
 611     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 612
 613     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 614     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
 615 }
 616
 617 sub volume_snapshot_delete {
 618     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 619
 620     return 1 if $running && !$scfg->{krbd};
 621
 622     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 623
 624     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 625
 626     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 627     if ($protected){
 628         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 629         run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
 630     }
 631
 632     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 633
 634     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 635
 636     return undef;
 637 }
 638
 639 sub volume_has_feature {
 640     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 641
 642    my $features = {
 643         snapshot => { current => 1, snap => 1},
 644         clone => { base => 1, snap => 1},
 645         template => { current => 1},
 646         copy => { base => 1, current => 1, snap => 1},
 647         sparseinit => { base => 1, current => 1},
 648     };
 649
 650     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 651         $class->parse_volname($volname);
 652
 653     my $key = undef;
 654     if($snapname){
 655         $key = 'snap';
 656     }else{
 657         $key =  $isBase ? 'base' : 'current';
 658     }
 659     return 1 if $features->{$feature}->{$key};
 660
 661     return undef;
 662 }
 663
 664 1;