PVE/Storage/RBDPlugin.pm

   1 package PVE::Storage::RBDPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use PVE::Tools qw(run_command trim);
   7 use PVE::Storage::Plugin;
   8 use PVE::JSONSchema qw(get_standard_option);
   9
  10 use base qw(PVE::Storage::Plugin);
  11
  12 sub rbd_unittobytes {
  13   {
  14        "M"  => 1024*1024,
  15        "G"  => 1024*1024*1024,
  16        "T"  => 1024*1024*1024*1024,
  17   }
  18 }
  19
  20 my $add_pool_to_disk = sub {
  21     my ($scfg, $disk) = @_;
  22
  23     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  24
  25     return "$pool/$disk";
  26 };
  27
  28 my $rbd_cmd = sub {
  29     my ($scfg, $storeid, $op, @options) = @_;
  30
  31     my $monhost = $scfg->{monhost};
  32     $monhost =~ s/;/,/g;
  33
  34     my $keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
  35     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  36     my $username =  $scfg->{username} ? $scfg->{username} : 'admin';
  37
  38     my $cmd = ['/usr/bin/rbd', '-p', $pool, '-m', $monhost];
  39
  40     if(-e $keyring){
  41         push @$cmd, '-n', "client.$username";
  42         push @$cmd, '--keyring', $keyring;
  43         push @$cmd, '--auth_supported', 'cephx';
  44     }else{
  45         push @$cmd, '--auth_supported', 'none';
  46     }
  47
  48     push @$cmd, $op;
  49
  50     push @$cmd, @options if scalar(@options);
  51
  52     return $cmd;
  53 };
  54
  55 my $rados_cmd = sub {
  56     my ($scfg, $storeid, $op, @options) = @_;
  57
  58     my $monhost = $scfg->{monhost};
  59     $monhost =~ s/;/,/g;
  60
  61     my $keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
  62     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
  63     my $username =  $scfg->{username} ? $scfg->{username} : 'admin';
  64
  65     my $cmd = ['/usr/bin/rados', '-p', $pool, '-m', $monhost];
  66
  67     if(-e $keyring){
  68         push @$cmd, '-n', "client.$username";
  69         push @$cmd, '--keyring', $keyring;
  70         push @$cmd, '--auth_supported', 'cephx';
  71     }else{
  72         push @$cmd, '--auth_supported', 'none';
  73     }
  74
  75     push @$cmd, $op;
  76
  77     push @$cmd, @options if scalar(@options);
  78
  79     return $cmd;
  80 };
  81
  82 sub run_rbd_command {
  83     my ($cmd, %args) = @_;
  84
  85     my $lasterr;
  86     my $errmsg = $args{errmsg} . ": " || "";
  87     if (!exists($args{errfunc})) {
  88         # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
  89         # at least 1 child(ren) in pool cephstor1
  90         $args{errfunc} = sub {
  91             my $line = shift;
  92             if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
  93                 $lasterr = "$1\n";
  94             } else {
  95                 $lasterr = $line;
  96             }
  97             print STDERR $lasterr;
  98             *STDERR->flush();
  99         };
 100     }
 101
 102     eval { run_command($cmd, %args); };
 103     if (my $err = $@) {
 104         die $errmsg . $lasterr if length($lasterr);
 105         die $err;
 106     }
 107
 108     return undef;
 109 }
 110
 111 sub rbd_ls {
 112     my ($scfg, $storeid) = @_;
 113
 114     my $cmd = &$rbd_cmd($scfg, $storeid, 'ls', '-l');
 115     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 116
 117     my $list = {};
 118
 119     my $parser = sub {
 120         my $line = shift;
 121
 122         if ($line =~  m/^((vm|base)-(\d+)-disk-\d+)\s+(\d+)(M|G|T)\s((\S+)\/((vm|base)-\d+-\S+@\S+))?/) {
 123             my ($image, $owner, $size, $unit, $parent) = ($1, $3, $4, $5, $8);
 124
 125             $list->{$pool}->{$image} = {
 126                 name => $image,
 127                 size => $size*rbd_unittobytes()->{$unit},
 128                 parent => $parent,
 129                 vmid => $owner
 130             };
 131         }
 132     };
 133
 134     eval {
 135         run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 136     };
 137     my $err = $@;
 138
 139     die $err if $err && $err !~ m/doesn't contain rbd images/ ;
 140
 141     return $list;
 142 }
 143
 144 sub rbd_volume_info {
 145     my ($scfg, $storeid, $volname, $snap) = @_;
 146
 147     my $cmd = undef;
 148
 149     if($snap){
 150        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname, '--snap', $snap);
 151     }else{
 152        $cmd = &$rbd_cmd($scfg, $storeid, 'info', $volname);
 153     }
 154
 155     my $size = undef;
 156     my $parent = undef;
 157     my $format = undef;
 158     my $protected = undef;
 159
 160     my $parser = sub {
 161         my $line = shift;
 162
 163         if ($line =~ m/size (\d+) (M|G|T)B in (\d+) objects/) {
 164             $size = $1 * rbd_unittobytes()->{$2} if ($1);
 165         } elsif ($line =~ m/parent:\s(\S+)\/(\S+)/) {
 166             $parent = $2;
 167         } elsif ($line =~ m/format:\s(\d+)/) {
 168             $format = $1;
 169         } elsif ($line =~ m/protected:\s(\S+)/) {
 170             $protected = 1 if $1 eq "True";
 171         }
 172
 173     };
 174
 175     run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
 176
 177     return ($size, $parent, $format, $protected);
 178 }
 179
 180 sub addslashes {
 181     my $text = shift;
 182     $text =~ s/;/\\;/g;
 183     $text =~ s/:/\\:/g;
 184     return $text;
 185 }
 186
 187 # Configuration
 188
 189 PVE::JSONSchema::register_format('pve-storage-monhost', \&parse_monhost);
 190 sub parse_monhost {
 191     my ($name, $noerr) = @_;
 192
 193     if ($name !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 194         return undef if $noerr;
 195         die "lvm name '$name' contains illegal characters\n";
 196     }
 197
 198     return $name;
 199 }
 200
 201 sub type {
 202     return 'rbd';
 203 }
 204
 205 sub plugindata {
 206     return {
 207         content => [ {images => 1}, { images => 1 }],
 208     };
 209 }
 210
 211 sub properties {
 212     return {
 213         monhost => {
 214             description => "Monitors daemon ips.",
 215             type => 'string',
 216         },
 217         pool => {
 218             description => "Pool.",
 219             type => 'string',
 220         },
 221         username => {
 222             description => "RBD Id.",
 223             type => 'string',
 224         },
 225         authsupported => {
 226             description => "Authsupported.",
 227             type => 'string',
 228         },
 229     };
 230 }
 231
 232 sub options {
 233     return {
 234         nodes => { optional => 1 },
 235         disable => { optional => 1 },
 236         monhost => { fixed => 1 },
 237         pool => { optional => 1 },
 238         username => { optional => 1 },
 239         content => { optional => 1 },
 240     };
 241 }
 242
 243 # Storage implementation
 244
 245 sub parse_volname {
 246     my ($class, $volname) = @_;
 247
 248     if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
 249         return ('images', $4, $7, $2, $3, $5);
 250     }
 251
 252     die "unable to parse rbd volume name '$volname'\n";
 253 }
 254
 255 sub path {
 256     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 257
 258     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 259     $name .= '@'.$snapname if $snapname;
 260
 261     my $monhost = addslashes($scfg->{monhost});
 262     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 263     my $username =  $scfg->{username} ? $scfg->{username} : 'admin';
 264
 265     my $path = "rbd:$pool/$name:mon_host=$monhost";
 266     my $keyring = "/etc/pve/priv/ceph/${storeid}.keyring";
 267
 268     if(-e $keyring ){
 269         $path .= ":id=$username:auth_supported=cephx:keyring=$keyring";
 270     }else{
 271         $path .= ":auth_supported=none";
 272     }
 273
 274     return ($path, $vmid, $vtype);
 275 }
 276
 277 my $find_free_diskname = sub {
 278     my ($storeid, $scfg, $vmid) = @_;
 279
 280     my $rbd = rbd_ls($scfg, $storeid);
 281     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 282     my $disk_ids = {};
 283     my $dat = $rbd->{$pool};
 284
 285     foreach my $image (keys %$dat) {
 286         my $volname = $dat->{$image}->{name};
 287         if ($volname =~ m/(vm|base)-$vmid-disk-(\d+)/){
 288             $disk_ids->{$2} = 1;
 289         }
 290     }
 291     #fix: can we search in $rbd hash key with a regex to find (vm|base) ?
 292     for (my $i = 1; $i < 100; $i++) {
 293         if (!$disk_ids->{$i}) {
 294             return "vm-$vmid-disk-$i";
 295         }
 296     }
 297
 298     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 299 };
 300
 301 sub create_base {
 302     my ($class, $storeid, $scfg, $volname) = @_;
 303
 304     my $snap = '__base__';
 305
 306     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 307         $class->parse_volname($volname);
 308
 309     die "create_base not possible with base image\n" if $isBase;
 310
 311     my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
 312     die "rbd volume info on '$name' failed\n" if !($size);
 313
 314     die "rbd image must be at format V2" if $format ne "2";
 315
 316     die "volname '$volname' contains wrong information about parent $parent $basename\n"
 317         if $basename && (!$parent || $parent ne $basename."@".$snap);
 318
 319     my $newname = $name;
 320     $newname =~ s/^vm-/base-/;
 321
 322     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 323
 324     my $cmd = &$rbd_cmd($scfg, $storeid, 'rename', &$add_pool_to_disk($scfg, $name), &$add_pool_to_disk($scfg, $newname));
 325     run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
 326
 327     my $running  = undef; #fixme : is create_base always offline ?
 328
 329     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 330
 331     my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
 332
 333     if (!$protected){
 334         my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
 335         run_rbd_command($cmd, errmsg => "rbd protect $newname snap $snap' error");
 336     }
 337
 338     return $newvolname;
 339
 340 }
 341
 342 sub clone_image {
 343     my ($class, $scfg, $storeid, $volname, $vmid) = @_;
 344
 345     my $snap = '__base__';
 346
 347     my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
 348         $class->parse_volname($volname);
 349
 350     die "clone_image onyl works on base images\n" if !$isBase;
 351
 352     my $name = &$find_free_diskname($storeid, $scfg, $vmid);
 353
 354     warn "clone $volname: $basename to $name\n";
 355
 356     my $newvol = "$basename/$name";
 357
 358     my $cmd = &$rbd_cmd($scfg, $storeid, 'clone', &$add_pool_to_disk($scfg, $basename), '--snap', $snap, &$add_pool_to_disk($scfg, $name));
 359     run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
 360
 361     return $newvol;
 362 }
 363
 364 sub alloc_image {
 365     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 366
 367
 368     die "illegal name '$name' - sould be 'vm-$vmid-*'\n"
 369         if  $name && $name !~ m/^vm-$vmid-/;
 370
 371     $name = &$find_free_diskname($storeid, $scfg, $vmid);
 372
 373     my $cmd = &$rbd_cmd($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
 374     run_rbd_command($cmd, errmsg => "rbd create $name' error");
 375
 376     return $name;
 377 }
 378
 379 sub free_image {
 380     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 381
 382     my ($vtype, $name, $vmid, undef, undef, undef) =
 383         $class->parse_volname($volname);
 384
 385     if ($isBase) {
 386         my $snap = '__base__';
 387         my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
 388         if ($protected){
 389             my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
 390             run_rbd_command($cmd, errmsg => "rbd unprotect $name snap $snap' error");
 391         }
 392     }
 393
 394     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'purge',  $name);
 395     run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
 396
 397     $cmd = &$rbd_cmd($scfg, $storeid, 'rm', $name);
 398     run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
 399
 400     return undef;
 401 }
 402
 403 sub list_images {
 404     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 405
 406     $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
 407     my $pool =  $scfg->{pool} ? $scfg->{pool} : 'rbd';
 408
 409     my $res = [];
 410
 411     if (my $dat = $cache->{rbd}->{$pool}) {
 412         foreach my $image (keys %$dat) {
 413
 414             my $volname = $dat->{$image}->{name};
 415
 416             my $volid = "$storeid:$volname";
 417
 418             my $owner = $dat->{$volname}->{vmid};
 419             if ($vollist) {
 420                 my $found = grep { $_ eq $volid } @$vollist;
 421                 next if !$found;
 422             } else {
 423                 next if defined ($vmid) && ($owner ne $vmid);
 424             }
 425
 426             my $info = $dat->{$volname};
 427             $info->{volid} = $volid;
 428             $info->{format} = 'raw';
 429
 430             push @$res, $info;
 431         }
 432     }
 433
 434     return $res;
 435 }
 436
 437 sub status {
 438     my ($class, $storeid, $scfg, $cache) = @_;
 439
 440     my $cmd = &$rados_cmd($scfg, $storeid, 'df');
 441
 442     my $stats = {};
 443
 444     my $parser = sub {
 445         my $line = shift;
 446         if ($line =~ m/^\s+total\s(\S+)\s+(\d+)/) {
 447             $stats->{$1} = $2;
 448         }
 449     };
 450
 451     eval {
 452         run_rbd_command($cmd, errmsg => "rados error", errfunc => sub {}, outfunc => $parser);
 453     };
 454
 455     my $total = $stats->{space} ? $stats->{space}*1024 : 0;
 456     my $free = $stats->{avail} ? $stats->{avail}*1024 : 0;
 457     my $used = $stats->{used} ? $stats->{used}*1024: 0;
 458     my $active = 1;
 459
 460     return ($total, $free, $used, $active);
 461 }
 462
 463 sub activate_storage {
 464     my ($class, $storeid, $scfg, $cache) = @_;
 465     return 1;
 466 }
 467
 468 sub deactivate_storage {
 469     my ($class, $storeid, $scfg, $cache) = @_;
 470     return 1;
 471 }
 472
 473 sub activate_volume {
 474     my ($class, $storeid, $scfg, $volname, $exclusive, $cache) = @_;
 475     return 1;
 476 }
 477
 478 sub deactivate_volume {
 479     my ($class, $storeid, $scfg, $volname, $exclusive, $cache) = @_;
 480     return 1;
 481 }
 482
 483 sub volume_size_info {
 484     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 485
 486     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 487     my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
 488     return $size;
 489 }
 490
 491 sub volume_resize {
 492     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 493
 494     return 1 if $running;
 495
 496     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 497
 498     my $cmd = &$rbd_cmd($scfg, $storeid, 'resize', '--size', ($size/1024/1024), $name);
 499     run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
 500     return undef;
 501 }
 502
 503 sub volume_snapshot {
 504     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 505
 506     return 1 if $running;
 507
 508     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 509
 510     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
 511     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 512     return undef;
 513 }
 514
 515 sub volume_snapshot_rollback {
 516     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 517
 518     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 519
 520     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
 521     run_rbd_command($cmd, errmsg => "rbd snapshot $volname to $snap' error");
 522 }
 523
 524 sub volume_snapshot_delete {
 525     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 526
 527     return 1 if $running;
 528
 529     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 530
 531     my $cmd = &$rbd_cmd($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
 532
 533     run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
 534
 535     return undef;
 536 }
 537
 538 sub volume_has_feature {
 539     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 540
 541    my $features = {
 542         snapshot => { current => 1, snap => 1},
 543         clone => { base => 1},
 544         template => { current => 1},
 545         copy => { base => 1, current => 1, snap => 1},
 546     };
 547
 548     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 549         $class->parse_volname($volname);
 550
 551     my $key = undef;
 552     if($snapname){
 553         $key = 'snap';
 554     }else{
 555         $key =  $isBase ? 'base' : 'current';
 556     }
 557     return 1 if $features->{$feature}->{$key};
 558
 559     return undef;
 560 }
 561
 562 1;