PVE/Storage/ZFSPoolPlugin.pm

   1 package PVE::Storage::ZFSPoolPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use POSIX;
   7 use PVE::Tools qw(run_command);
   8 use PVE::Storage::Plugin;
   9
  10
  11 use base qw(PVE::Storage::Plugin);
  12
  13 sub type {
  14     return 'zfspool';
  15 }
  16
  17 sub plugindata {
  18     return {
  19         content => [ {images => 1, rootdir => 1}, {images => 1 , rootdir => 1}],
  20         format => [ { raw => 1, subvol => 1 } , 'raw' ],
  21     };
  22 }
  23
  24 sub properties {
  25     return {
  26         blocksize => {
  27             description => "block size",
  28             type => 'string',
  29         },
  30         sparse => {
  31             description => "use sparse volumes",
  32             type => 'boolean',
  33         },
  34     };
  35 }
  36
  37 sub options {
  38     return {
  39         pool => { fixed => 1 },
  40         blocksize => { optional => 1 },
  41         sparse => { optional => 1 },
  42         nodes => { optional => 1 },
  43         disable => { optional => 1 },
  44         content => { optional => 1 },
  45     };
  46 }
  47
  48 # static zfs helper methods
  49
  50 sub zfs_parse_size {
  51     my ($text) = @_;
  52
  53     return 0 if !$text;
  54
  55     if ($text =~ m/^(\d+(\.\d+)?)([TGMK])?$/) {
  56
  57         my ($size, $reminder, $unit) = ($1, $2, $3);
  58
  59         if ($unit) {
  60             if ($unit eq 'K') {
  61                 $size *= 1024;
  62             } elsif ($unit eq 'M') {
  63                 $size *= 1024*1024;
  64             } elsif ($unit eq 'G') {
  65                 $size *= 1024*1024*1024;
  66             } elsif ($unit eq 'T') {
  67                 $size *= 1024*1024*1024*1024;
  68             } else {
  69                 die "got unknown zfs size unit '$unit'\n";
  70             }
  71         }
  72
  73         if ($reminder) {
  74             $size = ceil($size);
  75         }
  76
  77         return $size;
  78
  79     }
  80
  81     warn "unable to parse zfs size '$text'\n";
  82
  83     return 0;
  84 }
  85
  86 sub zfs_parse_zvol_list {
  87     my ($text) = @_;
  88
  89     my $list = ();
  90
  91     return $list if !$text;
  92
  93     my @lines = split /\n/, $text;
  94     foreach my $line (@lines) {
  95         my ($dataset, $size, $origin, $type, $refquota) = split(/\s+/, $line);
  96         next if !($type eq 'volume' || $type eq 'filesystem');
  97
  98         my $zvol = {};
  99         my @parts = split /\//, $dataset;
 100         next if scalar(@parts) < 2; # we need pool/name
 101         my $name = pop @parts;
 102         my $pool = join('/', @parts);
 103
 104         next unless $name =~ m!^(vm|base|subvol)-(\d+)-(\S+)$!;
 105         $zvol->{owner} = $2;
 106
 107         $zvol->{pool} = $pool;
 108         $zvol->{name} = $name;
 109         if ($type eq 'filesystem') {
 110             if ($refquota eq 'none') {
 111                 $zvol->{size} = 0;
 112             } else {
 113                 $zvol->{size} = zfs_parse_size($refquota);
 114             }
 115             $zvol->{format} = 'subvol';
 116         } else {
 117             $zvol->{size} = zfs_parse_size($size);
 118             $zvol->{format} = 'raw';
 119         }
 120         if ($origin !~ /^-$/) {
 121             $zvol->{origin} = $origin;
 122         }
 123         push @$list, $zvol;
 124     }
 125
 126     return $list;
 127 }
 128
 129 sub parse_volname {
 130     my ($class, $volname) = @_;
 131
 132     if ($volname =~ m/^(((base|vm)-(\d+)-\S+)\/)?((base)?(vm|subvol)?-(\d+)-\S+)$/) {
 133         my $format = $7 && $7 eq 'subvol' ? 'subvol' : 'raw';
 134         return ('images', $5, $8, $2, $4, $6, $format);
 135     }
 136
 137     die "unable to parse zfs volume name '$volname'\n";
 138 }
 139
 140 # virtual zfs methods (subclass can overwrite them)
 141
 142 sub path {
 143     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 144
 145     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 146
 147     my $path = '';
 148
 149     if ($vtype eq "images") {
 150         if ($volname =~ m/^subvol-/) {
 151             # fixme: we currently assume standard mount point?!
 152             $path = "/$scfg->{pool}/$volname";
 153         } else {
 154             $path = "/dev/zvol/$scfg->{pool}/$volname";
 155         }
 156         $path .= "\@$snapname" if defined($snapname);
 157     } else {
 158         die "$vtype is not allowed in ZFSPool!";
 159     }
 160
 161     return ($path, $vmid, $vtype);
 162 }
 163
 164 sub zfs_request {
 165     my ($class, $scfg, $timeout, $method, @params) = @_;
 166
 167     $timeout = 5 if !$timeout;
 168
 169     my $cmd = [];
 170
 171     if ($method eq 'zpool_list') {
 172         push @$cmd, 'zpool', 'list';
 173     } else {
 174         push @$cmd, 'zfs', $method;
 175     }
 176
 177     push @$cmd, @params;
 178
 179     my $msg = '';
 180
 181     my $output = sub {
 182         my $line = shift;
 183         $msg .= "$line\n";
 184     };
 185
 186     run_command($cmd, errmsg => "zfs error", outfunc => $output, timeout => $timeout);
 187
 188     return $msg;
 189 }
 190
 191 sub alloc_image {
 192     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 193
 194     my $volname = $name;
 195
 196     if ($fmt eq 'raw') {
 197
 198         die "illegal name '$volname' - sould be 'vm-$vmid-*'\n"
 199             if $volname && $volname !~ m/^vm-$vmid-/;
 200         $volname = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $fmt)
 201             if !$volname;
 202
 203         $class->zfs_create_zvol($scfg, $volname, $size);
 204         my $devname = "/dev/zvol/$scfg->{pool}/$volname";
 205
 206         run_command("udevadm trigger --subsystem-match block");
 207         system("udevadm settle --timeout 10 --exit-if-exists=${devname}");
 208
 209     } elsif ( $fmt eq 'subvol') {
 210
 211         die "illegal name '$volname' - sould be 'subvol-$vmid-*'\n"
 212             if $volname && $volname !~ m/^subvol-$vmid-/;
 213         $volname = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $fmt)
 214             if !$volname;
 215
 216         die "illegal name '$volname' - sould be 'subvol-$vmid-*'\n"
 217             if $volname !~ m/^subvol-$vmid-/;
 218
 219         $class->zfs_create_subvol($scfg, $volname, $size);
 220
 221     } else {
 222         die "unsupported format '$fmt'";
 223     }
 224
 225     return $volname;
 226 }
 227
 228 sub free_image {
 229     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 230
 231     my (undef, $name, undef) = $class->parse_volname($volname);
 232
 233     $class->zfs_delete_zvol($scfg, $name);
 234
 235     return undef;
 236 }
 237
 238 sub list_images {
 239     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 240
 241     $cache->{zfs} = $class->zfs_list_zvol($scfg) if !$cache->{zfs};
 242     my $zfspool = $scfg->{pool};
 243     my $res = [];
 244
 245     if (my $dat = $cache->{zfs}->{$zfspool}) {
 246
 247         foreach my $image (keys %$dat) {
 248
 249             my $volname = $dat->{$image}->{name};
 250             my $parent = $dat->{$image}->{parent};
 251
 252             my $volid = undef;
 253             if ($parent && $parent =~ m/^(\S+)@(\S+)$/) {
 254                 my ($basename) = ($1);
 255                 $volid = "$storeid:$basename/$volname";
 256             } else {
 257                 $volid = "$storeid:$volname";
 258             }
 259
 260             my $owner = $dat->{$volname}->{vmid};
 261             if ($vollist) {
 262                 my $found = grep { $_ eq $volid } @$vollist;
 263                 next if !$found;
 264             } else {
 265                 next if defined ($vmid) && ($owner ne $vmid);
 266             }
 267
 268             my $info = $dat->{$volname};
 269             $info->{volid} = $volid;
 270             push @$res, $info;
 271         }
 272     }
 273     return $res;
 274 }
 275
 276 sub zfs_get_pool_stats {
 277     my ($class, $scfg) = @_;
 278
 279     my $available = 0;
 280     my $used = 0;
 281
 282     my $text = $class->zfs_request($scfg, undef, 'get', '-o', 'value', '-Hp',
 283                'available,used', $scfg->{pool});
 284
 285     my @lines = split /\n/, $text;
 286
 287     if($lines[0] =~ /^(\d+)$/) {
 288         $available = $1;
 289     }
 290
 291     if($lines[1] =~ /^(\d+)$/) {
 292         $used = $1;
 293     }
 294
 295     return ($available, $used);
 296 }
 297
 298 sub zfs_create_zvol {
 299     my ($class, $scfg, $zvol, $size) = @_;
 300
 301     my $cmd = ['create'];
 302
 303     push @$cmd, '-s' if $scfg->{sparse};
 304
 305     push @$cmd, '-b', $scfg->{blocksize} if $scfg->{blocksize};
 306
 307     push @$cmd, '-V', "${size}k", "$scfg->{pool}/$zvol";
 308
 309     $class->zfs_request($scfg, undef, @$cmd);
 310 }
 311
 312 sub zfs_create_subvol {
 313     my ($class, $scfg, $volname, $size) = @_;
 314
 315     my $dataset = "$scfg->{pool}/$volname";
 316
 317     my $cmd = ['create', '-o', 'acltype=posixacl', '-o', 'xattr=sa',
 318                '-o', "refquota=${size}k", $dataset];
 319
 320     $class->zfs_request($scfg, undef, @$cmd);
 321 }
 322
 323 sub zfs_delete_zvol {
 324     my ($class, $scfg, $zvol) = @_;
 325
 326     my $err;
 327
 328     for (my $i = 0; $i < 6; $i++) {
 329
 330         eval { $class->zfs_request($scfg, undef, 'destroy', '-r', "$scfg->{pool}/$zvol"); };
 331         if ($err = $@) {
 332             if ($err =~ m/^zfs error:(.*): dataset is busy.*/) {
 333                 sleep(1);
 334             } elsif ($err =~ m/^zfs error:.*: dataset does not exist.*$/) {
 335                 $err = undef;
 336                 last;
 337             } else {
 338                 die $err;
 339             }
 340         } else {
 341             last;
 342         }
 343     }
 344
 345     die $err if $err;
 346 }
 347
 348 sub zfs_list_zvol {
 349     my ($class, $scfg) = @_;
 350
 351     my $text = $class->zfs_request($scfg, 10, 'list', '-o', 'name,volsize,origin,type,refquota', '-t', 'volume,filesystem', '-Hr');
 352     my $zvols = zfs_parse_zvol_list($text);
 353     return undef if !$zvols;
 354
 355     my $list = ();
 356     foreach my $zvol (@$zvols) {
 357         my $pool = $zvol->{pool};
 358         my $name = $zvol->{name};
 359         my $parent = $zvol->{origin};
 360         if($zvol->{origin} && $zvol->{origin} =~ m/^$scfg->{pool}\/(\S+)$/){
 361             $parent = $1;
 362         }
 363
 364         $list->{$pool}->{$name} = {
 365             name => $name,
 366             size => $zvol->{size},
 367             parent => $parent,
 368             format => $zvol->{format},
 369             vmid => $zvol->{owner},
 370         };
 371     }
 372
 373     return $list;
 374 }
 375
 376 sub zfs_find_free_diskname {
 377     my ($class, $storeid, $scfg, $vmid, $format) = @_;
 378
 379     my $name = undef;
 380     my $volumes = $class->zfs_list_zvol($scfg);
 381
 382     my $disk_ids = {};
 383     my $dat = $volumes->{$scfg->{pool}};
 384
 385     foreach my $image (keys %$dat) {
 386         my $volname = $dat->{$image}->{name};
 387         if ($volname =~ m/(vm|base|subvol)-$vmid-disk-(\d+)/){
 388             $disk_ids->{$2} = 1;
 389         }
 390     }
 391
 392     for (my $i = 1; $i < 100; $i++) {
 393         if (!$disk_ids->{$i}) {
 394             return $format eq 'subvol' ? "subvol-$vmid-disk-$i" : "vm-$vmid-disk-$i";
 395         }
 396     }
 397
 398     die "unable to allocate an image name for VM $vmid in storage '$storeid'\n";
 399 }
 400
 401 sub zfs_get_latest_snapshot {
 402     my ($class, $scfg, $volname) = @_;
 403
 404     # abort rollback if snapshot is not the latest
 405     my @params = ('-t', 'snapshot', '-o', 'name', '-s', 'creation');
 406     my $text = $class->zfs_request($scfg, undef, 'list', @params);
 407     my @snapshots = split(/\n/, $text);
 408
 409     my $recentsnap;
 410     foreach (@snapshots) {
 411         if (/$scfg->{pool}\/$volname/) {
 412             s/^.*@//;
 413             $recentsnap = $_;
 414         }
 415     }
 416
 417     return $recentsnap;
 418 }
 419
 420 sub status {
 421     my ($class, $storeid, $scfg, $cache) = @_;
 422
 423     my $total = 0;
 424     my $free = 0;
 425     my $used = 0;
 426     my $active = 0;
 427
 428     eval {
 429         ($free, $used) = $class->zfs_get_pool_stats($scfg);
 430         $active = 1;
 431         $total = $free + $used;
 432     };
 433     warn $@ if $@;
 434
 435     return ($total, $free, $used, $active);
 436 }
 437
 438 sub volume_size_info {
 439     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 440
 441     my (undef, undef, undef, undef, undef, undef, $format) =
 442         $class->parse_volname($volname);
 443
 444     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 445     my $text = $class->zfs_request($scfg, undef, 'get', '-Hp', $attr, "$scfg->{pool}/$volname");
 446
 447     if ($text =~ /\s$attr\s(\d+)\s/) {
 448         return $1;
 449     }
 450
 451     die "Could not get zfs volume size\n";
 452 }
 453
 454 sub volume_snapshot {
 455     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 456
 457     $class->zfs_request($scfg, undef, 'snapshot', "$scfg->{pool}/$volname\@$snap");
 458 }
 459
 460 sub volume_snapshot_delete {
 461     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 462
 463     $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
 464     $class->zfs_request($scfg, undef, 'destroy', "$scfg->{pool}/$volname\@$snap");
 465 }
 466
 467 sub volume_snapshot_rollback {
 468     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 469
 470     $class->zfs_request($scfg, undef, 'rollback', "$scfg->{pool}/$volname\@$snap");
 471 }
 472
 473 sub volume_rollback_is_possible {
 474     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 475
 476     my $recentsnap = $class->zfs_get_latest_snapshot($scfg, $volname);
 477     if ($snap ne $recentsnap) {
 478         die "can't rollback, more recent snapshots exist\n";
 479     }
 480
 481     return 1;
 482 }
 483
 484 sub activate_storage {
 485     my ($class, $storeid, $scfg, $cache) = @_;
 486
 487     my @param = ('-o', 'name', '-H');
 488
 489     my $text = $class->zfs_request($scfg, undef, 'zpool_list', @param);
 490
 491     # Note: $scfg->{pool} can include dataset <pool>/<dataset>
 492     my $pool = $scfg->{pool};
 493     $pool =~ s!/.*$!!;
 494
 495     if ($text !~ $pool) {
 496         run_command("zpool import -d /dev/disk/by-id/ -a");
 497     }
 498     return 1;
 499 }
 500
 501 sub deactivate_storage {
 502     my ($class, $storeid, $scfg, $cache) = @_;
 503     return 1;
 504 }
 505
 506 sub activate_volume {
 507     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 508     return 1;
 509 }
 510
 511 sub deactivate_volume {
 512     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 513     return 1;
 514 }
 515
 516 sub clone_image {
 517     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 518
 519     $snap ||= '__base__';
 520
 521     my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) =
 522         $class->parse_volname($volname);
 523
 524     die "clone_image only works on base images\n" if !$isBase;
 525
 526     my $name = $class->zfs_find_free_diskname($storeid, $scfg, $vmid, $format);
 527
 528     $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name");
 529
 530     return $name;
 531 }
 532
 533 sub create_base {
 534     my ($class, $storeid, $scfg, $volname) = @_;
 535
 536     my $snap = '__base__';
 537
 538     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 539         $class->parse_volname($volname);
 540
 541     die "create_base not possible with base image\n" if $isBase;
 542
 543     my $newname = $name;
 544     $newname =~ s/^vm-/base-/;
 545
 546     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 547
 548     $class->zfs_request($scfg, undef, 'rename', "$scfg->{pool}/$name", "$scfg->{pool}/$newname");
 549
 550     my $running  = undef; #fixme : is create_base always offline ?
 551
 552     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 553
 554     return $newvolname;
 555 }
 556
 557 sub volume_resize {
 558     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 559
 560     my $new_size = int($size/1024);
 561
 562     my (undef, undef, undef, undef, undef, undef, $format) =
 563         $class->parse_volname($volname);
 564
 565     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 566
 567     $class->zfs_request($scfg, undef, 'set', "$attr=${new_size}k", "$scfg->{pool}/$volname");
 568
 569     return $new_size;
 570 }
 571
 572 sub volume_has_feature {
 573     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 574
 575     my $features = {
 576         snapshot => { current => 1, snap => 1},
 577         clone => { base => 1},
 578         template => { current => 1},
 579         copy => { base => 1, current => 1},
 580         sparseinit => { base => 1, current => 1},
 581     };
 582
 583     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 584         $class->parse_volname($volname);
 585
 586     my $key = undef;
 587
 588     if ($snapname) {
 589         $key = 'snap';
 590     } else {
 591         $key = $isBase ? 'base' : 'current';
 592     }
 593
 594     return 1 if $features->{$feature}->{$key};
 595
 596     return undef;
 597 }
 598
 599 1;