PVE/Storage/ZFSPoolPlugin.pm

   1 package PVE::Storage::ZFSPoolPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Net::IP;
   8 use POSIX;
   9
  10 use PVE::ProcFSTools;
  11 use PVE::RPCEnvironment;
  12 use PVE::Storage::Plugin;
  13 use PVE::Tools qw(run_command);
  14
  15 use base qw(PVE::Storage::Plugin);
  16
  17 sub type {
  18     return 'zfspool';
  19 }
  20
  21 sub plugindata {
  22     return {
  23         content => [ {images => 1, rootdir => 1}, {images => 1 , rootdir => 1}],
  24         format => [ { raw => 1, subvol => 1 } , 'raw' ],
  25     };
  26 }
  27
  28 sub properties {
  29     return {
  30         blocksize => {
  31             description => "block size",
  32             type => 'string',
  33         },
  34         sparse => {
  35             description => "use sparse volumes",
  36             type => 'boolean',
  37         },
  38         mountpoint => {
  39             description => "mount point",
  40             type => 'string', format => 'pve-storage-path',
  41         },
  42     };
  43 }
  44
  45 sub options {
  46     return {
  47         pool => { fixed => 1 },
  48         blocksize => { optional => 1 },
  49         sparse => { optional => 1 },
  50         nodes => { optional => 1 },
  51         disable => { optional => 1 },
  52         content => { optional => 1 },
  53         bwlimit => { optional => 1 },
  54         mountpoint => { optional => 1 },
  55     };
  56 }
  57
  58 # static zfs helper methods
  59
  60 sub zfs_parse_zvol_list {
  61     my ($text) = @_;
  62
  63     my $list = ();
  64
  65     return $list if !$text;
  66
  67     my @lines = split /\n/, $text;
  68     foreach my $line (@lines) {
  69         my ($dataset, $size, $origin, $type, $refquota) = split(/\s+/, $line);
  70         next if !($type eq 'volume' || $type eq 'filesystem');
  71
  72         my $zvol = {};
  73         my @parts = split /\//, $dataset;
  74         next if scalar(@parts) < 2; # we need pool/name
  75         my $name = pop @parts;
  76         my $pool = join('/', @parts);
  77
  78         next unless $name =~ m!^(vm|base|subvol|basevol)-(\d+)-(\S+)$!;
  79         $zvol->{owner} = $2;
  80
  81         $zvol->{pool} = $pool;
  82         $zvol->{name} = $name;
  83         if ($type eq 'filesystem') {
  84             if ($refquota eq 'none') {
  85                 $zvol->{size} = 0;
  86             } else {
  87                 $zvol->{size} = $refquota + 0;
  88             }
  89             $zvol->{format} = 'subvol';
  90         } else {
  91             $zvol->{size} = $size + 0;
  92             $zvol->{format} = 'raw';
  93         }
  94         if ($origin !~ /^-$/) {
  95             $zvol->{origin} = $origin;
  96         }
  97         push @$list, $zvol;
  98     }
  99
 100     return $list;
 101 }
 102
 103 sub parse_volname {
 104     my ($class, $volname) = @_;
 105
 106     if ($volname =~ m/^(((base|basevol)-(\d+)-\S+)\/)?((base|basevol|vm|subvol)-(\d+)-\S+)$/) {
 107         my $format = ($6 eq 'subvol' || $6 eq 'basevol') ? 'subvol' : 'raw';
 108         my $isBase = ($6 eq 'base' || $6 eq 'basevol');
 109         return ('images', $5, $7, $2, $4, $isBase, $format);
 110     }
 111
 112     die "unable to parse zfs volume name '$volname'\n";
 113 }
 114
 115 # virtual zfs methods (subclass can overwrite them)
 116
 117 sub on_add_hook {
 118     my ($class, $storeid, $scfg, %param) = @_;
 119
 120     my $cfg_mountpoint = $scfg->{mountpoint};
 121
 122     # ignore failure, pool might currently not be imported
 123     my $mountpoint;
 124     eval {
 125         my $res = $class->zfs_get_properties($scfg, 'mountpoint', $scfg->{pool}, 1);
 126         $mountpoint = PVE::Storage::Plugin::verify_path($res, 1) if defined($res);
 127     };
 128
 129     if (defined($cfg_mountpoint)) {
 130         if (defined($mountpoint) && !($cfg_mountpoint =~ m|^\Q$mountpoint\E/?$|)) {
 131             warn "warning for $storeid - mountpoint: $cfg_mountpoint " .
 132                  "does not match current mount point: $mountpoint\n";
 133         }
 134     } else {
 135         $scfg->{mountpoint} = $mountpoint;
 136     }
 137
 138     return;
 139 }
 140
 141 sub path {
 142     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 143
 144     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
 145
 146     my $path = '';
 147     my $mountpoint = $scfg->{mountpoint} // "/$scfg->{pool}";
 148
 149     if ($vtype eq "images") {
 150         if ($name =~ m/^subvol-/ || $name =~ m/^basevol-/) {
 151             $path = "$mountpoint/$name";
 152         } else {
 153             $path = "/dev/zvol/$scfg->{pool}/$name";
 154         }
 155         $path .= "\@$snapname" if defined($snapname);
 156     } else {
 157         die "$vtype is not allowed in ZFSPool!";
 158     }
 159
 160     return ($path, $vmid, $vtype);
 161 }
 162
 163 sub zfs_request {
 164     my ($class, $scfg, $timeout, $method, @params) = @_;
 165
 166     my $cmd = [];
 167
 168     if ($method eq 'zpool_list') {
 169         push @$cmd, 'zpool', 'list';
 170     } elsif ($method eq 'zpool_import') {
 171         push @$cmd, 'zpool', 'import';
 172         $timeout = 15 if !$timeout || $timeout < 15;
 173     } else {
 174         push @$cmd, 'zfs', $method;
 175     }
 176     push @$cmd, @params;
 177
 178     my $msg = '';
 179     my $output = sub { $msg .= "$_[0]\n" };
 180
 181     $timeout = PVE::RPCEnvironment->is_worker() ? 60*60 : 5 if !$timeout;
 182
 183     run_command($cmd, errmsg => "zfs error", outfunc => $output, timeout => $timeout);
 184
 185     return $msg;
 186 }
 187
 188 sub zfs_wait_for_zvol_link {
 189     my ($class, $scfg, $volname, $timeout) = @_;
 190
 191     my $default_timeout = PVE::RPCEnvironment->is_worker() ? 60*5 : 10;
 192     $timeout = $default_timeout if !defined($timeout);
 193
 194     my ($devname, undef, undef) = $class->path($scfg, $volname);
 195
 196     for (my $i = 1; $i <= $timeout; $i++) {
 197         last if -b $devname;
 198         die "timeout: no zvol device link for '$volname' found after $timeout sec found.\n"
 199             if $i == $timeout;
 200
 201         sleep(1);
 202     }
 203 }
 204
 205 sub alloc_image {
 206     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 207
 208     my $volname = $name;
 209
 210     if ($fmt eq 'raw') {
 211
 212         die "illegal name '$volname' - should be 'vm-$vmid-*'\n"
 213             if $volname && $volname !~ m/^vm-$vmid-/;
 214         $volname = $class->find_free_diskname($storeid, $scfg, $vmid, $fmt)
 215             if !$volname;
 216
 217         $class->zfs_create_zvol($scfg, $volname, $size);
 218         $class->zfs_wait_for_zvol_link($scfg, $volname);
 219
 220     } elsif ( $fmt eq 'subvol') {
 221
 222         die "illegal name '$volname' - should be 'subvol-$vmid-*'\n"
 223             if $volname && $volname !~ m/^subvol-$vmid-/;
 224         $volname = $class->find_free_diskname($storeid, $scfg, $vmid, $fmt)
 225             if !$volname;
 226
 227         die "illegal name '$volname' - should be 'subvol-$vmid-*'\n"
 228             if $volname !~ m/^subvol-$vmid-/;
 229
 230         $class->zfs_create_subvol($scfg, $volname, $size);
 231
 232     } else {
 233         die "unsupported format '$fmt'";
 234     }
 235
 236     return $volname;
 237 }
 238
 239 sub free_image {
 240     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 241
 242     my (undef, $name, undef) = $class->parse_volname($volname);
 243
 244     $class->zfs_delete_zvol($scfg, $name);
 245
 246     return undef;
 247 }
 248
 249 sub list_images {
 250     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 251
 252     $cache->{zfs} = $class->zfs_list_zvol($scfg) if !$cache->{zfs};
 253     my $zfspool = $scfg->{pool};
 254     my $res = [];
 255
 256     if (my $dat = $cache->{zfs}->{$zfspool}) {
 257
 258         foreach my $image (keys %$dat) {
 259
 260             my $info = $dat->{$image};
 261
 262             my $volname = $info->{name};
 263             my $parent = $info->{parent};
 264             my $owner = $info->{vmid};
 265
 266             if ($parent && $parent =~ m/^(\S+)\@__base__$/) {
 267                 my ($basename) = ($1);
 268                 $info->{volid} = "$storeid:$basename/$volname";
 269             } else {
 270                 $info->{volid} = "$storeid:$volname";
 271             }
 272
 273             if ($vollist) {
 274                 my $found = grep { $_ eq $info->{volid} } @$vollist;
 275                 next if !$found;
 276             } else {
 277                 next if defined ($vmid) && ($owner ne $vmid);
 278             }
 279
 280             push @$res, $info;
 281         }
 282     }
 283     return $res;
 284 }
 285
 286 sub zfs_get_properties {
 287     my ($class, $scfg, $properties, $dataset, $timeout) = @_;
 288
 289     my $result = $class->zfs_request($scfg, $timeout, 'get', '-o', 'value',
 290                                      '-Hp', $properties, $dataset);
 291     my @values = split /\n/, $result;
 292     return wantarray ? @values : $values[0];
 293 }
 294
 295 sub zfs_get_pool_stats {
 296     my ($class, $scfg) = @_;
 297
 298     my $available = 0;
 299     my $used = 0;
 300
 301     my @lines = $class->zfs_get_properties($scfg, 'available,used', $scfg->{pool});
 302
 303     if($lines[0] =~ /^(\d+)$/) {
 304         $available = $1;
 305     }
 306
 307     if($lines[1] =~ /^(\d+)$/) {
 308         $used = $1;
 309     }
 310
 311     return ($available, $used);
 312 }
 313
 314 sub zfs_create_zvol {
 315     my ($class, $scfg, $zvol, $size) = @_;
 316
 317     # always align size to 1M as workaround until
 318     # https://github.com/zfsonlinux/zfs/issues/8541 is solved
 319     my $padding = (1024 - $size % 1024) % 1024;
 320     $size = $size + $padding;
 321
 322     my $cmd = ['create'];
 323
 324     push @$cmd, '-s' if $scfg->{sparse};
 325
 326     push @$cmd, '-b', $scfg->{blocksize} if $scfg->{blocksize};
 327
 328     push @$cmd, '-V', "${size}k", "$scfg->{pool}/$zvol";
 329
 330     $class->zfs_request($scfg, undef, @$cmd);
 331 }
 332
 333 sub zfs_create_subvol {
 334     my ($class, $scfg, $volname, $size) = @_;
 335
 336     my $dataset = "$scfg->{pool}/$volname";
 337     my $quota = $size ? "${size}k" : "none";
 338
 339     my $cmd = ['create', '-o', 'acltype=posixacl', '-o', 'xattr=sa',
 340                '-o', "refquota=${quota}", $dataset];
 341
 342     $class->zfs_request($scfg, undef, @$cmd);
 343 }
 344
 345 sub zfs_delete_zvol {
 346     my ($class, $scfg, $zvol) = @_;
 347
 348     my $err;
 349
 350     for (my $i = 0; $i < 6; $i++) {
 351
 352         eval { $class->zfs_request($scfg, undef, 'destroy', '-r', "$scfg->{pool}/$zvol"); };
 353         if ($err = $@) {
 354             if ($err =~ m/^zfs error:(.*): dataset is busy.*/) {
 355                 sleep(1);
 356             } elsif ($err =~ m/^zfs error:.*: dataset does not exist.*$/) {
 357                 $err = undef;
 358                 last;
 359             } else {
 360                 die $err;
 361             }
 362         } else {
 363             last;
 364         }
 365     }
 366
 367     die $err if $err;
 368 }
 369
 370 sub zfs_list_zvol {
 371     my ($class, $scfg) = @_;
 372
 373     my $text = $class->zfs_request($scfg, 10, 'list', '-o', 'name,volsize,origin,type,refquota', '-t', 'volume,filesystem', '-Hrp');
 374     my $zvols = zfs_parse_zvol_list($text);
 375     return undef if !$zvols;
 376
 377     my $list = ();
 378     foreach my $zvol (@$zvols) {
 379         my $pool = $zvol->{pool};
 380         my $name = $zvol->{name};
 381         my $parent = $zvol->{origin};
 382         if($zvol->{origin} && $zvol->{origin} =~ m/^$scfg->{pool}\/(\S+)$/){
 383             $parent = $1;
 384         }
 385
 386         $list->{$pool}->{$name} = {
 387             name => $name,
 388             size => $zvol->{size},
 389             parent => $parent,
 390             format => $zvol->{format},
 391             vmid => $zvol->{owner},
 392         };
 393     }
 394
 395     return $list;
 396 }
 397
 398 sub zfs_get_sorted_snapshot_list {
 399     my ($class, $scfg, $volname, $sort_params) = @_;
 400
 401     my $vname = ($class->parse_volname($volname))[1];
 402
 403     my @params = ('-H', '-t', 'snapshot', '-o', 'name', $sort_params->@*, "$scfg->{pool}\/$vname");
 404     my $text = $class->zfs_request($scfg, undef, 'list', @params);
 405     my @snapshots = split(/\n/, $text);
 406
 407     my $snap_names = [];
 408     for my $snapshot (@snapshots) {
 409         (my $snap_name = $snapshot) =~ s/^.*@//;
 410         push $snap_names->@*, $snap_name;
 411     }
 412     return $snap_names;
 413 }
 414
 415 sub status {
 416     my ($class, $storeid, $scfg, $cache) = @_;
 417
 418     my $total = 0;
 419     my $free = 0;
 420     my $used = 0;
 421     my $active = 0;
 422
 423     eval {
 424         ($free, $used) = $class->zfs_get_pool_stats($scfg);
 425         $active = 1;
 426         $total = $free + $used;
 427     };
 428     warn $@ if $@;
 429
 430     return ($total, $free, $used, $active);
 431 }
 432
 433 sub volume_size_info {
 434     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
 435
 436     my (undef, $vname, undef, undef, undef, undef, $format) =
 437         $class->parse_volname($volname);
 438
 439     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 440     my $value = $class->zfs_get_properties($scfg, $attr, "$scfg->{pool}/$vname");
 441     if ($value =~ /^(\d+)$/) {
 442         return $1;
 443     }
 444
 445     die "Could not get zfs volume size\n";
 446 }
 447
 448 sub volume_snapshot {
 449     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 450
 451     my $vname = ($class->parse_volname($volname))[1];
 452
 453     $class->zfs_request($scfg, undef, 'snapshot', "$scfg->{pool}/$vname\@$snap");
 454 }
 455
 456 sub volume_snapshot_delete {
 457     my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
 458
 459     my $vname = ($class->parse_volname($volname))[1];
 460
 461     $class->deactivate_volume($storeid, $scfg, $vname, $snap, {});
 462     $class->zfs_request($scfg, undef, 'destroy', "$scfg->{pool}/$vname\@$snap");
 463 }
 464
 465 sub volume_snapshot_rollback {
 466     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 467
 468     my (undef, $vname, undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 469
 470     my $msg = $class->zfs_request($scfg, undef, 'rollback', "$scfg->{pool}/$vname\@$snap");
 471
 472     # we have to unmount rollbacked subvols, to invalidate wrong kernel
 473     # caches, they get mounted in activate volume again
 474     # see zfs bug #10931 https://github.com/openzfs/zfs/issues/10931
 475     if ($format eq 'subvol') {
 476         eval { $class->zfs_request($scfg, undef, 'unmount', "$scfg->{pool}/$vname"); };
 477         if (my $err = $@) {
 478             die $err if $err !~ m/not currently mounted$/;
 479         }
 480     }
 481
 482     return $msg;
 483 }
 484
 485 sub volume_rollback_is_possible {
 486     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 487
 488     # can't use '-S creation', because zfs list won't reverse the order when the
 489     # creation time is the same second, breaking at least our tests.
 490     my $snapshots = $class->zfs_get_sorted_snapshot_list($scfg, $volname, ['-s', 'creation']);
 491     my $recentsnap = $snapshots->[-1];
 492
 493     die "can't rollback, no snapshots exist at all\n"
 494         if !defined($recentsnap);
 495
 496     die "can't rollback, '$snap' is not most recent snapshot\n"
 497         if $snap ne $recentsnap;
 498
 499     return 1;
 500 }
 501
 502 sub volume_snapshot_list {
 503     my ($class, $scfg, $storeid, $volname) = @_;
 504
 505     my $snaps = [];
 506     # return an empty array if dataset does not exist.
 507     eval { $snaps = $class->zfs_get_sorted_snapshot_list($scfg, $volname, ['-S', 'name']); };
 508     return $snaps;
 509 }
 510
 511 my sub dataset_mounted_heuristic {
 512     my ($dataset) = @_;
 513
 514     my $mounts = PVE::ProcFSTools::parse_proc_mounts();
 515     for my $mp (@$mounts) {
 516         my ($what, $dir, $fs) = $mp->@*;
 517         next if $fs ne 'zfs';
 518         # check for root-dataset or any child-dataset (root-dataset could have 'canmount=off')
 519         # If any child is mounted heuristically assume that `zfs mount -a` was successful
 520         next if $what !~ m!^$dataset(?:/|$)!;
 521         return 1;
 522     }
 523     return 0;
 524 }
 525
 526 sub activate_storage {
 527     my ($class, $storeid, $scfg, $cache) = @_;
 528
 529     # Note: $scfg->{pool} can include dataset <pool>/<dataset>
 530     my $dataset = $scfg->{pool};
 531     my $pool = ($dataset =~ s!/.*$!!r);
 532
 533     return 1 if dataset_mounted_heuristic($dataset); # early return
 534
 535     my $pool_imported = sub {
 536         my @param = ('-o', 'name', '-H', $pool);
 537         my $res = eval { $class->zfs_request($scfg, undef, 'zpool_list', @param) };
 538         warn "$@\n" if $@;
 539
 540         return defined($res) && $res =~ m/$pool/;
 541     };
 542
 543     if (!$pool_imported->()) {
 544         # import can only be done if not yet imported!
 545         my @param = ('-d', '/dev/disk/by-id/', '-o', 'cachefile=none', $pool);
 546         eval { $class->zfs_request($scfg, undef, 'zpool_import', @param) };
 547         if (my $err = $@) {
 548             # just could've raced with another import, so recheck if it is imported
 549             die "could not activate storage '$storeid', $err\n" if !$pool_imported->();
 550         }
 551     }
 552     eval { $class->zfs_request($scfg, undef, 'mount', '-a') };
 553     die "could not activate storage '$storeid', $@\n" if $@;
 554     return 1;
 555 }
 556
 557 sub deactivate_storage {
 558     my ($class, $storeid, $scfg, $cache) = @_;
 559     return 1;
 560 }
 561
 562 sub activate_volume {
 563     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 564
 565     return 1 if defined($snapname);
 566
 567     my (undef, $dataset, undef, undef, undef, undef, $format) = $class->parse_volname($volname);
 568
 569     if ($format eq 'raw') {
 570         $class->zfs_wait_for_zvol_link($scfg, $volname);
 571     } elsif ($format eq 'subvol') {
 572         my $mounted = $class->zfs_get_properties($scfg, 'mounted', "$scfg->{pool}/$dataset");
 573         if ($mounted !~ m/^yes$/) {
 574             $class->zfs_request($scfg, undef, 'mount', "$scfg->{pool}/$dataset");
 575         }
 576     }
 577
 578     return 1;
 579 }
 580
 581 sub deactivate_volume {
 582     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 583     return 1;
 584 }
 585
 586 sub clone_image {
 587     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 588
 589     $snap ||= '__base__';
 590
 591     my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) =
 592         $class->parse_volname($volname);
 593
 594     die "clone_image only works on base images\n" if !$isBase;
 595
 596     my $name = $class->find_free_diskname($storeid, $scfg, $vmid, $format);
 597
 598     if ($format eq 'subvol') {
 599         my $size = $class->zfs_request($scfg, undef, 'list', '-Hp', '-o', 'refquota', "$scfg->{pool}/$basename");
 600         chomp($size);
 601         $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name", '-o', "refquota=$size");
 602     } else {
 603         $class->zfs_request($scfg, undef, 'clone', "$scfg->{pool}/$basename\@$snap", "$scfg->{pool}/$name");
 604     }
 605
 606     return "$basename/$name";
 607 }
 608
 609 sub create_base {
 610     my ($class, $storeid, $scfg, $volname) = @_;
 611
 612     my $snap = '__base__';
 613
 614     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format) =
 615         $class->parse_volname($volname);
 616
 617     die "create_base not possible with base image\n" if $isBase;
 618
 619     my $newname = $name;
 620     if ( $format eq 'subvol' ) {
 621         $newname =~ s/^subvol-/basevol-/;
 622     } else {
 623         $newname =~ s/^vm-/base-/;
 624     }
 625     my $newvolname = $basename ? "$basename/$newname" : "$newname";
 626
 627     $class->zfs_request($scfg, undef, 'rename', "$scfg->{pool}/$name", "$scfg->{pool}/$newname");
 628
 629     my $running  = undef; #fixme : is create_base always offline ?
 630
 631     $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
 632
 633     return $newvolname;
 634 }
 635
 636 sub volume_resize {
 637     my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
 638
 639     my $new_size = int($size/1024);
 640
 641     my (undef, $vname, undef, undef, undef, undef, $format) =
 642         $class->parse_volname($volname);
 643
 644     my $attr = $format eq 'subvol' ? 'refquota' : 'volsize';
 645
 646     # align size to 1M so we always have a valid multiple of the volume block size
 647     if ($format eq 'raw') {
 648         my $padding = (1024 - $new_size % 1024) % 1024;
 649         $new_size = $new_size + $padding;
 650     }
 651
 652     $class->zfs_request($scfg, undef, 'set', "$attr=${new_size}k", "$scfg->{pool}/$vname");
 653
 654     return $new_size;
 655 }
 656
 657 sub storage_can_replicate {
 658     my ($class, $scfg, $storeid, $format) = @_;
 659
 660     return 1 if $format eq 'raw' || $format eq 'subvol';
 661
 662     return 0;
 663 }
 664
 665 sub volume_has_feature {
 666     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 667
 668     my $features = {
 669         snapshot => { current => 1, snap => 1},
 670         clone => { base => 1},
 671         template => { current => 1},
 672         copy => { base => 1, current => 1},
 673         sparseinit => { base => 1, current => 1},
 674         replicate => { base => 1, current => 1},
 675     };
 676
 677     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 678         $class->parse_volname($volname);
 679
 680     my $key = undef;
 681
 682     if ($snapname) {
 683         $key = 'snap';
 684     } else {
 685         $key = $isBase ? 'base' : 'current';
 686     }
 687
 688     return 1 if $features->{$feature}->{$key};
 689
 690     return undef;
 691 }
 692
 693 sub volume_export {
 694     my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
 695
 696     die "unsupported export stream format for $class: $format\n"
 697         if $format ne 'zfs';
 698
 699     die "$class storage can only export snapshots\n"
 700         if !defined($snapshot);
 701
 702     my $dataset = ($class->parse_volname($volname))[1];
 703
 704     my $fd = fileno($fh);
 705     die "internal error: invalid file handle for volume_export\n"
 706         if !defined($fd);
 707     $fd = ">&$fd";
 708
 709     # For zfs we always create a replication stream (-R) which means the remote
 710     # side will always delete non-existing source snapshots. This should work
 711     # for all our use cases.
 712     my $cmd = ['zfs', 'send', '-Rpv'];
 713     if (defined($base_snapshot)) {
 714         my $arg = $with_snapshots ? '-I' : '-i';
 715         push @$cmd, $arg, $base_snapshot;
 716     }
 717     push @$cmd, '--', "$scfg->{pool}/$dataset\@$snapshot";
 718
 719     run_command($cmd, output => $fd);
 720
 721     return;
 722 }
 723
 724 sub volume_export_formats {
 725     my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_;
 726
 727     my @formats = ('zfs');
 728     # TODOs:
 729     # push @formats, 'fies' if $volname !~ /^(?:basevol|subvol)-/;
 730     # push @formats, 'raw' if !$base_snapshot && !$with_snapshots;
 731     return @formats;
 732 }
 733
 734 sub volume_import {
 735     my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots, $allow_rename) = @_;
 736
 737     die "unsupported import stream format for $class: $format\n"
 738         if $format ne 'zfs';
 739
 740     my $fd = fileno($fh);
 741     die "internal error: invalid file handle for volume_import\n"
 742         if !defined($fd);
 743
 744     my (undef, $dataset, $vmid) = $class->parse_volname($volname);
 745     my $zfspath = "$scfg->{pool}/$dataset";
 746     my $suffix = defined($base_snapshot) ? "\@$base_snapshot" : '';
 747     my $exists = 0 == run_command(['zfs', 'get', '-H', 'name', $zfspath.$suffix],
 748                                   noerr => 1, quiet => 1);
 749     if (defined($base_snapshot)) {
 750         die "base snapshot '$zfspath\@$base_snapshot' doesn't exist\n" if !$exists;
 751     } elsif ($exists) {
 752         die "volume '$zfspath' already exists\n" if !$allow_rename;
 753         warn "volume '$zfspath' already exists - importing with a different name\n";
 754         $dataset = $class->find_free_diskname($storeid, $scfg, $vmid, $format);
 755         $zfspath = "$scfg->{pool}/$dataset";
 756     }
 757
 758     eval { run_command(['zfs', 'recv', '-F', '--', $zfspath], input => "<&$fd") };
 759     if (my $err = $@) {
 760         if (defined($base_snapshot)) {
 761             eval { run_command(['zfs', 'rollback', '-r', '--', "$zfspath\@$base_snapshot"]) };
 762         } else {
 763             eval { run_command(['zfs', 'destroy', '-r', '--', $zfspath]) };
 764         }
 765         die $err;
 766     }
 767
 768     return "$storeid:$dataset";
 769 }
 770
 771 sub volume_import_formats {
 772     my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_;
 773
 774     return $class->volume_export_formats($scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots);
 775 }
 776
 777 1;