PVE/CLI/qm.pm

   1 package PVE::CLI::qm;
   2
   3 use strict;
   4 use warnings;
   5
   6 # Note: disable '+' prefix for Getopt::Long (for resize command)
   7 use Getopt::Long qw(:config no_getopt_compat);
   8
   9 use Fcntl ':flock';
  10 use File::Path;
  11 use IO::Socket::UNIX;
  12 use IO::Select;
  13
  14 use PVE::Tools qw(extract_param);
  15 use PVE::Cluster;
  16 use PVE::SafeSyslog;
  17 use PVE::INotify;
  18 use PVE::RPCEnvironment;
  19 use PVE::QemuServer;
  20 use PVE::QemuServer::ImportDisk;
  21 use PVE::API2::Qemu;
  22 use JSON;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use Term::ReadLine;
  25
  26 use PVE::CLIHandler;
  27
  28 use base qw(PVE::CLIHandler);
  29
  30 my $upid_exit = sub {
  31     my $upid = shift;
  32     my $status = PVE::Tools::upid_read_status($upid);
  33     exit($status eq 'OK' ? 0 : -1);
  34 };
  35
  36 my $nodename = PVE::INotify::nodename();
  37
  38 sub setup_environment {
  39     PVE::RPCEnvironment->setup_default_cli_env();
  40 }
  41
  42 sub run_vnc_proxy {
  43     my ($path) = @_;
  44
  45     my $c;
  46     while ( ++$c < 10 && !-e $path ) { sleep(1); }
  47
  48     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  49
  50     die "unable to connect to socket '$path' - $!" if !$s;
  51
  52     my $select = new IO::Select;
  53
  54     $select->add(\*STDIN);
  55     $select->add($s);
  56
  57     my $timeout = 60*15; # 15 minutes
  58
  59     my @handles;
  60     while ($select->count &&
  61            scalar(@handles = $select->can_read ($timeout))) {
  62         foreach my $h (@handles) {
  63             my $buf;
  64             my $n = $h->sysread($buf, 4096);
  65
  66             if ($h == \*STDIN) {
  67                 if ($n) {
  68                     syswrite($s, $buf);
  69                 } else {
  70                     exit(0);
  71                 }
  72             } elsif ($h == $s) {
  73                 if ($n) {
  74                     syswrite(\*STDOUT, $buf);
  75                 } else {
  76                     exit(0);
  77                 }
  78             }
  79         }
  80     }
  81     exit(0);
  82 }
  83
  84 sub print_recursive_hash {
  85     my ($prefix, $hash, $key) = @_;
  86
  87     if (ref($hash) eq 'HASH') {
  88         if (defined($key)) {
  89             print "$prefix$key:\n";
  90         }
  91         foreach my $itemkey (keys %$hash) {
  92             print_recursive_hash("\t$prefix", $hash->{$itemkey}, $itemkey);
  93         }
  94     } elsif (ref($hash) eq 'ARRAY') {
  95         if (defined($key)) {
  96             print "$prefix$key:\n";
  97         }
  98         foreach my $item (@$hash) {
  99             print_recursive_hash("\t$prefix", $item);
 100         }
 101     } elsif (!ref($hash) && defined($hash)) {
 102         if (defined($key)) {
 103             print "$prefix$key: $hash\n";
 104         } else {
 105             print "$prefix$hash\n";
 106         }
 107     }
 108 }
 109
 110 __PACKAGE__->register_method ({
 111     name => 'showcmd',
 112     path => 'showcmd',
 113     method => 'GET',
 114     description => "Show command line which is used to start the VM (debug info).",
 115     parameters => {
 116         additionalProperties => 0,
 117         properties => {
 118             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 119         },
 120     },
 121     returns => { type => 'null'},
 122     code => sub {
 123         my ($param) = @_;
 124
 125         my $storecfg = PVE::Storage::config();
 126         print PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}) . "\n";
 127
 128         return undef;
 129     }});
 130
 131 __PACKAGE__->register_method ({
 132     name => 'status',
 133     path => 'status',
 134     method => 'GET',
 135     description => "Show VM status.",
 136     parameters => {
 137         additionalProperties => 0,
 138         properties => {
 139             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 140             verbose => {
 141                 description => "Verbose output format",
 142                 type => 'boolean',
 143                 optional => 1,
 144             }
 145         },
 146     },
 147     returns => { type => 'null'},
 148     code => sub {
 149         my ($param) = @_;
 150
 151         # test if VM exists
 152         my $conf = PVE::QemuConfig->load_config ($param->{vmid});
 153
 154         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid}, 1);
 155         my $stat = $vmstatus->{$param->{vmid}};
 156         if ($param->{verbose}) {
 157             foreach my $k (sort (keys %$stat)) {
 158                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 159                 my $v = $stat->{$k};
 160                 print_recursive_hash("", $v, $k);
 161             }
 162         } else {
 163             my $status = $stat->{qmpstatus} || 'unknown';
 164             print "status: $status\n";
 165         }
 166
 167         return undef;
 168     }});
 169
 170 __PACKAGE__->register_method ({
 171     name => 'vncproxy',
 172     path => 'vncproxy',
 173     method => 'PUT',
 174     description => "Proxy VM VNC traffic to stdin/stdout",
 175     parameters => {
 176         additionalProperties => 0,
 177         properties => {
 178             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 179         },
 180     },
 181     returns => { type => 'null'},
 182     code => sub {
 183         my ($param) = @_;
 184
 185         my $vmid = $param->{vmid};
 186         my $vnc_socket = PVE::QemuServer::vnc_socket($vmid);
 187
 188         if (my $ticket = $ENV{LC_PVE_TICKET}) {  # NOTE: ssh on debian only pass LC_* variables
 189             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,password");
 190             PVE::QemuServer::vm_mon_cmd($vmid, "set_password", protocol => 'vnc', password => $ticket);
 191             PVE::QemuServer::vm_mon_cmd($vmid, "expire_password", protocol => 'vnc', time => "+30");
 192         } else {
 193             PVE::QemuServer::vm_mon_cmd($vmid, "change", device => 'vnc', target => "unix:$vnc_socket,x509,password");
 194         }
 195
 196         run_vnc_proxy($vnc_socket);
 197
 198         return undef;
 199     }});
 200
 201 __PACKAGE__->register_method ({
 202     name => 'unlock',
 203     path => 'unlock',
 204     method => 'PUT',
 205     description => "Unlock the VM.",
 206     parameters => {
 207         additionalProperties => 0,
 208         properties => {
 209             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 210         },
 211     },
 212     returns => { type => 'null'},
 213     code => sub {
 214         my ($param) = @_;
 215
 216         my $vmid = $param->{vmid};
 217
 218         PVE::QemuConfig->lock_config ($vmid, sub {
 219             my $conf = PVE::QemuConfig->load_config($vmid);
 220             delete $conf->{lock};
 221             delete $conf->{pending}->{lock} if $conf->{pending}; # just to be sure
 222             PVE::QemuConfig->write_config($vmid, $conf);
 223         });
 224
 225         return undef;
 226     }});
 227
 228 __PACKAGE__->register_method ({
 229     name => 'nbdstop',
 230     path => 'nbdstop',
 231     method => 'PUT',
 232     description => "Stop embedded nbd server.",
 233     parameters => {
 234         additionalProperties => 0,
 235         properties => {
 236             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid }),
 237         },
 238     },
 239     returns => { type => 'null'},
 240     code => sub {
 241         my ($param) = @_;
 242
 243         my $vmid = $param->{vmid};
 244
 245         PVE::QemuServer::nbd_stop($vmid);
 246
 247         return undef;
 248     }});
 249
 250 __PACKAGE__->register_method ({
 251     name => 'mtunnel',
 252     path => 'mtunnel',
 253     method => 'POST',
 254     description => "Used by qmigrate - do not use manually.",
 255     parameters => {
 256         additionalProperties => 0,
 257         properties => {},
 258     },
 259     returns => { type => 'null'},
 260     code => sub {
 261         my ($param) = @_;
 262
 263         if (!PVE::Cluster::check_cfs_quorum(1)) {
 264             print "no quorum\n";
 265             return undef;
 266         }
 267
 268         my $tunnel_write = sub {
 269             my $text = shift;
 270             chomp $text;
 271             print "$text\n";
 272             *STDOUT->flush();
 273         };
 274
 275         $tunnel_write->("tunnel online");
 276         $tunnel_write->("ver 1");
 277
 278         while (my $line = <>) {
 279             chomp $line;
 280             last if $line =~ m/^quit$/;
 281         }
 282
 283         return undef;
 284     }});
 285
 286 __PACKAGE__->register_method ({
 287     name => 'wait',
 288     path => 'wait',
 289     method => 'GET',
 290     description => "Wait until the VM is stopped.",
 291     parameters => {
 292         additionalProperties => 0,
 293         properties => {
 294             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 295             timeout => {
 296                 description => "Timeout in seconds. Default is to wait forever.",
 297                 type => 'integer',
 298                 minimum => 1,
 299                 optional => 1,
 300             }
 301         },
 302     },
 303     returns => { type => 'null'},
 304     code => sub {
 305         my ($param) = @_;
 306
 307         my $vmid = $param->{vmid};
 308         my $timeout = $param->{timeout};
 309
 310         my $pid = PVE::QemuServer::check_running ($vmid);
 311         return if !$pid;
 312
 313         print "waiting until VM $vmid stopps (PID $pid)\n";
 314
 315         my $count = 0;
 316         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 317             $count++;
 318             sleep 1;
 319         }
 320
 321         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 322
 323         return undef;
 324     }});
 325
 326 __PACKAGE__->register_method ({
 327     name => 'monitor',
 328     path => 'monitor',
 329     method => 'POST',
 330     description => "Enter Qemu Monitor interface.",
 331     parameters => {
 332         additionalProperties => 0,
 333         properties => {
 334             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 335         },
 336     },
 337     returns => { type => 'null'},
 338     code => sub {
 339         my ($param) = @_;
 340
 341         my $vmid = $param->{vmid};
 342
 343         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 344
 345         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 346
 347         my $term = new Term::ReadLine ('qm');
 348
 349         my $input;
 350         while (defined ($input = $term->readline('qm> '))) {
 351             chomp $input;
 352
 353             next if $input =~ m/^\s*$/;
 354
 355             last if $input =~ m/^\s*q(uit)?\s*$/;
 356
 357             eval {
 358                 print PVE::QemuServer::vm_human_monitor_command ($vmid, $input);
 359             };
 360             print "ERROR: $@" if $@;
 361         }
 362
 363         return undef;
 364
 365     }});
 366
 367 __PACKAGE__->register_method ({
 368     name => 'rescan',
 369     path => 'rescan',
 370     method => 'POST',
 371     description => "Rescan all storages and update disk sizes and unused disk images.",
 372     parameters => {
 373         additionalProperties => 0,
 374         properties => {
 375             vmid => get_standard_option('pve-vmid', {
 376                 optional => 1,
 377                 completion => \&PVE::QemuServer::complete_vmid,
 378             }),
 379         },
 380     },
 381     returns => { type => 'null'},
 382     code => sub {
 383         my ($param) = @_;
 384
 385         PVE::QemuServer::rescan($param->{vmid});
 386
 387         return undef;
 388     }});
 389
 390 __PACKAGE__->register_method ({
 391     name => 'importdisk',
 392     path => 'importdisk',
 393     method => 'POST',
 394     description => "Import an external disk image as an unused disk in a VM. The
 395  image format has to be supported by qemu-img(1).",
 396     parameters => {
 397         additionalProperties => 0,
 398         properties => {
 399             vmid => get_standard_option('pve-vmid', {completion => \&PVE::QemuServer::complete_vmid}),
 400             source => {
 401                 description => 'Path to the disk image to import',
 402                 type => 'string',
 403                 optional => 0,
 404             },
 405             storage => get_standard_option('pve-storage-id', {
 406                 description => 'Target storage ID',
 407                 completion => \&PVE::QemuServer::complete_storage,
 408                 optional => 0,
 409             }),
 410             format => {
 411                 type => 'string',
 412                 description => 'Target format',
 413                 enum => [ 'raw', 'qcow2', 'vmdk' ],
 414                 optional => 1,
 415             },
 416         },
 417     },
 418     returns => { type => 'null'},
 419     code => sub {
 420         my ($param) = @_;
 421
 422         my $vmid = extract_param($param, 'vmid');
 423         my $source = extract_param($param, 'source');
 424         my $storeid = extract_param($param, 'storage');
 425         my $format = extract_param($param, 'format');
 426
 427         my $vm_conf = PVE::QemuConfig->load_config($vmid);
 428         PVE::QemuConfig->check_lock($vm_conf);
 429         die "$source: non-existent or non-regular file\n" if (! -f $source);
 430
 431         my $storecfg = PVE::Storage::config();
 432         PVE::Storage::storage_check_enabled($storecfg, $storeid);
 433
 434         my $target_storage_config =
 435             PVE::Storage::storage_config($storecfg, $storeid);
 436         die "storage $storeid does not support vm images\n"
 437             if !$target_storage_config->{content}->{images};
 438
 439         PVE::QemuServer::ImportDisk::do_import($source, $vmid, $storeid, { format => $format });
 440
 441         return undef;
 442     }});
 443
 444 __PACKAGE__->register_method ({
 445     name => 'terminal',
 446     path => 'terminal',
 447     method => 'POST',
 448     description => "Open a terminal using a serial device (The VM need to have a serial device configured, for example 'serial0: socket')",
 449     parameters => {
 450         additionalProperties => 0,
 451         properties => {
 452             vmid => get_standard_option('pve-vmid', { completion => \&PVE::QemuServer::complete_vmid_running }),
 453             iface => {
 454                 description => "Select the serial device. By default we simply use the first suitable device.",
 455                 type => 'string',
 456                 optional => 1,
 457                 enum => [qw(serial0 serial1 serial2 serial3)],
 458             }
 459         },
 460     },
 461     returns => { type => 'null'},
 462     code => sub {
 463         my ($param) = @_;
 464
 465         my $vmid = $param->{vmid};
 466
 467         my $conf = PVE::QemuConfig->load_config ($vmid); # check if VM exists
 468
 469         my $iface = $param->{iface};
 470
 471         if ($iface) {
 472             die "serial interface '$iface' is not configured\n" if !$conf->{$iface};
 473             die "wrong serial type on interface '$iface'\n" if $conf->{$iface} ne 'socket';
 474         } else {
 475             foreach my $opt (qw(serial0 serial1 serial2 serial3)) {
 476                 if ($conf->{$opt} && ($conf->{$opt} eq 'socket')) {
 477                     $iface = $opt;
 478                     last;
 479                 }
 480             }
 481             die "unable to find a serial interface\n" if !$iface;
 482         }
 483
 484         die "VM $vmid not running\n" if !PVE::QemuServer::check_running($vmid);
 485
 486         my $socket = "/var/run/qemu-server/${vmid}.$iface";
 487
 488         my $cmd = "socat UNIX-CONNECT:$socket STDIO,raw,echo=0,escape=0x0f";
 489
 490         print "starting serial terminal on interface $iface (press control-O to exit)\n";
 491
 492         system($cmd);
 493
 494         return undef;
 495     }});
 496
 497
 498 my $print_agent_result = sub {
 499     my ($data) = @_;
 500
 501     my $result = $data->{result};
 502     return if !defined($result);
 503
 504     my $class = ref($result);
 505
 506     if (!$class) {
 507         chomp $result;
 508         return if $result =~ m/^\s*$/;
 509         print "$result\n";
 510         return;
 511     }
 512
 513     if (($class eq 'HASH') && !scalar(keys %$result)) { # empty hash
 514         return;
 515     }
 516
 517     print to_json($result, { pretty => 1, canonical => 1});
 518 };
 519
 520 our $cmddef = {
 521     list => [ "PVE::API2::Qemu", 'vmlist', [],
 522              { node => $nodename }, sub {
 523                  my $vmlist = shift;
 524
 525                  exit 0 if (!scalar(@$vmlist));
 526
 527                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 528                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 529
 530                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 531                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 532                      $rec->{qmpstatus} || $rec->{status},
 533                      ($rec->{maxmem} || 0)/(1024*1024),
 534                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 535                      $rec->{pid}||0;
 536                  }
 537
 538
 539               } ],
 540
 541     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 542
 543     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename }, $upid_exit ],
 544
 545     clone => [ "PVE::API2::Qemu", 'clone_vm', ['vmid', 'newid'], { node => $nodename }, $upid_exit ],
 546
 547     migrate => [ "PVE::API2::Qemu", 'migrate_vm', ['vmid', 'target'], { node => $nodename }, $upid_exit ],
 548
 549     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 550
 551     resize => [ "PVE::API2::Qemu", 'resize_vm', ['vmid', 'disk', 'size'], { node => $nodename } ],
 552
 553     move_disk => [ "PVE::API2::Qemu", 'move_vm_disk', ['vmid', 'disk', 'storage'], { node => $nodename }, $upid_exit ],
 554
 555     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid'], { node => $nodename } ],
 556
 557     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 558                 { node => $nodename }, sub {
 559                     my $config = shift;
 560                     foreach my $k (sort (keys %$config)) {
 561                         next if $k eq 'digest';
 562                         my $v = $config->{$k};
 563                         if ($k eq 'description') {
 564                             $v = PVE::Tools::encode_text($v);
 565                         }
 566                         print "$k: $v\n";
 567                     }
 568                 }],
 569
 570     pending => [ "PVE::API2::Qemu", 'vm_pending', ['vmid'],
 571                 { node => $nodename }, sub {
 572                     my $data = shift;
 573                     foreach my $item (sort { $a->{key} cmp $b->{key}} @$data) {
 574                         my $k = $item->{key};
 575                         next if $k eq 'digest';
 576                         my $v = $item->{value};
 577                         my $p = $item->{pending};
 578                         if ($k eq 'description') {
 579                             $v = PVE::Tools::encode_text($v) if defined($v);
 580                             $p = PVE::Tools::encode_text($p) if defined($p);
 581                         }
 582                         if (defined($v)) {
 583                             if ($item->{delete}) {
 584                                 print "del $k: $v\n";
 585                             } elsif (defined($p)) {
 586                                 print "cur $k: $v\n";
 587                                 print "new $k: $p\n";
 588                             } else {
 589                                 print "cur $k: $v\n";
 590                             }
 591                         } elsif (defined($p)) {
 592                             print "new $k: $p\n";
 593                         }
 594                     }
 595                 }],
 596
 597     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 598
 599     status => [ __PACKAGE__, 'status', ['vmid']],
 600
 601     snapshot => [ "PVE::API2::Qemu", 'snapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 602
 603     delsnapshot => [ "PVE::API2::Qemu", 'delsnapshot', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 604
 605     listsnapshot => [ "PVE::API2::Qemu", 'snapshot_list', ['vmid'], { node => $nodename },
 606                     sub {
 607                         my $res = shift;
 608                         foreach my $e (@$res) {
 609                             my $headline = $e->{description} || 'no-description';
 610                             $headline =~ s/\n.*//sg;
 611                             my $parent = $e->{parent} // 'no-parent';
 612                             printf("%-20s %-20s %s\n", $e->{name}, $parent, $headline);
 613                         }
 614                     }],
 615
 616     rollback => [ "PVE::API2::Qemu", 'rollback', ['vmid', 'snapname'], { node => $nodename } , $upid_exit ],
 617
 618     template => [ "PVE::API2::Qemu", 'template', ['vmid'], { node => $nodename }],
 619
 620     start => [ "PVE::API2::Qemu", 'vm_start', ['vmid'], { node => $nodename } , $upid_exit ],
 621
 622     stop => [ "PVE::API2::Qemu", 'vm_stop', ['vmid'], { node => $nodename }, $upid_exit ],
 623
 624     reset => [ "PVE::API2::Qemu", 'vm_reset', ['vmid'], { node => $nodename }, $upid_exit ],
 625
 626     shutdown => [ "PVE::API2::Qemu", 'vm_shutdown', ['vmid'], { node => $nodename }, $upid_exit ],
 627
 628     suspend => [ "PVE::API2::Qemu", 'vm_suspend', ['vmid'], { node => $nodename }, $upid_exit ],
 629
 630     resume => [ "PVE::API2::Qemu", 'vm_resume', ['vmid'], { node => $nodename }, $upid_exit ],
 631
 632     sendkey => [ "PVE::API2::Qemu", 'vm_sendkey', ['vmid', 'key'], { node => $nodename } ],
 633
 634     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 635
 636     wait => [ __PACKAGE__, 'wait', ['vmid']],
 637
 638     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 639
 640     rescan  => [ __PACKAGE__, 'rescan', []],
 641
 642     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 643
 644     agent  => [ "PVE::API2::Qemu", 'agent', ['vmid', 'command'],
 645                 { node => $nodename }, $print_agent_result ],
 646
 647     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 648
 649     nbdstop => [ __PACKAGE__, 'nbdstop', ['vmid']],
 650
 651     terminal => [ __PACKAGE__, 'terminal', ['vmid']],
 652
 653     importdisk => [ __PACKAGE__, 'importdisk', ['vmid', 'source', 'storage']],
 654 };
 655
 656 1;