PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $tunnel_addr) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$tunnel_addr) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if ($tunnel->{sock_addr}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     PVE::QemuConfig->check_lock($conf);
 224
 225     my $running = 0;
 226     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 227         die "can't migrate running VM without --online\n" if !$online;
 228         $running = $pid;
 229
 230         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 231
 232         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 233         # Since the parameter itself contains no reference to a custom model,
 234         # this makes migration independent of changes to "cpu-models.conf".
 235         if ($conf->{cpu}) {
 236             my $cpuconf = PVE::QemuServer::CPUConfig::parse_cpu_conf_basic($conf->{cpu});
 237             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 238                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 239             }
 240         }
 241     }
 242
 243     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 244     if (scalar @$loc_res) {
 245         if ($self->{running} || !$self->{opts}->{force}) {
 246             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 247         } else {
 248             $self->log('info', "migrating VM which uses local devices");
 249         }
 250     }
 251
 252     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 253
 254     my $need_activate = [];
 255     foreach my $volid (@$vollist) {
 256         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 257
 258         # check if storage is available on both nodes
 259         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 260
 261         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 262         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 263
 264         if ($scfg->{shared}) {
 265             # PVE::Storage::activate_storage checks this for non-shared storages
 266             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 267             warn "Used shared storage '$sid' is not online on source node!\n"
 268                 if !$plugin->check_connection($sid, $scfg);
 269         } else {
 270             # only activate if not shared
 271             next if ($volid =~ m/vm-\d+-cloudinit/);
 272             push @$need_activate, $volid;
 273         }
 274     }
 275
 276     # activate volumes
 277     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 278
 279     # test ssh connection
 280     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 281     eval { $self->cmd_quiet($cmd); };
 282     die "Can't connect to destination address using public key\n" if $@;
 283
 284     return $running;
 285 }
 286
 287 sub sync_disks {
 288     my ($self, $vmid) = @_;
 289
 290     my $conf = $self->{vmconf};
 291
 292     # local volumes which have been copied
 293     # and their old_id => new_id pairs
 294     $self->{volumes} = [];
 295     $self->{volume_map} = {};
 296
 297     my $storecfg = $self->{storecfg};
 298     eval {
 299
 300         # found local volumes and their origin
 301         my $local_volumes = {};
 302         my $local_volumes_errors = {};
 303         my $other_errors = [];
 304         my $abort = 0;
 305
 306         my $log_error = sub {
 307             my ($msg, $volid) = @_;
 308
 309             if (defined($volid)) {
 310                 $local_volumes_errors->{$volid} = $msg;
 311             } else {
 312                 push @$other_errors, $msg;
 313             }
 314             $abort = 1;
 315         };
 316
 317         my @sids = PVE::Storage::storage_ids($storecfg);
 318         foreach my $storeid (@sids) {
 319             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 320             next if $scfg->{shared};
 321             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 322
 323             # get list from PVE::Storage (for unused volumes)
 324             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 325
 326             next if @{$dl->{$storeid}} == 0;
 327
 328             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 329             # check if storage is available on target node
 330             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 331
 332             # grandfather in existing mismatches
 333             if ($targetsid ne $storeid) {
 334                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 335                 die "content type 'images' is not available on storage '$targetsid'\n"
 336                     if !$target_scfg->{content}->{images};
 337             }
 338
 339             PVE::Storage::foreach_volid($dl, sub {
 340                 my ($volid, $sid, $volinfo) = @_;
 341
 342                 $local_volumes->{$volid}->{ref} = 'storage';
 343
 344                 # If with_snapshots is not set for storage migrate, it tries to use
 345                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 346                 # back to qcow2 is currently not possible.
 347                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 348                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 349             });
 350         }
 351
 352         my $rep_cfg = PVE::ReplicationConfig->new();
 353         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 354         my $replicatable_volumes = !$replication_jobcfg ? {}
 355             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 356
 357         my $test_volid = sub {
 358             my ($volid, $attr) = @_;
 359
 360             if ($volid =~ m|^/|) {
 361                 return if $attr->{shared};
 362                 $local_volumes->{$volid}->{ref} = 'config';
 363                 die "local file/device\n";
 364             }
 365
 366             my $snaprefs = $attr->{referenced_in_snapshot};
 367
 368             if ($attr->{cdrom}) {
 369                 if ($volid eq 'cdrom') {
 370                     my $msg = "can't migrate local cdrom drive";
 371                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 372                         my $snapnames = join(', ', sort keys %$snaprefs);
 373                         $msg .= " (referenced in snapshot - $snapnames)";
 374                     }
 375                     &$log_error("$msg\n");
 376                     return;
 377                 }
 378                 return if $volid eq 'none';
 379             }
 380
 381             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 382
 383             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 384             # check if storage is available on both nodes
 385             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 386             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 387
 388             return if $scfg->{shared};
 389
 390             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 391             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 392
 393             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 394
 395             if ($attr->{cdrom}) {
 396                 if ($volid =~ /vm-\d+-cloudinit/) {
 397                     $local_volumes->{$volid}->{ref} = 'generated';
 398                     return;
 399                 }
 400                 die "local cdrom image\n";
 401             }
 402
 403             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 404
 405             die "owned by other VM (owner = VM $owner)\n"
 406                 if !$owner || ($owner != $vmid);
 407
 408             return if $attr->{is_vmstate};
 409
 410             if (defined($snaprefs)) {
 411                 $local_volumes->{$volid}->{snapshots} = 1;
 412
 413                 # we cannot migrate shapshots on local storage
 414                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 415
 416                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 417                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 418                     die "non-migratable snapshot exists\n";
 419                 }
 420             }
 421
 422             die "referenced by linked clone(s)\n"
 423                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 424         };
 425
 426         PVE::QemuServer::foreach_volid($conf, sub {
 427             my ($volid, $attr) = @_;
 428             eval { $test_volid->($volid, $attr); };
 429             if (my $err = $@) {
 430                 &$log_error($err, $volid);
 431             }
 432         });
 433
 434         foreach my $vol (sort keys %$local_volumes) {
 435             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 436             my $ref = $local_volumes->{$vol}->{ref};
 437             if ($ref eq 'storage') {
 438                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 439             } elsif ($ref eq 'config') {
 440                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 441                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 442                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 443             } elsif ($ref eq 'snapshot') {
 444                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 445             } elsif ($ref eq 'generated') {
 446                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 447             } else {
 448                 $self->log('info', "found $type disk '$vol'\n");
 449             }
 450         }
 451
 452         foreach my $vol (sort keys %$local_volumes_errors) {
 453             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 454         }
 455         foreach my $err (@$other_errors) {
 456             $self->log('warn', "$err");
 457         }
 458
 459         if ($abort) {
 460             die "can't migrate VM - check log\n";
 461         }
 462
 463         # additional checks for local storage
 464         foreach my $volid (keys %$local_volumes) {
 465             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 466             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 467
 468             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 469
 470             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 471                 if !$migratable;
 472
 473             # image is a linked clone on local storage, se we can't migrate.
 474             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 475                 die "can't migrate '$volid' as it's a clone of '$basename'";
 476             }
 477         }
 478
 479         if ($replication_jobcfg) {
 480             if ($self->{running}) {
 481
 482                 my $version = PVE::QemuServer::kvm_user_version();
 483                 if (!min_version($version, 4, 2)) {
 484                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 485                 }
 486
 487                 my $live_replicatable_volumes = {};
 488                 PVE::QemuConfig->foreach_volume($conf, sub {
 489                     my ($ds, $drive) = @_;
 490
 491                     my $volid = $drive->{file};
 492                     $live_replicatable_volumes->{$ds} = $volid
 493                         if defined($replicatable_volumes->{$volid});
 494                 });
 495                 foreach my $drive (keys %$live_replicatable_volumes) {
 496                     my $volid = $live_replicatable_volumes->{$drive};
 497
 498                     my $bitmap = "repl_$drive";
 499
 500                     # start tracking before replication to get full delta + a few duplicates
 501                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 502                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 503
 504                     # other info comes from target node in phase 2
 505                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 506                 }
 507             }
 508             $self->log('info', "replicating disk images");
 509
 510             my $start_time = time();
 511             my $logfunc = sub { $self->log('info', shift) };
 512             $self->{replicated_volumes} = PVE::Replication::run_replication(
 513                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 514         }
 515
 516         # sizes in config have to be accurate for remote node to correctly
 517         # allocate disks, rescan to be sure
 518         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 519         PVE::QemuConfig->foreach_volume($conf, sub {
 520             my ($key, $drive) = @_;
 521             return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 522             return if !defined($local_volumes->{$key}); # only update sizes for local volumes
 523
 524             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 525             if (defined($updated)) {
 526                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 527                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 528             }
 529         });
 530
 531         # we want to set the efidisk size in the config to the size of the
 532         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 533         if (defined($conf->{efidisk0})) {
 534             PVE::QemuServer::update_efidisk_size($conf);
 535         }
 536
 537         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 538
 539         foreach my $volid (keys %$local_volumes) {
 540             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 541             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 542             my $ref = $local_volumes->{$volid}->{ref};
 543             if ($self->{running} && $ref eq 'config') {
 544                 push @{$self->{online_local_volumes}}, $volid;
 545             } elsif ($ref eq 'generated') {
 546                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 547                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 548                 push @{$self->{volumes}}, $volid;
 549                 next;
 550             } else {
 551                 next if $self->{replicated_volumes}->{$volid};
 552                 push @{$self->{volumes}}, $volid;
 553                 my $opts = $self->{opts};
 554                 # use 'migrate' limit for transfer to other node
 555                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 556                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 557                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 558
 559                 my $storage_migrate_opts = {
 560                     'bwlimit' => $bwlimit,
 561                     'insecure' => $opts->{migration_type} eq 'insecure',
 562                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 563                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 564                 };
 565
 566                 my $logfunc = sub { $self->log('info', $_[0]); };
 567                 my $new_volid = eval {
 568                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 569                                                   $targetsid, $storage_migrate_opts, $logfunc);
 570                 };
 571                 if (my $err = $@) {
 572                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 573                 }
 574
 575                 $self->{volume_map}->{$volid} = $new_volid;
 576                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 577             }
 578         }
 579     };
 580     die "Failed to sync data - $@" if $@;
 581 }
 582
 583 sub cleanup_remotedisks {
 584     my ($self) = @_;
 585
 586     foreach my $target_drive (keys %{$self->{target_drive}}) {
 587         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 588         next if !defined($drivestr);
 589
 590         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 591
 592         # don't clean up replicated disks!
 593         next if defined($self->{replicated_volumes}->{$drive->{file}});
 594
 595         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 596
 597         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 598
 599         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 600         if (my $err = $@) {
 601             $self->log('err', $err);
 602             $self->{errors} = 1;
 603         }
 604     }
 605 }
 606
 607 sub cleanup_bitmaps {
 608     my ($self) = @_;
 609     foreach my $drive (keys %{$self->{target_drive}}) {
 610         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 611         next if !$bitmap;
 612         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 613         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 614     }
 615 }
 616
 617 sub phase1 {
 618     my ($self, $vmid) = @_;
 619
 620     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 621
 622     my $conf = $self->{vmconf};
 623
 624     # set migrate lock in config file
 625     $conf->{lock} = 'migrate';
 626     PVE::QemuConfig->write_config($vmid, $conf);
 627
 628     sync_disks($self, $vmid);
 629
 630     # sync_disks fixes disk sizes to match their actual size, write changes so
 631     # target allocates correct volumes
 632     PVE::QemuConfig->write_config($vmid, $conf);
 633 };
 634
 635 sub phase1_cleanup {
 636     my ($self, $vmid, $err) = @_;
 637
 638     $self->log('info', "aborting phase 1 - cleanup resources");
 639
 640     my $conf = $self->{vmconf};
 641     delete $conf->{lock};
 642     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 643     if (my $err = $@) {
 644         $self->log('err', $err);
 645     }
 646
 647     if ($self->{volumes}) {
 648         foreach my $volid (@{$self->{volumes}}) {
 649             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 650             # fixme: try to remove ?
 651         }
 652     }
 653
 654     eval { $self->cleanup_bitmaps() };
 655     if (my $err =$@) {
 656         $self->log('err', $err);
 657     }
 658
 659 }
 660
 661 sub phase2 {
 662     my ($self, $vmid) = @_;
 663
 664     my $conf = $self->{vmconf};
 665
 666     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 667
 668     my $raddr;
 669     my $rport;
 670     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 671     my $nodename = PVE::INotify::nodename();
 672
 673     ## start on remote node
 674     my $cmd = [@{$self->{rem_ssh}}];
 675
 676     my $spice_ticket;
 677     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 678         my $res = mon_cmd($vmid, 'query-spice');
 679         $spice_ticket = $res->{ticket};
 680     }
 681
 682     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 683
 684     my $migration_type = $self->{opts}->{migration_type};
 685
 686     push @$cmd, '--migration_type', $migration_type;
 687
 688     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 689       if $self->{opts}->{migration_network};
 690
 691     if ($migration_type eq 'insecure') {
 692         push @$cmd, '--stateuri', 'tcp';
 693     } else {
 694         push @$cmd, '--stateuri', 'unix';
 695     }
 696
 697     if ($self->{forcemachine}) {
 698         push @$cmd, '--machine', $self->{forcemachine};
 699     }
 700
 701     if ($self->{forcecpu}) {
 702         push @$cmd, '--force-cpu', $self->{forcecpu};
 703     }
 704
 705     if ($self->{online_local_volumes}) {
 706         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 707     }
 708
 709     my $spice_port;
 710     my $tunnel_addr = [];
 711     my $sock_addr = [];
 712     # version > 0 for unix socket support
 713     my $nbd_protocol_version = 1;
 714     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 715     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 716     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 717
 718     my $number_of_online_replicated_volumes = 0;
 719
 720     # prevent auto-vivification
 721     if ($self->{online_local_volumes}) {
 722         foreach my $volid (@{$self->{online_local_volumes}}) {
 723             next if !$self->{replicated_volumes}->{$volid};
 724             $number_of_online_replicated_volumes++;
 725             $input .= "replicated_volume: $volid\n";
 726         }
 727     }
 728
 729     my $target_replicated_volumes = {};
 730
 731     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 732     # instead we pipe it through STDIN
 733     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 734         my $line = shift;
 735
 736         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 737             $raddr = $1;
 738             $rport = int($2);
 739             $ruri = "tcp:$raddr:$rport";
 740         }
 741         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 742             $raddr = $1;
 743             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 744             $ruri = "unix:$raddr";
 745         }
 746         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 747             $raddr = "localhost";
 748             $rport = int($1);
 749             $ruri = "tcp:$raddr:$rport";
 750         }
 751         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 752             $spice_port = int($1);
 753         }
 754         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 755             my $drivestr = $4;
 756             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 757             my $targetdrive = $3;
 758             $targetdrive =~ s/drive-//g;
 759
 760             $self->{stopnbd} = 1;
 761             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 762             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 763         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 764             my $drivestr = $4;
 765             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 766             my $nbd_unix_addr = $1;
 767             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 768             my $targetdrive = $3;
 769             $targetdrive =~ s/drive-//g;
 770
 771             $self->{stopnbd} = 1;
 772             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 773             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 774             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 775             push @$sock_addr, $nbd_unix_addr;
 776         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 777             my $drive = $1;
 778             my $volid = $2;
 779             $target_replicated_volumes->{$volid} = $drive;
 780         } elsif ($line =~ m/^QEMU: (.*)$/) {
 781             $self->log('info', "[$self->{node}] $1\n");
 782         }
 783     }, errfunc => sub {
 784         my $line = shift;
 785         $self->log('info', "[$self->{node}] $line");
 786     }, noerr => 1);
 787
 788     die "remote command failed with exit code $exitcode\n" if $exitcode;
 789
 790     die "unable to detect remote migration address\n" if !$raddr;
 791
 792     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 793         die "number of replicated disks on source and target node do not match - target node too old?\n"
 794     }
 795
 796     $self->log('info', "start remote tunnel");
 797
 798     if ($migration_type eq 'secure') {
 799
 800         if ($ruri =~ /^unix:/) {
 801             unlink $raddr;
 802             push @$tunnel_addr, "$raddr:$raddr";
 803             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 804             push @$sock_addr, $raddr;
 805
 806             my $unix_socket_try = 0; # wait for the socket to become ready
 807             while ($unix_socket_try <= 100) {
 808                 $unix_socket_try++;
 809                 my $available = 0;
 810                 foreach my $sock (@$sock_addr) {
 811                     if (-S $sock) {
 812                         $available++;
 813                     }
 814                 }
 815
 816                 if ($available == @$sock_addr) {
 817                     last;
 818                 }
 819
 820                 usleep(50000);
 821             }
 822             if ($unix_socket_try > 100) {
 823                 $self->{errors} = 1;
 824                 $self->finish_tunnel($self->{tunnel});
 825                 die "Timeout, migration socket $ruri did not get ready";
 826             }
 827
 828         } elsif ($ruri =~ /^tcp:/) {
 829             my $tunnel_addr;
 830             if ($raddr eq "localhost") {
 831                 # for backwards compatibility with older qemu-server versions
 832                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 833                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 834                 $tunnel_addr = "$lport:localhost:$rport";
 835             }
 836
 837             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 838
 839         } else {
 840             die "unsupported protocol in migration URI: $ruri\n";
 841         }
 842     } else {
 843         #fork tunnel for insecure migration, to send faster commands like resume
 844         $self->{tunnel} = $self->fork_tunnel();
 845     }
 846     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 847
 848     my $start = time();
 849
 850     my $opt_bwlimit = $self->{opts}->{bwlimit};
 851
 852     if (defined($self->{online_local_volumes})) {
 853         $self->{storage_migration} = 1;
 854         $self->{storage_migration_jobs} = {};
 855         $self->log('info', "starting storage migration");
 856
 857         die "The number of local disks does not match between the source and the destination.\n"
 858             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 859         foreach my $drive (keys %{$self->{target_drive}}){
 860             my $target = $self->{target_drive}->{$drive};
 861             my $nbd_uri = $target->{nbd_uri};
 862
 863             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 864             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 865
 866             my $source_volid = $source_drive->{file};
 867             my $target_volid = $target_drive->{file};
 868
 869             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 870             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 871
 872             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 873             my $bitmap = $target->{bitmap};
 874
 875             $self->log('info', "$drive: start migration to $nbd_uri");
 876             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 877
 878             $self->{volume_map}->{$source_volid} = $target_volid;
 879             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 880         }
 881     }
 882
 883     $self->log('info', "starting online/live migration on $ruri");
 884     $self->{livemigration} = 1;
 885
 886     # load_defaults
 887     my $defaults = PVE::QemuServer::load_defaults();
 888
 889     $self->log('info', "set migration_caps");
 890     eval {
 891         PVE::QemuServer::set_migration_caps($vmid);
 892     };
 893     warn $@ if $@;
 894
 895     my $qemu_migrate_params = {};
 896
 897     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 898     # migrate_speed parameter in qm.conf - take the lower of the two.
 899     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 900     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 901     # migrate_speed is in MB/s, bwlimit in KB/s
 902     $migrate_speed *= 1024;
 903
 904     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 905
 906     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 907     # default of 8192m which is basically unlimited
 908     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 909
 910     # qmp takes migrate_speed in B/s.
 911     $migrate_speed *= 1024;
 912     $self->log('info', "migration speed limit: $migrate_speed B/s");
 913     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 914
 915     my $migrate_downtime = $defaults->{migrate_downtime};
 916     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 917     # migrate-set-parameters expects limit in ms
 918     $migrate_downtime *= 1000;
 919     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 920     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 921
 922     # set cachesize to 10% of the total memory
 923     my $memory =  $conf->{memory} || $defaults->{memory};
 924     my $cachesize = int($memory * 1048576 / 10);
 925     $cachesize = round_powerof2($cachesize);
 926
 927     $self->log('info', "migration cachesize: $cachesize B");
 928     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 929
 930     $self->log('info', "set migration parameters");
 931     eval {
 932         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 933     };
 934     $self->log('info', "migrate-set-parameters error: $@") if $@;
 935
 936     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 937         my $rpcenv = PVE::RPCEnvironment::get();
 938         my $authuser = $rpcenv->get_user();
 939
 940         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 941
 942         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 943         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 944
 945         $self->log('info', "spice client_migrate_info");
 946
 947         eval {
 948             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 949                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 950                                                 'cert-subject' => $subject);
 951         };
 952         $self->log('info', "client_migrate_info error: $@") if $@;
 953
 954     }
 955
 956     $self->log('info', "start migrate command to $ruri");
 957     eval {
 958         mon_cmd($vmid, "migrate", uri => $ruri);
 959     };
 960     my $merr = $@;
 961     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 962
 963     my $lstat = 0;
 964     my $usleep = 1000000;
 965     my $i = 0;
 966     my $err_count = 0;
 967     my $lastrem = undef;
 968     my $downtimecounter = 0;
 969     while (1) {
 970         $i++;
 971         my $avglstat = $lstat/$i if $lstat;
 972
 973         usleep($usleep);
 974         my $stat;
 975         eval {
 976             $stat = mon_cmd($vmid, "query-migrate");
 977         };
 978         if (my $err = $@) {
 979             $err_count++;
 980             warn "query migrate failed: $err\n";
 981             $self->log('info', "query migrate failed: $err");
 982             if ($err_count <= 5) {
 983                 usleep(1000000);
 984                 next;
 985             }
 986             die "too many query migrate failures - aborting\n";
 987         }
 988
 989         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 990             sleep(1);
 991             next;
 992         }
 993
 994         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 995             $merr = undef;
 996             $err_count = 0;
 997             if ($stat->{status} eq 'completed') {
 998                 my $delay = time() - $start;
 999                 if ($delay > 0) {
1000                     my $mbps = sprintf "%.2f", $memory / $delay;
1001                     my $downtime = $stat->{downtime} || 0;
1002                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
1003                 }
1004             }
1005
1006             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1007                 $self->log('info', "migration status error: $stat->{status}");
1008                 die "aborting\n"
1009             }
1010
1011             if ($stat->{status} ne 'active') {
1012                 $self->log('info', "migration status: $stat->{status}");
1013                 last;
1014             }
1015
1016             if ($stat->{ram}->{transferred} ne $lstat) {
1017                 my $trans = $stat->{ram}->{transferred} || 0;
1018                 my $rem = $stat->{ram}->{remaining} || 0;
1019                 my $total = $stat->{ram}->{total} || 0;
1020                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1021                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1022                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1023                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1024                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1025                 # reduce sleep if remainig memory is lower than the average transfer speed
1026                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1027
1028                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1029                            "remaining ${rem}), total ${total})");
1030
1031                 if (${xbzrlecachesize}) {
1032                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1033                 }
1034
1035                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1036                     $downtimecounter++;
1037                 }
1038                 $lastrem = $rem;
1039
1040                 if ($downtimecounter > 5) {
1041                     $downtimecounter = 0;
1042                     $migrate_downtime *= 2;
1043                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1044                     eval {
1045                         # migrate-set-parameters does not touch values not
1046                         # specified, so this only changes downtime-limit
1047                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1048                     };
1049                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1050                 }
1051
1052             }
1053
1054
1055             $lstat = $stat->{ram}->{transferred};
1056
1057         } else {
1058             die $merr if $merr;
1059             die "unable to parse migration status '$stat->{status}' - aborting\n";
1060         }
1061     }
1062 }
1063
1064 sub phase2_cleanup {
1065     my ($self, $vmid, $err) = @_;
1066
1067     return if !$self->{errors};
1068     $self->{phase2errors} = 1;
1069
1070     $self->log('info', "aborting phase 2 - cleanup resources");
1071
1072     $self->log('info', "migrate_cancel");
1073     eval {
1074         mon_cmd($vmid, "migrate_cancel");
1075     };
1076     $self->log('info', "migrate_cancel error: $@") if $@;
1077
1078     my $conf = $self->{vmconf};
1079     delete $conf->{lock};
1080     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1081     if (my $err = $@) {
1082         $self->log('err', $err);
1083     }
1084
1085     # cleanup ressources on target host
1086     if ($self->{storage_migration}) {
1087         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1088         if (my $err = $@) {
1089             $self->log('err', $err);
1090         }
1091     }
1092
1093     eval { $self->cleanup_bitmaps() };
1094     if (my $err =$@) {
1095         $self->log('err', $err);
1096     }
1097
1098     my $nodename = PVE::INotify::nodename();
1099
1100     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1101     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1102     if (my $err = $@) {
1103         $self->log('err', $err);
1104         $self->{errors} = 1;
1105     }
1106
1107     # cleanup after stopping, otherwise disks might be in-use by target VM!
1108     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1109     if (my $err = $@) {
1110         $self->log('err', $err);
1111     }
1112
1113
1114     if ($self->{tunnel}) {
1115         eval { finish_tunnel($self, $self->{tunnel});  };
1116         if (my $err = $@) {
1117             $self->log('err', $err);
1118             $self->{errors} = 1;
1119         }
1120     }
1121 }
1122
1123 sub phase3 {
1124     my ($self, $vmid) = @_;
1125
1126     my $volids = $self->{volumes};
1127     return if $self->{phase2errors};
1128
1129     # destroy local copies
1130     foreach my $volid (@$volids) {
1131         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1132         if (my $err = $@) {
1133             $self->log('err', "removing local copy of '$volid' failed - $err");
1134             $self->{errors} = 1;
1135             last if $err =~ /^interrupted by signal$/;
1136         }
1137     }
1138 }
1139
1140 sub phase3_cleanup {
1141     my ($self, $vmid, $err) = @_;
1142
1143     my $conf = $self->{vmconf};
1144     return if $self->{phase2errors};
1145
1146     my $tunnel = $self->{tunnel};
1147
1148     if ($self->{storage_migration}) {
1149         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1150         # to avoid it trying to re-establish it. We are in blockjob ready state,
1151         # thus, this command changes to it to blockjob complete (see qapi docs)
1152         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1153
1154         if (my $err = $@) {
1155             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1156             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1157             die "Failed to complete storage migration: $err\n";
1158         }
1159     }
1160
1161     if ($self->{volume_map}) {
1162         my $target_drives = $self->{target_drive};
1163
1164         # FIXME: for NBD storage migration we now only update the volid, and
1165         # not the full drivestr from the target node. Workaround that until we
1166         # got some real rescan, to avoid things like wrong format in the drive
1167         delete $conf->{$_} for keys %$target_drives;
1168         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1169
1170         for my $drive (keys %$target_drives) {
1171             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1172         }
1173         PVE::QemuConfig->write_config($vmid, $conf);
1174     }
1175
1176     # transfer replication state before move config
1177     $self->transfer_replication_state() if $self->{replicated_volumes};
1178
1179     # move config to remote node
1180     my $conffile = PVE::QemuConfig->config_file($vmid);
1181     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1182
1183     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1184         if !rename($conffile, $newconffile);
1185
1186     $self->switch_replication_job_target() if $self->{replicated_volumes};
1187
1188     if ($self->{livemigration}) {
1189         if ($self->{stopnbd}) {
1190             $self->log('info', "stopping NBD storage migration server on target.");
1191             # stop nbd server on remote vm - requirement for resume since 2.9
1192             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1193
1194             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1195             if (my $err = $@) {
1196                 $self->log('err', $err);
1197                 $self->{errors} = 1;
1198             }
1199         }
1200
1201         # config moved and nbd server stopped - now we can resume vm on target
1202         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1203             eval {
1204                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1205             };
1206             if (my $err = $@) {
1207                 $self->log('err', $err);
1208                 $self->{errors} = 1;
1209             }
1210         } else {
1211             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1212             my $logf = sub {
1213                 my $line = shift;
1214                 $self->log('err', $line);
1215             };
1216             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1217             if (my $err = $@) {
1218                 $self->log('err', $err);
1219                 $self->{errors} = 1;
1220             }
1221         }
1222
1223         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1224             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1225             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1226         }
1227     }
1228
1229     # close tunnel on successful migration, on error phase2_cleanup closed it
1230     if ($tunnel) {
1231         eval { finish_tunnel($self, $tunnel);  };
1232         if (my $err = $@) {
1233             $self->log('err', $err);
1234             $self->{errors} = 1;
1235         }
1236     }
1237
1238     eval {
1239         my $timer = 0;
1240         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1241             $self->log('info', "Waiting for spice server migration");
1242             while (1) {
1243                 my $res = mon_cmd($vmid, 'query-spice');
1244                 last if int($res->{'migrated'}) == 1;
1245                 last if $timer > 50;
1246                 $timer ++;
1247                 usleep(200000);
1248             }
1249         }
1250     };
1251
1252     # always stop local VM
1253     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1254     if (my $err = $@) {
1255         $self->log('err', "stopping vm failed - $err");
1256         $self->{errors} = 1;
1257     }
1258
1259     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1260     eval {
1261         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1262         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1263     };
1264     if (my $err = $@) {
1265         $self->log('err', $err);
1266         $self->{errors} = 1;
1267     }
1268
1269     if($self->{storage_migration}) {
1270         # destroy local copies
1271         my $volids = $self->{online_local_volumes};
1272
1273         foreach my $volid (@$volids) {
1274             # keep replicated volumes!
1275             next if $self->{replicated_volumes}->{$volid};
1276
1277             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1278             if (my $err = $@) {
1279                 $self->log('err', "removing local copy of '$volid' failed - $err");
1280                 $self->{errors} = 1;
1281                 last if $err =~ /^interrupted by signal$/;
1282             }
1283         }
1284
1285     }
1286
1287     # clear migrate lock
1288     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1289     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1290 }
1291
1292 sub final_cleanup {
1293     my ($self, $vmid) = @_;
1294
1295     # nothing to do
1296 }
1297
1298 sub round_powerof2 {
1299     return 1 if $_[0] < 2;
1300     return 2 << int(log($_[0]-1)/log(2));
1301 }
1302
1303 1;