PVE/QemuServer/Memory.pm

   1 package PVE::QemuServer::Memory;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools qw(run_command lock_file lock_file_full file_read_firstline dir_glob_foreach);
   7 use PVE::Exception qw(raise raise_param_exc);
   8
   9 use PVE::QemuServer;
  10 use PVE::QemuServer::Monitor qw(mon_cmd);
  11
  12 my $MAX_NUMA = 8;
  13 my $MAX_MEM = 4194304;
  14 my $STATICMEM = 1024;
  15
  16 sub get_numa_node_list {
  17     my ($conf) = @_;
  18     my @numa_map;
  19     for (my $i = 0; $i < $MAX_NUMA; $i++) {
  20         my $entry = $conf->{"numa$i"} or next;
  21         my $numa = PVE::QemuServer::parse_numa($entry) or next;
  22         push @numa_map, $i;
  23     }
  24     return @numa_map if @numa_map;
  25     my $sockets = $conf->{sockets} || 1;
  26     return (0..($sockets-1));
  27 }
  28
  29 # only valid when numa nodes map to a single host node
  30 sub get_numa_guest_to_host_map {
  31     my ($conf) = @_;
  32     my $map = {};
  33     for (my $i = 0; $i < $MAX_NUMA; $i++) {
  34         my $entry = $conf->{"numa$i"} or next;
  35         my $numa = PVE::QemuServer::parse_numa($entry) or next;
  36         $map->{$i} = print_numa_hostnodes($numa->{hostnodes});
  37     }
  38     return $map if %$map;
  39     my $sockets = $conf->{sockets} || 1;
  40     return {map { $_ => $_ } (0..($sockets-1))};
  41 }
  42
  43 sub foreach_dimm{
  44     my ($conf, $vmid, $memory, $sockets, $func) = @_;
  45
  46     my $dimm_id = 0;
  47     my $current_size = 0;
  48     my $dimm_size = 0;
  49
  50     if($conf->{hugepages} && $conf->{hugepages} == 1024) {
  51         $current_size = 1024 * $sockets;
  52         $dimm_size = 1024;
  53     } else {
  54         $current_size = 1024;
  55         $dimm_size = 512;
  56     }
  57
  58     return if $current_size == $memory;
  59
  60     my @numa_map = get_numa_node_list($conf);
  61
  62     for (my $j = 0; $j < 8; $j++) {
  63         for (my $i = 0; $i < 32; $i++) {
  64             my $name = "dimm${dimm_id}";
  65             $dimm_id++;
  66             my $numanode = $numa_map[$i % @numa_map];
  67             $current_size += $dimm_size;
  68             &$func($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory);
  69             return  $current_size if $current_size >= $memory;
  70         }
  71         $dimm_size *= 2;
  72     }
  73 }
  74
  75 sub foreach_reverse_dimm {
  76     my ($conf, $vmid, $memory, $sockets, $func) = @_;
  77
  78     my $dimm_id = 253;
  79     my $current_size = 0;
  80     my $dimm_size = 0;
  81
  82     if($conf->{hugepages} && $conf->{hugepages} == 1024) {
  83         $current_size = 8355840;
  84         $dimm_size = 131072;
  85     } else {
  86         $current_size = 4177920;
  87         $dimm_size = 65536;
  88     }
  89
  90     return if $current_size == $memory;
  91
  92     my @numa_map = get_numa_node_list($conf);
  93
  94     for (my $j = 0; $j < 8; $j++) {
  95         for (my $i = 0; $i < 32; $i++) {
  96             my $name = "dimm${dimm_id}";
  97             $dimm_id--;
  98             my $numanode = $numa_map[(31-$i) % @numa_map];
  99             $current_size -= $dimm_size;
 100             &$func($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory);
 101             return  $current_size if $current_size <= $memory;
 102         }
 103         $dimm_size /= 2;
 104     }
 105 }
 106
 107 sub qemu_memory_hotplug {
 108     my ($vmid, $conf, $defaults, $opt, $value) = @_;
 109
 110     return $value if !PVE::QemuServer::check_running($vmid);
 111
 112     my $sockets = 1;
 113     $sockets = $conf->{sockets} if $conf->{sockets};
 114
 115     my $memory = $conf->{memory} || $defaults->{memory};
 116     $value = $defaults->{memory} if !$value;
 117     return $value if $value == $memory;
 118
 119     my $static_memory = $STATICMEM;
 120     $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 121
 122     die "memory can't be lower than $static_memory MB" if $value < $static_memory;
 123     die "you cannot add more memory than $MAX_MEM MB!\n" if $memory > $MAX_MEM;
 124
 125     if($value > $memory) {
 126
 127         my $numa_hostmap;
 128
 129         foreach_dimm($conf, $vmid, $value, $sockets, sub {
 130             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 131
 132                 return if $current_size <= $conf->{memory};
 133
 134                 if ($conf->{hugepages}) {
 135                     $numa_hostmap = get_numa_guest_to_host_map($conf) if !$numa_hostmap;
 136
 137                     my $hugepages_size = hugepages_size($conf, $dimm_size);
 138                     my $path = hugepages_mount_path($hugepages_size);
 139                     my $host_numanode = $numa_hostmap->{$numanode};
 140                     my $hugepages_topology->{$hugepages_size}->{$host_numanode} = hugepages_nr($dimm_size, $hugepages_size);
 141
 142                     my $code = sub {
 143                         my $hugepages_host_topology = hugepages_host_topology();
 144                         hugepages_allocate($hugepages_topology, $hugepages_host_topology);
 145
 146                         eval { mon_cmd($vmid, "object-add", 'qom-type' => "memory-backend-file", id => "mem-$name", size => int($dimm_size*1024*1024), 'mem-path' => $path, share => JSON::true, prealloc => JSON::true ) };
 147                         if (my $err = $@) {
 148                             hugepages_reset($hugepages_host_topology);
 149                             die $err;
 150                         }
 151
 152                         hugepages_pre_deallocate($hugepages_topology);
 153                     };
 154                     eval { hugepages_update_locked($code); };
 155
 156                 } else {
 157                     eval { mon_cmd($vmid, "object-add", 'qom-type' => "memory-backend-ram", id => "mem-$name", size => int($dimm_size*1024*1024) ) };
 158                 }
 159
 160                 if (my $err = $@) {
 161                     eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 162                     die $err;
 163                 }
 164
 165                 eval { mon_cmd($vmid, "device_add", driver => "pc-dimm", id => "$name", memdev => "mem-$name", node => $numanode) };
 166                 if (my $err = $@) {
 167                     eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 168                     die $err;
 169                 }
 170                 #update conf after each succesful module hotplug
 171                 $conf->{memory} = $current_size;
 172                 PVE::QemuConfig->write_config($vmid, $conf);
 173         });
 174
 175     } else {
 176
 177         foreach_reverse_dimm($conf, $vmid, $value, $sockets, sub {
 178             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 179
 180                 return if $current_size >= $conf->{memory};
 181                 print "try to unplug memory dimm $name\n";
 182
 183                 my $retry = 0;
 184                 while (1) {
 185                     eval { PVE::QemuServer::qemu_devicedel($vmid, $name) };
 186                     sleep 3;
 187                     my $dimm_list = qemu_dimm_list($vmid);
 188                     last if !$dimm_list->{$name};
 189                     raise_param_exc({ $name => "error unplug memory module" }) if $retry > 5;
 190                     $retry++;
 191                 }
 192
 193                 #update conf after each succesful module unplug
 194                 $conf->{memory} = $current_size;
 195
 196                 eval { PVE::QemuServer::qemu_objectdel($vmid, "mem-$name"); };
 197                 PVE::QemuConfig->write_config($vmid, $conf);
 198         });
 199     }
 200 }
 201
 202 sub qemu_dimm_list {
 203     my ($vmid) = @_;
 204
 205     my $dimmarray = mon_cmd($vmid, "query-memory-devices");
 206     my $dimms = {};
 207
 208     foreach my $dimm (@$dimmarray) {
 209
 210         $dimms->{$dimm->{data}->{id}}->{id} = $dimm->{data}->{id};
 211         $dimms->{$dimm->{data}->{id}}->{node} = $dimm->{data}->{node};
 212         $dimms->{$dimm->{data}->{id}}->{addr} = $dimm->{data}->{addr};
 213         $dimms->{$dimm->{data}->{id}}->{size} = $dimm->{data}->{size};
 214         $dimms->{$dimm->{data}->{id}}->{slot} = $dimm->{data}->{slot};
 215     }
 216     return $dimms;
 217 }
 218
 219 sub config {
 220     my ($conf, $vmid, $sockets, $cores, $defaults, $hotplug_features, $cmd) = @_;
 221
 222     my $memory = $conf->{memory} || $defaults->{memory};
 223     my $static_memory = 0;
 224
 225     if ($hotplug_features->{memory}) {
 226         die "NUMA needs to be enabled for memory hotplug\n" if !$conf->{numa};
 227         die "Total memory is bigger than ${MAX_MEM}MB\n" if $memory > $MAX_MEM;
 228
 229         for (my $i = 0; $i < $MAX_NUMA; $i++) {
 230             die "cannot enable memory hotplugging with custom NUMA topology\n"
 231                 if $conf->{"numa$i"};
 232         }
 233
 234         my $sockets = 1;
 235         $sockets = $conf->{sockets} if $conf->{sockets};
 236
 237         $static_memory = $STATICMEM;
 238         $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 239
 240         die "minimum memory must be ${static_memory}MB\n" if($memory < $static_memory);
 241         push @$cmd, '-m', "size=${static_memory},slots=255,maxmem=${MAX_MEM}M";
 242
 243     } else {
 244
 245         $static_memory = $memory;
 246         push @$cmd, '-m', $static_memory;
 247     }
 248
 249     die "numa needs to be enabled to use hugepages" if $conf->{hugepages} && !$conf->{numa};
 250
 251     if ($conf->{numa}) {
 252
 253         my $numa_totalmemory = undef;
 254         for (my $i = 0; $i < $MAX_NUMA; $i++) {
 255             next if !$conf->{"numa$i"};
 256             my $numa = PVE::QemuServer::parse_numa($conf->{"numa$i"});
 257             next if !$numa;
 258             # memory
 259             die "missing NUMA node$i memory value\n" if !$numa->{memory};
 260             my $numa_memory = $numa->{memory};
 261             $numa_totalmemory += $numa_memory;
 262
 263             my $mem_object = print_mem_object($conf, "ram-node$i", $numa_memory);
 264
 265             # cpus
 266             my $cpulists = $numa->{cpus};
 267             die "missing NUMA node$i cpus\n" if !defined($cpulists);
 268             my $cpus = join(',cpus=', map {
 269                 my ($start, $end) = @$_;
 270                 defined($end) ? "$start-$end" : $start
 271             } @$cpulists);
 272
 273             # hostnodes
 274             my $hostnodelists = $numa->{hostnodes};
 275             if (defined($hostnodelists)) {
 276
 277                 my $hostnodes = print_numa_hostnodes($hostnodelists);
 278
 279                 # policy
 280                 my $policy = $numa->{policy};
 281                 die "you need to define a policy for hostnode $hostnodes\n" if !$policy;
 282                 $mem_object .= ",host-nodes=$hostnodes,policy=$policy";
 283             } else {
 284                 die "numa hostnodes need to be defined to use hugepages" if $conf->{hugepages};
 285             }
 286
 287             push @$cmd, '-object', $mem_object;
 288             push @$cmd, '-numa', "node,nodeid=$i,cpus=$cpus,memdev=ram-node$i";
 289         }
 290
 291         die "total memory for NUMA nodes must be equal to vm static memory\n"
 292             if $numa_totalmemory && $numa_totalmemory != $static_memory;
 293
 294         #if no custom tology, we split memory and cores across numa nodes
 295         if (!$numa_totalmemory) {
 296             my $numa_memory = ($static_memory / $sockets);
 297
 298             for (my $i = 0; $i < $sockets; $i++)  {
 299                 die "host NUMA node$i doesn't exist\n" if ! -d "/sys/devices/system/node/node$i/" && $conf->{hugepages};
 300
 301                 my $mem_object = print_mem_object($conf, "ram-node$i", $numa_memory);
 302                 push @$cmd, '-object', $mem_object;
 303
 304                 my $cpus = ($cores * $i);
 305                 $cpus .= "-" . ($cpus + $cores - 1) if $cores > 1;
 306
 307                 push @$cmd, '-numa', "node,nodeid=$i,cpus=$cpus,memdev=ram-node$i";
 308             }
 309         }
 310     }
 311
 312     if ($hotplug_features->{memory}) {
 313         foreach_dimm($conf, $vmid, $memory, $sockets, sub {
 314             my ($conf, $vmid, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 315
 316             my $mem_object = print_mem_object($conf, "mem-$name", $dimm_size);
 317
 318             push @$cmd, "-object" , $mem_object;
 319             push @$cmd, "-device", "pc-dimm,id=$name,memdev=mem-$name,node=$numanode";
 320
 321             die "memory size ($memory) must be aligned to $dimm_size for hotplugging\n"
 322                 if $current_size > $memory;
 323         });
 324     }
 325 }
 326
 327 sub print_mem_object {
 328     my ($conf, $id, $size) = @_;
 329
 330     if ($conf->{hugepages}) {
 331
 332         my $hugepages_size = hugepages_size($conf, $size);
 333         my $path = hugepages_mount_path($hugepages_size);
 334
 335         return "memory-backend-file,id=$id,size=${size}M,mem-path=$path,share=on,prealloc=yes";
 336     } else {
 337         return "memory-backend-ram,id=$id,size=${size}M";
 338     }
 339
 340 }
 341
 342 sub print_numa_hostnodes {
 343     my ($hostnodelists) = @_;
 344
 345     my $hostnodes;
 346     foreach my $hostnoderange (@$hostnodelists) {
 347         my ($start, $end) = @$hostnoderange;
 348         $hostnodes .= ',' if $hostnodes;
 349         $hostnodes .= $start;
 350         $hostnodes .= "-$end" if defined($end);
 351         $end //= $start;
 352         for (my $i = $start; $i <= $end; ++$i ) {
 353             die "host NUMA node$i doesn't exist\n" if ! -d "/sys/devices/system/node/node$i/";
 354         }
 355     }
 356     return $hostnodes;
 357 }
 358
 359 sub hugepages_mount {
 360
 361    my $mountdata = PVE::ProcFSTools::parse_proc_mounts();
 362
 363    foreach my $size (qw(2048 1048576)) {
 364         next if (! -d "/sys/kernel/mm/hugepages/hugepages-${size}kB");
 365
 366         my $path = "/run/hugepages/kvm/${size}kB";
 367
 368         my $found = grep {
 369             $_->[2] =~ /^hugetlbfs/ &&
 370             $_->[1] eq $path
 371         } @$mountdata;
 372
 373         if (!$found) {
 374
 375             File::Path::make_path($path) if (!-d $path);
 376             my $cmd = ['/bin/mount', '-t', 'hugetlbfs', '-o', "pagesize=${size}k", 'hugetlbfs', $path];
 377             run_command($cmd, errmsg => "hugepage mount error");
 378         }
 379    }
 380 }
 381
 382 sub hugepages_mount_path {
 383    my ($size) = @_;
 384
 385    $size = $size * 1024;
 386    return "/run/hugepages/kvm/${size}kB";
 387
 388 }
 389
 390 sub hugepages_nr {
 391   my ($size, $hugepages_size) = @_;
 392
 393   return $size / $hugepages_size;
 394 }
 395
 396 sub hugepages_size {
 397     my ($conf, $size) = @_;
 398     die "hugepages option is not enabled" if !$conf->{hugepages};
 399     die "memory size '$size' is not a positive even integer; cannot use for hugepages\n"
 400         if $size <= 0 || $size & 1;
 401
 402     my $page_chunk = sub { -d  "/sys/kernel/mm/hugepages/hugepages-". ($_[0] * 1024) ."kB" };
 403     die "your system doesn't support hugepages\n" if !$page_chunk->(2) && !$page_chunk->(1024);
 404
 405     if ($conf->{hugepages} eq 'any') {
 406
 407         # try to use 1GB if available && memory size is matching
 408         if ($page_chunk->(1024) && ($size & 1023) == 0) {
 409             return 1024;
 410         } elsif ($page_chunk->(2)) {
 411             return 2;
 412         } else {
 413             die "host only supports 1024 GB hugepages, but requested size '$size' is not a multiple of 1024 MB\n"
 414         }
 415     } else {
 416
 417         my $hugepagesize = $conf->{hugepages};
 418
 419         if (!$page_chunk->($hugepagesize)) {
 420             die "your system doesn't support hugepages of $hugepagesize MB\n";
 421         } elsif (($size % $hugepagesize) != 0) {
 422             die "Memory size $size is not a multiple of the requested hugepages size $hugepagesize\n";
 423         }
 424
 425         return $hugepagesize
 426     }
 427 }
 428
 429 sub hugepages_topology {
 430     my ($conf) = @_;
 431
 432     my $hugepages_topology = {};
 433
 434     return if !$conf->{numa};
 435
 436     my $defaults = PVE::QemuServer::load_defaults();
 437     my $memory = $conf->{memory} || $defaults->{memory};
 438     my $static_memory = 0;
 439     my $sockets = 1;
 440     $sockets = $conf->{smp} if $conf->{smp}; # old style - no longer iused
 441     $sockets = $conf->{sockets} if $conf->{sockets};
 442     my $numa_custom_topology = undef;
 443     my $hotplug_features = PVE::QemuServer::parse_hotplug_features(defined($conf->{hotplug}) ? $conf->{hotplug} : '1');
 444
 445     if ($hotplug_features->{memory}) {
 446         $static_memory = $STATICMEM;
 447         $static_memory = $static_memory * $sockets if ($conf->{hugepages} && $conf->{hugepages} == 1024);
 448     } else {
 449         $static_memory = $memory;
 450     }
 451
 452     #custom numa topology
 453     for (my $i = 0; $i < $MAX_NUMA; $i++) {
 454         next if !$conf->{"numa$i"};
 455         my $numa = PVE::QemuServer::parse_numa($conf->{"numa$i"});
 456         next if !$numa;
 457
 458         $numa_custom_topology = 1;
 459         my $numa_memory = $numa->{memory};
 460         my $hostnodelists = $numa->{hostnodes};
 461         my $hostnodes = print_numa_hostnodes($hostnodelists);
 462
 463         die "more than 1 hostnode value in numa node is not supported when hugepages are enabled" if $hostnodes !~ m/^(\d)$/;
 464         my $hugepages_size = hugepages_size($conf, $numa_memory);
 465         $hugepages_topology->{$hugepages_size}->{$hostnodes} += hugepages_nr($numa_memory, $hugepages_size);
 466
 467     }
 468
 469     #if no custom numa tology, we split memory and cores across numa nodes
 470     if(!$numa_custom_topology) {
 471
 472         my $numa_memory = ($static_memory / $sockets);
 473
 474         for (my $i = 0; $i < $sockets; $i++)  {
 475
 476             my $hugepages_size = hugepages_size($conf, $numa_memory);
 477             $hugepages_topology->{$hugepages_size}->{$i} += hugepages_nr($numa_memory, $hugepages_size);
 478         }
 479     }
 480
 481     if ($hotplug_features->{memory}) {
 482         my $numa_hostmap = get_numa_guest_to_host_map($conf);
 483
 484         foreach_dimm($conf, undef, $memory, $sockets, sub {
 485             my ($conf, undef, $name, $dimm_size, $numanode, $current_size, $memory) = @_;
 486
 487             $numanode = $numa_hostmap->{$numanode};
 488
 489             my $hugepages_size = hugepages_size($conf, $dimm_size);
 490             $hugepages_topology->{$hugepages_size}->{$numanode} += hugepages_nr($dimm_size, $hugepages_size);
 491         });
 492     }
 493
 494     return $hugepages_topology;
 495 }
 496
 497 sub hugepages_host_topology {
 498
 499     #read host hugepages
 500     my $hugepages_host_topology = {};
 501
 502     dir_glob_foreach("/sys/devices/system/node/", 'node(\d+)', sub {
 503         my ($nodepath, $numanode) = @_;
 504
 505         dir_glob_foreach("/sys/devices/system/node/$nodepath/hugepages/", 'hugepages\-(\d+)kB', sub {
 506             my ($hugepages_path, $hugepages_size) = @_;
 507
 508             $hugepages_size = $hugepages_size / 1024;
 509             my $hugepages_nr = PVE::Tools::file_read_firstline("/sys/devices/system/node/$nodepath/hugepages/$hugepages_path/nr_hugepages");
 510             $hugepages_host_topology->{$hugepages_size}->{$numanode} = $hugepages_nr;
 511         });
 512     });
 513
 514     return $hugepages_host_topology;
 515 }
 516
 517 sub hugepages_allocate {
 518     my ($hugepages_topology, $hugepages_host_topology) = @_;
 519
 520     #allocate new hupages if needed
 521     foreach my $size (sort keys %$hugepages_topology) {
 522
 523         my $nodes = $hugepages_topology->{$size};
 524
 525         foreach my $numanode (keys %$nodes) {
 526
 527             my $hugepages_size = $size * 1024;
 528             my $hugepages_requested = $hugepages_topology->{$size}->{$numanode};
 529             my $path = "/sys/devices/system/node/node${numanode}/hugepages/hugepages-${hugepages_size}kB/";
 530             my $hugepages_free = PVE::Tools::file_read_firstline($path."free_hugepages");
 531             my $hugepages_nr = PVE::Tools::file_read_firstline($path."nr_hugepages");
 532
 533             if ($hugepages_requested > $hugepages_free) {
 534                 my $hugepages_needed = $hugepages_requested - $hugepages_free;
 535                 PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr + $hugepages_needed);
 536                 #verify that is correctly allocated
 537                 $hugepages_free = PVE::Tools::file_read_firstline($path."free_hugepages");
 538                 if ($hugepages_free < $hugepages_requested) {
 539                     #rollback to initial host config
 540                     hugepages_reset($hugepages_host_topology);
 541                     die "hugepage allocation failed";
 542                 }
 543             }
 544
 545         }
 546     }
 547
 548 }
 549
 550 sub hugepages_default_nr_hugepages {
 551     my ($size) = @_;
 552
 553     my $cmdline = PVE::Tools::file_read_firstline("/proc/cmdline");
 554     my $args = PVE::Tools::split_args($cmdline);
 555
 556     my $parsed_size = 2; # default is 2M
 557
 558     foreach my $arg (@$args) {
 559         if ($arg eq "hugepagesz=2M") {
 560             $parsed_size = 2;
 561         } elsif ($arg eq "hugepagesz=1G") {
 562             $parsed_size = 1024;
 563         } elsif ($arg =~ m/^hugepages=(\d+)?$/) {
 564             if ($parsed_size == $size) {
 565                 return $1;
 566             }
 567         }
 568     }
 569
 570     return 0;
 571 }
 572
 573 sub hugepages_pre_deallocate {
 574     my ($hugepages_topology) = @_;
 575
 576     foreach my $size (sort keys %$hugepages_topology) {
 577
 578         my $hugepages_size = $size * 1024;
 579         my $path = "/sys/kernel/mm/hugepages/hugepages-${hugepages_size}kB/";
 580         my $hugepages_nr = hugepages_default_nr_hugepages($size);
 581         PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr);
 582     }
 583 }
 584
 585 sub hugepages_reset {
 586     my ($hugepages_topology) = @_;
 587
 588     foreach my $size (sort keys %$hugepages_topology) {
 589
 590         my $nodes = $hugepages_topology->{$size};
 591         foreach my $numanode (keys %$nodes) {
 592
 593             my $hugepages_nr = $hugepages_topology->{$size}->{$numanode};
 594             my $hugepages_size = $size * 1024;
 595             my $path = "/sys/devices/system/node/node${numanode}/hugepages/hugepages-${hugepages_size}kB/";
 596
 597             PVE::ProcFSTools::write_proc_entry($path."nr_hugepages", $hugepages_nr);
 598         }
 599     }
 600 }
 601
 602 sub hugepages_update_locked {
 603     my ($code, @param) = @_;
 604
 605     my $timeout = 60; #could be long if a lot of hugepages need to be alocated
 606
 607     my $lock_filename = "/var/lock/hugepages.lck";
 608
 609     my $res = lock_file($lock_filename, $timeout, $code, @param);
 610     die $@ if $@;
 611
 612     return $res;
 613 }
 614 1;
 615