PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 my sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 }
 277 my sub duration_to_human {
 278     my ($seconds) = @_;
 279
 280     return sprintf('%2ds', $seconds) if $seconds < 60;
 281     my $minutes = $seconds / 60;
 282     $seconds = $seconds % 60;
 283
 284     return sprintf('%2dm %2ds', $minutes, $seconds) if $minutes < 60;
 285     my $hours = $minutes / 60;
 286     $minutes = $minutes % 60;
 287
 288     return sprintf('%2dh %2dm %2ds', $hours, $minutes, $seconds) if $hours < 24;
 289     my $days = $hours / 24;
 290     $hours = $hours % 24;
 291
 292     return sprintf('%2dd %2dh %2dm', $days, $hours, $minutes);
 293 }
 294
 295 my $bitmap_action_to_human = sub {
 296     my ($self, $info) = @_;
 297
 298     my $action = $info->{action};
 299
 300     if ($action eq "not-used") {
 301         return "disabled (no support)" if $self->{vm_was_running};
 302         return "disabled (VM not running)";
 303     } elsif ($action eq "not-used-removed") {
 304         return "disabled (old bitmap cleared)";
 305     } elsif ($action eq "new") {
 306         return "created new";
 307     } elsif ($action eq "used") {
 308         if ($info->{dirty} == 0) {
 309             return "OK (drive clean)";
 310         } else {
 311             my $size = bytes_to_human($info->{size});
 312             my $dirty = bytes_to_human($info->{dirty});
 313             return "OK ($dirty of $size dirty)";
 314         }
 315     } elsif ($action eq "invalid") {
 316         return "existing bitmap was invalid and has been cleared";
 317     } else {
 318         return "unknown";
 319     }
 320 };
 321
 322 my $query_backup_status_loop = sub {
 323     my ($self, $vmid, $job_uuid, $qemu_support) = @_;
 324
 325     my $starttime = time ();
 326     my $last_time = $starttime;
 327     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 328     my ($transferred, $reused);
 329
 330     my $get_mbps = sub {
 331         my ($mb, $delta) = @_;
 332         return "0 B/s" if $mb <= 0;
 333         my $bw = int(($mb / $delta));
 334         return bytes_to_human($bw) . "/s";
 335     };
 336
 337     my $target = 0;
 338     my $last_reused = 0;
 339     my $has_query_bitmap = $qemu_support && $qemu_support->{'query-bitmap-info'};
 340     my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 341     if ($has_query_bitmap) {
 342         my $total = 0;
 343         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 344         for my $info (sort { $a->{drive} cmp $b->{drive} } @$bitmap_info) {
 345             if (!$is_template) {
 346                 my $text = $bitmap_action_to_human->($self, $info);
 347                 my $drive = $info->{drive};
 348                 $drive =~ s/^drive-//; # for consistency
 349                 $self->loginfo("$drive: dirty-bitmap status: $text");
 350             }
 351             $target += $info->{dirty};
 352             $total += $info->{size};
 353             $last_reused += $info->{size} - $info->{dirty};
 354         }
 355         if ($target < $total) {
 356             my $total_h = bytes_to_human($total);
 357             my $target_h = bytes_to_human($target);
 358             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 359         }
 360     }
 361
 362     my $first_round = 1;
 363     while(1) {
 364         my $status = mon_cmd($vmid, 'query-backup');
 365
 366         my $total = $status->{total} || 0;
 367         my $dirty = $status->{dirty};
 368         $target = (defined($dirty) && $dirty < $total) ? $dirty : $total if !$has_query_bitmap;
 369         $transferred = $status->{transferred} || 0;
 370         $reused = $status->{reused};
 371         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 372         my $zero = $status->{'zero-bytes'} || 0;
 373
 374         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 375
 376         my $ctime = time();
 377         my $duration = $ctime - $starttime;
 378
 379         my $rbytes = $transferred - $last_transferred;
 380         my $wbytes;
 381         if ($reused) {
 382             # reused includes zero bytes for PBS
 383             $wbytes = $rbytes - ($reused - $last_reused);
 384         } else {
 385             $wbytes = $rbytes - ($zero - $last_zero);
 386         }
 387
 388         my $timediff = ($ctime - $last_time) || 1; # fixme
 389         my $mbps_read = $get_mbps->($rbytes, $timediff);
 390         my $mbps_write = $get_mbps->($wbytes, $timediff);
 391         my $target_h = bytes_to_human($target);
 392         my $transferred_h = bytes_to_human($transferred);
 393
 394         if (!$has_query_bitmap && $first_round && $target != $total) { # FIXME: remove with PVE 7.0
 395             my $total_h = bytes_to_human($total);
 396             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 397         }
 398
 399         my $statusline = sprintf("%3d%% ($transferred_h of $target_h) in %s"
 400             .", read: $mbps_read, write: $mbps_write", $percent, duration_to_human($duration));
 401
 402         my $res = $status->{status} || 'unknown';
 403         if ($res ne 'active') {
 404             $self->loginfo($statusline);
 405             if ($res ne 'done') {
 406                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 407                 die "got unexpected status '$res'\n";
 408             }
 409             $last_target = $target if $target;
 410             $last_total = $total if $total;
 411             $last_zero = $zero if $zero;
 412             $last_transferred = $transferred if $transferred;
 413             last;
 414         }
 415         if ($percent != $last_percent && ($timediff > 2)) {
 416             $self->loginfo($statusline);
 417             $last_percent = $percent;
 418             $last_target = $target if $target;
 419             $last_total = $total if $total;
 420             $last_zero = $zero if $zero;
 421             $last_transferred = $transferred if $transferred;
 422             $last_time = $ctime;
 423             $last_reused = $reused;
 424         }
 425         sleep(1);
 426         $first_round = 0 if $first_round;
 427     }
 428
 429     my $duration = time() - $starttime;
 430
 431     if ($last_zero) {
 432         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 433         my $zero_h = bytes_to_human($last_zero, 2);
 434         $self->loginfo("backup is sparse: $zero_h (${zero_per}%) total zero data");
 435     }
 436     if ($reused) {
 437         my $reused_h = bytes_to_human($reused, 2);
 438         my $reuse_per = int($reused * 100 / $last_total);
 439         $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 440     }
 441     if ($transferred) {
 442         my $transferred_h = bytes_to_human($transferred, 2);
 443         if ($duration) {
 444             my $mbps = $get_mbps->($transferred, $duration);
 445             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 446         } else {
 447             $self->loginfo("transferred $transferred_h in <1 seconds");
 448         }
 449     }
 450
 451     return {
 452         total => $last_total,
 453         reused => $reused,
 454     };
 455 };
 456
 457 sub archive_pbs {
 458     my ($self, $task, $vmid) = @_;
 459
 460     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 461     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 462
 463     my $opts = $self->{vzdump}->{opts};
 464     my $scfg = $opts->{scfg};
 465
 466     my $starttime = time();
 467
 468     my $server = $scfg->{server};
 469     my $datastore = $scfg->{datastore};
 470     my $username = $scfg->{username} // 'root@pam';
 471     my $fingerprint = $scfg->{fingerprint};
 472
 473     my $repo = "$username\@$server:$datastore";
 474     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 475     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 476
 477     my $diskcount = scalar(@{$task->{disks}});
 478     # proxmox-backup-client can only handle raw files and block devs
 479     # only use it (directly) for disk-less VMs
 480     if (!$diskcount) {
 481         my @pathlist;
 482         $self->loginfo("backup contains no disks");
 483
 484         local $ENV{PBS_PASSWORD} = $password;
 485         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 486         my $cmd = [
 487             '/usr/bin/proxmox-backup-client',
 488             'backup',
 489             '--repository', $repo,
 490             '--backup-type', 'vm',
 491             '--backup-id', "$vmid",
 492             '--backup-time', $task->{backup_time},
 493         ];
 494
 495         push @$cmd, "qemu-server.conf:$conffile";
 496         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 497
 498         $self->loginfo("starting template backup");
 499         $self->loginfo(join(' ', @$cmd));
 500
 501         $self->cmd($cmd);
 502
 503         return;
 504     }
 505
 506     # get list early so we die on unkown drive types before doing anything
 507     my $devlist = _get_task_devlist($task);
 508
 509     $self->enforce_vm_running_for_backup($vmid);
 510
 511     my $backup_job_uuid;
 512     eval {
 513         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 514             die "interrupted by signal\n";
 515         };
 516
 517         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 518         if (!$qemu_support) {
 519             die "PBS backups are not supported by the running QEMU version. Please make "
 520               . "sure you've installed the latest version and the VM has been restarted.\n";
 521         }
 522
 523         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 524
 525         my $params = {
 526             format => "pbs",
 527             'backup-file' => $repo,
 528             'backup-id' => "$vmid",
 529             'backup-time' => $task->{backup_time},
 530             password => $password,
 531             devlist => $devlist,
 532             'config-file' => $conffile,
 533         };
 534         $params->{speed} = $opts->{bwlimit}*1024 if $opts->{bwlimit};
 535         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 536         $params->{'firewall-file'} = $firewall if -e $firewall;
 537         if (-e $keyfile) {
 538             $self->loginfo("enabling encryption");
 539             $params->{keyfile} = $keyfile;
 540             $params->{encrypt} = JSON::true;
 541         } else {
 542             $params->{encrypt} = JSON::false;
 543         }
 544
 545         my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 546         $params->{'use-dirty-bitmap'} = JSON::true
 547             if $qemu_support->{'pbs-dirty-bitmap'} && $self->{vm_was_running} && !$is_template;
 548
 549         $params->{timeout} = 60; # give some time to connect to the backup server
 550
 551         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 552         my $qmperr = $@;
 553         $backup_job_uuid = $res->{UUID} if $res;
 554
 555         if ($fs_frozen) {
 556             $self->qga_fs_thaw($vmid);
 557         }
 558
 559         die $qmperr if $qmperr;
 560         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 561
 562         $self->loginfo("started backup task '$backup_job_uuid'");
 563
 564         $self->resume_vm_after_job_start($task, $vmid);
 565
 566         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 567         $task->{size} = $stat->{total};
 568     };
 569     my $err = $@;
 570     if ($err) {
 571         $self->logerr($err);
 572         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 573     }
 574     $self->restore_vm_power_state($vmid);
 575
 576     die $err if $err;
 577 }
 578
 579 my $fork_compressor_pipe = sub {
 580     my ($self, $comp, $outfileno) = @_;
 581
 582     my @pipefd = POSIX::pipe();
 583     my $cpid = fork();
 584     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 585     if ($cpid == 0) {
 586         eval {
 587             POSIX::close($pipefd[1]);
 588             # redirect STDIN
 589             my $fd = fileno(STDIN);
 590             close STDIN;
 591             POSIX::close(0) if $fd != 0;
 592             die "unable to redirect STDIN - $!"
 593                 if !open(STDIN, "<&", $pipefd[0]);
 594
 595             # redirect STDOUT
 596             $fd = fileno(STDOUT);
 597             close STDOUT;
 598             POSIX::close (1) if $fd != 1;
 599
 600             die "unable to redirect STDOUT - $!"
 601                 if !open(STDOUT, ">&", $outfileno);
 602
 603             exec($comp);
 604             die "fork compressor '$comp' failed\n";
 605         };
 606         if (my $err = $@) {
 607             $self->logerr($err);
 608             POSIX::_exit(1);
 609         }
 610         POSIX::_exit(0);
 611         kill(-9, $$);
 612     } else {
 613         POSIX::close($pipefd[0]);
 614         $outfileno = $pipefd[1];
 615     }
 616
 617     return ($cpid, $outfileno);
 618 };
 619
 620 sub archive_vma {
 621     my ($self, $task, $vmid, $filename, $comp) = @_;
 622
 623     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 624     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 625
 626     my $opts = $self->{vzdump}->{opts};
 627
 628     my $starttime = time();
 629
 630     my $speed = 0;
 631     if ($opts->{bwlimit}) {
 632         $speed = $opts->{bwlimit}*1024;
 633     }
 634
 635     my $diskcount = scalar(@{$task->{disks}});
 636     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 637         my @pathlist;
 638         foreach my $di (@{$task->{disks}}) {
 639             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 640                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 641             } else {
 642                 die "implement me";
 643             }
 644         }
 645
 646         if (!$diskcount) {
 647             $self->loginfo("backup contains no disks");
 648         }
 649
 650         my $outcmd;
 651         if ($comp) {
 652             $outcmd = "exec:$comp";
 653         } else {
 654             $outcmd = "exec:cat";
 655         }
 656
 657         $outcmd .= " > $filename" if !$opts->{stdout};
 658
 659         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 660         push @$cmd, '-c', $firewall if -e $firewall;
 661         push @$cmd, $outcmd, @pathlist;
 662
 663         $self->loginfo("starting template backup");
 664         $self->loginfo(join(' ', @$cmd));
 665
 666         if ($opts->{stdout}) {
 667             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 668         } else {
 669             $self->cmd($cmd);
 670         }
 671
 672         return;
 673     }
 674
 675     my $devlist = _get_task_devlist($task);
 676
 677     $self->enforce_vm_running_for_backup($vmid);
 678
 679     my $cpid;
 680     my $backup_job_uuid;
 681
 682     eval {
 683         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 684             die "interrupted by signal\n";
 685         };
 686
 687         my $outfh;
 688         if ($opts->{stdout}) {
 689             $outfh = $opts->{stdout};
 690         } else {
 691             $outfh = IO::File->new($filename, "w") ||
 692                 die "unable to open file '$filename' - $!\n";
 693         }
 694         my $outfileno = fileno($outfh);
 695
 696         if ($comp) {
 697             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 698         }
 699
 700         my $qmpclient = PVE::QMPClient->new();
 701         my $backup_cb = sub {
 702             my ($vmid, $resp) = @_;
 703             $backup_job_uuid = $resp->{return}->{UUID};
 704         };
 705         my $add_fd_cb = sub {
 706             my ($vmid, $resp) = @_;
 707
 708             my $params = {
 709                 'backup-file' => "/dev/fdname/backup",
 710                 speed => $speed,
 711                 'config-file' => $conffile,
 712                 devlist => $devlist
 713             };
 714             $params->{'firewall-file'} = $firewall if -e $firewall;
 715
 716             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 717         };
 718
 719         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 720
 721         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 722
 723         eval { $qmpclient->queue_execute(30) };
 724         my $qmperr = $@;
 725
 726         if ($fs_frozen) {
 727             $self->qga_fs_thaw($vmid);
 728         }
 729
 730         die $qmperr if $qmperr;
 731         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 732
 733         if ($cpid) {
 734             POSIX::close($outfileno) == 0 ||
 735                 die "close output file handle failed\n";
 736         }
 737
 738         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 739
 740         $self->loginfo("started backup task '$backup_job_uuid'");
 741
 742         $self->resume_vm_after_job_start($task, $vmid);
 743
 744         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 745     };
 746     my $err = $@;
 747     if ($err) {
 748         $self->logerr($err);
 749         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 750     }
 751
 752     $self->restore_vm_power_state($vmid);
 753
 754     if ($err) {
 755         if ($cpid) {
 756             kill(9, $cpid);
 757             waitpid($cpid, 0);
 758         }
 759         die $err;
 760     }
 761
 762     if ($cpid && (waitpid($cpid, 0) > 0)) {
 763         my $stat = $?;
 764         my $ec = $stat >> 8;
 765         my $signal = $stat & 127;
 766         if ($ec || $signal) {
 767             die "$comp failed - wrong exit status $ec" .
 768                 ($signal ? " (signal $signal)\n" : "\n");
 769         }
 770     }
 771 }
 772
 773 sub _get_task_devlist {
 774     my ($task) = @_;
 775
 776     my $devlist = '';
 777     foreach my $di (@{$task->{disks}}) {
 778         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 779             $devlist .= ',' if $devlist;
 780             $devlist .= $di->{qmdevice};
 781         } else {
 782             die "implement me (type '$di->{type}')";
 783         }
 784     }
 785     return $devlist;
 786 }
 787
 788 sub qga_fs_freeze {
 789     my ($self, $task, $vmid) = @_;
 790     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 791
 792     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 793         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 794         return;
 795     }
 796
 797     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 798     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 799     $self->logerr($@) if $@;
 800
 801     return 1; # even on mon command error, ensure we always thaw again
 802 }
 803
 804 # only call if fs_freeze return 1
 805 sub qga_fs_thaw {
 806     my ($self, $vmid) = @_;
 807
 808     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 809     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 810     $self->logerr($@) if $@;
 811 }
 812
 813 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 814 # one if VM isn't already running
 815 sub enforce_vm_running_for_backup {
 816     my ($self, $vmid) = @_;
 817
 818     if (PVE::QemuServer::check_running($vmid)) {
 819         $self->{vm_was_running} = 1;
 820         return;
 821     }
 822
 823     eval {
 824         $self->loginfo("starting kvm to execute backup task");
 825         # start with skiplock
 826         my $params = {
 827             skiplock => 1,
 828             skiptemplate => 1,
 829             paused => 1,
 830         };
 831         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 832     };
 833     die $@ if $@;
 834 }
 835
 836 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 837 sub resume_vm_after_job_start {
 838     my ($self, $task, $vmid) = @_;
 839
 840     return if !$self->{vm_was_running};
 841
 842     if (my $stoptime = $task->{vmstoptime}) {
 843         my $delay = time() - $task->{vmstoptime};
 844         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 845         $self->loginfo("resuming VM again after $delay seconds");
 846     } else {
 847         $self->loginfo("resuming VM again");
 848     }
 849     mon_cmd($vmid, 'cont');
 850 }
 851
 852 # stop again if VM was not running before
 853 sub restore_vm_power_state {
 854     my ($self, $vmid) = @_;
 855
 856     # we always let VMs keep running
 857     return if $self->{vm_was_running};
 858
 859     eval {
 860         my $resp = mon_cmd($vmid, 'query-status');
 861         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 862         if ($status eq 'prelaunch') {
 863             $self->loginfo("stopping kvm after backup task");
 864             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 865         } else {
 866             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 867         }
 868     };
 869     warn $@ if $@;
 870 }
 871
 872 sub mon_backup_cancel {
 873     my ($self, $vmid) = @_;
 874
 875     $self->loginfo("aborting backup job");
 876     eval { mon_cmd($vmid, 'backup-cancel') };
 877     $self->logerr($@) if $@;
 878 }
 879
 880 sub snapshot {
 881     my ($self, $task, $vmid) = @_;
 882
 883     # nothing to do
 884 }
 885
 886 sub cleanup {
 887     my ($self, $task, $vmid) = @_;
 888
 889     # nothing to do ?
 890 }
 891
 892 1;