PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 };
 277
 278 my $query_backup_status_loop = sub {
 279     my ($self, $vmid, $job_uuid) = @_;
 280
 281     my $starttime = time ();
 282     my $last_time = $starttime;
 283     my ($last_percent, $last_total, $last_target,  $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 284     my ($transferred, $reused);
 285     my $first_round = 1;
 286
 287     my $get_mbps = sub {
 288         my ($mb, $delta) = @_;
 289         return "0 B/s" if $mb <= 0;
 290         my $bw = int(($mb / $delta));
 291         return bytes_to_human($bw) . "/s";
 292     };
 293
 294     while(1) {
 295         my $status = mon_cmd($vmid, 'query-backup');
 296
 297         my $total = $status->{total} || 0;
 298         my $dirty = $status->{dirty};
 299         my $target = (defined($dirty) && $dirty < $total) ? $dirty : $total;
 300         $transferred = $status->{transferred} || 0;
 301         $reused = $status->{reused};
 302         my $percent = $target ? int(($transferred * 100)/$target) : 0;
 303         my $zero = $status->{'zero-bytes'} || 0;
 304
 305         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 306
 307         my $ctime = time();
 308         my $duration = $ctime - $starttime;
 309
 310         my $rbytes = $transferred - $last_transferred;
 311         my $wbytes = $rbytes - ($zero - $last_zero);
 312
 313         my $timediff = ($ctime - $last_time) || 1; # fixme
 314         my $mbps_read = $get_mbps->($rbytes, $timediff);
 315         my $mbps_write = $get_mbps->($wbytes, $timediff);
 316         my $target_h = bytes_to_human($target);
 317         my $transferred_h = bytes_to_human($transferred);
 318
 319         if ($first_round && $target != $total) {
 320             my $total_h = bytes_to_human($total);
 321             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 322         }
 323
 324         my $statusline = "status: $percent% ($transferred_h of $target_h), duration $duration"
 325             .", read: $mbps_read, write: $mbps_write";
 326
 327         my $res = $status->{status} || 'unknown';
 328         if ($res ne 'active') {
 329             $self->loginfo($statusline);
 330             if ($res ne 'done') {
 331                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 332                 die "got unexpected status '$res'\n";
 333             }
 334             last;
 335         }
 336         if ($percent != $last_percent && ($timediff > 2)) {
 337             $self->loginfo($statusline);
 338             $last_percent = $percent;
 339             $last_target = $target if $target;
 340             $last_total = $total if $total;
 341             $last_zero = $zero if $zero;
 342             $last_transferred = $transferred if $transferred;
 343             $last_time = $ctime;
 344         }
 345         sleep(1);
 346         $first_round = 0;
 347     }
 348
 349     my $duration = time() - $starttime;
 350     if ($transferred && $duration) {
 351         my $transferred_h = bytes_to_human($transferred, 2);
 352         my $mbps = $get_mbps->($transferred, $duration);
 353         if ($reused) {
 354             my $reused_h = bytes_to_human($reused, 2);
 355             my $reuse_per = int($reused * 100 / $last_total);
 356             $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%) from last backup");
 357             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 358         } else {
 359             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 360         }
 361     }
 362
 363     if ($last_zero) {
 364         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 365         my $zero_h = bytes_to_human($last_zero, 2);
 366         $self->loginfo("Backup is sparse: ${zero_per}% ($zero_h) zero data");
 367     }
 368 };
 369
 370 sub archive_pbs {
 371     my ($self, $task, $vmid) = @_;
 372
 373     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 374     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 375
 376     my $opts = $self->{vzdump}->{opts};
 377     my $scfg = $opts->{scfg};
 378
 379     my $starttime = time();
 380
 381     my $server = $scfg->{server};
 382     my $datastore = $scfg->{datastore};
 383     my $username = $scfg->{username} // 'root@pam';
 384     my $fingerprint = $scfg->{fingerprint};
 385
 386     my $repo = "$username\@$server:$datastore";
 387     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 388
 389     my $diskcount = scalar(@{$task->{disks}});
 390     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 391         my @pathlist;
 392         foreach my $di (@{$task->{disks}}) {
 393             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 394                 push @pathlist, "$di->{qmdevice}.img:$di->{path}";
 395             } else {
 396                 die "implement me (type $di->{type})";
 397             }
 398         }
 399
 400         if (!$diskcount) {
 401             $self->loginfo("backup contains no disks");
 402         }
 403
 404         local $ENV{PBS_PASSWORD} = $password;
 405         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 406         my $cmd = [
 407             '/usr/bin/proxmox-backup-client',
 408             'backup',
 409             '--repository', $repo,
 410             '--backup-type', 'vm',
 411             '--backup-id', "$vmid",
 412             '--backup-time', $task->{backup_time},
 413         ];
 414
 415         push @$cmd, "qemu-server.conf:$conffile";
 416         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 417         push @$cmd, @pathlist if scalar(@pathlist);
 418
 419         $self->loginfo("starting template backup");
 420         $self->loginfo(join(' ', @$cmd));
 421
 422         $self->cmd($cmd);
 423
 424         return;
 425     }
 426
 427     # get list early so we die on unkown drive types before doing anything
 428     my $devlist = _get_task_devlist($task);
 429
 430     $self->enforce_vm_running_for_backup($vmid);
 431
 432     my $backup_job_uuid;
 433     eval {
 434         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 435             die "interrupted by signal\n";
 436         };
 437
 438         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 439
 440         my $params = {
 441             format => "pbs",
 442             'backup-file' => $repo,
 443             'backup-id' => "$vmid",
 444             'backup-time' => $task->{backup_time},
 445             password => $password,
 446             devlist => $devlist,
 447             'config-file' => $conffile,
 448             'use-dirty-bitmap' => JSON::true,
 449         };
 450         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 451         $params->{'firewall-file'} = $firewall if -e $firewall;
 452
 453         $params->{timeout} = 60; # give some time to connect to the backup server
 454
 455         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 456         my $qmperr = $@;
 457         $backup_job_uuid = $res->{UUID} if $res;
 458
 459         if ($fs_frozen) {
 460             $self->qga_fs_thaw($vmid);
 461         }
 462
 463         die $qmperr if $qmperr;
 464         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 465
 466         $self->loginfo("started backup task '$backup_job_uuid'");
 467
 468         $self->resume_vm_after_job_start($task, $vmid);
 469
 470         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 471     };
 472     my $err = $@;
 473     if ($err) {
 474         $self->logerr($err);
 475         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 476     }
 477     $self->restore_vm_power_state($vmid);
 478
 479     die $err if $err;
 480 }
 481
 482 my $fork_compressor_pipe = sub {
 483     my ($self, $comp, $outfileno) = @_;
 484
 485     my @pipefd = POSIX::pipe();
 486     my $cpid = fork();
 487     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 488     if ($cpid == 0) {
 489         eval {
 490             POSIX::close($pipefd[1]);
 491             # redirect STDIN
 492             my $fd = fileno(STDIN);
 493             close STDIN;
 494             POSIX::close(0) if $fd != 0;
 495             die "unable to redirect STDIN - $!"
 496                 if !open(STDIN, "<&", $pipefd[0]);
 497
 498             # redirect STDOUT
 499             $fd = fileno(STDOUT);
 500             close STDOUT;
 501             POSIX::close (1) if $fd != 1;
 502
 503             die "unable to redirect STDOUT - $!"
 504                 if !open(STDOUT, ">&", $outfileno);
 505
 506             exec($comp);
 507             die "fork compressor '$comp' failed\n";
 508         };
 509         if (my $err = $@) {
 510             $self->logerr($err);
 511             POSIX::_exit(1);
 512         }
 513         POSIX::_exit(0);
 514         kill(-9, $$);
 515     } else {
 516         POSIX::close($pipefd[0]);
 517         $outfileno = $pipefd[1];
 518     }
 519
 520     return ($cpid, $outfileno);
 521 };
 522
 523 sub archive_vma {
 524     my ($self, $task, $vmid, $filename, $comp) = @_;
 525
 526     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 527     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 528
 529     my $opts = $self->{vzdump}->{opts};
 530
 531     my $starttime = time();
 532
 533     my $speed = 0;
 534     if ($opts->{bwlimit}) {
 535         $speed = $opts->{bwlimit}*1024;
 536     }
 537
 538     my $diskcount = scalar(@{$task->{disks}});
 539     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 540         my @pathlist;
 541         foreach my $di (@{$task->{disks}}) {
 542             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 543                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 544             } else {
 545                 die "implement me";
 546             }
 547         }
 548
 549         if (!$diskcount) {
 550             $self->loginfo("backup contains no disks");
 551         }
 552
 553         my $outcmd;
 554         if ($comp) {
 555             $outcmd = "exec:$comp";
 556         } else {
 557             $outcmd = "exec:cat";
 558         }
 559
 560         $outcmd .= " > $filename" if !$opts->{stdout};
 561
 562         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 563         push @$cmd, '-c', $firewall if -e $firewall;
 564         push @$cmd, $outcmd, @pathlist;
 565
 566         $self->loginfo("starting template backup");
 567         $self->loginfo(join(' ', @$cmd));
 568
 569         if ($opts->{stdout}) {
 570             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 571         } else {
 572             $self->cmd($cmd);
 573         }
 574
 575         return;
 576     }
 577
 578     my $devlist = _get_task_devlist($task);
 579
 580     $self->enforce_vm_running_for_backup($vmid);
 581
 582     my $cpid;
 583     my $backup_job_uuid;
 584
 585     eval {
 586         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 587             die "interrupted by signal\n";
 588         };
 589
 590         my $outfh;
 591         if ($opts->{stdout}) {
 592             $outfh = $opts->{stdout};
 593         } else {
 594             $outfh = IO::File->new($filename, "w") ||
 595                 die "unable to open file '$filename' - $!\n";
 596         }
 597         my $outfileno = fileno($outfh);
 598
 599         if ($comp) {
 600             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 601         }
 602
 603         my $qmpclient = PVE::QMPClient->new();
 604         my $backup_cb = sub {
 605             my ($vmid, $resp) = @_;
 606             $backup_job_uuid = $resp->{return}->{UUID};
 607         };
 608         my $add_fd_cb = sub {
 609             my ($vmid, $resp) = @_;
 610
 611             my $params = {
 612                 'backup-file' => "/dev/fdname/backup",
 613                 speed => $speed,
 614                 'config-file' => $conffile,
 615                 devlist => $devlist
 616             };
 617             $params->{'firewall-file'} = $firewall if -e $firewall;
 618
 619             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 620         };
 621
 622         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 623
 624         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 625
 626         eval { $qmpclient->queue_execute(30) };
 627         my $qmperr = $@;
 628
 629         if ($fs_frozen) {
 630             $self->qga_fs_thaw($vmid);
 631         }
 632
 633         die $qmperr if $qmperr;
 634         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 635
 636         if ($cpid) {
 637             POSIX::close($outfileno) == 0 ||
 638                 die "close output file handle failed\n";
 639         }
 640
 641         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 642
 643         $self->loginfo("started backup task '$backup_job_uuid'");
 644
 645         $self->resume_vm_after_job_start($task, $vmid);
 646
 647         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 648     };
 649     my $err = $@;
 650     if ($err) {
 651         $self->logerr($err);
 652         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 653     }
 654
 655     $self->restore_vm_power_state($vmid);
 656
 657     if ($err) {
 658         if ($cpid) {
 659             kill(9, $cpid);
 660             waitpid($cpid, 0);
 661         }
 662         die $err;
 663     }
 664
 665     if ($cpid && (waitpid($cpid, 0) > 0)) {
 666         my $stat = $?;
 667         my $ec = $stat >> 8;
 668         my $signal = $stat & 127;
 669         if ($ec || $signal) {
 670             die "$comp failed - wrong exit status $ec" .
 671                 ($signal ? " (signal $signal)\n" : "\n");
 672         }
 673     }
 674 }
 675
 676 sub _get_task_devlist {
 677     my ($task) = @_;
 678
 679     my $devlist = '';
 680     foreach my $di (@{$task->{disks}}) {
 681         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 682             $devlist .= ',' if $devlist;
 683             $devlist .= $di->{qmdevice};
 684         } else {
 685             die "implement me (type '$di->{type}')";
 686         }
 687     }
 688     return $devlist;
 689 }
 690
 691 sub qga_fs_freeze {
 692     my ($self, $task, $vmid) = @_;
 693     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 694
 695     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 696         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 697         return;
 698     }
 699
 700     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 701     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 702     $self->logerr($@) if $@;
 703
 704     return 1; # even on mon command error, ensure we always thaw again
 705 }
 706
 707 # only call if fs_freeze return 1
 708 sub qga_fs_thaw {
 709     my ($self, $vmid) = @_;
 710
 711     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 712     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 713     $self->logerr($@) if $@;
 714 }
 715
 716 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 717 # one if VM isn't already running
 718 sub enforce_vm_running_for_backup {
 719     my ($self, $vmid) = @_;
 720
 721     if (PVE::QemuServer::check_running($vmid)) {
 722         $self->{vm_was_running} = 1;
 723         return;
 724     }
 725
 726     eval {
 727         $self->loginfo("starting kvm to execute backup task");
 728         # start with skiplock
 729         my $params = {
 730             skiplock => 1,
 731             paused => 1,
 732         };
 733         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 734     };
 735     die $@ if $@;
 736 }
 737
 738 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 739 sub resume_vm_after_job_start {
 740     my ($self, $task, $vmid) = @_;
 741
 742     return if !$self->{vm_was_running};
 743
 744     if (my $stoptime = $task->{vmstoptime}) {
 745         my $delay = time() - $task->{vmstoptime};
 746         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 747         $self->loginfo("resuming VM again after $delay seconds");
 748     } else {
 749         $self->loginfo("resuming VM again");
 750     }
 751     mon_cmd($vmid, 'cont');
 752 }
 753
 754 # stop again if VM was not running before
 755 sub restore_vm_power_state {
 756     my ($self, $vmid) = @_;
 757
 758     # we always let VMs keep running
 759     return if $self->{vm_was_running};
 760
 761     eval {
 762         my $resp = mon_cmd($vmid, 'query-status');
 763         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 764         if ($status eq 'prelaunch') {
 765             $self->loginfo("stopping kvm after backup task");
 766             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 767         } else {
 768             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 769         }
 770     };
 771     warn $@ if $@;
 772 }
 773
 774 sub mon_backup_cancel {
 775     my ($self, $vmid) = @_;
 776
 777     $self->loginfo("aborting backup job");
 778     eval { mon_cmd($vmid, 'backup-cancel') };
 779     $self->logerr($@) if $@;
 780 }
 781
 782 sub snapshot {
 783     my ($self, $task, $vmid) = @_;
 784
 785     # nothing to do
 786 }
 787
 788 sub cleanup {
 789     my ($self, $task, $vmid) = @_;
 790
 791     # nothing to do ?
 792 }
 793
 794 1;