PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11 use POSIX qw(EINTR EAGAIN);
  12
  13 use PVE::Cluster qw(cfs_read_file);
  14 use PVE::INotify;
  15 use PVE::IPCC;
  16 use PVE::JSONSchema;
  17 use PVE::PBSClient;
  18 use PVE::RESTEnvironment qw(log_warn);
  19 use PVE::QMPClient;
  20 use PVE::Storage::Plugin;
  21 use PVE::Storage::PBSPlugin;
  22 use PVE::Storage;
  23 use PVE::Tools;
  24 use PVE::VZDump;
  25 use PVE::Format qw(render_duration render_bytes);
  26
  27 use PVE::QemuConfig;
  28 use PVE::QemuServer;
  29 use PVE::QemuServer::Machine;
  30 use PVE::QemuServer::Monitor qw(mon_cmd);
  31
  32 use base qw (PVE::VZDump::Plugin);
  33
  34 sub new {
  35     my ($class, $vzdump) = @_;
  36
  37     PVE::VZDump::check_bin('qm');
  38
  39     my $self = bless { vzdump => $vzdump }, $class;
  40
  41     $self->{vmlist} = PVE::QemuServer::vzlist();
  42     $self->{storecfg} = PVE::Storage::config();
  43
  44     return $self;
  45 };
  46
  47 sub type {
  48     return 'qemu';
  49 }
  50
  51 sub vmlist {
  52     my ($self) = @_;
  53     return [ keys %{$self->{vmlist}} ];
  54 }
  55
  56 sub prepare {
  57     my ($self, $task, $vmid, $mode) = @_;
  58
  59     $task->{disks} = [];
  60
  61     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  62
  63     $self->loginfo("VM Name: $conf->{name}")
  64         if defined($conf->{name});
  65
  66     $self->{vm_was_running} = 1;
  67     $self->{vm_was_paused} = 0;
  68     if (!PVE::QemuServer::check_running($vmid)) {
  69         $self->{vm_was_running} = 0;
  70     } elsif (PVE::QemuServer::vm_is_paused($vmid, 0)) {
  71         # Do not treat a suspended VM as paused, as it would cause us to skip
  72         # fs-freeze even if the VM wakes up before we reach qga_fs_freeze.
  73         $self->{vm_was_paused} = 1;
  74     }
  75
  76     $task->{hostname} = $conf->{name};
  77
  78     my $hostname = PVE::INotify::nodename();
  79
  80     my $vollist = [];
  81     my $drivehash = {};
  82     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  83
  84     foreach my $volume (@{$backup_volumes}) {
  85         my $name = $volume->{key};
  86         my $volume_config = $volume->{volume_config};
  87         my $volid = $volume_config->{file};
  88
  89         if (!$volume->{included}) {
  90             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  91             next;
  92         } elsif ($self->{vm_was_running} && $volume_config->{iothread} &&
  93                  !PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  94             die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  95                 "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  96         } else {
  97             my $log = "include disk '$name' '$volid'";
  98             if (defined(my $size = $volume_config->{size})) {
  99                 my $readable_size = PVE::JSONSchema::format_size($size);
 100                 $log .= " $readable_size";
 101             }
 102             $self->loginfo($log);
 103         }
 104
 105         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 106         push @$vollist, $volid if $storeid;
 107         $drivehash->{$name} = $volume->{volume_config};
 108     }
 109
 110     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 111
 112     foreach my $ds (sort keys %$drivehash) {
 113         my $drive = $drivehash->{$ds};
 114
 115         my $volid = $drive->{file};
 116         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 117
 118         my $path = $volid;
 119         if ($storeid) {
 120             $path = PVE::Storage::path($self->{storecfg}, $volid);
 121         }
 122         next if !$path;
 123
 124         my ($size, $format);
 125         if ($storeid) {
 126             # The call in list context can be expensive for certain plugins like RBD, just get size
 127             $size = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 128             die "cannot determine size of volume '$volid' - $@\n" if $@;
 129
 130             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 131             $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 132         } else {
 133             ($size, $format) = eval {
 134                 PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5);
 135             };
 136             die "cannot determine size and format of volume '$volid' - $@\n" if $@;
 137         }
 138
 139         my $diskinfo = {
 140             path => $path,
 141             volid => $volid,
 142             storeid => $storeid,
 143             format => $format,
 144             virtdev => $ds,
 145             qmdevice => "drive-$ds",
 146         };
 147
 148         if ($ds eq 'tpmstate0') {
 149             # TPM drive only exists for backup, which is reflected in the name
 150             $diskinfo->{qmdevice} = 'drive-tpmstate0-backup';
 151             $task->{tpmpath} = $path;
 152         }
 153
 154         if (-b $path) {
 155             $diskinfo->{type} = 'block';
 156         } else {
 157             $diskinfo->{type} = 'file';
 158         }
 159
 160         push @{$task->{disks}}, $diskinfo;
 161     }
 162 }
 163
 164 sub vm_status {
 165     my ($self, $vmid) = @_;
 166
 167     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 168
 169     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 170 }
 171
 172 sub lock_vm {
 173     my ($self, $vmid) = @_;
 174
 175     PVE::QemuConfig->set_lock($vmid, 'backup');
 176 }
 177
 178 sub unlock_vm {
 179     my ($self, $vmid) = @_;
 180
 181     PVE::QemuConfig->remove_lock($vmid, 'backup');
 182 }
 183
 184 sub stop_vm {
 185     my ($self, $task, $vmid) = @_;
 186
 187     my $opts = $self->{vzdump}->{opts};
 188
 189     my $wait = $opts->{stopwait} * 60;
 190     # send shutdown and wait
 191     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 192 }
 193
 194 sub start_vm {
 195     my ($self, $task, $vmid) = @_;
 196
 197     $self->cmd ("qm start $vmid --skiplock");
 198 }
 199
 200 sub suspend_vm {
 201     my ($self, $task, $vmid) = @_;
 202
 203     return if $self->{vm_was_paused};
 204
 205     $self->cmd ("qm suspend $vmid --skiplock");
 206 }
 207
 208 sub resume_vm {
 209     my ($self, $task, $vmid) = @_;
 210
 211     return if $self->{vm_was_paused};
 212
 213     $self->cmd ("qm resume $vmid --skiplock");
 214 }
 215
 216 sub assemble {
 217     my ($self, $task, $vmid) = @_;
 218
 219     my $conffile = PVE::QemuConfig->config_file($vmid);
 220
 221     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 222     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 223     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 224
 225     my $outfd = IO::File->new (">$outfile") ||
 226         die "unable to open '$outfile'";
 227     my $conffd = IO::File->new ($conffile, 'r') ||
 228         die "unable open '$conffile'";
 229
 230     my $found_snapshot;
 231     my $found_pending;
 232     my $found_cloudinit;
 233     while (defined (my $line = <$conffd>)) {
 234         next if $line =~ m/^\#vzdump\#/; # just to be sure
 235         next if $line =~ m/^\#qmdump\#/; # just to be sure
 236         if ($line =~ m/^\[(.*)\]\s*$/) {
 237             if ($1 =~ m/PENDING/i) {
 238                 $found_pending = 1;
 239             } elsif ($1 =~ m/special:cloudinit/) {
 240                 $found_cloudinit = 1;
 241             } else {
 242                 $found_snapshot = 1;
 243             }
 244         }
 245         next if $found_snapshot || $found_pending || $found_cloudinit; # skip all snapshots,pending changes and cloudinit config data
 246
 247         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 248             $self->loginfo("skip unused drive '$1' (not included into backup)");
 249             next;
 250         }
 251         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 252
 253         print $outfd $line;
 254     }
 255
 256     foreach my $di (@{$task->{disks}}) {
 257         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 258             my $storeid = $di->{storeid} || '';
 259             my $format = $di->{format} || '';
 260             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 261         } else {
 262             die "internal error";
 263         }
 264     }
 265
 266     if ($found_snapshot) {
 267         $self->loginfo("snapshots found (not included into backup)");
 268     }
 269     if ($found_pending) {
 270         $self->loginfo("pending configuration changes found (not included into backup)");
 271     }
 272
 273     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 274 }
 275
 276 sub archive {
 277     my ($self, $task, $vmid, $filename, $comp) = @_;
 278
 279     my $opts = $self->{vzdump}->{opts};
 280     my $scfg = $opts->{scfg};
 281
 282     if ($self->{vzdump}->{opts}->{pbs}) {
 283         $self->archive_pbs($task, $vmid);
 284     } else {
 285         $self->archive_vma($task, $vmid, $filename, $comp);
 286     }
 287 }
 288
 289 my $bitmap_action_to_human = sub {
 290     my ($self, $info) = @_;
 291
 292     my $action = $info->{action};
 293
 294     if ($action eq "not-used") {
 295         return "disabled (no support)";
 296     } elsif ($action eq "not-used-removed") {
 297         return "disabled (old bitmap cleared)";
 298     } elsif ($action eq "new") {
 299         return "created new";
 300     } elsif ($action eq "used") {
 301         if ($info->{dirty} == 0) {
 302             return "OK (drive clean)";
 303         } else {
 304             my $size = render_bytes($info->{size}, 1);
 305             my $dirty = render_bytes($info->{dirty}, 1);
 306             return "OK ($dirty of $size dirty)";
 307         }
 308     } elsif ($action eq "invalid") {
 309         return "existing bitmap was invalid and has been cleared";
 310     } else {
 311         return "unknown";
 312     }
 313 };
 314
 315 my $query_backup_status_loop = sub {
 316     my ($self, $vmid, $job_uuid, $qemu_support) = @_;
 317
 318     my $starttime = time ();
 319     my $last_time = $starttime;
 320     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 321     my ($transferred, $reused);
 322
 323     my $get_mbps = sub {
 324         my ($mb, $delta) = @_;
 325         return "0 B/s" if $mb <= 0;
 326         my $bw = int(($mb / $delta));
 327         return render_bytes($bw, 1) . "/s";
 328     };
 329
 330     my $target = 0;
 331     my $last_reused = 0;
 332     my $has_query_bitmap = $qemu_support && $qemu_support->{'query-bitmap-info'};
 333     my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 334     if ($has_query_bitmap) {
 335         my $total = 0;
 336         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 337         for my $info (sort { $a->{drive} cmp $b->{drive} } @$bitmap_info) {
 338             if (!$is_template) {
 339                 my $text = $bitmap_action_to_human->($self, $info);
 340                 my $drive = $info->{drive};
 341                 $drive =~ s/^drive-//; # for consistency
 342                 $self->loginfo("$drive: dirty-bitmap status: $text");
 343             }
 344             $target += $info->{dirty};
 345             $total += $info->{size};
 346             $last_reused += $info->{size} - $info->{dirty};
 347         }
 348         if ($target < $total) {
 349             my $total_h = render_bytes($total, 1);
 350             my $target_h = render_bytes($target, 1);
 351             $self->loginfo("using fast incremental mode (dirty-bitmap), $target_h dirty of $total_h total");
 352         }
 353     }
 354
 355     my $last_finishing = 0;
 356     while(1) {
 357         my $status = mon_cmd($vmid, 'query-backup');
 358
 359         my $total = $status->{total} || 0;
 360         my $dirty = $status->{dirty};
 361         $target = (defined($dirty) && $dirty < $total) ? $dirty : $total if !$has_query_bitmap;
 362         $transferred = $status->{transferred} || 0;
 363         $reused = $status->{reused};
 364         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 365         my $zero = $status->{'zero-bytes'} || 0;
 366
 367         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 368
 369         my $ctime = time();
 370         my $duration = $ctime - $starttime;
 371
 372         my $rbytes = $transferred - $last_transferred;
 373         my $wbytes;
 374         if ($reused) {
 375             # reused includes zero bytes for PBS
 376             $wbytes = $rbytes - ($reused - $last_reused);
 377         } else {
 378             $wbytes = $rbytes - ($zero - $last_zero);
 379         }
 380
 381         my $timediff = ($ctime - $last_time) || 1; # fixme
 382         my $mbps_read = $get_mbps->($rbytes, $timediff);
 383         my $mbps_write = $get_mbps->($wbytes, $timediff);
 384         my $target_h = render_bytes($target, 1);
 385         my $transferred_h = render_bytes($transferred, 1);
 386
 387         my $statusline = sprintf("%3d%% ($transferred_h of $target_h) in %s"
 388             .", read: $mbps_read, write: $mbps_write", $percent, render_duration($duration));
 389
 390         my $res = $status->{status} || 'unknown';
 391         if ($res ne 'active') {
 392             if ($last_percent < 100) {
 393                 $self->loginfo($statusline);
 394             }
 395             if ($res ne 'done') {
 396                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 397                 die "got unexpected status '$res'\n";
 398             }
 399             $last_target = $target if $target;
 400             $last_total = $total if $total;
 401             $last_zero = $zero if $zero;
 402             $last_transferred = $transferred if $transferred;
 403             last;
 404         }
 405         if ($percent != $last_percent && ($timediff > 2)) {
 406             $self->loginfo($statusline);
 407             $last_percent = $percent;
 408             $last_target = $target if $target;
 409             $last_total = $total if $total;
 410             $last_zero = $zero if $zero;
 411             $last_transferred = $transferred if $transferred;
 412             $last_time = $ctime;
 413             $last_reused = $reused;
 414
 415             if (!$last_finishing && $status->{finishing}) {
 416                 $self->loginfo("Waiting for server to finish backup validation...");
 417             }
 418             $last_finishing = $status->{finishing};
 419         }
 420         sleep(1);
 421     }
 422
 423     my $duration = time() - $starttime;
 424
 425     if ($last_zero) {
 426         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 427         my $zero_h = render_bytes($last_zero);
 428         $self->loginfo("backup is sparse: $zero_h (${zero_per}%) total zero data");
 429     }
 430     if ($reused) {
 431         my $reused_h = render_bytes($reused);
 432         my $reuse_per = int($reused * 100 / $last_total);
 433         $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 434     }
 435     if ($transferred) {
 436         my $transferred_h = render_bytes($transferred);
 437         if ($duration) {
 438             my $mbps = $get_mbps->($transferred, $duration);
 439             $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 440         } else {
 441             $self->loginfo("transferred $transferred_h in <1 seconds");
 442         }
 443     }
 444
 445     return {
 446         total => $last_total,
 447         reused => $reused,
 448     };
 449 };
 450
 451 my $attach_tpmstate_drive = sub {
 452     my ($self, $task, $vmid) = @_;
 453
 454     return if !$task->{tpmpath};
 455
 456     # unconditionally try to remove the tpmstate-named drive - it only exists
 457     # for backing up, and avoids errors if left over from some previous event
 458     eval { PVE::QemuServer::qemu_drivedel($vmid, "tpmstate0-backup"); };
 459
 460     $self->loginfo('attaching TPM drive to QEMU for backup');
 461
 462     my $drive = "file=$task->{tpmpath},if=none,read-only=on,id=drive-tpmstate0-backup";
 463     $drive =~ s/\\/\\\\/g;
 464     my $ret = PVE::QemuServer::Monitor::hmp_cmd($vmid, "drive_add auto \"$drive\"");
 465     die "attaching TPM drive failed - $ret\n" if $ret !~ m/OK/s;
 466 };
 467
 468 my $detach_tpmstate_drive = sub {
 469     my ($task, $vmid) = @_;
 470     return if !$task->{tpmpath} || !PVE::QemuServer::check_running($vmid);
 471     eval { PVE::QemuServer::qemu_drivedel($vmid, "tpmstate0-backup"); };
 472 };
 473
 474 my sub add_backup_performance_options {
 475     my ($qmp_param, $perf, $qemu_support) = @_;
 476
 477     return if !$perf || scalar(keys $perf->%*) == 0;
 478
 479     if (!$qemu_support) {
 480         my $settings_string = join(', ', sort keys $perf->%*);
 481         log_warn("ignoring setting(s): $settings_string - issue checking if supported");
 482         return;
 483     }
 484
 485     if (defined($perf->{'max-workers'})) {
 486         if ($qemu_support->{'backup-max-workers'}) {
 487             $qmp_param->{'max-workers'} = int($perf->{'max-workers'});
 488         } else {
 489             log_warn("ignoring 'max-workers' setting - not supported by running QEMU");
 490         }
 491     }
 492 }
 493
 494 sub get_and_check_pbs_encryption_config {
 495     my ($self) = @_;
 496
 497     my $opts = $self->{vzdump}->{opts};
 498     my $scfg = $opts->{scfg};
 499
 500     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 501     my $master_keyfile = PVE::Storage::PBSPlugin::pbs_master_pubkey_file_name($scfg, $opts->{storage});
 502
 503     if (-e $keyfile) {
 504         if (-e $master_keyfile) {
 505             $self->loginfo("enabling encryption with master key feature");
 506             return ($keyfile, $master_keyfile);
 507         } elsif ($scfg->{'master-pubkey'}) {
 508             die "master public key configured but no key file found\n";
 509         } else {
 510             $self->loginfo("enabling encryption");
 511             return ($keyfile, undef);
 512         }
 513     } else {
 514         my $encryption_fp = $scfg->{'encryption-key'};
 515         die "encryption configured ('$encryption_fp') but no encryption key file found!\n"
 516             if $encryption_fp;
 517         if (-e $master_keyfile) {
 518             $self->log(
 519                 'warn',
 520                 "backup target storage is configured with master-key, but no encryption key set!"
 521                 ." Ignoring master key settings and creating unencrypted backup."
 522             );
 523         }
 524         return (undef, undef);
 525     }
 526     die "internal error - unhandled case for getting & checking PBS encryption ($keyfile, $master_keyfile)!";
 527 }
 528
 529 sub archive_pbs {
 530     my ($self, $task, $vmid) = @_;
 531
 532     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 533     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 534
 535     my $opts = $self->{vzdump}->{opts};
 536     my $scfg = $opts->{scfg};
 537
 538     my $starttime = time();
 539
 540     my $fingerprint = $scfg->{fingerprint};
 541     my $repo = PVE::PBSClient::get_repository($scfg);
 542     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 543     my ($keyfile, $master_keyfile) = $self->get_and_check_pbs_encryption_config();
 544
 545     my $diskcount = scalar(@{$task->{disks}});
 546     # proxmox-backup-client can only handle raw files and block devs, so only use it (directly) for
 547     # disk-less VMs
 548     if (!$diskcount) {
 549         $self->loginfo("backup contains no disks");
 550
 551         local $ENV{PBS_PASSWORD} = $password;
 552         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 553         my $cmd = [
 554             '/usr/bin/proxmox-backup-client',
 555             'backup',
 556             '--repository', $repo,
 557             '--backup-type', 'vm',
 558             '--backup-id', "$vmid",
 559             '--backup-time', $task->{backup_time},
 560         ];
 561         if (defined(my $ns = $scfg->{namespace})) {
 562             push @$cmd, '--ns', $ns;
 563         }
 564         if (defined($keyfile)) {
 565             push @$cmd, '--keyfile', $keyfile;
 566             push @$cmd, '--master-pubkey-file', $master_keyfile if defined($master_keyfile);
 567         }
 568
 569         push @$cmd, "qemu-server.conf:$conffile";
 570         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 571
 572         $self->loginfo("starting template backup");
 573         $self->loginfo(join(' ', @$cmd));
 574
 575         $self->cmd($cmd);
 576
 577         return;
 578     }
 579
 580     # get list early so we die on unkown drive types before doing anything
 581     my $devlist = _get_task_devlist($task);
 582
 583     $self->enforce_vm_running_for_backup($vmid);
 584     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 585
 586     my $backup_job_uuid;
 587     eval {
 588         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 589             die "interrupted by signal\n";
 590         };
 591
 592         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 593         my $err = $@;
 594         if (!$qemu_support || $err) {
 595             die "query-proxmox-support returned empty value\n" if !$err;
 596             if ($err =~ m/The command query-proxmox-support has not been found/) {
 597                 die "PBS backups are not supported by the running QEMU version. Please make "
 598                   . "sure you've installed the latest version and the VM has been restarted.\n";
 599             } else {
 600                 die "QMP command query-proxmox-support failed - $err\n";
 601             }
 602         }
 603
 604         # pve-qemu supports it since 5.2.0-1 (PVE 6.4), so safe to die since PVE 8
 605         die "master key configured but running QEMU version does not support master keys\n"
 606             if !defined($qemu_support->{'pbs-masterkey'}) && defined($master_keyfile);
 607
 608         $attach_tpmstate_drive->($self, $task, $vmid);
 609
 610         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 611
 612         my $params = {
 613             format => "pbs",
 614             'backup-file' => $repo,
 615             'backup-id' => "$vmid",
 616             'backup-time' => $task->{backup_time},
 617             password => $password,
 618             devlist => $devlist,
 619             'config-file' => $conffile,
 620         };
 621         if (defined(my $ns = $scfg->{namespace})) {
 622             $params->{'backup-ns'} = $ns;
 623         }
 624
 625         $params->{speed} = $opts->{bwlimit}*1024 if $opts->{bwlimit};
 626         add_backup_performance_options($params, $opts->{performance}, $qemu_support);
 627
 628         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 629         $params->{'firewall-file'} = $firewall if -e $firewall;
 630
 631         $params->{encrypt} = defined($keyfile) ? JSON::true : JSON::false;
 632         if (defined($keyfile)) {
 633             $params->{keyfile} = $keyfile;
 634             $params->{"master-keyfile"} = $master_keyfile if defined($master_keyfile);
 635         }
 636
 637         my $is_template = PVE::QemuConfig->is_template($self->{vmlist}->{$vmid});
 638         $params->{'use-dirty-bitmap'} = JSON::true
 639             if $qemu_support->{'pbs-dirty-bitmap'} && !$is_template;
 640
 641         $params->{timeout} = 125; # give some time to connect to the backup server
 642
 643         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 644         my $qmperr = $@;
 645         $backup_job_uuid = $res->{UUID} if $res;
 646
 647         if ($fs_frozen) {
 648             $self->qga_fs_thaw($vmid);
 649         }
 650
 651         die $qmperr if $qmperr;
 652         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 653
 654         $self->loginfo("started backup task '$backup_job_uuid'");
 655
 656         $self->resume_vm_after_job_start($task, $vmid);
 657
 658         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 659         $task->{size} = $stat->{total};
 660     };
 661     my $err = $@;
 662     if ($err) {
 663         $self->logerr($err);
 664         $self->mon_backup_cancel($vmid);
 665         $self->resume_vm_after_job_start($task, $vmid);
 666     }
 667     $self->restore_vm_power_state($vmid);
 668
 669     die $err if $err;
 670 }
 671
 672 my $fork_compressor_pipe = sub {
 673     my ($self, $comp, $outfileno) = @_;
 674
 675     my @pipefd = POSIX::pipe();
 676     my $cpid = fork();
 677     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 678     if ($cpid == 0) {
 679         eval {
 680             POSIX::close($pipefd[1]);
 681             # redirect STDIN
 682             my $fd = fileno(STDIN);
 683             close STDIN;
 684             POSIX::close(0) if $fd != 0;
 685             die "unable to redirect STDIN - $!"
 686                 if !open(STDIN, "<&", $pipefd[0]);
 687
 688             # redirect STDOUT
 689             $fd = fileno(STDOUT);
 690             close STDOUT;
 691             POSIX::close (1) if $fd != 1;
 692
 693             die "unable to redirect STDOUT - $!"
 694                 if !open(STDOUT, ">&", $outfileno);
 695
 696             exec($comp);
 697             die "fork compressor '$comp' failed\n";
 698         };
 699         if (my $err = $@) {
 700             $self->logerr($err);
 701             POSIX::_exit(1);
 702         }
 703         POSIX::_exit(0);
 704         kill(-9, $$);
 705     } else {
 706         POSIX::close($pipefd[0]);
 707         $outfileno = $pipefd[1];
 708     }
 709
 710     return ($cpid, $outfileno);
 711 };
 712
 713 sub archive_vma {
 714     my ($self, $task, $vmid, $filename, $comp) = @_;
 715
 716     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 717     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 718
 719     my $opts = $self->{vzdump}->{opts};
 720
 721     my $starttime = time();
 722
 723     my $speed = 0;
 724     if ($opts->{bwlimit}) {
 725         $speed = $opts->{bwlimit}*1024;
 726     }
 727
 728     my $diskcount = scalar(@{$task->{disks}});
 729     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 730         my @pathlist;
 731         foreach my $di (@{$task->{disks}}) {
 732             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 733                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 734             } else {
 735                 die "implement me";
 736             }
 737         }
 738
 739         if (!$diskcount) {
 740             $self->loginfo("backup contains no disks");
 741         }
 742
 743         my $outcmd;
 744         if ($comp) {
 745             $outcmd = "exec:$comp";
 746         } else {
 747             $outcmd = "exec:cat";
 748         }
 749
 750         $outcmd .= " > $filename" if !$opts->{stdout};
 751
 752         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 753         push @$cmd, '-c', $firewall if -e $firewall;
 754         push @$cmd, $outcmd, @pathlist;
 755
 756         $self->loginfo("starting template backup");
 757         $self->loginfo(join(' ', @$cmd));
 758
 759         if ($opts->{stdout}) {
 760             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 761         } else {
 762             $self->cmd($cmd);
 763         }
 764
 765         return;
 766     }
 767
 768     my $devlist = _get_task_devlist($task);
 769
 770     $self->enforce_vm_running_for_backup($vmid);
 771     $self->{qmeventd_fh} = PVE::QemuServer::register_qmeventd_handle($vmid);
 772
 773     my $cpid;
 774     my $backup_job_uuid;
 775
 776     eval {
 777         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 778             die "interrupted by signal\n";
 779         };
 780
 781         # Currently, failing to determine Proxmox support is not critical here, because it's only
 782         # used for performance settings like 'max-workers'.
 783         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 784         log_warn($@) if $@;
 785
 786         $attach_tpmstate_drive->($self, $task, $vmid);
 787
 788         my $outfh;
 789         if ($opts->{stdout}) {
 790             $outfh = $opts->{stdout};
 791         } else {
 792             $outfh = IO::File->new($filename, "w") ||
 793                 die "unable to open file '$filename' - $!\n";
 794         }
 795         my $outfileno = fileno($outfh);
 796
 797         if ($comp) {
 798             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 799         }
 800
 801         my $qmpclient = PVE::QMPClient->new();
 802         my $backup_cb = sub {
 803             my ($vmid, $resp) = @_;
 804             $backup_job_uuid = $resp->{return}->{UUID};
 805         };
 806         my $add_fd_cb = sub {
 807             my ($vmid, $resp) = @_;
 808
 809             my $params = {
 810                 'backup-file' => "/dev/fdname/backup",
 811                 speed => $speed,
 812                 'config-file' => $conffile,
 813                 devlist => $devlist
 814             };
 815             $params->{'firewall-file'} = $firewall if -e $firewall;
 816             add_backup_performance_options($params, $opts->{performance}, $qemu_support);
 817
 818             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 819         };
 820
 821         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 822
 823         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 824
 825         eval { $qmpclient->queue_execute(30) };
 826         my $qmperr = $@;
 827
 828         if ($fs_frozen) {
 829             $self->qga_fs_thaw($vmid);
 830         }
 831
 832         die $qmperr if $qmperr;
 833         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 834
 835         if ($cpid) {
 836             POSIX::close($outfileno) == 0 ||
 837                 die "close output file handle failed\n";
 838         }
 839
 840         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 841
 842         $self->loginfo("started backup task '$backup_job_uuid'");
 843
 844         $self->resume_vm_after_job_start($task, $vmid);
 845
 846         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 847     };
 848     my $err = $@;
 849     if ($err) {
 850         $self->logerr($err);
 851         $self->mon_backup_cancel($vmid);
 852         $self->resume_vm_after_job_start($task, $vmid);
 853     }
 854
 855     $self->restore_vm_power_state($vmid);
 856
 857     if ($err) {
 858         if ($cpid) {
 859             kill(9, $cpid);
 860             waitpid($cpid, 0);
 861         }
 862         die $err;
 863     }
 864
 865     if ($cpid && (waitpid($cpid, 0) > 0)) {
 866         my $stat = $?;
 867         my $ec = $stat >> 8;
 868         my $signal = $stat & 127;
 869         if ($ec || $signal) {
 870             die "$comp failed - wrong exit status $ec" .
 871                 ($signal ? " (signal $signal)\n" : "\n");
 872         }
 873     }
 874 }
 875
 876 sub _get_task_devlist {
 877     my ($task) = @_;
 878
 879     my $devlist = '';
 880     foreach my $di (@{$task->{disks}}) {
 881         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 882             $devlist .= ',' if $devlist;
 883             $devlist .= $di->{qmdevice};
 884         } else {
 885             die "implement me (type '$di->{type}')";
 886         }
 887     }
 888     return $devlist;
 889 }
 890
 891 sub qga_fs_freeze {
 892     my ($self, $task, $vmid) = @_;
 893     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running} || $self->{vm_was_paused};
 894
 895     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 896         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 897         return;
 898     }
 899
 900     my $freeze = PVE::QemuServer::get_qga_key($self->{vmlist}->{$vmid}, 'freeze-fs-on-backup') // 1;
 901     if (!$freeze) {
 902         $self->loginfo("skipping guest-agent 'fs-freeze', disabled in VM options");
 903         return;
 904     }
 905
 906     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 907     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 908     $self->logerr($@) if $@;
 909
 910     return 1; # even on mon command error, ensure we always thaw again
 911 }
 912
 913 # only call if fs_freeze return 1
 914 sub qga_fs_thaw {
 915     my ($self, $vmid) = @_;
 916
 917     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 918     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 919     $self->logerr($@) if $@;
 920 }
 921
 922 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 923 # one if VM isn't already running
 924 sub enforce_vm_running_for_backup {
 925     my ($self, $vmid) = @_;
 926
 927     if (PVE::QemuServer::check_running($vmid)) {
 928         $self->{vm_was_running} = 1;
 929         return;
 930     }
 931
 932     eval {
 933         $self->loginfo("starting kvm to execute backup task");
 934         # start with skiplock
 935         my $params = {
 936             skiplock => 1,
 937             skiptemplate => 1,
 938             paused => 1,
 939         };
 940         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 941     };
 942     die $@ if $@;
 943 }
 944
 945 # resume VM again once in a clear state (stop mode backup of running VM)
 946 sub resume_vm_after_job_start {
 947     my ($self, $task, $vmid) = @_;
 948
 949     return if !$self->{vm_was_running} || $self->{vm_was_paused};
 950
 951     if (my $stoptime = $task->{vmstoptime}) {
 952         my $delay = time() - $task->{vmstoptime};
 953         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 954         $self->loginfo("resuming VM again after $delay seconds");
 955     } else {
 956         $self->loginfo("resuming VM again");
 957     }
 958     mon_cmd($vmid, 'cont', timeout => 45);
 959 }
 960
 961 # stop again if VM was not running before
 962 sub restore_vm_power_state {
 963     my ($self, $vmid) = @_;
 964
 965     # we always let VMs keep running
 966     return if $self->{vm_was_running};
 967
 968     eval {
 969         my $resp = mon_cmd($vmid, 'query-status');
 970         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 971         if ($status eq 'prelaunch') {
 972             $self->loginfo("stopping kvm after backup task");
 973             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 974         } else {
 975             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 976         }
 977     };
 978     warn $@ if $@;
 979 }
 980
 981 sub mon_backup_cancel {
 982     my ($self, $vmid) = @_;
 983
 984     $self->loginfo("aborting backup job");
 985     eval { mon_cmd($vmid, 'backup-cancel') };
 986     $self->logerr($@) if $@;
 987 }
 988
 989 sub snapshot {
 990     my ($self, $task, $vmid) = @_;
 991
 992     # nothing to do
 993 }
 994
 995 sub cleanup {
 996     my ($self, $task, $vmid) = @_;
 997
 998     $detach_tpmstate_drive->($task, $vmid);
 999
1000     if ($self->{qmeventd_fh}) {
1001         close($self->{qmeventd_fh});
1002     }
1003 }
1004
1005 1;