qm

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Getopt::Long;
   5 use Fcntl ':flock';
   6 use File::Path;
   7 use IO::Socket::UNIX;
   8 use IO::Select;
   9
  10 use PVE::Tools qw(extract_param);
  11 use PVE::Cluster;
  12 use PVE::SafeSyslog;
  13 use PVE::INotify;
  14 use PVE::RPCEnvironment;
  15 use PVE::QemuServer;
  16 use PVE::API2::Qemu;
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use Term::ReadLine;
  19
  20 use PVE::CLIHandler;
  21
  22 use base qw(PVE::CLIHandler);
  23
  24 $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
  25
  26 initlog('qm');
  27
  28 die "please run as root\n" if $> != 0;
  29
  30 PVE::INotify::inotify_init();
  31
  32 my $rpcenv = PVE::RPCEnvironment->init('cli');
  33
  34 $rpcenv->init_request();
  35 $rpcenv->set_language($ENV{LANG});
  36 $rpcenv->set_user('root@pam');
  37
  38 my $nodename = PVE::INotify::nodename();
  39
  40 PVE::JSONSchema::register_standard_option('skiplock', {
  41     description => "Ignore locks - only root is allowed to use this option.",
  42     type => 'boolean',
  43     optional => 1,
  44 });
  45
  46 sub run_vnc_proxy {
  47     my ($vmid) = @_;
  48
  49     my $path = PVE::QemuServer::vnc_socket($vmid);
  50
  51     my $s = IO::Socket::UNIX->new(Peer => $path, Timeout => 120);
  52
  53     die "unable to connect to socket '$path' - $!" if !$s;
  54
  55     my $select = new IO::Select;
  56
  57     $select->add(\*STDIN);
  58     $select->add($s);
  59
  60     my $timeout = 60*15; # 15 minutes
  61
  62     my @handles;
  63     while ($select->count &&
  64            scalar(@handles = $select->can_read ($timeout))) {
  65         foreach my $h (@handles) {
  66             my $buf;
  67             my $n = $h->sysread($buf, 4096);
  68
  69             if ($h == \*STDIN) {
  70                 if ($n) {
  71                     syswrite($s, $buf);
  72                 } else {
  73                     exit(0);
  74                 }
  75             } elsif ($h == $s) {
  76                 if ($n) {
  77                     syswrite(\*STDOUT, $buf);
  78                 } else {
  79                     exit(0);
  80                 }
  81             }
  82         }
  83     }
  84     exit(0);
  85 }
  86
  87 __PACKAGE__->register_method ({
  88     name => 'showcmd',
  89     path => 'showcmd',
  90     method => 'GET',
  91     description => "Show command line which is used to start the VM (debug info).",
  92     parameters => {
  93         additionalProperties => 0,
  94         properties => {
  95             vmid => get_standard_option('pve-vmid'),
  96         },
  97     },
  98     returns => { type => 'null'},
  99     code => sub {
 100         my ($param) = @_;
 101
 102         my $storecfg = PVE::Storage::config();
 103         print PVE::QemuServer::vm_commandline($storecfg, $param->{vmid}) . "\n";
 104
 105         return undef;
 106     }});
 107
 108 __PACKAGE__->register_method ({
 109     name => 'status',
 110     path => 'status',
 111     method => 'GET',
 112     description => "Show VM status.",
 113     parameters => {
 114         additionalProperties => 0,
 115         properties => {
 116             vmid => get_standard_option('pve-vmid'),
 117             verbose => {
 118                 description => "Verbose output format",
 119                 type => 'boolean',
 120                 optional => 1,
 121             }
 122         },
 123     },
 124     returns => { type => 'null'},
 125     code => sub {
 126         my ($param) = @_;
 127
 128         # test if VM exists
 129         my $conf = PVE::QemuServer::load_config ($param->{vmid});
 130
 131         my $vmstatus = PVE::QemuServer::vmstatus($param->{vmid});
 132         my $stat = $vmstatus->{$param->{vmid}};
 133         if ($param->{verbose}) {
 134             foreach my $k (sort (keys %$stat)) {
 135                 next if $k eq 'cpu' || $k eq 'relcpu'; # always 0
 136                 my $v = $stat->{$k};
 137                 next if !defined($v);
 138                 print "$k: $v\n";
 139             }
 140         } else {
 141             my $status = $stat->{status} || 'unknown';
 142             print "status: $status\n";
 143         }
 144
 145         return undef;
 146     }});
 147
 148 __PACKAGE__->register_method ({
 149     name => 'vncproxy',
 150     path => 'vncproxy',
 151     method => 'PUT',
 152     description => "Proxy VM VNC traffic to stdin/stdout",
 153     parameters => {
 154         additionalProperties => 0,
 155         properties => {
 156             vmid => get_standard_option('pve-vmid'),
 157         },
 158     },
 159     returns => { type => 'null'},
 160     code => sub {
 161         my ($param) = @_;
 162
 163         my $vmid = $param->{vmid};
 164
 165         run_vnc_proxy ($vmid);
 166
 167         return undef;
 168     }});
 169
 170 __PACKAGE__->register_method ({
 171     name => 'unlock',
 172     path => 'unlock',
 173     method => 'PUT',
 174     description => "Unlock the VM.",
 175     parameters => {
 176         additionalProperties => 0,
 177         properties => {
 178             vmid => get_standard_option('pve-vmid'),
 179         },
 180     },
 181     returns => { type => 'null'},
 182     code => sub {
 183         my ($param) = @_;
 184
 185         my $vmid = $param->{vmid};
 186
 187         PVE::QemuServer::lock_config ($vmid, sub {
 188             PVE::QemuServer::change_config_nolock  ($vmid, {}, { lock => 1 }, 1);
 189         });
 190
 191         return undef;
 192     }});
 193
 194 __PACKAGE__->register_method ({
 195     name => 'mtunnel',
 196     path => 'mtunnel',
 197     method => 'POST',
 198     description => "Used by qmigrate - do not use manually.",
 199     parameters => {
 200         additionalProperties => 0,
 201         properties => {},
 202     },
 203     returns => { type => 'null'},
 204     code => sub {
 205         my ($param) = @_;
 206
 207         if (!PVE::Cluster::check_cfs_quorum(1)) {
 208             print "no quorum\n";
 209             return undef;
 210         }
 211
 212         print "tunnel online\n";
 213         *STDOUT->flush();
 214
 215         while (my $line = <>) {
 216             chomp $line;
 217             last if $line =~ m/^quit$/;
 218         }
 219
 220         return undef;
 221     }});
 222
 223 __PACKAGE__->register_method ({
 224     name => 'startall',
 225     path => 'startall',
 226     method => 'POST',
 227     description => "Start all virtual machines (when onboot=1).",
 228     parameters => {
 229         additionalProperties => 0,
 230         properties => {},
 231     },
 232     returns => { type => 'null'},
 233     code => sub {
 234         my ($param) = @_;
 235
 236         my $vzlist = PVE::QemuServer::vzlist();
 237         my $storecfg = PVE::Storage::config();
 238
 239         my $count = 0;
 240         foreach my $vmid (keys %$vzlist) {
 241             next if $vzlist->{$vmid}->{pid}; # already running
 242
 243             sleep(2) if $count != 0; # reduce load
 244             $count++;
 245
 246             eval {
 247                 my $conf = PVE::QemuServer::load_config($vmid);
 248                 if ($conf->{onboot}) {
 249                     print STDERR "Starting Qemu VM $vmid\n";
 250                     PVE::QemuServer::vm_start($storecfg, $vmid);
 251                 }
 252             };
 253             print STDERR $@ if $@;
 254         }
 255
 256         return undef;
 257     }});
 258
 259 __PACKAGE__->register_method ({
 260     name => 'stopall',
 261     path => 'stopall',
 262     method => 'POST',
 263     description => "Stop all virtual machines.",
 264     parameters => {
 265         additionalProperties => 0,
 266         properties => {
 267             timeout => {
 268                 description => "Timeout in seconds. Default is to wait 3 minutes.",
 269                 type => 'integer',
 270                 minimum => 1,
 271                 optional => 1,
 272             }
 273         },
 274     },
 275     returns => { type => 'null'},
 276     code => sub {
 277         my ($param) = @_;
 278
 279         my $timeout = $param->{timeout};
 280
 281         PVE::QemuServer::vm_stopall($timeout);
 282
 283         return undef;
 284     }});
 285
 286 __PACKAGE__->register_method ({
 287     name => 'wait',
 288     path => 'wait',
 289     method => 'GET',
 290     description => "Wait until the VM is stopped.",
 291     parameters => {
 292         additionalProperties => 0,
 293         properties => {
 294             vmid => get_standard_option('pve-vmid'),
 295             timeout => {
 296                 description => "Timeout in seconds. Default is to wait forever.",
 297                 type => 'integer',
 298                 minimum => 1,
 299                 optional => 1,
 300             }
 301         },
 302     },
 303     returns => { type => 'null'},
 304     code => sub {
 305         my ($param) = @_;
 306
 307         my $vmid = $param->{vmid};
 308         my $timeout = $param->{timeout};
 309
 310         my $pid = PVE::QemuServer::check_running ($vmid);
 311         return if !$pid;
 312
 313         print "waiting until VM $vmid stopps (PID $pid)\n";
 314
 315         my $count = 0;
 316         while ((!$timeout || ($count < $timeout)) && PVE::QemuServer::check_running ($vmid)) {
 317             $count++;
 318             sleep 1;
 319         }
 320
 321         die "wait failed - got timeout\n" if PVE::QemuServer::check_running ($vmid);
 322
 323         return undef;
 324     }});
 325
 326 __PACKAGE__->register_method ({
 327     name => 'monitor',
 328     path => 'monitor',
 329     method => 'POST',
 330     description => "Enter Qemu Monitor interface.",
 331     parameters => {
 332         additionalProperties => 0,
 333         properties => {
 334             vmid => get_standard_option('pve-vmid'),
 335         },
 336     },
 337     returns => { type => 'null'},
 338     code => sub {
 339         my ($param) = @_;
 340
 341         my $vmid = $param->{vmid};
 342
 343         my $conf = PVE::QemuServer::load_config ($vmid); # check if VM exists
 344
 345         print "Entering Qemu Monitor for VM $vmid - type 'help' for help\n";
 346
 347         my $term = new Term::ReadLine ('qm');
 348
 349         my $input;
 350         while (defined ($input = $term->readline('qm> '))) {
 351             chomp $input;
 352
 353             next if $input =~ m/^\s*$/;
 354
 355             last if $input =~ m/^\s*q(uit)?\s*$/;
 356
 357             eval {
 358                 print PVE::QemuServer::vm_monitor_command ($vmid, $input);
 359             };
 360             print "ERROR: $@" if $@;
 361         }
 362
 363         return undef;
 364
 365     }});
 366
 367 my $cmddef = {
 368     list => [ "PVE::API2::Qemu", 'vmlist', [],
 369              { node => $nodename }, sub {
 370                  my $vmlist = shift;
 371
 372                  exit 0 if (!scalar(@$vmlist));
 373
 374                  printf "%10s %-20s %-10s %-10s %12s %-10s\n",
 375                  qw(VMID NAME STATUS MEM(MB) BOOTDISK(GB) PID);
 376
 377                  foreach my $rec (sort { $a->{vmid} <=> $b->{vmid} } @$vmlist) {
 378                      printf "%10s %-20s %-10s %-10s %12.2f %-10s\n", $rec->{vmid}, $rec->{name},
 379                      $rec->{status},
 380                      ($rec->{maxmem} || 0)/(1024*1024),
 381                      ($rec->{maxdisk} || 0)/(1024*1024*1024),
 382                      $rec->{pid}||0;
 383                  }
 384
 385
 386               } ],
 387
 388     create => [ "PVE::API2::Qemu", 'create_vm', ['vmid'], { node => $nodename } ],
 389
 390     destroy => [ "PVE::API2::Qemu", 'destroy_vm', ['vmid'], { node => $nodename } ],
 391
 392     set => [ "PVE::API2::Qemu", 'update_vm', ['vmid'], { node => $nodename } ],
 393
 394     unlink => [ "PVE::API2::Qemu", 'unlink', ['vmid', 'idlist'], { node => $nodename } ],
 395
 396     config => [ "PVE::API2::Qemu", 'vm_config', ['vmid'],
 397                 { node => $nodename }, sub {
 398                     my $config = shift;
 399                     foreach my $k (sort (keys %$config)) {
 400                         next if $k eq 'digest';
 401                         my $v = $config->{$k};
 402                         if ($k eq 'description') {
 403                             $v = PVE::Tools::encode_text($v);
 404                         }
 405                         print "$k: $v\n";
 406                     }
 407                 }],
 408
 409     showcmd => [ __PACKAGE__, 'showcmd', ['vmid']],
 410
 411     status => [ __PACKAGE__, 'status', ['vmid']],
 412
 413     vncproxy => [ __PACKAGE__, 'vncproxy', ['vmid']],
 414
 415     wait => [ __PACKAGE__, 'wait', ['vmid']],
 416
 417     unlock => [ __PACKAGE__, 'unlock', ['vmid']],
 418
 419     monitor  => [ __PACKAGE__, 'monitor', ['vmid']],
 420
 421     startall => [ __PACKAGE__, 'startall', []],
 422
 423     stopall => [ __PACKAGE__, 'stopall', []],
 424
 425     mtunnel => [ __PACKAGE__, 'mtunnel', []],
 426 };
 427
 428 sub register_vm_command {
 429     my ($cmd, $descr) = @_;
 430
 431     # we create a wrapper, because we want one 'description' per command
 432     __PACKAGE__->register_method ({
 433         name => $cmd,
 434         path => $cmd,
 435         method => 'PUT',
 436         description => $descr,
 437         parameters => {
 438             additionalProperties => 0,
 439             properties => {
 440                 vmid => get_standard_option('pve-vmid'),
 441                 skiplock => get_standard_option('skiplock'),
 442             },
 443         },
 444         returns => { type => 'null'},
 445         code => sub {
 446             my ($param) = @_;
 447
 448             $param->{command} = $cmd;
 449             $param->{node} = $nodename;
 450
 451             return PVE::API2::Qemu->vm_command($param);
 452         }});
 453
 454     $cmddef->{$cmd} = [ __PACKAGE__, $cmd, ['vmid']];
 455 }
 456
 457 register_vm_command('start', "Start virtual machine.");
 458 register_vm_command('stop', "Stop virtual machine.");
 459 register_vm_command('reset', "Reset virtual machine.");
 460 register_vm_command('shutdown', "Shutdown virtual machine (send ACPI showdown request)");
 461 register_vm_command('suspend', "Suspend virtual machine.");
 462 register_vm_command('resume', "Resume virtual machine.");
 463 register_vm_command('cad', "Send CTRL-ALT-DELETE keys.");
 464
 465 my $cmd = shift;
 466
 467 PVE::CLIHandler::handle_cmd($cmddef, "qm", $cmd, \@ARGV, undef, $0);
 468
 469 exit 0;
 470
 471 __END__
 472
 473 =head1 NAME
 474
 475 qm - qemu/kvm virtual machine manager
 476
 477 =head1 SYNOPSIS
 478
 479 =include synopsis
 480
 481 =head1 DESCRIPTION
 482
 483 qm is a script to manage virtual machines with qemu/kvm. You can
 484 create and destroy virtual machines, and control execution
 485 (start/stop/suspend/resume). Besides that, you can use qm to set
 486 parameters in the associated config file. It is also possible to
 487 create and delete virtual disks.
 488
 489 =head1 CONFIGURATION
 490
 491 All configuration files consists of lines in the form
 492
 493        PARAMETER: value
 494
 495 See L<vm.conf|vm.conf> for a complete list of options.
 496
 497 Configuration files are stored inside the Proxmox configuration file system, and can be access at F</etc/pve/qemu-server/C<VMID>.conf>.
 498
 499 The default for option 'keyboard' is read from
 500 F</etc/pve/datacenter.conf>.
 501
 502 =head1 Locks
 503
 504 Online migration and backups (vzdump) set a lock to prevent
 505 unintentional action on such VMs. Sometimes you need remove such lock
 506 manually (power failure).
 507
 508  qm unlock <vmid>
 509
 510 =head1 EXAMPLES
 511
 512  # create a new VM with 4 GB ide disk
 513  qm create 300 -ide0 4 -net0 e1000 -cdrom proxmox-mailgateway_2.1.iso
 514
 515  # start the new VM
 516  qm start 300
 517
 518  # send shutdown, then wait until VM is stopped
 519  qm shutdown 300 && qm wait 300
 520
 521  # same as above, but only wait for 40 seconds
 522  qm shutdown 300 && qm wait 300 -timeout 40
 523
 524
 525 =include pve_copyright