Maintainers.txt: Remove EdkCompatibilityPkg information

[mirror_edk2.git] / EdkCompatibilityPkg / Foundation / Library / EfiCommonLib / Ia32 / EfiZeroMem.S

#/*++\r
#\r
#Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
#This program and the accompanying materials                          \r
#are licensed and made available under the terms and conditions of the BSD License         \r
#which accompanies this distribution.  The full text of the license may be found at        \r
#http://opensource.org/licenses/bsd-license.php                                            \r
#                                                                                          \r
#THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     \r
#WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.             \r
#\r
#Module Name:\r
#\r
#  EfiZeroMem.c\r
#\r
#Abstract:\r
#\r
#  This is the code that supports IA32-optimized ZeroMem service\r
#\r
#--*/\r
#include "EfiBind.h"\r
#---------------------------------------------------------------------------\r
    .686: \r
    #.MODEL flat,C\r
    .mmx: \r
    .code: \r
\r
#---------------------------------------------------------------------------\r
.globl ASM_PFX(EfiCommonLibZeroMem)\r
#VOID\r
#EfiCommonLibZeroMem (\r
#  IN VOID   *Buffer,\r
#  IN UINTN  Count\r
#  )\r
#/*++\r
#\r
#Input:  VOID   *Buffer - Pointer to buffer to clear\r
#        UINTN  Count  - Number of bytes to clear\r
#\r
#Output: None.\r
#\r
#Saves:\r
#\r
#Modifies:\r
#\r
#Description:  This function is an optimized zero-memory function.\r
#\r
#Notes:  This function tries to zero memory 8 bytes at a time. As a result, \r
#        it first picks up any misaligned bytes, then words, before getting \r
#        in the main loop that does the 8-byte clears.\r
#\r
#--*/\r
ASM_PFX(EfiCommonLibZeroMem):\r
#  UINT64 MmxSave;\r
    pushl %ebp\r
    movl  %esp, %ebp\r
    pushl %ecx # Reserve space for local variable MmxSave\r
    pushl %ecx\r
    pushl %edi\r
\r
    movl  0xC(%ebp), %ecx  # Count\r
    movl  8(%ebp), %edi # Buffer\r
\r
    # Pick up misaligned start bytes (get pointer 4-byte aligned)\r
_StartByteZero: \r
    movl  %edi, %eax\r
    andb  $3, %al                     # check lower 2 bits of address\r
    testb %al, %al\r
    je    _ZeroBlocks                 # already aligned?\r
    cmpl  $0, %ecx\r
    je    _ZeroMemDone\r
\r
    # Clear the byte memory location\r
    movb  $0, (%edi)\r
    incl   %edi\r
\r
    # Decrement our count\r
    decl   %ecx\r
    jmp   _StartByteZero        # back to top of loop\r
\r
_ZeroBlocks: \r
\r
    # Compute how many 64-byte blocks we can clear \r
    movl  %ecx, %edx\r
    shrl  $6, %ecx                    # convert to 64-byte count\r
    shll  $6, %ecx                    # convert back to bytes\r
    subl  %ecx, %edx                  # subtract from the original count\r
    shrl  $6, %ecx                    # and this is how many 64-byte blocks\r
\r
    # If no 64-byte blocks, then skip \r
    cmpl   $0, %ecx\r
    je    _ZeroRemaining\r
\r
    # Save mm0\r
    movq  %mm0, -8(%ebp)  # Save mm0 to MmxSave\r
\r
    pxor  %mm0, %mm0        # Clear mm0\r
\r
_B: \r
    movq  %mm0, %ds:(%edi)\r
    movq  %mm0, %ds:8(%edi)\r
    movq  %mm0, %ds:16(%edi)\r
    movq  %mm0, %ds:24(%edi)\r
    movq  %mm0, %ds:32(%edi)\r
    movq  %mm0, %ds:40(%edi)\r
    movq  %mm0, %ds:48(%edi)\r
    movq  %mm0, %ds:56(%edi)\r
\r
    addl   $64, %edi\r
    decl   %ecx\r
    jnz    _B\r
\r
# Restore mm0\r
    movq  -8(%ebp), %mm0 # Restore mm0 from MmxSave\r
    emms                                 # Exit MMX Instruction\r
\r
_ZeroRemaining: \r
    # Zero out as many DWORDS as possible\r
    movl  %edx, %ecx\r
    shrl  $2, %ecx\r
    xorl  %eax, %eax\r
\r
    rep\r
    stosl\r
\r
    # Zero out remaining as bytes\r
    movl  %edx, %ecx\r
    andl  $03, %ecx\r
\r
    rep\r
    stosb\r
\r
_ZeroMemDone: \r
\r
    popl   %edi\r
    leave\r
    ret\r
#EfiCommonLibZeroMem ENDP\r
\r