[qemu-server.git] / PVE / QemuConfig.pm

package PVE::QemuConfig;

use strict;
use warnings;

use PVE::AbstractConfig;
use PVE::INotify;
use PVE::QemuServer;
use PVE::Storage;
use PVE::Tools;

use base qw(PVE::AbstractConfig);

my $nodename = PVE::INotify::nodename();

mkdir "/etc/pve/nodes/$nodename";
my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
mkdir $confdir;

my $lock_dir = "/var/lock/qemu-server";
mkdir $lock_dir;

my $MAX_UNUSED_DISKS = 256;

# BEGIN implemented abstract methods from PVE::AbstractConfig

sub guest_type {
    return "VM";
}

sub __config_max_unused_disks {
    my ($class) = @_;

    return $MAX_UNUSED_DISKS;
}

sub config_file_lock {
    my ($class, $vmid) = @_;

    return "$lock_dir/lock-$vmid.conf";
}

sub cfs_config_path {
    my ($class, $vmid, $node) = @_;

    $node = $nodename if !$node;
    return "nodes/$node/qemu-server/$vmid.conf";
}

sub has_feature {
    my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;

    my $err;
    PVE::QemuServer::foreach_drive($conf, sub {
	my ($ds, $drive) = @_;

	return if PVE::QemuServer::drive_is_cdrom($drive);
	return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
	my $volid = $drive->{file};
	$err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
   });

    return $err ? 0 : 1;
}

sub get_replicatable_volumes {
    my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;

    my $volhash = {};

    my $test_volid = sub {
	my ($volid, $attr) = @_;

	return if $attr->{cdrom};

	return if !$cleanup && !$attr->{replicate};

	if ($volid =~ m|^/|) {
	    return if !$attr->{replicate};
	    return if $cleanup || $noerr;
	    die "unable to replicate local file/device '$volid'\n";
	}

	my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
	return if !$storeid;

	my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
	return if $scfg->{shared};

	my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
	return if !$owner || ($owner != $vmid);

	if ($vtype ne 'images') {
	    return if $cleanup || $noerr;
	    die "unable to replicate volume '$volid', type '$vtype'\n";
	}

	if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
	    return if $cleanup || $noerr;
	    die "missing replicate feature on volume '$volid'\n";
	}

	$volhash->{$volid} = 1;
    };

    PVE::QemuServer::foreach_volid($conf, $test_volid);

    # add 'unusedX' volumes to volhash
    foreach my $key (keys %$conf) {
	if ($key =~ m/^unused/) {
	    $test_volid->($conf->{$key}, { replicate => 1 });
	}
    }

    return $volhash;
}

sub __snapshot_save_vmstate {
    my ($class, $vmid, $conf, $snapname, $storecfg, $statestorage, $suspend) = @_;

    # first, use explicitly configured storage
    # either directly via API, or via conf
    my $target = $statestorage // $conf->{vmstatestorage};

    if (!$target) {
	my ($shared, $local);
	PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
	    my ($sid) = @_;
	    my $scfg = PVE::Storage::storage_config($storecfg, $sid);
	    my $dst = $scfg->{shared} ? \$shared : \$local;
	    $$dst = $sid if !$$dst || $scfg->{path}; # prefer file based storage
	});

	# second, use shared storage where VM has at least one disk
	# third, use local storage where VM has at least one disk
	# fall back to local storage
	$target = $shared // $local // 'local';
    }

    my $defaults = PVE::QemuServer::load_defaults();
    my $mem_size = $conf->{memory} // $defaults->{memory};
    my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
    # our savevm-start does live-save of the memory until the space left in the
    # volume is just enough for the remaining memory content + internal state
    # then it stops the vm and copies the rest so we reserve twice the
    # memory content + state to minimize vm downtime
    my $size = $mem_size*2 + $driver_state_size;
    my $scfg = PVE::Storage::storage_config($storecfg, $target);

    my $name = "vm-$vmid-state-$snapname";
    $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage

    my $statefile = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
    my $runningmachine = PVE::QemuServer::get_current_qemu_machine($vmid);

    if ($suspend) {
	$conf->{vmstate} = $statefile;
	$conf->{runningmachine} = $runningmachine;
    } else {
	my $snap = $conf->{snapshots}->{$snapname};
	$snap->{vmstate} = $statefile;
	$snap->{runningmachine} = $runningmachine;
    }

    return $statefile;
}

sub __snapshot_check_running {
    my ($class, $vmid) = @_;
    return PVE::QemuServer::check_running($vmid);
}

sub __snapshot_check_freeze_needed {
    my ($class, $vmid, $config, $save_vmstate) = @_;

    my $running = $class->__snapshot_check_running($vmid);
    if (!$save_vmstate) {
	return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
    } else {
	return ($running, 0);
    }
}

sub __snapshot_freeze {
    my ($class, $vmid, $unfreeze) = @_;

    if ($unfreeze) {
	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
	warn "guest-fsfreeze-thaw problems - $@" if $@;
    } else {
	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
	warn "guest-fsfreeze-freeze problems - $@" if $@;
    }
}

sub __snapshot_create_vol_snapshots_hook {
    my ($class, $vmid, $snap, $running, $hook) = @_;

    if ($running) {
	my $storecfg = PVE::Storage::config();

	if ($hook eq "before") {
	    if ($snap->{vmstate}) {
		my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
		PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);

		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
		for(;;) {
		    my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
		    if (!$stat->{status}) {
			die "savevm not active\n";
		    } elsif ($stat->{status} eq 'active') {
			sleep(1);
			next;
		    } elsif ($stat->{status} eq 'completed') {
			last;
		    } else {
			die "query-savevm returned status '$stat->{status}'\n";
		    }
		}
	    } else {
		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
	    }
	} elsif ($hook eq "after") {
	    eval {
		PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
		PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
	    };
	    warn $@ if $@;
	} elsif ($hook eq "after-freeze") {
	    # savevm-end is async, we need to wait
	    for (;;) {
		my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
		if (!$stat->{bytes}) {
		    last;
		} else {
		    print "savevm not yet finished\n";
		    sleep(1);
		    next;
		}
	    }
	}
    }
}

sub __snapshot_create_vol_snapshot {
    my ($class, $vmid, $ds, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $volid = $drive->{file};
    my $device = "drive-$ds";
    my $storecfg = PVE::Storage::config();

    PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
}

sub __snapshot_delete_remove_drive {
    my ($class, $snap, $remove_drive) = @_;

    if ($remove_drive eq 'vmstate') {
	delete $snap->{$remove_drive};
    } else {
	my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
	return if PVE::QemuServer::drive_is_cdrom($drive);

	my $volid = $drive->{file};
	delete $snap->{$remove_drive};
	$class->add_unused_volume($snap, $volid);
    }
}

sub __snapshot_delete_vmstate_file {
    my ($class, $snap, $force) = @_;

    my $storecfg = PVE::Storage::config();

    eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
    if (my $err = $@) {
	die $err if !$force;
	warn $err;
    }
}

sub __snapshot_delete_vol_snapshot {
    my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);
    my $storecfg = PVE::Storage::config();
    my $volid = $drive->{file};
    my $device = "drive-$ds";

    PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);

    push @$unused, $volid;
}

sub __snapshot_rollback_hook {
    my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;

    if ($prepare) {
	# we save the machine of the current config
	$data->{oldmachine} = $conf->{machine};
    } else {
	# if we have a 'runningmachine' entry in the snapshot we use that
	# for the forcemachine parameter, else we use the old logic
	if (defined($conf->{runningmachine})) {
	    $data->{forcemachine} = $conf->{runningmachine};
	    delete $conf->{runningmachine};
	} else {
	    # Note: old code did not store 'machine', so we try to be smart
	    # and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
	    $data->{forcemachine} = $conf->{machine} || 'pc-i440fx-1.4';

	    # we remove the 'machine' configuration if not explicitly specified
	    # in the original config.
	    delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
	}

	if ($conf->{vmgenid}) {
	    # tell the VM that it's another generation, so it can react
	    # appropriately, e.g. dirty-mark copies of distributed databases or
	    # re-initializing its random number generator
	    $conf->{vmgenid} = PVE::QemuServer::generate_uuid();
	}
    }

    return;
}

sub __snapshot_rollback_vol_possible {
    my ($class, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $storecfg = PVE::Storage::config();
    my $volid = $drive->{file};

    PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
}

sub __snapshot_rollback_vol_rollback {
    my ($class, $drive, $snapname) = @_;

    return if PVE::QemuServer::drive_is_cdrom($drive);

    my $storecfg = PVE::Storage::config();
    PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
}

sub __snapshot_rollback_vm_stop {
    my ($class, $vmid) = @_;

    my $storecfg = PVE::Storage::config();
    PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
}

sub __snapshot_rollback_vm_start {
    my ($class, $vmid, $vmstate, $data) = @_;

    my $storecfg = PVE::Storage::config();
    PVE::QemuServer::vm_start($storecfg, $vmid, $vmstate, undef, undef, undef, $data->{forcemachine});
}

sub __snapshot_rollback_get_unused {
    my ($class, $conf, $snap) = @_;

    my $unused = [];

    $class->__snapshot_foreach_volume($conf, sub {
	my ($vs, $volume) = @_;

	return if PVE::QemuServer::drive_is_cdrom($volume);

	my $found = 0;
	my $volid = $volume->{file};

	$class->__snapshot_foreach_volume($snap, sub {
	    my ($ds, $drive) = @_;

	    return if $found;
	    return if PVE::QemuServer::drive_is_cdrom($drive);

	    $found = 1
		if ($drive->{file} && $drive->{file} eq $volid);
	});

	push @$unused, $volid if !$found;
    });

    return $unused;
}

sub __snapshot_foreach_volume {
    my ($class, $conf, $func) = @_;

    PVE::QemuServer::foreach_drive($conf, $func);
}
# END implemented abstract methods from PVE::AbstractConfig

1;
Commit	Line	Data
ffda963f FG	1	package PVE::QemuConfig;
	2
	3	use strict;
	4	use warnings;
	5
b2c9558d FG	6	use PVE::AbstractConfig;
	7	use PVE::INotify;
	8	use PVE::QemuServer;
	9	use PVE::Storage;
	10	use PVE::Tools;
	11
ffda963f FG	12	use base qw(PVE::AbstractConfig);
	13
	14	my $nodename = PVE::INotify::nodename();
	15
	16	mkdir "/etc/pve/nodes/$nodename";
	17	my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
	18	mkdir $confdir;
	19
	20	my $lock_dir = "/var/lock/qemu-server";
	21	mkdir $lock_dir;
	22
c9db2240	23	my $MAX_UNUSED_DISKS = 256;
ffda963f FG	24
	25	# BEGIN implemented abstract methods from PVE::AbstractConfig
	26
	27	sub guest_type {
	28	return "VM";
	29	}
	30
	31	sub __config_max_unused_disks {
3aa44d3b	32	my ($class) = @_;
ffda963f FG	33
	34	return $MAX_UNUSED_DISKS;
	35	}
	36
	37	sub config_file_lock {
	38	my ($class, $vmid) = @_;
	39
	40	return "$lock_dir/lock-$vmid.conf";
	41	}
	42
	43	sub cfs_config_path {
	44	my ($class, $vmid, $node) = @_;
	45
	46	$node = $nodename if !$node;
	47	return "nodes/$node/qemu-server/$vmid.conf";
	48	}
	49
b2c9558d FG	50	sub has_feature {
	51	my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
	52
	53	my $err;
	54	PVE::QemuServer::foreach_drive($conf, sub {
	55	my ($ds, $drive) = @_;
	56
	57	return if PVE::QemuServer::drive_is_cdrom($drive);
5282865b	58	return if $backup_only && defined($drive->{backup}) && !$drive->{backup};
b2c9558d FG	59	my $volid = $drive->{file};
	60	$err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
	61	});
	62
	63	return $err ? 0 : 1;
	64	}
	65
3aa44d3b	66	sub get_replicatable_volumes {
c78f43b9	67	my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
3aa44d3b DM	68
	69	my $volhash = {};
	70
	71	my $test_volid = sub {
f949eb77	72	my ($volid, $attr) = @_;
3aa44d3b	73
a6cb40f7 DM	74	return if $attr->{cdrom};
	75
	76	return if !$cleanup && !$attr->{replicate};
	77
4ab3bcc8 DM	78	if ($volid =~ m\|^/\|) {
4ab3bcc8 DM	79	return if !$attr->{replicate};
a6cb40f7	80	return if $cleanup \|\| $noerr;
4ab3bcc8 DM	81	die "unable to replicate local file/device '$volid'\n";
	82	}
	83
a722d4ff DM	84	my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
	85	return if !$storeid;
	86
6f249d94	87	my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
a722d4ff DM	88	return if $scfg->{shared};
a722d4ff DM	89
f7e7767f DM	90	my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
	91	return if !$owner \|\| ($owner != $vmid);
	92
a6cb40f7 DM	93	if ($vtype ne 'images') {
	94	return if $cleanup \|\| $noerr;
	95	die "unable to replicate volume '$volid', type '$vtype'\n";
	96	}
3aa44d3b DM	97
3aa44d3b DM	98	if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
e5857ca8	99	return if $cleanup \|\| $noerr;
3aa44d3b DM	100	die "missing replicate feature on volume '$volid'\n";
	101	}
	102
	103	$volhash->{$volid} = 1;
	104	};
	105
f949eb77	106	PVE::QemuServer::foreach_volid($conf, $test_volid);
3aa44d3b	107
8299257e DM	108	# add 'unusedX' volumes to volhash
	109	foreach my $key (keys %$conf) {
	110	if ($key =~ m/^unused/) {
	111	$test_volid->($conf->{$key}, { replicate => 1 });
	112	}
	113	}
	114
3aa44d3b DM	115	return $volhash;
	116	}
	117
b2c9558d	118	sub __snapshot_save_vmstate {
48b4cdc2	119	my ($class, $vmid, $conf, $snapname, $storecfg, $statestorage, $suspend) = @_;
b2c9558d	120
2eeb0c93	121	# first, use explicitly configured storage
48b4cdc2 DC	122	# either directly via API, or via conf
48b4cdc2 DC	123	my $target = $statestorage // $conf->{vmstatestorage};
b2c9558d FG	124
b2c9558d FG	125	if (!$target) {
2eeb0c93	126	my ($shared, $local);
65a5ce88	127	PVE::QemuServer::foreach_storage_used_by_vm($conf, sub {
b2c9558d FG	128	my ($sid) = @_;
b2c9558d FG	129	my $scfg = PVE::Storage::storage_config($storecfg, $sid);
2eeb0c93 FG	130	my $dst = $scfg->{shared} ? \$shared : \$local;
2eeb0c93 FG	131	$$dst = $sid if !$$dst \|\| $scfg->{path}; # prefer file based storage
b2c9558d	132	});
b2c9558d	133
2eeb0c93 FG	134	# second, use shared storage where VM has at least one disk
	135	# third, use local storage where VM has at least one disk
	136	# fall back to local storage
	137	$target = $shared // $local // 'local';
	138	}
b2c9558d	139
22ea69ca AA	140	my $defaults = PVE::QemuServer::load_defaults();
22ea69ca AA	141	my $mem_size = $conf->{memory} // $defaults->{memory};
566caaa4	142	my $driver_state_size = 500; # assume 500MB is enough to safe all driver state;
b3983fa1 DC	143	# our savevm-start does live-save of the memory until the space left in the
	144	# volume is just enough for the remaining memory content + internal state
	145	# then it stops the vm and copies the rest so we reserve twice the
	146	# memory content + state to minimize vm downtime
22ea69ca	147	my $size = $mem_size*2 + $driver_state_size;
159719e5	148	my $scfg = PVE::Storage::storage_config($storecfg, $target);
b2c9558d FG	149
b2c9558d FG	150	my $name = "vm-$vmid-state-$snapname";
b2c9558d	151	$name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
159719e5 DC	152
	153	my $statefile = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
	154	my $runningmachine = PVE::QemuServer::get_current_qemu_machine($vmid);
	155
	156	if ($suspend) {
	157	$conf->{vmstate} = $statefile;
	158	$conf->{runningmachine} = $runningmachine;
	159	} else {
	160	my $snap = $conf->{snapshots}->{$snapname};
	161	$snap->{vmstate} = $statefile;
	162	$snap->{runningmachine} = $runningmachine;
	163	}
	164
	165	return $statefile;
b2c9558d FG	166	}
	167
	168	sub __snapshot_check_running {
	169	my ($class, $vmid) = @_;
	170	return PVE::QemuServer::check_running($vmid);
	171	}
	172
	173	sub __snapshot_check_freeze_needed {
	174	my ($class, $vmid, $config, $save_vmstate) = @_;
	175
	176	my $running = $class->__snapshot_check_running($vmid);
278e2c9d	177	if (!$save_vmstate) {
9d66b397	178	return ($running, $running && PVE::QemuServer::parse_guest_agent($config)->{enabled} && PVE::QemuServer::qga_check_running($vmid));
b2c9558d FG	179	} else {
	180	return ($running, 0);
	181	}
	182	}
	183
	184	sub __snapshot_freeze {
	185	my ($class, $vmid, $unfreeze) = @_;
	186
	187	if ($unfreeze) {
	188	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
	189	warn "guest-fsfreeze-thaw problems - $@" if $@;
	190	} else {
	191	eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
	192	warn "guest-fsfreeze-freeze problems - $@" if $@;
	193	}
	194	}
	195
	196	sub __snapshot_create_vol_snapshots_hook {
	197	my ($class, $vmid, $snap, $running, $hook) = @_;
	198
	199	if ($running) {
3a8deb55 AD	200	my $storecfg = PVE::Storage::config();
3a8deb55 AD	201
b2c9558d FG	202	if ($hook eq "before") {
b2c9558d FG	203	if ($snap->{vmstate}) {
b2c9558d	204	my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
3a8deb55 AD	205	PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
3a8deb55 AD	206
b2c9558d FG	207	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
	208	for(;;) {
	209	my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
	210	if (!$stat->{status}) {
	211	die "savevm not active\n";
	212	} elsif ($stat->{status} eq 'active') {
	213	sleep(1);
	214	next;
	215	} elsif ($stat->{status} eq 'completed') {
	216	last;
	217	} else {
	218	die "query-savevm returned status '$stat->{status}'\n";
	219	}
	220	}
	221	} else {
	222	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
	223	}
	224	} elsif ($hook eq "after") {
a022e3fd	225	eval {
3a8deb55 AD	226	PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
	227	PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
	228	};
b2c9558d FG	229	warn $@ if $@;
	230	} elsif ($hook eq "after-freeze") {
	231	# savevm-end is async, we need to wait
	232	for (;;) {
	233	my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
	234	if (!$stat->{bytes}) {
	235	last;
	236	} else {
	237	print "savevm not yet finished\n";
	238	sleep(1);
	239	next;
	240	}
	241	}
	242	}
	243	}
	244	}
	245
	246	sub __snapshot_create_vol_snapshot {
	247	my ($class, $vmid, $ds, $drive, $snapname) = @_;
	248
	249	return if PVE::QemuServer::drive_is_cdrom($drive);
	250
	251	my $volid = $drive->{file};
	252	my $device = "drive-$ds";
	253	my $storecfg = PVE::Storage::config();
	254
	255	PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
	256	}
	257
	258	sub __snapshot_delete_remove_drive {
	259	my ($class, $snap, $remove_drive) = @_;
	260
	261	if ($remove_drive eq 'vmstate') {
	262	delete $snap->{$remove_drive};
	263	} else {
	264	my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
	265	return if PVE::QemuServer::drive_is_cdrom($drive);
	266
	267	my $volid = $drive->{file};
	268	delete $snap->{$remove_drive};
	269	$class->add_unused_volume($snap, $volid);
	270	}
	271	}
	272
	273	sub __snapshot_delete_vmstate_file {
	274	my ($class, $snap, $force) = @_;
	275
	276	my $storecfg = PVE::Storage::config();
	277
	278	eval { PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
	279	if (my $err = $@) {
	280	die $err if !$force;
	281	warn $err;
	282	}
	283	}
	284
	285	sub __snapshot_delete_vol_snapshot {
	286	my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
	287
	288	return if PVE::QemuServer::drive_is_cdrom($drive);
	289	my $storecfg = PVE::Storage::config();
	290	my $volid = $drive->{file};
	291	my $device = "drive-$ds";
	292
293	PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);
294
295	push @$unused, $volid;
296	}
297
58b1a8d7 DC	298	sub __snapshot_rollback_hook {
	299	my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;
	300
	301	if ($prepare) {
	302	# we save the machine of the current config
	303	$data->{oldmachine} = $conf->{machine};
	304	} else {
e6d35c71 TL	305	# if we have a 'runningmachine' entry in the snapshot we use that
e6d35c71 TL	306	# for the forcemachine parameter, else we use the old logic
c6737ef1 DC	307	if (defined($conf->{runningmachine})) {
	308	$data->{forcemachine} = $conf->{runningmachine};
	309	delete $conf->{runningmachine};
	310	} else {
	311	# Note: old code did not store 'machine', so we try to be smart
	312	# and guess the snapshot was generated with kvm 1.4 (pc-i440fx-1.4).
	313	$data->{forcemachine} = $conf->{machine} \|\| 'pc-i440fx-1.4';
	314
	315	# we remove the 'machine' configuration if not explicitly specified
	316	# in the original config.
	317	delete $conf->{machine} if $snap->{vmstate} && !defined($data->{oldmachine});
	318	}
6ee499ff DC	319
6ee499ff DC	320	if ($conf->{vmgenid}) {
4f4d9772 TL	321	# tell the VM that it's another generation, so it can react
	322	# appropriately, e.g. dirty-mark copies of distributed databases or
	323	# re-initializing its random number generator
6ee499ff DC	324	$conf->{vmgenid} = PVE::QemuServer::generate_uuid();
6ee499ff DC	325	}
58b1a8d7 DC	326	}
	327
	328	return;
	329	}
	330
b2c9558d FG	331	sub __snapshot_rollback_vol_possible {
	332	my ($class, $drive, $snapname) = @_;
	333
	334	return if PVE::QemuServer::drive_is_cdrom($drive);
	335
	336	my $storecfg = PVE::Storage::config();
	337	my $volid = $drive->{file};
	338
	339	PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
	340	}
	341
	342	sub __snapshot_rollback_vol_rollback {
	343	my ($class, $drive, $snapname) = @_;
	344
	345	return if PVE::QemuServer::drive_is_cdrom($drive);
	346
	347	my $storecfg = PVE::Storage::config();
	348	PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
	349	}
	350
	351	sub __snapshot_rollback_vm_stop {
	352	my ($class, $vmid) = @_;
	353
	354	my $storecfg = PVE::Storage::config();
	355	PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
	356	}
	357
	358	sub __snapshot_rollback_vm_start {
58b1a8d7	359	my ($class, $vmid, $vmstate, $data) = @_;
b2c9558d FG	360
b2c9558d FG	361	my $storecfg = PVE::Storage::config();
5c1d42b7	362	PVE::QemuServer::vm_start($storecfg, $vmid, $vmstate, undef, undef, undef, $data->{forcemachine});
b2c9558d FG	363	}
b2c9558d FG	364
c4a54ed5 FG	365	sub __snapshot_rollback_get_unused {
	366	my ($class, $conf, $snap) = @_;
	367
	368	my $unused = [];
	369
	370	$class->__snapshot_foreach_volume($conf, sub {
	371	my ($vs, $volume) = @_;
	372
	373	return if PVE::QemuServer::drive_is_cdrom($volume);
	374
	375	my $found = 0;
	376	my $volid = $volume->{file};
	377
	378	$class->__snapshot_foreach_volume($snap, sub {
	379	my ($ds, $drive) = @_;
	380
	381	return if $found;
	382	return if PVE::QemuServer::drive_is_cdrom($drive);
	383
	384	$found = 1
	385	if ($drive->{file} && $drive->{file} eq $volid);
	386	});
	387
	388	push @$unused, $volid if !$found;
	389	});
	390
	391	return $unused;
	392	}
	393
b2c9558d FG	394	sub __snapshot_foreach_volume {
	395	my ($class, $conf, $func) = @_;
	396
	397	PVE::QemuServer::foreach_drive($conf, $func);
	398	}
ffda963f FG	399	# END implemented abstract methods from PVE::AbstractConfig
	400
	401	1;