]>
Commit | Line | Data |
---|---|---|
c9c0d073 BB |
1 | dnl # |
2 | dnl # Default ZFS kernel configuration | |
3 | dnl # | |
4 | AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [ | |
5 | ZFS_AC_KERNEL | |
6 | ZFS_AC_SPL | |
319a99a3 | 7 | ZFS_AC_TEST_MODULE |
c9c0d073 | 8 | ZFS_AC_KERNEL_CONFIG |
ea04106b | 9 | ZFS_AC_KERNEL_DECLARE_EVENT_CLASS |
e10b0808 | 10 | ZFS_AC_KERNEL_CURRENT_BIO_TAIL |
c9c0d073 | 11 | ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS |
c06d4368 | 12 | ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID |
c9c0d073 BB |
13 | ZFS_AC_KERNEL_TYPE_FMODE_T |
14 | ZFS_AC_KERNEL_KOBJ_NAME_LEN | |
b5a28807 | 15 | ZFS_AC_KERNEL_3ARG_BLKDEV_GET |
45066d1f | 16 | ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH |
c9c0d073 | 17 | ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE |
2b7ab9d4 | 18 | ZFS_AC_KERNEL_LOOKUP_BDEV |
c9c0d073 BB |
19 | ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS |
20 | ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE | |
2404b014 | 21 | ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE |
ea04106b | 22 | ZFS_AC_KERNEL_BIO_BVEC_ITER |
f4af6bb7 BB |
23 | ZFS_AC_KERNEL_BIO_FAILFAST_DTD |
24 | ZFS_AC_KERNEL_REQ_FAILFAST_MASK | |
c9c0d073 | 25 | ZFS_AC_KERNEL_BIO_END_IO_T_ARGS |
e10b0808 AX |
26 | ZFS_AC_KERNEL_BIO_RW_BARRIER |
27 | ZFS_AC_KERNEL_BIO_RW_DISCARD | |
b18019d2 | 28 | ZFS_AC_KERNEL_BLK_QUEUE_FLUSH |
34037afe ED |
29 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS |
30 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS | |
c9c0d073 | 31 | ZFS_AC_KERNEL_GET_DISK_RO |
b5a28807 | 32 | ZFS_AC_KERNEL_GET_GENDISK |
ee5fd0bb | 33 | ZFS_AC_KERNEL_DISCARD_GRANULARITY |
777d4af8 | 34 | ZFS_AC_KERNEL_CONST_XATTR_HANDLER |
f9637c6c BB |
35 | ZFS_AC_KERNEL_XATTR_HANDLER_GET |
36 | ZFS_AC_KERNEL_XATTR_HANDLER_SET | |
a08ee875 LG |
37 | ZFS_AC_KERNEL_XATTR_HANDLER_LIST |
38 | ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE | |
39 | ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS | |
40 | ZFS_AC_KERNEL_POSIX_ACL_RELEASE | |
41 | ZFS_AC_KERNEL_POSIX_ACL_CHMOD | |
42 | ZFS_AC_KERNEL_POSIX_ACL_CACHING | |
43 | ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T | |
44 | ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION | |
45 | ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA | |
46 | ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL | |
47 | ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS | |
48 | ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL | |
49 | ZFS_AC_KERNEL_CURRENT_UMASK | |
47621f3d | 50 | ZFS_AC_KERNEL_SHOW_OPTIONS |
ea04106b | 51 | ZFS_AC_KERNEL_FILE_INODE |
adcd70bd | 52 | ZFS_AC_KERNEL_FSYNC |
2c395def | 53 | ZFS_AC_KERNEL_EVICT_INODE |
8780c539 | 54 | ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS |
ab26409d BB |
55 | ZFS_AC_KERNEL_NR_CACHED_OBJECTS |
56 | ZFS_AC_KERNEL_FREE_CACHED_OBJECTS | |
cb2d1901 | 57 | ZFS_AC_KERNEL_FALLOCATE |
95f5c63b | 58 | ZFS_AC_KERNEL_MKDIR_UMODE_T |
8f195a90 | 59 | ZFS_AC_KERNEL_LOOKUP_NAMEIDATA |
558ef6d0 | 60 | ZFS_AC_KERNEL_CREATE_NAMEIDATA |
4d815aed | 61 | ZFS_AC_KERNEL_GET_LINK |
e10b0808 | 62 | ZFS_AC_KERNEL_PUT_LINK |
ea1fdf46 | 63 | ZFS_AC_KERNEL_TRUNCATE_RANGE |
ebe7e575 | 64 | ZFS_AC_KERNEL_AUTOMOUNT |
756c3e5a | 65 | ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE |
393b44c7 | 66 | ZFS_AC_KERNEL_COMMIT_METADATA |
739a1a82 | 67 | ZFS_AC_KERNEL_CLEAR_INODE |
bdf4328b | 68 | ZFS_AC_KERNEL_INSERT_INODE_LOCKED |
6a0936ba | 69 | ZFS_AC_KERNEL_D_MAKE_ROOT |
055656d4 | 70 | ZFS_AC_KERNEL_D_OBTAIN_ALIAS |
ea04106b | 71 | ZFS_AC_KERNEL_D_PRUNE_ALIASES |
f1a05fa1 NB |
72 | ZFS_AC_KERNEL_D_SET_D_OP |
73 | ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA | |
74 | ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS | |
df554c14 | 75 | ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE |
b3129792 | 76 | ZFS_AC_KERNEL_TRUNCATE_SETSIZE |
5c03efc3 | 77 | ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY |
166dd49d | 78 | ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY |
2cf7f52b | 79 | ZFS_AC_KERNEL_MOUNT_NODEV |
ab26409d | 80 | ZFS_AC_KERNEL_SHRINK |
ea04106b | 81 | ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID |
c06d4368 | 82 | ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD |
ee930353 | 83 | ZFS_AC_KERNEL_S_D_OP |
5547c2f1 | 84 | ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER |
28eb9213 | 85 | ZFS_AC_KERNEL_SET_NLINK |
6d1d976b | 86 | ZFS_AC_KERNEL_ELEVATOR_CHANGE |
3c203610 | 87 | ZFS_AC_KERNEL_5ARG_SGET |
c06d4368 AX |
88 | ZFS_AC_KERNEL_LSEEK_EXECUTE |
89 | ZFS_AC_KERNEL_VFS_ITERATE | |
ea04106b | 90 | ZFS_AC_KERNEL_VFS_RW_ITERATE |
e10b0808 AX |
91 | ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS |
92 | ZFS_AC_KERNEL_FOLLOW_DOWN_ONE | |
93 | ZFS_AC_KERNEL_MAKE_REQUEST_FN | |
94 | ZFS_AC_KERNEL_GENERIC_IO_ACCT | |
c9c0d073 | 95 | |
8366cd6a | 96 | AS_IF([test "$LINUX_OBJ" != "$LINUX"], [ |
6283f55e | 97 | KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ" |
8366cd6a | 98 | ]) |
6283f55e BB |
99 | AC_SUBST(KERNELMAKE_PARAMS) |
100 | ||
101 | ||
c9c0d073 BB |
102 | dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other |
103 | dnl # compiler options are added by the kernel build system. | |
8a7e1cee | 104 | KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE" |
e10b0808 | 105 | KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE" |
c9c0d073 BB |
106 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL" |
107 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\"" | |
c9c0d073 | 108 | |
c9c0d073 BB |
109 | AC_SUBST(KERNELCPPFLAGS) |
110 | ]) | |
111 | ||
112 | dnl # | |
113 | dnl # Detect name used for Module.symvers file in kernel | |
114 | dnl # | |
115 | AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [ | |
116 | modpost=$LINUX/scripts/Makefile.modpost | |
117 | AC_MSG_CHECKING([kernel file name for module symbols]) | |
319a99a3 | 118 | AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [ |
8366cd6a | 119 | AS_IF([grep -q Modules.symvers $modpost], [ |
c9c0d073 | 120 | LINUX_SYMBOLS=Modules.symvers |
8366cd6a | 121 | ], [ |
c9c0d073 | 122 | LINUX_SYMBOLS=Module.symvers |
8366cd6a | 123 | ]) |
a60b1c0a | 124 | |
8366cd6a | 125 | AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [ |
a60b1c0a BB |
126 | AC_MSG_ERROR([ |
127 | *** Please make sure the kernel devel package for your distribution | |
c06d4368 | 128 | *** is installed. If you are building with a custom kernel, make sure the |
a60b1c0a BB |
129 | *** kernel is configured, built, and the '--with-linux=PATH' configure |
130 | *** option refers to the location of the kernel source.]) | |
8366cd6a PS |
131 | ]) |
132 | ], [ | |
c9c0d073 | 133 | LINUX_SYMBOLS=NONE |
8366cd6a | 134 | ]) |
c9c0d073 BB |
135 | AC_MSG_RESULT($LINUX_SYMBOLS) |
136 | AC_SUBST(LINUX_SYMBOLS) | |
137 | ]) | |
138 | ||
139 | dnl # | |
140 | dnl # Detect the kernel to be built against | |
141 | dnl # | |
142 | AC_DEFUN([ZFS_AC_KERNEL], [ | |
143 | AC_ARG_WITH([linux], | |
144 | AS_HELP_STRING([--with-linux=PATH], | |
145 | [Path to kernel source]), | |
146 | [kernelsrc="$withval"]) | |
147 | ||
148 | AC_ARG_WITH(linux-obj, | |
149 | AS_HELP_STRING([--with-linux-obj=PATH], | |
150 | [Path to kernel build objects]), | |
151 | [kernelbuild="$withval"]) | |
152 | ||
153 | AC_MSG_CHECKING([kernel source directory]) | |
8366cd6a PS |
154 | AS_IF([test -z "$kernelsrc"], [ |
155 | AS_IF([test -e "/lib/modules/$(uname -r)/source"], [ | |
1b94c25c BB |
156 | headersdir="/lib/modules/$(uname -r)/source" |
157 | sourcelink=$(readlink -f "$headersdir") | |
8366cd6a | 158 | ], [test -e "/lib/modules/$(uname -r)/build"], [ |
1b94c25c | 159 | headersdir="/lib/modules/$(uname -r)/build" |
c9c0d073 | 160 | sourcelink=$(readlink -f "$headersdir") |
8366cd6a | 161 | ], [ |
c9c0d073 | 162 | sourcelink=$(ls -1d /usr/src/kernels/* \ |
8366cd6a | 163 | /usr/src/linux-* \ |
c9c0d073 | 164 | 2>/dev/null | grep -v obj | tail -1) |
8366cd6a | 165 | ]) |
c9c0d073 | 166 | |
8366cd6a | 167 | AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [ |
c9c0d073 | 168 | kernelsrc=`readlink -f ${sourcelink}` |
8366cd6a | 169 | ], [ |
56a517ae | 170 | kernelsrc="[Not found]" |
8366cd6a PS |
171 | ]) |
172 | ], [ | |
173 | AS_IF([test "$kernelsrc" = "NONE"], [ | |
c9c0d073 | 174 | kernsrcver=NONE |
8366cd6a PS |
175 | ]) |
176 | ]) | |
c9c0d073 BB |
177 | |
178 | AC_MSG_RESULT([$kernelsrc]) | |
56a517ae BB |
179 | AS_IF([test ! -d "$kernelsrc"], [ |
180 | AC_MSG_ERROR([ | |
181 | *** Please make sure the kernel devel package for your distribution | |
c06d4368 | 182 | *** is installed and then try again. If that fails, you can specify the |
56a517ae BB |
183 | *** location of the kernel source with the '--with-linux=PATH' option.]) |
184 | ]) | |
185 | ||
c9c0d073 | 186 | AC_MSG_CHECKING([kernel build directory]) |
8366cd6a PS |
187 | AS_IF([test -z "$kernelbuild"], [ |
188 | AS_IF([test -e "/lib/modules/$(uname -r)/build"], [ | |
1b94c25c | 189 | kernelbuild=`readlink -f /lib/modules/$(uname -r)/build` |
8366cd6a | 190 | ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [ |
c9c0d073 | 191 | kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu} |
8366cd6a | 192 | ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [ |
70574182 | 193 | kernelbuild=${kernelsrc}-obj/${target_cpu}/default |
8366cd6a | 194 | ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [ |
c9c0d073 | 195 | kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu} |
8366cd6a | 196 | ], [ |
c9c0d073 | 197 | kernelbuild=${kernelsrc} |
8366cd6a PS |
198 | ]) |
199 | ]) | |
c9c0d073 BB |
200 | AC_MSG_RESULT([$kernelbuild]) |
201 | ||
202 | AC_MSG_CHECKING([kernel source version]) | |
203 | utsrelease1=$kernelbuild/include/linux/version.h | |
204 | utsrelease2=$kernelbuild/include/linux/utsrelease.h | |
205 | utsrelease3=$kernelbuild/include/generated/utsrelease.h | |
8366cd6a | 206 | AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [ |
c9c0d073 | 207 | utsrelease=linux/version.h |
8366cd6a | 208 | ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [ |
c9c0d073 | 209 | utsrelease=linux/utsrelease.h |
8366cd6a | 210 | ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [ |
c9c0d073 | 211 | utsrelease=generated/utsrelease.h |
8366cd6a | 212 | ]) |
c9c0d073 | 213 | |
8366cd6a | 214 | AS_IF([test "$utsrelease"], [ |
c9c0d073 BB |
215 | kernsrcver=`(echo "#include <$utsrelease>"; |
216 | echo "kernsrcver=UTS_RELEASE") | | |
217 | cpp -I $kernelbuild/include | | |
218 | grep "^kernsrcver=" | cut -d \" -f 2` | |
219 | ||
8366cd6a | 220 | AS_IF([test -z "$kernsrcver"], [ |
c9c0d073 BB |
221 | AC_MSG_RESULT([Not found]) |
222 | AC_MSG_ERROR([*** Cannot determine kernel version.]) | |
8366cd6a PS |
223 | ]) |
224 | ], [ | |
c9c0d073 | 225 | AC_MSG_RESULT([Not found]) |
319a99a3 ED |
226 | if test "x$enable_linux_builtin" != xyes; then |
227 | AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.]) | |
228 | else | |
229 | AC_MSG_ERROR([ | |
230 | *** Cannot find UTS_RELEASE definition. | |
231 | *** Please run 'make prepare' inside the kernel source tree.]) | |
232 | fi | |
8366cd6a | 233 | ]) |
c9c0d073 BB |
234 | |
235 | AC_MSG_RESULT([$kernsrcver]) | |
236 | ||
237 | LINUX=${kernelsrc} | |
238 | LINUX_OBJ=${kernelbuild} | |
239 | LINUX_VERSION=${kernsrcver} | |
240 | ||
241 | AC_SUBST(LINUX) | |
242 | AC_SUBST(LINUX_OBJ) | |
243 | AC_SUBST(LINUX_VERSION) | |
244 | ||
245 | ZFS_AC_MODULE_SYMVERS | |
246 | ]) | |
247 | ||
c9c0d073 BB |
248 | |
249 | dnl # | |
250 | dnl # Detect the SPL module to be built against | |
251 | dnl # | |
252 | AC_DEFUN([ZFS_AC_SPL], [ | |
253 | AC_ARG_WITH([spl], | |
254 | AS_HELP_STRING([--with-spl=PATH], | |
255 | [Path to spl source]), | |
256 | [splsrc="$withval"]) | |
257 | ||
258 | AC_ARG_WITH([spl-obj], | |
259 | AS_HELP_STRING([--with-spl-obj=PATH], | |
260 | [Path to spl build objects]), | |
261 | [splbuild="$withval"]) | |
262 | ||
c06d4368 AX |
263 | AC_ARG_WITH([spl-timeout], |
264 | AS_HELP_STRING([--with-spl-timeout=SECS], | |
265 | [Wait SECS for SPL header and symver file @<:@default=0@:>@]), | |
266 | [timeout="$withval"], [timeout=0]) | |
267 | ||
9b2af9a0 BB |
268 | dnl # |
269 | dnl # The existence of spl.release.in is used to identify a valid | |
270 | dnl # source directory. In order of preference: | |
271 | dnl # | |
272 | splsrc0="/var/lib/dkms/spl/${VERSION}/build" | |
ea04106b AX |
273 | splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}" |
274 | splsrc2="/usr/local/src/spl-${VERSION}" | |
275 | splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}" | |
276 | splsrc4="/usr/src/spl-${VERSION}" | |
277 | splsrc5="../spl/" | |
278 | splsrc6="$LINUX" | |
c9c0d073 BB |
279 | |
280 | AC_MSG_CHECKING([spl source directory]) | |
9b2af9a0 BB |
281 | AS_IF([test -z "${splsrc}"], [ |
282 | AS_IF([ test -e "${splsrc0}/spl.release.in"], [ | |
283 | splsrc=${splsrc0} | |
284 | ], [ test -e "${splsrc1}/spl.release.in"], [ | |
285 | splsrc=${splsrc1} | |
286 | ], [ test -e "${splsrc2}/spl.release.in"], [ | |
287 | splsrc=${splsrc2} | |
288 | ], [ test -e "${splsrc3}/spl.release.in"], [ | |
289 | splsrc=$(readlink -f "${splsrc3}") | |
290 | ], [ test -e "${splsrc4}/spl.release.in" ], [ | |
291 | splsrc=${splsrc4} | |
ea04106b AX |
292 | ], [ test -e "${splsrc5}/spl.release.in"], [ |
293 | splsrc=$(readlink -f "${splsrc5}") | |
294 | ], [ test -e "${splsrc6}/spl.release.in" ], [ | |
295 | splsrc=${splsrc6} | |
8366cd6a | 296 | ], [ |
9b2af9a0 | 297 | splsrc="[Not found]" |
8366cd6a PS |
298 | ]) |
299 | ], [ | |
300 | AS_IF([test "$splsrc" = "NONE"], [ | |
c9c0d073 BB |
301 | splbuild=NONE |
302 | splsrcver=NONE | |
8366cd6a PS |
303 | ]) |
304 | ]) | |
c9c0d073 BB |
305 | |
306 | AC_MSG_RESULT([$splsrc]) | |
9b2af9a0 BB |
307 | AS_IF([ test ! -e "$splsrc/spl.release.in"], [ |
308 | AC_MSG_ERROR([ | |
309 | *** Please make sure the kmod spl devel package for your distribution | |
310 | *** is installed then try again. If that fails you can specify the | |
311 | *** location of the spl source with the '--with-spl=PATH' option.]) | |
312 | ]) | |
313 | ||
314 | dnl # | |
315 | dnl # The existence of the spl_config.h is used to identify a valid | |
316 | dnl # spl object directory. In many cases the object and source | |
317 | dnl # directory are the same, however the objects may also reside | |
318 | dnl # is a subdirectory named after the kernel version. | |
319 | dnl # | |
c06d4368 AX |
320 | dnl # This file is supposed to be available after DKMS finishes |
321 | dnl # building the SPL kernel module for the target kernel. The | |
322 | dnl # '--with-spl-timeout' option can be passed to pause here, | |
323 | dnl # waiting for the file to appear from a concurrently building | |
324 | dnl # SPL package. | |
325 | dnl # | |
c9c0d073 | 326 | AC_MSG_CHECKING([spl build directory]) |
c06d4368 AX |
327 | while true; do |
328 | AS_IF([test -z "$splbuild"], [ | |
329 | AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [ | |
330 | splbuild="${splsrc}/${LINUX_VERSION}" | |
331 | ], [ test -e "${splsrc}/spl_config.h" ], [ | |
332 | splbuild="${splsrc}" | |
e10b0808 AX |
333 | ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [ |
334 | splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,') | |
c06d4368 AX |
335 | ], [ |
336 | splbuild="[Not found]" | |
337 | ]) | |
338 | ]) | |
339 | AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [ | |
340 | break; | |
9b2af9a0 | 341 | ], [ |
c06d4368 AX |
342 | sleep 1 |
343 | timeout=$((timeout-1)) | |
9b2af9a0 | 344 | ]) |
c06d4368 | 345 | done |
9b2af9a0 | 346 | |
c9c0d073 | 347 | AC_MSG_RESULT([$splbuild]) |
9b2af9a0 BB |
348 | AS_IF([ ! test -e "$splbuild/spl_config.h"], [ |
349 | AC_MSG_ERROR([ | |
350 | *** Please make sure the kmod spl devel <kernel> package for your | |
351 | *** distribution is installed then try again. If that fails you | |
352 | *** can specify the location of the spl objects with the | |
353 | *** '--with-spl-obj=PATH' option.]) | |
354 | ]) | |
c9c0d073 BB |
355 | |
356 | AC_MSG_CHECKING([spl source version]) | |
8366cd6a PS |
357 | AS_IF([test -r $splbuild/spl_config.h && |
358 | fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [ | |
c9c0d073 BB |
359 | |
360 | splsrcver=`(echo "#include <spl_config.h>"; | |
b40a77ae | 361 | echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") | |
5e612145 | 362 | cpp -I $splbuild | |
b40a77ae | 363 | grep "^splsrcver=" | tr -d \" | cut -d= -f2` |
8366cd6a | 364 | ]) |
c9c0d073 | 365 | |
8366cd6a | 366 | AS_IF([test -z "$splsrcver"], [ |
c9c0d073 BB |
367 | AC_MSG_RESULT([Not found]) |
368 | AC_MSG_ERROR([ | |
2984e0bb PS |
369 | *** Cannot determine the version of the spl source. |
370 | *** Please prepare the spl source before running this script]) | |
8366cd6a | 371 | ]) |
c9c0d073 BB |
372 | |
373 | AC_MSG_RESULT([$splsrcver]) | |
374 | ||
375 | SPL=${splsrc} | |
376 | SPL_OBJ=${splbuild} | |
377 | SPL_VERSION=${splsrcver} | |
378 | ||
379 | AC_SUBST(SPL) | |
380 | AC_SUBST(SPL_OBJ) | |
381 | AC_SUBST(SPL_VERSION) | |
382 | ||
c06d4368 AX |
383 | dnl # |
384 | dnl # Detect the name used for the SPL Module.symvers file. If one | |
385 | dnl # does not exist this is likely because the SPL has been configured | |
386 | dnl # but not built. The '--with-spl-timeout' option can be passed | |
387 | dnl # to pause here, waiting for the file to appear from a concurrently | |
388 | dnl # building SPL package. If the file does not appear in time, a good | |
389 | dnl # guess is made as to what this file will be named based on what it | |
390 | dnl # is named in the kernel build products. This file will first be | |
391 | dnl # used at link time so if the guess is wrong the build will fail | |
392 | dnl # then. This unfortunately means the ZFS package does not contain a | |
393 | dnl # reliable mechanism to detect symbols exported by the SPL at | |
394 | dnl # configure time. | |
395 | dnl # | |
396 | AC_MSG_CHECKING([spl file name for module symbols]) | |
397 | SPL_SYMBOLS=NONE | |
398 | ||
399 | while true; do | |
400 | AS_IF([test -r $SPL_OBJ/Module.symvers], [ | |
401 | SPL_SYMBOLS=Module.symvers | |
402 | ], [test -r $SPL_OBJ/Modules.symvers], [ | |
403 | SPL_SYMBOLS=Modules.symvers | |
404 | ], [test -r $SPL_OBJ/module/Module.symvers], [ | |
405 | SPL_SYMBOLS=Module.symvers | |
406 | ], [test -r $SPL_OBJ/module/Modules.symvers], [ | |
407 | SPL_SYMBOLS=Modules.symvers | |
408 | ]) | |
409 | ||
410 | AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [ | |
411 | break; | |
412 | ], [ | |
413 | sleep 1 | |
414 | timeout=$((timeout-1)) | |
415 | ]) | |
416 | done | |
417 | ||
418 | AS_IF([test "$SPL_SYMBOLS" = NONE], [ | |
419 | SPL_SYMBOLS=$LINUX_SYMBOLS | |
420 | ]) | |
421 | ||
422 | AC_MSG_RESULT([$SPL_SYMBOLS]) | |
423 | AC_SUBST(SPL_SYMBOLS) | |
c9c0d073 BB |
424 | ]) |
425 | ||
319a99a3 ED |
426 | dnl # |
427 | dnl # Basic toolchain sanity check. | |
428 | dnl # | |
ea04106b AX |
429 | AC_DEFUN([ZFS_AC_TEST_MODULE], [ |
430 | AC_MSG_CHECKING([whether modules can be built]) | |
319a99a3 ED |
431 | ZFS_LINUX_TRY_COMPILE([],[],[ |
432 | AC_MSG_RESULT([yes]) | |
433 | ],[ | |
434 | AC_MSG_RESULT([no]) | |
435 | if test "x$enable_linux_builtin" != xyes; then | |
436 | AC_MSG_ERROR([*** Unable to build an empty module.]) | |
437 | else | |
438 | AC_MSG_ERROR([ | |
439 | *** Unable to build an empty module. | |
440 | *** Please run 'make scripts' inside the kernel source tree.]) | |
441 | fi | |
442 | ]) | |
443 | ]) | |
444 | ||
15805c77 BB |
445 | dnl # |
446 | dnl # Certain kernel build options are not supported. These must be | |
447 | dnl # detected at configure time and cause a build failure. Otherwise | |
448 | dnl # modules may be successfully built that behave incorrectly. | |
449 | dnl # | |
e5b85622 | 450 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [ |
94a40997 AX |
451 | AS_IF([test "x$cross_compiling" != xyes], [ |
452 | AC_RUN_IFELSE([ | |
453 | AC_LANG_PROGRAM([ | |
454 | #include "$LINUX/include/linux/license.h" | |
455 | ], [ | |
456 | return !license_is_gpl_compatible("$ZFS_META_LICENSE"); | |
457 | ]) | |
458 | ], [ | |
459 | AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1], | |
460 | [Define to 1 if GPL-only symbols can be used]) | |
ea04106b | 461 | ], [ |
ea04106b | 462 | ]) |
e5b85622 BB |
463 | ]) |
464 | ||
e5b85622 BB |
465 | ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC |
466 | ]) | |
467 | ||
e5b85622 BB |
468 | dnl # |
469 | dnl # Check CONFIG_DEBUG_LOCK_ALLOC | |
470 | dnl # | |
471 | dnl # This is typically only set for debug kernels because it comes with | |
472 | dnl # a performance penalty. However, when it is set it maps the non-GPL | |
473 | dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol. | |
474 | dnl # This will cause a failure at link time which we'd rather know about | |
475 | dnl # at compile time. | |
476 | dnl # | |
477 | dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol | |
478 | dnl # with the upstream community we add a check to detect this case. | |
479 | dnl # | |
480 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [ | |
481 | ||
482 | ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [ | |
483 | AC_MSG_CHECKING([whether mutex_lock() is GPL-only]) | |
484 | tmp_flags="$EXTRA_KCFLAGS" | |
485 | ZFS_LINUX_TRY_COMPILE([ | |
486 | #include <linux/module.h> | |
487 | #include <linux/mutex.h> | |
488 | ||
489 | MODULE_LICENSE("$ZFS_META_LICENSE"); | |
490 | ],[ | |
491 | struct mutex lock; | |
492 | ||
493 | mutex_init(&lock); | |
494 | mutex_lock(&lock); | |
495 | mutex_unlock(&lock); | |
496 | ],[ | |
497 | AC_MSG_RESULT(no) | |
498 | ],[ | |
499 | AC_MSG_RESULT(yes) | |
500 | AC_MSG_ERROR([ | |
501 | *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible | |
cac1f230 NB |
502 | *** with the CDDL license and will prevent the module linking stage |
503 | *** from succeeding. You must rebuild your kernel without this | |
504 | *** option enabled.]) | |
e5b85622 BB |
505 | ]) |
506 | EXTRA_KCFLAGS="$tmp_flags" | |
507 | ], []) | |
c9c0d073 BB |
508 | ]) |
509 | ||
510 | dnl # | |
ea04106b AX |
511 | dnl # ZFS_LINUX_CONFTEST_H |
512 | dnl # | |
513 | AC_DEFUN([ZFS_LINUX_CONFTEST_H], [ | |
514 | cat - <<_ACEOF >conftest.h | |
515 | $1 | |
516 | _ACEOF | |
517 | ]) | |
518 | ||
c9c0d073 | 519 | dnl # |
ea04106b AX |
520 | dnl # ZFS_LINUX_CONFTEST_C |
521 | dnl # | |
522 | AC_DEFUN([ZFS_LINUX_CONFTEST_C], [ | |
c9c0d073 BB |
523 | cat confdefs.h - <<_ACEOF >conftest.c |
524 | $1 | |
525 | _ACEOF | |
526 | ]) | |
527 | ||
528 | dnl # | |
529 | dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY]) | |
530 | dnl # | |
531 | m4_define([ZFS_LANG_PROGRAM], [ | |
532 | $1 | |
533 | int | |
534 | main (void) | |
535 | { | |
536 | dnl Do *not* indent the following line: there may be CPP directives. | |
537 | dnl Don't move the `;' right after for the same reason. | |
538 | $2 | |
539 | ; | |
540 | return 0; | |
541 | } | |
542 | ]) | |
543 | ||
544 | dnl # | |
545 | dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE | |
546 | dnl # | |
547 | AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [ | |
ea04106b AX |
548 | m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])]) |
549 | m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])]) | |
fc88a6dd | 550 | rm -Rf build && mkdir -p build && touch build/conftest.mod.c |
c9c0d073 | 551 | echo "obj-m := conftest.o" >build/Makefile |
fc88a6dd ED |
552 | modpost_flag='' |
553 | test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage | |
c9c0d073 | 554 | AS_IF( |
ea04106b | 555 | [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])], |
c9c0d073 BB |
556 | [$4], |
557 | [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])] | |
558 | ) | |
559 | rm -Rf build | |
560 | ]) | |
561 | ||
562 | dnl # | |
563 | dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE | |
564 | dnl # | |
565 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE], | |
566 | [ZFS_LINUX_COMPILE_IFELSE( | |
567 | [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])], | |
568 | [modules], | |
569 | [test -s build/conftest.o], | |
570 | [$3], [$4]) | |
571 | ]) | |
572 | ||
573 | dnl # | |
574 | dnl # ZFS_LINUX_CONFIG | |
575 | dnl # | |
576 | AC_DEFUN([ZFS_LINUX_CONFIG], | |
577 | [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1]) | |
578 | ZFS_LINUX_TRY_COMPILE([ | |
0da78696 | 579 | #include <linux/module.h> |
c9c0d073 BB |
580 | ],[ |
581 | #ifndef CONFIG_$1 | |
582 | #error CONFIG_$1 not #defined | |
583 | #endif | |
584 | ],[ | |
585 | AC_MSG_RESULT([yes]) | |
586 | $2 | |
587 | ],[ | |
588 | AC_MSG_RESULT([no]) | |
589 | $3 | |
590 | ]) | |
591 | ]) | |
592 | ||
593 | dnl # | |
594 | dnl # ZFS_CHECK_SYMBOL_EXPORT | |
595 | dnl # check symbol exported or not | |
596 | dnl # | |
70574182 | 597 | AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [ |
c9c0d073 BB |
598 | grep -q -E '[[[:space:]]]$1[[[:space:]]]' \ |
599 | $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null | |
600 | rc=$? | |
70574182 | 601 | if test $rc -ne 0; then |
c9c0d073 BB |
602 | export=0 |
603 | for file in $2; do | |
70574182 ED |
604 | grep -q -E "EXPORT_SYMBOL.*($1)" \ |
605 | "$LINUX/$file" 2>/dev/null | |
c9c0d073 | 606 | rc=$? |
70574182 | 607 | if test $rc -eq 0; then |
8366cd6a PS |
608 | export=1 |
609 | break; | |
70574182 | 610 | fi |
c9c0d073 | 611 | done |
70574182 | 612 | if test $export -eq 0; then : |
c9c0d073 | 613 | $4 |
70574182 | 614 | else : |
c9c0d073 | 615 | $3 |
70574182 ED |
616 | fi |
617 | else : | |
c9c0d073 | 618 | $3 |
70574182 ED |
619 | fi |
620 | ]) | |
621 | ||
622 | dnl # | |
623 | dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL | |
624 | dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT | |
625 | dnl # is called if not compiling for builtin | |
626 | dnl # | |
627 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [ | |
628 | ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1]) | |
629 | if test $rc -ne 0; then : | |
630 | $6 | |
631 | else | |
632 | if test "x$enable_linux_builtin" != xyes; then | |
633 | ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1]) | |
634 | fi | |
635 | if test $rc -ne 0; then : | |
636 | $6 | |
637 | else : | |
638 | $5 | |
639 | fi | |
640 | fi | |
c9c0d073 | 641 | ]) |
ea04106b AX |
642 | |
643 | dnl # | |
644 | dnl # ZFS_LINUX_TRY_COMPILE_HEADER | |
645 | dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are | |
646 | dnl # provided via the fifth parameter | |
647 | dnl # | |
648 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], | |
649 | [ZFS_LINUX_COMPILE_IFELSE( | |
650 | [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])], | |
651 | [modules], | |
652 | [test -s build/conftest.o], | |
653 | [$3], [$4], [$5]) | |
654 | ]) |