]>
Commit | Line | Data |
---|---|---|
c9c0d073 BB |
1 | dnl # |
2 | dnl # Default ZFS kernel configuration | |
3 | dnl # | |
4 | AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [ | |
5 | ZFS_AC_KERNEL | |
6 | ZFS_AC_SPL | |
7 | ZFS_AC_KERNEL_CONFIG | |
8 | ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS | |
9 | ZFS_AC_KERNEL_TYPE_FMODE_T | |
10 | ZFS_AC_KERNEL_KOBJ_NAME_LEN | |
b5a28807 | 11 | ZFS_AC_KERNEL_3ARG_BLKDEV_GET |
45066d1f | 12 | ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH |
c9c0d073 BB |
13 | ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE |
14 | ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS | |
15 | ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE | |
16 | ZFS_AC_KERNEL_BIO_EMPTY_BARRIER | |
2959d94a | 17 | ZFS_AC_KERNEL_BIO_FAILFAST |
f4af6bb7 BB |
18 | ZFS_AC_KERNEL_BIO_FAILFAST_DTD |
19 | ZFS_AC_KERNEL_REQ_FAILFAST_MASK | |
c9c0d073 | 20 | ZFS_AC_KERNEL_BIO_END_IO_T_ARGS |
675de5aa | 21 | ZFS_AC_KERNEL_BIO_RW_SYNC |
c9c0d073 | 22 | ZFS_AC_KERNEL_BIO_RW_SYNCIO |
675de5aa | 23 | ZFS_AC_KERNEL_REQ_SYNC |
c9c0d073 | 24 | ZFS_AC_KERNEL_BLK_END_REQUEST |
b18019d2 | 25 | ZFS_AC_KERNEL_BLK_QUEUE_FLUSH |
34037afe ED |
26 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS |
27 | ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS | |
28 | ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE | |
29 | ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT | |
30 | ZFS_AC_KERNEL_BLK_QUEUE_NONROT | |
30930fba | 31 | ZFS_AC_KERNEL_BLK_QUEUE_DISCARD |
c9c0d073 BB |
32 | ZFS_AC_KERNEL_BLK_FETCH_REQUEST |
33 | ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST | |
34 | ZFS_AC_KERNEL_BLK_RQ_BYTES | |
35 | ZFS_AC_KERNEL_BLK_RQ_POS | |
36 | ZFS_AC_KERNEL_BLK_RQ_SECTORS | |
37 | ZFS_AC_KERNEL_GET_DISK_RO | |
b5a28807 | 38 | ZFS_AC_KERNEL_GET_GENDISK |
c9c0d073 BB |
39 | ZFS_AC_KERNEL_RQ_IS_SYNC |
40 | ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT | |
777d4af8 | 41 | ZFS_AC_KERNEL_CONST_XATTR_HANDLER |
f9637c6c BB |
42 | ZFS_AC_KERNEL_XATTR_HANDLER_GET |
43 | ZFS_AC_KERNEL_XATTR_HANDLER_SET | |
47621f3d | 44 | ZFS_AC_KERNEL_SHOW_OPTIONS |
adcd70bd | 45 | ZFS_AC_KERNEL_FSYNC |
2c395def | 46 | ZFS_AC_KERNEL_EVICT_INODE |
ab26409d BB |
47 | ZFS_AC_KERNEL_NR_CACHED_OBJECTS |
48 | ZFS_AC_KERNEL_FREE_CACHED_OBJECTS | |
cb2d1901 | 49 | ZFS_AC_KERNEL_FALLOCATE |
b39d3b9f | 50 | ZFS_AC_KERNEL_CREATE_UMODE_T |
ebe7e575 | 51 | ZFS_AC_KERNEL_AUTOMOUNT |
756c3e5a | 52 | ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE |
bdf4328b | 53 | ZFS_AC_KERNEL_INSERT_INODE_LOCKED |
6a0936ba | 54 | ZFS_AC_KERNEL_D_MAKE_ROOT |
055656d4 | 55 | ZFS_AC_KERNEL_D_OBTAIN_ALIAS |
df554c14 | 56 | ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE |
b3129792 | 57 | ZFS_AC_KERNEL_TRUNCATE_SETSIZE |
5c03efc3 | 58 | ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY |
166dd49d | 59 | ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY |
2cf7f52b | 60 | ZFS_AC_KERNEL_MOUNT_NODEV |
ab26409d | 61 | ZFS_AC_KERNEL_SHRINK |
76659dc1 | 62 | ZFS_AC_KERNEL_BDI |
5547c2f1 | 63 | ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER |
28eb9213 | 64 | ZFS_AC_KERNEL_SET_NLINK |
c9c0d073 | 65 | |
8366cd6a | 66 | AS_IF([test "$LINUX_OBJ" != "$LINUX"], [ |
6283f55e | 67 | KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ" |
8366cd6a | 68 | ]) |
6283f55e BB |
69 | AC_SUBST(KERNELMAKE_PARAMS) |
70 | ||
71 | ||
c9c0d073 BB |
72 | dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other |
73 | dnl # compiler options are added by the kernel build system. | |
8a7e1cee | 74 | KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE" |
c9c0d073 BB |
75 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL" |
76 | KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\"" | |
c9c0d073 | 77 | |
c9c0d073 BB |
78 | AC_SUBST(KERNELCPPFLAGS) |
79 | ]) | |
80 | ||
81 | dnl # | |
82 | dnl # Detect name used for Module.symvers file in kernel | |
83 | dnl # | |
84 | AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [ | |
85 | modpost=$LINUX/scripts/Makefile.modpost | |
86 | AC_MSG_CHECKING([kernel file name for module symbols]) | |
8366cd6a PS |
87 | AS_IF([test -f "$modpost"], [ |
88 | AS_IF([grep -q Modules.symvers $modpost], [ | |
c9c0d073 | 89 | LINUX_SYMBOLS=Modules.symvers |
8366cd6a | 90 | ], [ |
c9c0d073 | 91 | LINUX_SYMBOLS=Module.symvers |
8366cd6a | 92 | ]) |
a60b1c0a | 93 | |
8366cd6a | 94 | AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [ |
a60b1c0a BB |
95 | AC_MSG_ERROR([ |
96 | *** Please make sure the kernel devel package for your distribution | |
97 | *** is installed. If your building with a custom kernel make sure the | |
98 | *** kernel is configured, built, and the '--with-linux=PATH' configure | |
99 | *** option refers to the location of the kernel source.]) | |
8366cd6a PS |
100 | ]) |
101 | ], [ | |
c9c0d073 | 102 | LINUX_SYMBOLS=NONE |
8366cd6a | 103 | ]) |
c9c0d073 BB |
104 | AC_MSG_RESULT($LINUX_SYMBOLS) |
105 | AC_SUBST(LINUX_SYMBOLS) | |
106 | ]) | |
107 | ||
108 | dnl # | |
109 | dnl # Detect the kernel to be built against | |
110 | dnl # | |
111 | AC_DEFUN([ZFS_AC_KERNEL], [ | |
112 | AC_ARG_WITH([linux], | |
113 | AS_HELP_STRING([--with-linux=PATH], | |
114 | [Path to kernel source]), | |
115 | [kernelsrc="$withval"]) | |
116 | ||
117 | AC_ARG_WITH(linux-obj, | |
118 | AS_HELP_STRING([--with-linux-obj=PATH], | |
119 | [Path to kernel build objects]), | |
120 | [kernelbuild="$withval"]) | |
121 | ||
122 | AC_MSG_CHECKING([kernel source directory]) | |
8366cd6a PS |
123 | AS_IF([test -z "$kernelsrc"], [ |
124 | AS_IF([test -e "/lib/modules/$(uname -r)/source"], [ | |
1b94c25c BB |
125 | headersdir="/lib/modules/$(uname -r)/source" |
126 | sourcelink=$(readlink -f "$headersdir") | |
8366cd6a | 127 | ], [test -e "/lib/modules/$(uname -r)/build"], [ |
1b94c25c | 128 | headersdir="/lib/modules/$(uname -r)/build" |
c9c0d073 | 129 | sourcelink=$(readlink -f "$headersdir") |
8366cd6a | 130 | ], [ |
c9c0d073 | 131 | sourcelink=$(ls -1d /usr/src/kernels/* \ |
8366cd6a | 132 | /usr/src/linux-* \ |
c9c0d073 | 133 | 2>/dev/null | grep -v obj | tail -1) |
8366cd6a | 134 | ]) |
c9c0d073 | 135 | |
8366cd6a | 136 | AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [ |
c9c0d073 | 137 | kernelsrc=`readlink -f ${sourcelink}` |
8366cd6a | 138 | ], [ |
c9c0d073 BB |
139 | AC_MSG_RESULT([Not found]) |
140 | AC_MSG_ERROR([ | |
141 | *** Please make sure the kernel devel package for your distribution | |
142 | *** is installed then try again. If that fails you can specify the | |
143 | *** location of the kernel source with the '--with-linux=PATH' option.]) | |
8366cd6a PS |
144 | ]) |
145 | ], [ | |
146 | AS_IF([test "$kernelsrc" = "NONE"], [ | |
c9c0d073 | 147 | kernsrcver=NONE |
8366cd6a PS |
148 | ]) |
149 | ]) | |
c9c0d073 BB |
150 | |
151 | AC_MSG_RESULT([$kernelsrc]) | |
152 | AC_MSG_CHECKING([kernel build directory]) | |
8366cd6a PS |
153 | AS_IF([test -z "$kernelbuild"], [ |
154 | AS_IF([test -e "/lib/modules/$(uname -r)/build"], [ | |
1b94c25c | 155 | kernelbuild=`readlink -f /lib/modules/$(uname -r)/build` |
8366cd6a | 156 | ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [ |
c9c0d073 | 157 | kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu} |
8366cd6a | 158 | ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [ |
c9c0d073 | 159 | kernelbuild=${kernelsrc}-obj/${target_cpu}/default |
8366cd6a | 160 | ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [ |
c9c0d073 | 161 | kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu} |
8366cd6a | 162 | ], [ |
c9c0d073 | 163 | kernelbuild=${kernelsrc} |
8366cd6a PS |
164 | ]) |
165 | ]) | |
c9c0d073 BB |
166 | AC_MSG_RESULT([$kernelbuild]) |
167 | ||
168 | AC_MSG_CHECKING([kernel source version]) | |
169 | utsrelease1=$kernelbuild/include/linux/version.h | |
170 | utsrelease2=$kernelbuild/include/linux/utsrelease.h | |
171 | utsrelease3=$kernelbuild/include/generated/utsrelease.h | |
8366cd6a | 172 | AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [ |
c9c0d073 | 173 | utsrelease=linux/version.h |
8366cd6a | 174 | ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [ |
c9c0d073 | 175 | utsrelease=linux/utsrelease.h |
8366cd6a | 176 | ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [ |
c9c0d073 | 177 | utsrelease=generated/utsrelease.h |
8366cd6a | 178 | ]) |
c9c0d073 | 179 | |
8366cd6a | 180 | AS_IF([test "$utsrelease"], [ |
c9c0d073 BB |
181 | kernsrcver=`(echo "#include <$utsrelease>"; |
182 | echo "kernsrcver=UTS_RELEASE") | | |
183 | cpp -I $kernelbuild/include | | |
184 | grep "^kernsrcver=" | cut -d \" -f 2` | |
185 | ||
8366cd6a | 186 | AS_IF([test -z "$kernsrcver"], [ |
c9c0d073 BB |
187 | AC_MSG_RESULT([Not found]) |
188 | AC_MSG_ERROR([*** Cannot determine kernel version.]) | |
8366cd6a PS |
189 | ]) |
190 | ], [ | |
c9c0d073 BB |
191 | AC_MSG_RESULT([Not found]) |
192 | AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.]) | |
8366cd6a | 193 | ]) |
c9c0d073 BB |
194 | |
195 | AC_MSG_RESULT([$kernsrcver]) | |
196 | ||
197 | LINUX=${kernelsrc} | |
198 | LINUX_OBJ=${kernelbuild} | |
199 | LINUX_VERSION=${kernsrcver} | |
200 | ||
201 | AC_SUBST(LINUX) | |
202 | AC_SUBST(LINUX_OBJ) | |
203 | AC_SUBST(LINUX_VERSION) | |
204 | ||
205 | ZFS_AC_MODULE_SYMVERS | |
206 | ]) | |
207 | ||
208 | dnl # | |
209 | dnl # Detect name used for the additional SPL Module.symvers file. If one | |
210 | dnl # does not exist this is likely because the SPL has been configured | |
211 | dnl # but not built. To allow recursive builds a good guess is made as to | |
212 | dnl # what this file will be named based on what it is named in the kernel | |
213 | dnl # build products. This file will first be used at link time so if | |
214 | dnl # the guess is wrong the build will fail then. This unfortunately | |
215 | dnl # means the ZFS package does not contain a reliable mechanism to | |
216 | dnl # detect symbols exported by the SPL at configure time. | |
217 | dnl # | |
218 | AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [ | |
219 | AC_MSG_CHECKING([spl file name for module symbols]) | |
8366cd6a | 220 | AS_IF([test -r $SPL_OBJ/Module.symvers], [ |
c9c0d073 | 221 | SPL_SYMBOLS=Module.symvers |
8366cd6a | 222 | ], [test -r $SPL_OBJ/Modules.symvers], [ |
c9c0d073 | 223 | SPL_SYMBOLS=Modules.symvers |
8366cd6a | 224 | ], [test -r $SPL_OBJ/module/Module.symvers], [ |
6283f55e | 225 | SPL_SYMBOLS=Module.symvers |
8366cd6a | 226 | ], [test -r $SPL_OBJ/module/Modules.symvers], [ |
6283f55e | 227 | SPL_SYMBOLS=Modules.symvers |
8366cd6a | 228 | ], [ |
c9c0d073 | 229 | SPL_SYMBOLS=$LINUX_SYMBOLS |
8366cd6a | 230 | ]) |
c9c0d073 BB |
231 | |
232 | AC_MSG_RESULT([$SPL_SYMBOLS]) | |
233 | AC_SUBST(SPL_SYMBOLS) | |
234 | ]) | |
235 | ||
236 | dnl # | |
237 | dnl # Detect the SPL module to be built against | |
238 | dnl # | |
239 | AC_DEFUN([ZFS_AC_SPL], [ | |
240 | AC_ARG_WITH([spl], | |
241 | AS_HELP_STRING([--with-spl=PATH], | |
242 | [Path to spl source]), | |
243 | [splsrc="$withval"]) | |
244 | ||
245 | AC_ARG_WITH([spl-obj], | |
246 | AS_HELP_STRING([--with-spl-obj=PATH], | |
247 | [Path to spl build objects]), | |
248 | [splbuild="$withval"]) | |
249 | ||
250 | ||
251 | AC_MSG_CHECKING([spl source directory]) | |
8366cd6a | 252 | AS_IF([test -z "$splsrc"], [ |
c9c0d073 BB |
253 | sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \ |
254 | 2>/dev/null | tail -1` | |
255 | ||
8366cd6a | 256 | AS_IF([test -z "$sourcelink" || test ! -e $sourcelink], [ |
c9c0d073 | 257 | sourcelink=../spl |
8366cd6a | 258 | ]) |
c9c0d073 | 259 | |
8366cd6a | 260 | AS_IF([test -e $sourcelink], [ |
c9c0d073 | 261 | splsrc=`readlink -f ${sourcelink}` |
8366cd6a | 262 | ], [ |
c9c0d073 BB |
263 | AC_MSG_RESULT([Not found]) |
264 | AC_MSG_ERROR([ | |
265 | *** Please make sure the spl devel package for your distribution | |
266 | *** is installed then try again. If that fails you can specify the | |
267 | *** location of the spl source with the '--with-spl=PATH' option.]) | |
8366cd6a PS |
268 | ]) |
269 | ], [ | |
270 | AS_IF([test "$splsrc" = "NONE"], [ | |
c9c0d073 BB |
271 | splbuild=NONE |
272 | splsrcver=NONE | |
8366cd6a PS |
273 | ]) |
274 | ]) | |
c9c0d073 BB |
275 | |
276 | AC_MSG_RESULT([$splsrc]) | |
277 | AC_MSG_CHECKING([spl build directory]) | |
8366cd6a | 278 | AS_IF([test -z "$splbuild"], [ |
6283f55e | 279 | splbuild=${splsrc} |
8366cd6a | 280 | ]) |
c9c0d073 BB |
281 | AC_MSG_RESULT([$splbuild]) |
282 | ||
283 | AC_MSG_CHECKING([spl source version]) | |
8366cd6a PS |
284 | AS_IF([test -r $splbuild/spl_config.h && |
285 | fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [ | |
c9c0d073 BB |
286 | |
287 | splsrcver=`(echo "#include <spl_config.h>"; | |
b40a77ae | 288 | echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") | |
5e612145 | 289 | cpp -I $splbuild | |
b40a77ae | 290 | grep "^splsrcver=" | tr -d \" | cut -d= -f2` |
8366cd6a | 291 | ]) |
c9c0d073 | 292 | |
8366cd6a | 293 | AS_IF([test -z "$splsrcver"], [ |
c9c0d073 BB |
294 | AC_MSG_RESULT([Not found]) |
295 | AC_MSG_ERROR([ | |
2984e0bb PS |
296 | *** Cannot determine the version of the spl source. |
297 | *** Please prepare the spl source before running this script]) | |
8366cd6a | 298 | ]) |
c9c0d073 BB |
299 | |
300 | AC_MSG_RESULT([$splsrcver]) | |
301 | ||
302 | SPL=${splsrc} | |
303 | SPL_OBJ=${splbuild} | |
304 | SPL_VERSION=${splsrcver} | |
305 | ||
306 | AC_SUBST(SPL) | |
307 | AC_SUBST(SPL_OBJ) | |
308 | AC_SUBST(SPL_VERSION) | |
309 | ||
310 | ZFS_AC_SPL_MODULE_SYMVERS | |
311 | ]) | |
312 | ||
15805c77 BB |
313 | dnl # |
314 | dnl # Certain kernel build options are not supported. These must be | |
315 | dnl # detected at configure time and cause a build failure. Otherwise | |
316 | dnl # modules may be successfully built that behave incorrectly. | |
317 | dnl # | |
e5b85622 BB |
318 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [ |
319 | ||
320 | AS_IF([test "$ZFS_META_LICENSE" = GPL], [ | |
321 | AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1], | |
322 | [Define to 1 if licensed under the GPL]) | |
323 | ]) | |
324 | ||
325 | ZFS_AC_KERNEL_CONFIG_PREEMPT | |
326 | ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC | |
327 | ]) | |
328 | ||
c9c0d073 | 329 | dnl # |
e5b85622 | 330 | dnl # Check CONFIG_PREEMPT |
c9c0d073 | 331 | dnl # |
e5b85622 BB |
332 | dnl # Premptible kernels will be supported in the future. But at the |
333 | dnl # moment there are a few places in the code which need to be updated | |
334 | dnl # to accomidate them. Until that work occurs we should detect this | |
335 | dnl # at configure time and fail with a sensible message. Otherwise, | |
336 | dnl # people will be able to build successfully, however they will have | |
337 | dnl # stability problems. See https://github.com/zfsonlinux/zfs/issues/83 | |
c9c0d073 | 338 | dnl # |
e5b85622 | 339 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG_PREEMPT], [ |
c9c0d073 | 340 | |
15805c77 BB |
341 | ZFS_LINUX_CONFIG([PREEMPT], |
342 | AC_MSG_ERROR([ | |
2984e0bb PS |
343 | *** Kernel built with CONFIG_PREEMPT which is not supported. |
344 | *** You must rebuild your kernel without this option.]), []) | |
e5b85622 | 345 | ]) |
15805c77 | 346 | |
e5b85622 BB |
347 | dnl # |
348 | dnl # Check CONFIG_DEBUG_LOCK_ALLOC | |
349 | dnl # | |
350 | dnl # This is typically only set for debug kernels because it comes with | |
351 | dnl # a performance penalty. However, when it is set it maps the non-GPL | |
352 | dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol. | |
353 | dnl # This will cause a failure at link time which we'd rather know about | |
354 | dnl # at compile time. | |
355 | dnl # | |
356 | dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol | |
357 | dnl # with the upstream community we add a check to detect this case. | |
358 | dnl # | |
359 | AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [ | |
360 | ||
361 | ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [ | |
362 | AC_MSG_CHECKING([whether mutex_lock() is GPL-only]) | |
363 | tmp_flags="$EXTRA_KCFLAGS" | |
364 | ZFS_LINUX_TRY_COMPILE([ | |
365 | #include <linux/module.h> | |
366 | #include <linux/mutex.h> | |
367 | ||
368 | MODULE_LICENSE("$ZFS_META_LICENSE"); | |
369 | ],[ | |
370 | struct mutex lock; | |
371 | ||
372 | mutex_init(&lock); | |
373 | mutex_lock(&lock); | |
374 | mutex_unlock(&lock); | |
375 | ],[ | |
376 | AC_MSG_RESULT(no) | |
377 | ],[ | |
378 | AC_MSG_RESULT(yes) | |
379 | AC_MSG_ERROR([ | |
380 | *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible | |
cac1f230 NB |
381 | *** with the CDDL license and will prevent the module linking stage |
382 | *** from succeeding. You must rebuild your kernel without this | |
383 | *** option enabled.]) | |
e5b85622 BB |
384 | ]) |
385 | EXTRA_KCFLAGS="$tmp_flags" | |
386 | ], []) | |
c9c0d073 BB |
387 | ]) |
388 | ||
389 | dnl # | |
390 | dnl # ZFS_LINUX_CONFTEST | |
391 | dnl # | |
392 | AC_DEFUN([ZFS_LINUX_CONFTEST], [ | |
393 | cat confdefs.h - <<_ACEOF >conftest.c | |
394 | $1 | |
395 | _ACEOF | |
396 | ]) | |
397 | ||
398 | dnl # | |
399 | dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY]) | |
400 | dnl # | |
401 | m4_define([ZFS_LANG_PROGRAM], [ | |
402 | $1 | |
403 | int | |
404 | main (void) | |
405 | { | |
406 | dnl Do *not* indent the following line: there may be CPP directives. | |
407 | dnl Don't move the `;' right after for the same reason. | |
408 | $2 | |
409 | ; | |
410 | return 0; | |
411 | } | |
412 | ]) | |
413 | ||
414 | dnl # | |
415 | dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE | |
416 | dnl # | |
417 | AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [ | |
418 | m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])]) | |
419 | rm -Rf build && mkdir -p build | |
420 | echo "obj-m := conftest.o" >build/Makefile | |
421 | AS_IF( | |
422 | [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build) >/dev/null && AC_TRY_COMMAND([$3])], | |
423 | [$4], | |
424 | [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])] | |
425 | ) | |
426 | rm -Rf build | |
427 | ]) | |
428 | ||
429 | dnl # | |
430 | dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE | |
431 | dnl # | |
432 | AC_DEFUN([ZFS_LINUX_TRY_COMPILE], | |
433 | [ZFS_LINUX_COMPILE_IFELSE( | |
434 | [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])], | |
435 | [modules], | |
436 | [test -s build/conftest.o], | |
437 | [$3], [$4]) | |
438 | ]) | |
439 | ||
440 | dnl # | |
441 | dnl # ZFS_LINUX_CONFIG | |
442 | dnl # | |
443 | AC_DEFUN([ZFS_LINUX_CONFIG], | |
444 | [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1]) | |
445 | ZFS_LINUX_TRY_COMPILE([ | |
0da78696 | 446 | #include <linux/module.h> |
c9c0d073 BB |
447 | ],[ |
448 | #ifndef CONFIG_$1 | |
449 | #error CONFIG_$1 not #defined | |
450 | #endif | |
451 | ],[ | |
452 | AC_MSG_RESULT([yes]) | |
453 | $2 | |
454 | ],[ | |
455 | AC_MSG_RESULT([no]) | |
456 | $3 | |
457 | ]) | |
458 | ]) | |
459 | ||
460 | dnl # | |
461 | dnl # ZFS_CHECK_SYMBOL_EXPORT | |
462 | dnl # check symbol exported or not | |
463 | dnl # | |
464 | AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], | |
465 | [AC_MSG_CHECKING([whether symbol $1 is exported]) | |
466 | grep -q -E '[[[:space:]]]$1[[[:space:]]]' \ | |
467 | $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null | |
468 | rc=$? | |
8366cd6a | 469 | AS_IF([test $rc -ne 0], [ |
c9c0d073 BB |
470 | export=0 |
471 | for file in $2; do | |
472 | grep -q -E "EXPORT_SYMBOL.*($1)" "$LINUX/$file" 2>/dev/null | |
473 | rc=$? | |
8366cd6a PS |
474 | AS_IF([test $rc -eq 0], [ |
475 | export=1 | |
476 | break; | |
477 | ]) | |
c9c0d073 | 478 | done |
8366cd6a | 479 | AS_IF([test $export -eq 0], [ |
c9c0d073 BB |
480 | AC_MSG_RESULT([no]) |
481 | $4 | |
8366cd6a | 482 | ], [ |
c9c0d073 BB |
483 | AC_MSG_RESULT([yes]) |
484 | $3 | |
8366cd6a PS |
485 | ]) |
486 | ], [ | |
c9c0d073 BB |
487 | AC_MSG_RESULT([yes]) |
488 | $3 | |
8366cd6a | 489 | ]) |
c9c0d073 | 490 | ]) |