PVE/APLInfo.pm

   1 package PVE::APLInfo;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use PVE::SafeSyslog;
   7 use PVE::Tools;
   8 use LWP::UserAgent;
   9 use POSIX qw(strftime);
  10
  11 my $logfile = "/var/log/pveam.log";
  12 my $aplinfodir = "/var/lib/pve-manager/apl-info";
  13
  14 sub logmsg {
  15     my ($logfd, $msg) = @_;
  16
  17     chomp $msg;
  18
  19     my $tstr = strftime ("%b %d %H:%M:%S", localtime);
  20
  21     foreach my $line (split (/\n/, $msg)) {
  22         print $logfd "$tstr $line\n";
  23     }
  24 }
  25
  26 sub read_aplinfo_from_fh {
  27     my ($fh, $list, $source, $update) = @_;
  28
  29     local $/ = "";
  30
  31     while (my $rec = <$fh>) {
  32         chomp $rec;
  33
  34         my $res = {};
  35
  36         while ($rec) {
  37
  38             if ($rec =~ s/^Description:\s*([^\n]*)(\n\s+.*)*$//si) {
  39                 $res->{headline} = $1;
  40                 my $long = $2 || '';
  41                 $long =~ s/\n\s+/ /g;
  42                 $long =~ s/^\s+//g;
  43                 $long =~ s/\s+$//g;
  44                 $res->{description} = $long;
  45             } elsif ($rec =~ s/^Version:\s*(.*\S)\s*\n//i) {
  46                 my $version = $1;
  47                 if ($version =~ m/^(\d[a-zA-Z0-9\.\+\-\:\~]*)(-(\d+))?$/) {
  48                     $res->{version} = $version;
  49                 } else {
  50                     my $msg = "unable to parse appliance record: version = '$version'\n";
  51                     $update ? die $msg : warn $msg;
  52                 }
  53             } elsif ($rec =~ s/^Type:\s*(.*\S)\s*\n//i) {
  54                 my $type = $1;
  55                 if ($type =~ m/^(openvz|lxc)$/) {
  56                     $res->{type} = $type;
  57                 } else {
  58                     my $msg = "unable to parse appliance record: unknown type '$type'\n";
  59                     $update ? die $msg : warn $msg;
  60                 }
  61             } elsif ($rec =~ s/^([^:]+):\s*(.*\S)\s*\n//) {
  62                 $res->{lc $1} = $2;
  63             } else {
  64                 my $msg = "unable to parse appliance record: $rec\n";
  65                 $update ? die $msg : warn $msg;
  66                 $res = {};
  67                 last;
  68             }
  69         }
  70
  71         if ($res->{'package'} eq 'pve-web-news' && $res->{description}) {
  72             $list->{'all'}->{$res->{'package'}} = $res;
  73             next;
  74         }
  75
  76         $res->{section} = 'unknown' if !$res->{section};
  77
  78         if ($res->{'package'} && $res->{type} && $res->{os} && $res->{version} &&
  79             $res->{infopage}) {
  80             my $template;
  81             if ($res->{location}) {
  82                 $template = $res->{location};
  83                 $template =~ s|.*/([^/]+.tar.[gx]z)$|$1|;
  84                 if ($res->{location} !~ m|^([a-zA-Z]+)\://|) {
  85                     # relative localtion (no http:// prefix)
  86                     $res->{location} = "$source/$res->{location}";
  87                 }
  88             } else {
  89                 my $arch = $res->{architecture} || 'i386';
  90                 $template = "$res->{os}-$res->{package}_$res->{version}_$arch.tar.gz";
  91                 $template =~ s/$res->{os}-$res->{os}-/$res->{os}-/;
  92                 $res->{location} = "$source/$res->{section}/$template";
  93             }
  94             $res->{source} = $source;
  95             $res->{template} = $template;
  96             $list->{$res->{section}}->{$template} = $res;
  97             $list->{'all'}->{$template} = $res;
  98         } else {
  99             my $msg = "found incomplete appliance records\n";
 100             $update ? die $msg : warn $msg;
 101         }
 102     }
 103 }
 104
 105 sub read_aplinfo {
 106     my ($filename, $list, $source, $update) = @_;
 107
 108     my $fh = IO::File->new("<$filename") ||
 109         die "unable to open file '$filename' - $!\n";
 110
 111     eval { read_aplinfo_from_fh($fh, $list, $source, $update); };
 112     my $err = $@;
 113
 114     close($fh);
 115
 116     die $err if $err;
 117
 118     return $list;
 119 }
 120
 121 sub url_get {
 122     my ($ua, $url, $file, $logfh) = @_;
 123
 124     my $req = HTTP::Request->new(GET => $url);
 125
 126     logmsg ($logfh, "start download $url");
 127     my $res = $ua->request($req, $file);
 128
 129     if ($res->is_success) {
 130         logmsg ($logfh, "download finished: " . $res->status_line);
 131         return 0;
 132     }
 133
 134     logmsg ($logfh, "download failed: " . $res->status_line);
 135
 136     return 1;
 137 }
 138
 139 sub download_aplinfo {
 140     my ($ua, $aplurl, $host, $logfd) = @_;
 141
 142     my $aplsrcurl = "$aplurl/aplinfo.dat.gz";
 143     my $aplsigurl = "$aplurl/aplinfo.dat.asc";
 144
 145     my $tmp = "$aplinfodir/pveam-${host}.tmp.$$";
 146     my $tmpgz = "$tmp.gz";
 147     my $sigfn = "$tmp.asc";
 148
 149     eval {
 150
 151         if (url_get($ua, $aplsigurl, $sigfn, $logfd) != 0) {
 152             die "update failed - no signature file '$sigfn'\n";
 153         }
 154
 155         if (url_get($ua, $aplsrcurl, $tmpgz, $logfd) != 0) {
 156             die "update failed - no data file '$aplsrcurl'\n";
 157         }
 158
 159        eval {
 160            PVE::Tools::run_command(["gunzip", "-f", $tmpgz]);
 161        };
 162        die "update failed: unable to unpack '$tmpgz'\n" if $@;
 163
 164
 165
 166         # verify signature
 167         my $trustedkeyring = "/usr/share/doc/pve-manager/trustedkeys.gpg";
 168         my $cmd = "/usr/bin/gpgv -q --keyring $trustedkeyring $sigfn $tmp";
 169
 170         eval {
 171             my $logfunc = sub {
 172                 my $line = shift;
 173                 logmsg($logfd, "signature verification: $line");
 174             };
 175
 176             PVE::Tools::run_command($cmd,
 177                                     outfunc => $logfunc,
 178                                     errfunc => $logfunc);
 179         };
 180         die "unable to verify signature - $@\n" if $@;
 181
 182         # test syntax
 183         eval {
 184             read_aplinfo($tmp, {}, $aplurl, 1);
 185         };
 186         die "update failed: $@" if $@;
 187
 188         if (!rename($tmp, "$aplinfodir/$host")) {
 189             die "update failed: unable to store data\n";
 190         }
 191
 192         logmsg($logfd, "update sucessful");
 193     };
 194
 195     my $err = $@;
 196
 197     unlink $tmp;
 198     unlink $tmpgz;
 199     unlink $sigfn;
 200
 201     die $err if $err;
 202 }
 203
 204 sub get_apl_sources {
 205
 206     my $urls = [];
 207     push @$urls, "http://download.proxmox.com/images";
 208     push @$urls, "https://releases.turnkeylinux.org/pve";
 209
 210     return $urls;
 211 }
 212
 213 sub update {
 214     my ($proxy) = @_;
 215
 216     my $size;
 217     if (($size = (-s $logfile) || 0) > (1024*50)) {
 218         rename($logfile, "$logfile.0");
 219     }
 220     my $logfd = IO::File->new (">>$logfile");
 221     logmsg($logfd, "starting update");
 222
 223     my $ua = LWP::UserAgent->new;
 224     $ua->agent("PVE/1.0");
 225
 226     if ($proxy) {
 227         $ua->proxy(['http', 'https'], $proxy);
 228     } else {
 229         $ua->env_proxy;
 230     }
 231
 232     my $urls = get_apl_sources();
 233
 234     mkdir $aplinfodir;
 235
 236     my @dlerr = ();
 237     foreach my $aplurl (@$urls) {
 238         eval {
 239             my $uri = URI->new($aplurl);
 240             my $host = $uri->host();
 241             download_aplinfo($ua, $aplurl, $host, $logfd);
 242         };
 243         if (my $err = $@) {
 244             logmsg ($logfd, $err);
 245             push @dlerr, $aplurl;
 246         }
 247     }
 248
 249     close($logfd);
 250
 251     return 0 if scalar(@dlerr);
 252
 253     return 1;
 254 }
 255
 256 sub load_data {
 257
 258    my $urls = get_apl_sources();
 259
 260     my $list = {};
 261
 262     foreach my $aplurl (@$urls) {
 263
 264         eval {
 265
 266             my $uri = URI->new($aplurl);
 267             my $host = $uri->host();
 268             read_aplinfo("$aplinfodir/$host", $list, $aplurl);
 269         };
 270         warn $@ if $@;
 271     }
 272
 273     return $list;
 274 }
 275
 276 1;
 277