PVE/HTTPServer.pm

   1 package PVE::HTTPServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::INotify;
   8 use PVE::Tools;
   9 use PVE::APIServer::AnyEvent;
  10 use PVE::Exception qw(raise_param_exc raise_perm_exc raise);
  11
  12 use PVE::RPCEnvironment;
  13 use PVE::AccessControl;
  14 use PVE::CertCache;
  15 use PVE::Cluster;
  16 use PVE::API2Tools;
  17
  18 use Data::Dumper;
  19
  20 use base('PVE::APIServer::AnyEvent');
  21
  22 use HTTP::Status qw(:constants);
  23
  24 sub new {
  25     my ($this, %args) = @_;
  26
  27     my $class = ref($this) || $this;
  28
  29     my $self = $class->SUPER::new(%args);
  30
  31     $self->{rpcenv} = PVE::RPCEnvironment->init(
  32         $self->{trusted_env} ? 'priv' : 'pub', atfork =>  sub { $self-> atfork_handler() });
  33
  34     return $self;
  35 }
  36
  37 sub verify_spice_connect_url {
  38     my ($self, $connect_str) = @_;
  39
  40     my $rpcenv = $self->{rpcenv};
  41
  42     $rpcenv->init_request();
  43
  44     my ($vmid, $node, $port) = PVE::AccessControl::verify_spice_connect_url($connect_str);
  45
  46     return ($vmid, $node, $port);
  47 }
  48
  49 sub generate_csrf_prevention_token {
  50     my ($username) = @_;
  51
  52     return PVE::AccessControl::assemble_csrf_prevention_token($username);
  53 }
  54
  55 sub auth_handler {
  56     my ($self, $method, $rel_uri, $ticket, $token, $api_token, $peer_host) = @_;
  57
  58     my $rpcenv = $self->{rpcenv};
  59
  60     # set environment variables
  61     $rpcenv->set_user(undef);
  62     $rpcenv->set_language('C');
  63     $rpcenv->set_client_ip($peer_host);
  64
  65     eval { $rpcenv->init_request() };
  66     raise("RPCEnvironment init request failed: $@\n") if $@;
  67
  68     my $require_auth = 1;
  69
  70     # explicitly allow some calls without auth
  71     if (($rel_uri eq '/access/domains' && $method eq 'GET') ||
  72         ($rel_uri eq '/access/ticket' && ($method eq 'GET' || $method eq 'POST'))) {
  73         $require_auth = 0;
  74     }
  75
  76     my ($username, $age);
  77
  78     my $isUpload = 0;
  79
  80     if ($require_auth) {
  81         if ($api_token) {
  82             $username = PVE::AccessControl::verify_token($api_token);
  83             $rpcenv->set_user($username); #actually tokenid in this case
  84         } else {
  85             die "No ticket\n" if !$ticket;
  86
  87             ($username, $age, my $tfa_info) = PVE::AccessControl::verify_ticket($ticket);
  88             $rpcenv->check_user_enabled($username);
  89
  90             if (defined($tfa_info)) {
  91                 if (defined(my $challenge = $tfa_info->{challenge})) {
  92                     $rpcenv->set_u2f_challenge($challenge);
  93                 }
  94                 die "No ticket\n"
  95                     if ($rel_uri ne '/access/tfa' || $method ne 'POST');
  96             }
  97
  98             $rpcenv->set_user($username);
  99
 100             if ($method eq 'POST' && $rel_uri =~ m|^/nodes/([^/]+)/storage/([^/]+)/upload$|) {
 101                 my ($node, $storeid) = ($1, $2);
 102                 # we disable CSRF checks if $isUpload is set,
 103                 # to improve security we check user upload permission here
 104                 my $perm = { check => ['perm', "/storage/$storeid", ['Datastore.AllocateTemplate']] };
 105                 $rpcenv->check_api2_permissions($perm, $username, {});
 106                 $isUpload = 1;
 107             }
 108
 109             # we skip CSRF check for file upload, because it is
 110             # difficult to pass CSRF HTTP headers with native html forms,
 111             # and it should not be necessary at all.
 112             my $euid = $>;
 113             PVE::AccessControl::verify_csrf_prevention_token($username, $token)
 114                 if !$isUpload && ($euid != 0) && ($method ne 'GET');
 115         }
 116     }
 117
 118     return {
 119         ticket => $ticket,
 120         token => $token,
 121         userid => $username,
 122         age => $age,
 123         isUpload => $isUpload,
 124         api_token => $api_token,
 125     };
 126 }
 127
 128 sub rest_handler {
 129     my ($self, $clientip, $method, $rel_uri, $auth, $params) = @_;
 130
 131     my $rpcenv = $self->{rpcenv};
 132
 133     my $resp = {
 134         status => HTTP_NOT_IMPLEMENTED,
 135         message => "Method '$method $rel_uri' not implemented",
 136     };
 137
 138     my ($handler, $info);
 139
 140     eval {
 141         my $uri_param = {};
 142         ($handler, $info) = PVE::API2->find_handler($method, $rel_uri, $uri_param);
 143         return if !$handler || !$info;
 144
 145         foreach my $p (keys %{$params}) {
 146             if (defined($uri_param->{$p})) {
 147                 raise_param_exc({$p =>  "duplicate parameter (already defined in URI)"});
 148             }
 149             $uri_param->{$p} = $params->{$p};
 150         }
 151
 152         raise_perm_exc("URI '$rel_uri' not available with API token, need proper ticket.\n")
 153             if $auth->{api_token} && !$info->{allowtoken};
 154
 155         # check access permissions
 156         $rpcenv->check_api2_permissions($info->{permissions}, $auth->{userid}, $uri_param);
 157
 158         if ($info->{proxyto} || $info->{proxyto_callback}) {
 159             my $node = PVE::API2Tools::resolve_proxyto(
 160                 $rpcenv, $info->{proxyto_callback}, $info->{proxyto}, $uri_param);
 161
 162             if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
 163                 die "unable to proxy file uploads" if $auth->{isUpload};
 164                 my $remip = $self->remote_node_ip($node);
 165                 $resp = { proxy => $remip, proxynode => $node, proxy_params => $params };
 166                 return;
 167             }
 168         }
 169
 170         my $euid = $>;
 171         if ($info->{protected} && ($euid != 0)) {
 172             $resp = { proxy => 'localhost' , proxy_params => $params };
 173             return;
 174         }
 175
 176         $resp = {
 177             data => $handler->handle($info, $uri_param),
 178             info => $info, # useful to format output
 179             status => HTTP_OK,
 180         };
 181
 182         if (my $count = $rpcenv->get_result_attrib('total')) {
 183             $resp->{total} = $count;
 184         }
 185
 186         if (my $diff = $rpcenv->get_result_attrib('changes')) {
 187             $resp->{changes} = $diff;
 188         }
 189     };
 190     my $err = $@;
 191
 192     $rpcenv->set_user(undef); # clear after request
 193
 194     if ($err) {
 195         $resp = { info => $info };
 196         if (ref($err) eq "PVE::Exception") {
 197             $resp->{status} = $err->{code} || HTTP_INTERNAL_SERVER_ERROR;
 198             $resp->{errors} = $err->{errors} if $err->{errors};
 199             $resp->{message} = $err->{msg};
 200         } else {
 201             $resp->{status} =  HTTP_INTERNAL_SERVER_ERROR;
 202             $resp->{message} = $err;
 203         }
 204     }
 205
 206     return $resp;
 207 }
 208
 209 sub check_cert_fingerprint {
 210     my ($self, $cert) = @_;
 211
 212     return PVE::CertCache::check_cert_fingerprint($cert);
 213 }
 214
 215 sub initialize_cert_cache {
 216     my ($self, $node) = @_;
 217
 218     PVE::CertCache::initialize_cert_cache($node);
 219 }
 220
 221 sub remote_node_ip {
 222     my ($self, $node) = @_;
 223
 224     my $remip = PVE::Cluster::remote_node_ip($node);
 225
 226     die "unable to get remote IP address for node '$node'\n" if !$remip;
 227
 228     return $remip;
 229 }
 230
 231 1;