PVE/HTTPServer.pm

   1 package PVE::HTTPServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::INotify;
   8 use PVE::Tools;
   9 use PVE::APIServer::AnyEvent;
  10
  11 use PVE::RPCEnvironment;
  12 use PVE::AccessControl;
  13 use PVE::Cluster;
  14
  15 use Data::Dumper;
  16
  17 use base('PVE::APIServer::AnyEvent');
  18
  19 use HTTP::Status qw(:constants);
  20
  21 sub new {
  22     my ($this, %args) = @_;
  23
  24     my $class = ref($this) || $this;
  25
  26     my $self = $class->SUPER::new(%args);
  27
  28     $self->{rpcenv} = PVE::RPCEnvironment->init(
  29         $self->{trusted_env} ? 'priv' : 'pub', atfork =>  sub { $self-> atfork_handler() });
  30
  31     return $self;
  32 }
  33
  34 sub verify_spice_connect_url {
  35     my ($self, $connect_str) = @_;
  36
  37     my $rpcenv = $self->{rpcenv};
  38
  39     $rpcenv->init_request();
  40
  41     my ($vmid, $node, $port) = PVE::AccessControl::verify_spice_connect_url($connect_str);
  42
  43     return ($vmid, $node, $port);
  44 }
  45
  46 sub generate_csrf_prevention_token {
  47     my ($username) = @_;
  48
  49     return PVE::AccessControl::assemble_csrf_prevention_token($username);
  50 }
  51
  52 sub auth_handler {
  53     my ($self, $method, $rel_uri, $ticket, $token, $peer_host) = @_;
  54
  55     my $rpcenv = $self->{rpcenv};
  56
  57     # set environment variables
  58     $rpcenv->set_user(undef);
  59     $rpcenv->set_language('C');
  60     $rpcenv->set_client_ip($peer_host);
  61
  62     $rpcenv->init_request();
  63
  64     my $require_auth = 1;
  65
  66     # explicitly allow some calls without auth
  67     if (($rel_uri eq '/access/domains' && $method eq 'GET') ||
  68         ($rel_uri eq '/access/ticket' && ($method eq 'GET' || $method eq 'POST'))) {
  69         $require_auth = 0;
  70     }
  71
  72     my ($username, $age);
  73
  74     my $isUpload = 0;
  75
  76     if ($require_auth) {
  77
  78         die "No ticket\n" if !$ticket;
  79
  80         ($username, $age) = PVE::AccessControl::verify_ticket($ticket);
  81
  82         $rpcenv->set_user($username);
  83
  84         if ($method eq 'POST' && $rel_uri =~ m|^/nodes/([^/]+)/storage/([^/]+)/upload$|) {
  85             my ($node, $storeid) = ($1, $2);
  86             # we disable CSRF checks if $isUpload is set,
  87             # to improve security we check user upload permission here
  88             my $perm = { check => ['perm', "/storage/$storeid", ['Datastore.AllocateTemplate']] };
  89             $rpcenv->check_api2_permissions($perm, $username, {});
  90             $isUpload = 1;
  91         }
  92
  93         # we skip CSRF check for file upload, because it is
  94         # difficult to pass CSRF HTTP headers with native html forms,
  95         # and it should not be necessary at all.
  96         my $euid = $>;
  97         PVE::AccessControl::verify_csrf_prevention_token($username, $token)
  98             if !$isUpload && ($euid != 0) && ($method ne 'GET');
  99     }
 100
 101     return {
 102         ticket => $ticket,
 103         token => $token,
 104         userid => $username,
 105         age => $age,
 106         isUpload => $isUpload,
 107         cookie_name => $self->{cookie_name},
 108     };
 109 }
 110
 111 my $exc_to_res = sub {
 112     my ($info, $err, $status) = @_;
 113
 114     $status = $status || HTTP_INTERNAL_SERVER_ERROR;
 115
 116     my $resp = { info => $info };
 117     if (ref($err) eq "PVE::Exception") {
 118         $resp->{status} = $err->{code} || $status;
 119         $resp->{errors} = $err->{errors} if $err->{errors};
 120         $resp->{message} = $err->{msg};
 121     } else {
 122         $resp->{status} = $status;
 123         $resp->{message} = $err;
 124     }
 125
 126     return $resp;
 127 };
 128
 129 sub rest_handler {
 130     my ($self, $clientip, $method, $rel_uri, $auth, $params) = @_;
 131
 132     my $rpcenv = $self->{rpcenv};
 133
 134     my $uri_param = {};
 135     my ($handler, $info) = PVE::API2->find_handler($method, $rel_uri, $uri_param);
 136     if (!$handler || !$info) {
 137         $rpcenv->set_user(undef); # clear after request
 138         return {
 139             status => HTTP_NOT_IMPLEMENTED,
 140             message => "Method '$method $rel_uri' not implemented",
 141         };
 142     }
 143
 144     foreach my $p (keys %{$params}) {
 145         if (defined($uri_param->{$p})) {
 146             $rpcenv->set_user(undef); # clear after request
 147             return {
 148                 status => HTTP_BAD_REQUEST,
 149                 message => "Parameter verification failed - duplicate parameter '$p'",
 150             };
 151         }
 152         $uri_param->{$p} = $params->{$p};
 153     }
 154
 155     # check access permissions
 156     eval { $rpcenv->check_api2_permissions($info->{permissions}, $auth->{userid}, $uri_param); };
 157     if (my $err = $@) {
 158         $rpcenv->set_user(undef); # clear after request
 159         return &$exc_to_res($info, $err, HTTP_FORBIDDEN);
 160     }
 161
 162     if ($info->{proxyto}) {
 163         my $remip;
 164         my $node;
 165         eval {
 166             my $pn = $info->{proxyto};
 167             $node = $uri_param->{$pn};
 168             die "proxy parameter '$pn' does not exists" if !$node;
 169
 170             if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
 171                 die "unable to proxy file uploads" if $auth->{isUpload};
 172                 $remip = $self->remote_node_ip($node);
 173             }
 174         };
 175         if (my $err = $@) {
 176             $rpcenv->set_user(undef); # clear after request
 177             return &$exc_to_res($info, $err);
 178         }
 179         if ($remip) {
 180             $rpcenv->set_user(undef); # clear after request
 181             return { proxy => $remip, proxynode => $node, proxy_params => $params };
 182         }
 183     }
 184
 185     my $euid = $>;
 186     if ($info->{protected} && ($euid != 0)) {
 187         $rpcenv->set_user(undef); # clear after request
 188         return { proxy => 'localhost' , proxy_params => $params }
 189     }
 190
 191     my $resp = {
 192         info => $info, # useful to format output
 193         status => HTTP_OK,
 194     };
 195
 196     eval {
 197         $resp->{data} = $handler->handle($info, $uri_param);
 198
 199         if (my $count = $rpcenv->get_result_attrib('total')) {
 200             $resp->{total} = $count;
 201         }
 202         if (my $diff = $rpcenv->get_result_attrib('changes')) {
 203             $resp->{changes} = $diff;
 204         }
 205     };
 206     if (my $err = $@) {
 207         $rpcenv->set_user(undef); # clear after request
 208         return &$exc_to_res($info, $err);
 209     }
 210
 211     $rpcenv->set_user(undef); # clear after request
 212     return $resp;
 213 }
 214
 215 sub check_cert_fingerprint {
 216     my ($self, $cert) = @_;
 217
 218     return PVE::Cluster::check_cert_fingerprint($cert);
 219 }
 220
 221 sub initialize_cert_cache {
 222     my ($self, $node) = @_;
 223
 224     PVE::Cluster::initialize_cert_cache($node);
 225 }
 226
 227 sub remote_node_ip {
 228     my ($self, $node) = @_;
 229
 230     my $remip = PVE::Cluster::remote_node_ip($node);
 231
 232     die "unable to get remote IP address for node '$node'\n" if !$remip;
 233
 234     return $remip;
 235 }
 236
 237 1;