PVE/QemuConfig.pm

   1 package PVE::QemuConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::AbstractConfig;
   7 use PVE::INotify;
   8 use PVE::QemuServer;
   9 use PVE::Storage;
  10 use PVE::Tools;
  11
  12 use base qw(PVE::AbstractConfig);
  13
  14 my $nodename = PVE::INotify::nodename();
  15
  16 mkdir "/etc/pve/nodes/$nodename";
  17 my $confdir = "/etc/pve/nodes/$nodename/qemu-server";
  18 mkdir $confdir;
  19
  20 my $lock_dir = "/var/lock/qemu-server";
  21 mkdir $lock_dir;
  22
  23 my $MAX_UNUSED_DISKS = 8;
  24
  25 # BEGIN implemented abstract methods from PVE::AbstractConfig
  26
  27 sub guest_type {
  28     return "VM";
  29 }
  30
  31 sub __config_max_unused_disks {
  32     my ($class) = @_;
  33
  34     return $MAX_UNUSED_DISKS;
  35 }
  36
  37 sub config_file_lock {
  38     my ($class, $vmid) = @_;
  39
  40     return "$lock_dir/lock-$vmid.conf";
  41 }
  42
  43 sub cfs_config_path {
  44     my ($class, $vmid, $node) = @_;
  45
  46     $node = $nodename if !$node;
  47     return "nodes/$node/qemu-server/$vmid.conf";
  48 }
  49
  50 sub has_feature {
  51     my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
  52
  53     my $err;
  54     PVE::QemuServer::foreach_drive($conf, sub {
  55         my ($ds, $drive) = @_;
  56
  57         return if PVE::QemuServer::drive_is_cdrom($drive);
  58         return if $backup_only && !$drive->{backup};
  59         my $volid = $drive->{file};
  60         $err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $volid, $snapname, $running);
  61    });
  62
  63     return $err ? 0 : 1;
  64 }
  65
  66 sub get_replicatable_volumes {
  67     my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
  68
  69     my $volhash = {};
  70
  71     my $test_volid = sub {
  72         my ($volid, $attr) = @_;
  73
  74         if ($volid =~ m|^/|) {
  75             return if !$attr->{replicate};
  76             die "unable to replicate local file/device '$volid'\n";
  77         }
  78
  79         return if $attr->{cdrom};
  80
  81         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, $noerr);
  82         return if !$storeid;
  83
  84         my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
  85         return if $scfg->{shared};
  86
  87         my ($path, $owner, $vtype) = PVE::Storage::path($storecfg, $volid);
  88         return if !$owner || ($owner != $vmid);
  89
  90         die "unable to replicate volume '$volid', type '$vtype'\n" if $vtype ne 'images';
  91
  92         return if !$cleanup && !$attr->{replicate};
  93
  94         if (!PVE::Storage::volume_has_feature($storecfg, 'replicate', $volid)) {
  95             return if $cleanup || $noerr;
  96             die "missing replicate feature on volume '$volid'\n";
  97         }
  98
  99         $volhash->{$volid} = 1;
 100     };
 101
 102     PVE::QemuServer::foreach_volid($conf, $test_volid);
 103
 104     # add 'unusedX' volumes to volhash
 105     foreach my $key (keys %$conf) {
 106         if ($key =~ m/^unused/) {
 107             $test_volid->($conf->{$key}, { replicate => 1 });
 108         }
 109     }
 110
 111     return $volhash;
 112 }
 113
 114 sub __snapshot_save_vmstate {
 115     my ($class, $vmid, $conf, $snapname, $storecfg) = @_;
 116
 117     my $snap = $conf->{snapshots}->{$snapname};
 118
 119     my $target;
 120
 121     # search shared storage first
 122     PVE::QemuServer::foreach_writable_storage($conf, sub {
 123         my ($sid) = @_;
 124         my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 125         return if !$scfg->{shared};
 126
 127         $target = $sid if !$target || $scfg->{path}; # prefer file based storage
 128     });
 129
 130     if (!$target) {
 131         # now search local storage
 132         PVE::QemuServer::foreach_writable_storage($conf, sub {
 133             my ($sid) = @_;
 134             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
 135             return if $scfg->{shared};
 136
 137             $target = $sid if !$target || $scfg->{path}; # prefer file based storage;
 138         });
 139     }
 140
 141     $target = 'local' if !$target;
 142
 143     my $driver_state_size = 500; # assume 32MB is enough to safe all driver state;
 144     # we abort live save after $conf->{memory}, so we need at max twice that space
 145     my $size = $conf->{memory}*2 + $driver_state_size;
 146
 147     my $name = "vm-$vmid-state-$snapname";
 148     my $scfg = PVE::Storage::storage_config($storecfg, $target);
 149     $name .= ".raw" if $scfg->{path}; # add filename extension for file base storage
 150     $snap->{vmstate} = PVE::Storage::vdisk_alloc($storecfg, $target, $vmid, 'raw', $name, $size*1024);
 151     # always overwrite machine if we save vmstate. This makes sure we
 152     # can restore it later using correct machine type
 153     $snap->{machine} = PVE::QemuServer::get_current_qemu_machine($vmid);
 154 }
 155
 156 sub __snapshot_check_running {
 157     my ($class, $vmid) = @_;
 158     return PVE::QemuServer::check_running($vmid);
 159 }
 160
 161 sub __snapshot_check_freeze_needed {
 162     my ($class, $vmid, $config, $save_vmstate) = @_;
 163
 164     my $running = $class->__snapshot_check_running($vmid);
 165     if ($save_vmstate) {
 166         return ($running, $running && $config->{agent} && PVE::QemuServer::qga_check_running($vmid));
 167     } else {
 168         return ($running, 0);
 169     }
 170 }
 171
 172 sub __snapshot_freeze {
 173     my ($class, $vmid, $unfreeze) = @_;
 174
 175     if ($unfreeze) {
 176         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-thaw"); };
 177         warn "guest-fsfreeze-thaw problems - $@" if $@;
 178     } else {
 179         eval { PVE::QemuServer::vm_mon_cmd($vmid, "guest-fsfreeze-freeze"); };
 180         warn "guest-fsfreeze-freeze problems - $@" if $@;
 181     }
 182 }
 183
 184 sub __snapshot_create_vol_snapshots_hook {
 185     my ($class, $vmid, $snap, $running, $hook) = @_;
 186
 187     if ($running) {
 188         my $storecfg = PVE::Storage::config();
 189
 190         if ($hook eq "before") {
 191             if ($snap->{vmstate}) {
 192                 my $path = PVE::Storage::path($storecfg, $snap->{vmstate});
 193                 PVE::Storage::activate_volumes($storecfg, [$snap->{vmstate}]);
 194
 195                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start", statefile => $path);
 196                 for(;;) {
 197                     my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 198                     if (!$stat->{status}) {
 199                         die "savevm not active\n";
 200                     } elsif ($stat->{status} eq 'active') {
 201                         sleep(1);
 202                         next;
 203                     } elsif ($stat->{status} eq 'completed') {
 204                         last;
 205                     } else {
 206                         die "query-savevm returned status '$stat->{status}'\n";
 207                     }
 208                 }
 209             } else {
 210                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-start");
 211             }
 212         } elsif ($hook eq "after") {
 213             eval {
 214                 PVE::QemuServer::vm_mon_cmd($vmid, "savevm-end");
 215                 PVE::Storage::deactivate_volumes($storecfg, [$snap->{vmstate}]) if $snap->{vmstate};
 216             };
 217             warn $@ if $@;
 218         } elsif ($hook eq "after-freeze") {
 219             # savevm-end is async, we need to wait
 220             for (;;) {
 221                 my $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-savevm");
 222                 if (!$stat->{bytes}) {
 223                     last;
 224                 } else {
 225                     print "savevm not yet finished\n";
 226                     sleep(1);
 227                     next;
 228                 }
 229             }
 230         }
 231     }
 232 }
 233
 234 sub __snapshot_create_vol_snapshot {
 235     my ($class, $vmid, $ds, $drive, $snapname) = @_;
 236
 237     return if PVE::QemuServer::drive_is_cdrom($drive);
 238
 239     my $volid = $drive->{file};
 240     my $device = "drive-$ds";
 241     my $storecfg = PVE::Storage::config();
 242
 243     PVE::QemuServer::qemu_volume_snapshot($vmid, $device, $storecfg, $volid, $snapname);
 244 }
 245
 246 sub __snapshot_delete_remove_drive {
 247     my ($class, $snap, $remove_drive) = @_;
 248
 249     if ($remove_drive eq 'vmstate') {
 250         delete $snap->{$remove_drive};
 251     } else {
 252         my $drive = PVE::QemuServer::parse_drive($remove_drive, $snap->{$remove_drive});
 253         return if PVE::QemuServer::drive_is_cdrom($drive);
 254
 255         my $volid = $drive->{file};
 256         delete $snap->{$remove_drive};
 257         $class->add_unused_volume($snap, $volid);
 258     }
 259 }
 260
 261 sub __snapshot_delete_vmstate_file {
 262     my ($class, $snap, $force) = @_;
 263
 264     my $storecfg = PVE::Storage::config();
 265
 266     eval {  PVE::Storage::vdisk_free($storecfg, $snap->{vmstate}); };
 267     if (my $err = $@) {
 268         die $err if !$force;
 269         warn $err;
 270     }
 271 }
 272
 273 sub __snapshot_delete_vol_snapshot {
 274     my ($class, $vmid, $ds, $drive, $snapname, $unused) = @_;
 275
 276     return if PVE::QemuServer::drive_is_cdrom($drive);
 277     my $storecfg = PVE::Storage::config();
 278     my $volid = $drive->{file};
 279     my $device = "drive-$ds";
 280
 281     PVE::QemuServer::qemu_volume_snapshot_delete($vmid, $device, $storecfg, $volid, $snapname);
 282
 283     push @$unused, $volid;
 284 }
 285
 286 sub __snapshot_rollback_vol_possible {
 287     my ($class, $drive, $snapname) = @_;
 288
 289     return if PVE::QemuServer::drive_is_cdrom($drive);
 290
 291     my $storecfg = PVE::Storage::config();
 292     my $volid = $drive->{file};
 293
 294     PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
 295 }
 296
 297 sub __snapshot_rollback_vol_rollback {
 298     my ($class, $drive, $snapname) = @_;
 299
 300     return if PVE::QemuServer::drive_is_cdrom($drive);
 301
 302     my $storecfg = PVE::Storage::config();
 303     PVE::Storage::volume_snapshot_rollback($storecfg, $drive->{file}, $snapname);
 304 }
 305
 306 sub __snapshot_rollback_vm_stop {
 307     my ($class, $vmid) = @_;
 308
 309     my $storecfg = PVE::Storage::config();
 310     PVE::QemuServer::vm_stop($storecfg, $vmid, undef, undef, 5, undef, undef);
 311 }
 312
 313 sub __snapshot_rollback_vm_start {
 314     my ($class, $vmid, $vmstate, $forcemachine) = @_;
 315
 316     my $storecfg = PVE::Storage::config();
 317     my $statefile = PVE::Storage::path($storecfg, $vmstate);
 318     PVE::QemuServer::vm_start($storecfg, $vmid, $statefile, undef, undef, undef, $forcemachine);
 319 }
 320
 321 sub __snapshot_rollback_get_unused {
 322     my ($class, $conf, $snap) = @_;
 323
 324     my $unused = [];
 325
 326     $class->__snapshot_foreach_volume($conf, sub {
 327         my ($vs, $volume) = @_;
 328
 329         return if PVE::QemuServer::drive_is_cdrom($volume);
 330
 331         my $found = 0;
 332         my $volid = $volume->{file};
 333
 334         $class->__snapshot_foreach_volume($snap, sub {
 335             my ($ds, $drive) = @_;
 336
 337             return if $found;
 338             return if PVE::QemuServer::drive_is_cdrom($drive);
 339
 340             $found = 1
 341                 if ($drive->{file} && $drive->{file} eq $volid);
 342         });
 343
 344         push @$unused, $volid if !$found;
 345     });
 346
 347     return $unused;
 348 }
 349
 350 sub __snapshot_foreach_volume {
 351     my ($class, $conf, $func) = @_;
 352
 353     PVE::QemuServer::foreach_drive($conf, $func);
 354 }
 355 # END implemented abstract methods from PVE::AbstractConfig
 356
 357 1;