PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub read_tunnel {
  95     my ($self, $tunnel, $timeout) = @_;
  96
  97     $timeout = 60 if !defined($timeout);
  98
  99     my $reader = $tunnel->{reader};
 100
 101     my $output;
 102     eval {
 103         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 104     };
 105     die "reading from tunnel failed: $@\n" if $@;
 106
 107     chomp $output;
 108
 109     return $output;
 110 }
 111
 112 sub write_tunnel {
 113     my ($self, $tunnel, $timeout, $command) = @_;
 114
 115     $timeout = 60 if !defined($timeout);
 116
 117     my $writer = $tunnel->{writer};
 118
 119     eval {
 120         PVE::Tools::run_with_timeout($timeout, sub {
 121             print $writer "$command\n";
 122             $writer->flush();
 123         });
 124     };
 125     die "writing to tunnel failed: $@\n" if $@;
 126
 127     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 128         my $res = eval { $self->read_tunnel($tunnel, 10); };
 129         die "no reply to command '$command': $@\n" if $@;
 130
 131         if ($res eq 'OK') {
 132             return;
 133         } else {
 134             die "tunnel replied '$res' to command '$command'\n";
 135         }
 136     }
 137 }
 138
 139 sub fork_tunnel {
 140     my ($self, $tunnel_addr) = @_;
 141
 142     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
 143
 144     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 145
 146     my $tunnel = $self->fork_command_pipe($cmd);
 147
 148     eval {
 149         my $helo = $self->read_tunnel($tunnel, 60);
 150         die "no reply\n" if !$helo;
 151         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 152         die "got strange reply from mtunnel ('$helo')\n"
 153             if $helo !~ m/^tunnel online$/;
 154     };
 155     my $err = $@;
 156
 157     eval {
 158         my $ver = $self->read_tunnel($tunnel, 10);
 159         if ($ver =~ /^ver (\d+)$/) {
 160             $tunnel->{version} = $1;
 161             $self->log('info', "ssh tunnel $ver\n");
 162         } else {
 163             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 164         }
 165     };
 166
 167     if ($err) {
 168         $self->finish_command_pipe($tunnel);
 169         die "can't open migration tunnel - $err";
 170     }
 171     return $tunnel;
 172 }
 173
 174 sub finish_tunnel {
 175     my ($self, $tunnel) = @_;
 176
 177     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 178     my $err = $@;
 179
 180     $self->finish_command_pipe($tunnel, 30);
 181
 182     if ($tunnel->{sock_addr}) {
 183         # ssh does not clean up on local host
 184         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 185         PVE::Tools::run_command($cmd);
 186
 187         # .. and just to be sure check on remote side
 188         unshift @{$cmd}, @{$self->{rem_ssh}};
 189         PVE::Tools::run_command($cmd);
 190     }
 191
 192     die $err if $err;
 193 }
 194
 195 sub lock_vm {
 196     my ($self, $vmid, $code, @param) = @_;
 197
 198     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 199 }
 200
 201 sub prepare {
 202     my ($self, $vmid) = @_;
 203
 204     my $online = $self->{opts}->{online};
 205
 206     $self->{storecfg} = PVE::Storage::config();
 207
 208     # test if VM exists
 209     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 210
 211     PVE::QemuConfig->check_lock($conf);
 212
 213     my $running = 0;
 214     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 215         die "can't migrate running VM without --online\n" if !$online;
 216         $running = $pid;
 217
 218         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 219
 220     }
 221
 222     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 223         if ($self->{running} || !$self->{opts}->{force}) {
 224             die "can't migrate VM which uses local devices\n";
 225         } else {
 226             $self->log('info', "migrating VM which uses local devices");
 227         }
 228     }
 229
 230     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 231
 232     my $need_activate = [];
 233     foreach my $volid (@$vollist) {
 234         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 235
 236         # check if storage is available on both nodes
 237         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 238
 239         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 240         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 241
 242         if ($scfg->{shared}) {
 243             # PVE::Storage::activate_storage checks this for non-shared storages
 244             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 245             warn "Used shared storage '$sid' is not online on source node!\n"
 246                 if !$plugin->check_connection($sid, $scfg);
 247         } else {
 248             # only activate if not shared
 249             next if ($volid =~ m/vm-\d+-cloudinit/);
 250             push @$need_activate, $volid;
 251         }
 252     }
 253
 254     # activate volumes
 255     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 256
 257     # test ssh connection
 258     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 259     eval { $self->cmd_quiet($cmd); };
 260     die "Can't connect to destination address using public key\n" if $@;
 261
 262     return $running;
 263 }
 264
 265 sub sync_disks {
 266     my ($self, $vmid) = @_;
 267
 268     my $conf = $self->{vmconf};
 269
 270     # local volumes which have been copied
 271     $self->{volumes} = [];
 272
 273     my $override_targetsid = $self->{opts}->{targetstorage};
 274
 275     eval {
 276
 277         # found local volumes and their origin
 278         my $local_volumes = {};
 279         my $local_volumes_errors = {};
 280         my $other_errors = [];
 281         my $abort = 0;
 282
 283         my $sharedvm = 1;
 284
 285         my $log_error = sub {
 286             my ($msg, $volid) = @_;
 287
 288             if (defined($volid)) {
 289                 $local_volumes_errors->{$volid} = $msg;
 290             } else {
 291                 push @$other_errors, $msg;
 292             }
 293             $abort = 1;
 294         };
 295
 296         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 297         foreach my $storeid (@sids) {
 298             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 299             next if $scfg->{shared};
 300             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 301
 302             # get list from PVE::Storage (for unused volumes)
 303             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 304
 305             next if @{$dl->{$storeid}} == 0;
 306
 307             my $targetsid = $override_targetsid // $storeid;
 308
 309             # check if storage is available on target node
 310             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 311             $sharedvm = 0; # there is a non-shared disk
 312
 313             PVE::Storage::foreach_volid($dl, sub {
 314                 my ($volid, $sid, $volname) = @_;
 315
 316                 $local_volumes->{$volid}->{ref} = 'storage';
 317             });
 318         }
 319
 320         my $test_volid = sub {
 321             my ($volid, $attr) = @_;
 322
 323             if ($volid =~ m|^/|) {
 324                 return if $attr->{shared};
 325                 $local_volumes->{$volid}->{ref} = 'config';
 326                 die "local file/device\n";
 327             }
 328
 329             my $snaprefs = $attr->{referenced_in_snapshot};
 330
 331             if ($attr->{cdrom}) {
 332                 if ($volid eq 'cdrom') {
 333                     my $msg = "can't migrate local cdrom drive";
 334                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 335                         my $snapnames = join(', ', sort keys %$snaprefs);
 336                         $msg .= " (referenced in snapshot - $snapnames)";
 337                     }
 338                     &$log_error("$msg\n");
 339                     return;
 340                 }
 341                 return if $volid eq 'none';
 342             }
 343
 344             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 345
 346             my $targetsid = $override_targetsid // $sid;
 347             # check if storage is available on both nodes
 348             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 349             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 350
 351             return if $scfg->{shared};
 352
 353             $sharedvm = 0;
 354
 355             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 356
 357             if ($attr->{cdrom}) {
 358                 if ($volid =~ /vm-\d+-cloudinit/) {
 359                     $local_volumes->{$volid}->{ref} = 'generated';
 360                     return;
 361                 }
 362                 die "local cdrom image\n";
 363             }
 364
 365             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 366
 367             die "owned by other VM (owner = VM $owner)\n"
 368                 if !$owner || ($owner != $self->{vmid});
 369
 370             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 371             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 372             if (defined($snaprefs)) {
 373                 # we cannot migrate shapshots on local storage
 374                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 375
 376                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 377                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 378                     die "non-migratable snapshot exists\n";
 379                 }
 380             }
 381
 382             die "referenced by linked clone(s)\n"
 383                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 384         };
 385
 386         PVE::QemuServer::foreach_volid($conf, sub {
 387             my ($volid, $attr) = @_;
 388             eval { $test_volid->($volid, $attr); };
 389             if (my $err = $@) {
 390                 &$log_error($err, $volid);
 391             }
 392         });
 393
 394         foreach my $vol (sort keys %$local_volumes) {
 395             my $ref = $local_volumes->{$vol}->{ref};
 396             if ($ref eq 'storage') {
 397                 $self->log('info', "found local disk '$vol' (via storage)\n");
 398             } elsif ($ref eq 'config') {
 399                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 400                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 401                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 402             } elsif ($ref eq 'snapshot') {
 403                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 404             } elsif ($ref eq 'generated') {
 405                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 406             } else {
 407                 $self->log('info', "found local disk '$vol'\n");
 408             }
 409         }
 410
 411         foreach my $vol (sort keys %$local_volumes_errors) {
 412             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 413         }
 414         foreach my $err (@$other_errors) {
 415             $self->log('warn', "$err");
 416         }
 417
 418         if ($abort) {
 419             die "can't migrate VM - check log\n";
 420         }
 421
 422         # additional checks for local storage
 423         foreach my $volid (keys %$local_volumes) {
 424             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 425             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 426
 427             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 428                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 429
 430             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 431                 if !$migratable;
 432
 433             # image is a linked clone on local storage, se we can't migrate.
 434             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 435                 die "can't migrate '$volid' as it's a clone of '$basename'";
 436             }
 437         }
 438
 439         my $rep_volumes;
 440
 441         $self->log('info', "copying disk images");
 442
 443         my $rep_cfg = PVE::ReplicationConfig->new();
 444
 445         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 446             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 447             my $start_time = time();
 448             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 449             $rep_volumes = PVE::Replication::run_replication(
 450                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 451             $self->{replicated_volumes} = $rep_volumes;
 452         }
 453
 454         foreach my $volid (keys %$local_volumes) {
 455             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 456             my $targetsid = $override_targetsid // $sid;
 457             my $ref = $local_volumes->{$volid}->{ref};
 458             if ($self->{running} && $ref eq 'config') {
 459                 push @{$self->{online_local_volumes}}, $volid;
 460             } elsif ($ref eq 'generated') {
 461                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 462                 push @{$self->{volumes}}, $volid;
 463                 next;
 464             } else {
 465                 next if $rep_volumes->{$volid};
 466                 push @{$self->{volumes}}, $volid;
 467                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 468                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 469                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $targetsid,
 470                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 471             }
 472         }
 473     };
 474     die "Failed to sync data - $@" if $@;
 475 }
 476
 477 sub cleanup_remotedisks {
 478     my ($self) = @_;
 479
 480     foreach my $target_drive (keys %{$self->{target_drive}}) {
 481
 482         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 483         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 484
 485         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 486
 487         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 488         if (my $err = $@) {
 489             $self->log('err', $err);
 490             $self->{errors} = 1;
 491         }
 492     }
 493 }
 494
 495 sub phase1 {
 496     my ($self, $vmid) = @_;
 497
 498     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 499
 500     my $conf = $self->{vmconf};
 501
 502     # set migrate lock in config file
 503     $conf->{lock} = 'migrate';
 504     PVE::QemuConfig->write_config($vmid, $conf);
 505
 506     sync_disks($self, $vmid);
 507
 508 };
 509
 510 sub phase1_cleanup {
 511     my ($self, $vmid, $err) = @_;
 512
 513     $self->log('info', "aborting phase 1 - cleanup resources");
 514
 515     my $conf = $self->{vmconf};
 516     delete $conf->{lock};
 517     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 518     if (my $err = $@) {
 519         $self->log('err', $err);
 520     }
 521
 522     if ($self->{volumes}) {
 523         foreach my $volid (@{$self->{volumes}}) {
 524             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 525             # fixme: try to remove ?
 526         }
 527     }
 528 }
 529
 530 sub phase2 {
 531     my ($self, $vmid) = @_;
 532
 533     my $conf = $self->{vmconf};
 534
 535     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 536
 537     my $raddr;
 538     my $rport;
 539     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 540     my $nodename = PVE::INotify::nodename();
 541
 542     ## start on remote node
 543     my $cmd = [@{$self->{rem_ssh}}];
 544
 545     my $spice_ticket;
 546     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 547         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 548         $spice_ticket = $res->{ticket};
 549     }
 550
 551     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 552
 553     my $migration_type = $self->{opts}->{migration_type};
 554
 555     push @$cmd, '--migration_type', $migration_type;
 556
 557     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 558       if $self->{opts}->{migration_network};
 559
 560     if ($migration_type eq 'insecure') {
 561         push @$cmd, '--stateuri', 'tcp';
 562     } else {
 563         push @$cmd, '--stateuri', 'unix';
 564     }
 565
 566     if ($self->{forcemachine}) {
 567         push @$cmd, '--machine', $self->{forcemachine};
 568     }
 569
 570     if ($self->{online_local_volumes}) {
 571         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 572     }
 573
 574     my $spice_port;
 575
 576     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 577     # instead we pipe it through STDIN
 578     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 579         my $line = shift;
 580
 581         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 582             $raddr = $1;
 583             $rport = int($2);
 584             $ruri = "tcp:$raddr:$rport";
 585         }
 586         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 587             $raddr = $1;
 588             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 589             $ruri = "unix:$raddr";
 590         }
 591         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 592             $raddr = "localhost";
 593             $rport = int($1);
 594             $ruri = "tcp:$raddr:$rport";
 595         }
 596         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 597             $spice_port = int($1);
 598         }
 599         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 600             my $volid = $4;
 601             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 602             my $targetdrive = $3;
 603             $targetdrive =~ s/drive-//g;
 604
 605             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 606             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 607
 608         }
 609     }, errfunc => sub {
 610         my $line = shift;
 611         $self->log('info', $line);
 612     });
 613
 614     die "unable to detect remote migration address\n" if !$raddr;
 615
 616     $self->log('info', "start remote tunnel");
 617
 618     if ($migration_type eq 'secure') {
 619
 620         if ($ruri =~ /^unix:/) {
 621             unlink $raddr;
 622             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 623             $self->{tunnel}->{sock_addr} = $raddr;
 624
 625             my $unix_socket_try = 0; # wait for the socket to become ready
 626             while (! -S $raddr) {
 627                 $unix_socket_try++;
 628                 if ($unix_socket_try > 100) {
 629                     $self->{errors} = 1;
 630                     $self->finish_tunnel($self->{tunnel});
 631                     die "Timeout, migration socket $ruri did not get ready";
 632                 }
 633
 634                 usleep(50000);
 635             }
 636
 637         } elsif ($ruri =~ /^tcp:/) {
 638             my $tunnel_addr;
 639             if ($raddr eq "localhost") {
 640                 # for backwards compatibility with older qemu-server versions
 641                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 642                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 643                 $tunnel_addr = "$lport:localhost:$rport";
 644             }
 645
 646             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 647
 648         } else {
 649             die "unsupported protocol in migration URI: $ruri\n";
 650         }
 651     } else {
 652         #fork tunnel for insecure migration, to send faster commands like resume
 653         $self->{tunnel} = $self->fork_tunnel();
 654     }
 655
 656     my $start = time();
 657
 658     if (defined($self->{online_local_volumes})) {
 659         $self->{storage_migration} = 1;
 660         $self->{storage_migration_jobs} = {};
 661         $self->log('info', "starting storage migration");
 662
 663         die "The number of local disks does not match between the source and the destination.\n"
 664             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 665         foreach my $drive (keys %{$self->{target_drive}}){
 666             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 667             $self->log('info', "$drive: start migration to $nbd_uri");
 668             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 669         }
 670     }
 671
 672     $self->log('info', "starting online/live migration on $ruri");
 673     $self->{livemigration} = 1;
 674
 675     # load_defaults
 676     my $defaults = PVE::QemuServer::load_defaults();
 677
 678     # always set migrate speed (overwrite kvm default of 32m)
 679     # we set a very hight default of 8192m which is basically unlimited
 680     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 681     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 682     $migrate_speed = $migrate_speed * 1048576;
 683     $self->log('info', "migrate_set_speed: $migrate_speed");
 684     eval {
 685         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 686     };
 687     $self->log('info', "migrate_set_speed error: $@") if $@;
 688
 689     my $migrate_downtime = $defaults->{migrate_downtime};
 690     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 691     if (defined($migrate_downtime)) {
 692         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 693         eval {
 694             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 695         };
 696         $self->log('info', "migrate_set_downtime error: $@") if $@;
 697     }
 698
 699     $self->log('info', "set migration_caps");
 700     eval {
 701         PVE::QemuServer::set_migration_caps($vmid);
 702     };
 703     warn $@ if $@;
 704
 705     # set cachesize to 10% of the total memory
 706     my $memory =  $conf->{memory} || $defaults->{memory};
 707     my $cachesize = int($memory * 1048576 / 10);
 708     $cachesize = round_powerof2($cachesize);
 709
 710     $self->log('info', "set cachesize: $cachesize");
 711     eval {
 712         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 713     };
 714     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 715
 716     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 717         my $rpcenv = PVE::RPCEnvironment::get();
 718         my $authuser = $rpcenv->get_user();
 719
 720         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 721
 722         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 723         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 724
 725         $self->log('info', "spice client_migrate_info");
 726
 727         eval {
 728             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 729                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 730                                                 'cert-subject' => $subject);
 731         };
 732         $self->log('info', "client_migrate_info error: $@") if $@;
 733
 734     }
 735
 736     $self->log('info', "start migrate command to $ruri");
 737     eval {
 738         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 739     };
 740     my $merr = $@;
 741     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 742
 743     my $lstat = 0;
 744     my $usleep = 1000000;
 745     my $i = 0;
 746     my $err_count = 0;
 747     my $lastrem = undef;
 748     my $downtimecounter = 0;
 749     while (1) {
 750         $i++;
 751         my $avglstat = $lstat/$i if $lstat;
 752
 753         usleep($usleep);
 754         my $stat;
 755         eval {
 756             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 757         };
 758         if (my $err = $@) {
 759             $err_count++;
 760             warn "query migrate failed: $err\n";
 761             $self->log('info', "query migrate failed: $err");
 762             if ($err_count <= 5) {
 763                 usleep(1000000);
 764                 next;
 765             }
 766             die "too many query migrate failures - aborting\n";
 767         }
 768
 769         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 770             sleep(1);
 771             next;
 772         }
 773
 774         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 775             $merr = undef;
 776             $err_count = 0;
 777             if ($stat->{status} eq 'completed') {
 778                 my $delay = time() - $start;
 779                 if ($delay > 0) {
 780                     my $mbps = sprintf "%.2f", $memory / $delay;
 781                     my $downtime = $stat->{downtime} || 0;
 782                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 783                 }
 784             }
 785
 786             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 787                 $self->log('info', "migration status error: $stat->{status}");
 788                 die "aborting\n"
 789             }
 790
 791             if ($stat->{status} ne 'active') {
 792                 $self->log('info', "migration status: $stat->{status}");
 793                 last;
 794             }
 795
 796             if ($stat->{ram}->{transferred} ne $lstat) {
 797                 my $trans = $stat->{ram}->{transferred} || 0;
 798                 my $rem = $stat->{ram}->{remaining} || 0;
 799                 my $total = $stat->{ram}->{total} || 0;
 800                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 801                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 802                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 803                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 804                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 805                 # reduce sleep if remainig memory is lower than the average transfer speed
 806                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 807
 808                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 809                            "remaining ${rem}), total ${total})");
 810
 811                 if (${xbzrlecachesize}) {
 812                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 813                 }
 814
 815                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 816                     $downtimecounter++;
 817                 }
 818                 $lastrem = $rem;
 819
 820                 if ($downtimecounter > 5) {
 821                     $downtimecounter = 0;
 822                     $migrate_downtime *= 2;
 823                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 824                     eval {
 825                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 826                     };
 827                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 828                 }
 829
 830             }
 831
 832
 833             $lstat = $stat->{ram}->{transferred};
 834
 835         } else {
 836             die $merr if $merr;
 837             die "unable to parse migration status '$stat->{status}' - aborting\n";
 838         }
 839     }
 840 }
 841
 842 sub phase2_cleanup {
 843     my ($self, $vmid, $err) = @_;
 844
 845     return if !$self->{errors};
 846     $self->{phase2errors} = 1;
 847
 848     $self->log('info', "aborting phase 2 - cleanup resources");
 849
 850     $self->log('info', "migrate_cancel");
 851     eval {
 852         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 853     };
 854     $self->log('info', "migrate_cancel error: $@") if $@;
 855
 856     my $conf = $self->{vmconf};
 857     delete $conf->{lock};
 858     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 859     if (my $err = $@) {
 860         $self->log('err', $err);
 861     }
 862
 863     # cleanup ressources on target host
 864     if ($self->{storage_migration}) {
 865
 866         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 867         if (my $err = $@) {
 868             $self->log('err', $err);
 869         }
 870
 871         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 872         if (my $err = $@) {
 873             $self->log('err', $err);
 874         }
 875     }
 876
 877     my $nodename = PVE::INotify::nodename();
 878
 879     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 880     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 881     if (my $err = $@) {
 882         $self->log('err', $err);
 883         $self->{errors} = 1;
 884     }
 885
 886     if ($self->{tunnel}) {
 887         eval { finish_tunnel($self, $self->{tunnel});  };
 888         if (my $err = $@) {
 889             $self->log('err', $err);
 890             $self->{errors} = 1;
 891         }
 892     }
 893 }
 894
 895 sub phase3 {
 896     my ($self, $vmid) = @_;
 897
 898     my $volids = $self->{volumes};
 899     return if $self->{phase2errors};
 900
 901     # destroy local copies
 902     foreach my $volid (@$volids) {
 903         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 904         if (my $err = $@) {
 905             $self->log('err', "removing local copy of '$volid' failed - $err");
 906             $self->{errors} = 1;
 907             last if $err =~ /^interrupted by signal$/;
 908         }
 909     }
 910 }
 911
 912 sub phase3_cleanup {
 913     my ($self, $vmid, $err) = @_;
 914
 915     my $conf = $self->{vmconf};
 916     return if $self->{phase2errors};
 917
 918     my $tunnel = $self->{tunnel};
 919
 920     if ($self->{storage_migration}) {
 921         # finish block-job
 922         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 923
 924         if (my $err = $@) {
 925             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 926             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 927             die "Failed to completed storage migration\n";
 928         } else {
 929             foreach my $target_drive (keys %{$self->{target_drive}}) {
 930                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 931                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 932                 PVE::QemuConfig->write_config($vmid, $conf);
 933             }
 934         }
 935     }
 936
 937     # transfer replication state before move config
 938     $self->transfer_replication_state() if $self->{replicated_volumes};
 939
 940     # move config to remote node
 941     my $conffile = PVE::QemuConfig->config_file($vmid);
 942     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 943
 944     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 945         if !rename($conffile, $newconffile);
 946
 947     $self->switch_replication_job_target() if $self->{replicated_volumes};
 948
 949     if ($self->{livemigration}) {
 950         if ($self->{storage_migration}) {
 951             # stop nbd server on remote vm - requirement for resume since 2.9
 952             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 953
 954             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 955             if (my $err = $@) {
 956                 $self->log('err', $err);
 957                 $self->{errors} = 1;
 958             }
 959         }
 960
 961         # config moved and nbd server stopped - now we can resume vm on target
 962         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
 963             eval {
 964                 $self->write_tunnel($tunnel, 30, "resume $vmid");
 965             };
 966             if (my $err = $@) {
 967                 $self->log('err', $err);
 968                 $self->{errors} = 1;
 969             }
 970         } else {
 971             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 972             my $logf = sub {
 973                 my $line = shift;
 974                 $self->log('err', $line);
 975             };
 976             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
 977             if (my $err = $@) {
 978                 $self->log('err', $err);
 979                 $self->{errors} = 1;
 980             }
 981         }
 982
 983         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
 984             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
 985             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 986         }
 987     }
 988
 989     # close tunnel on successful migration, on error phase2_cleanup closed it
 990     if ($tunnel) {
 991         eval { finish_tunnel($self, $tunnel);  };
 992         if (my $err = $@) {
 993             $self->log('err', $err);
 994             $self->{errors} = 1;
 995         }
 996     }
 997
 998     eval {
 999         my $timer = 0;
1000         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1001             $self->log('info', "Waiting for spice server migration");
1002             while (1) {
1003                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
1004                 last if int($res->{'migrated'}) == 1;
1005                 last if $timer > 50;
1006                 $timer ++;
1007                 usleep(200000);
1008             }
1009         }
1010     };
1011
1012     # always stop local VM
1013     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1014     if (my $err = $@) {
1015         $self->log('err', "stopping vm failed - $err");
1016         $self->{errors} = 1;
1017     }
1018
1019     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1020     eval {
1021         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1022         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1023     };
1024     if (my $err = $@) {
1025         $self->log('err', $err);
1026         $self->{errors} = 1;
1027     }
1028
1029     if($self->{storage_migration}) {
1030         # destroy local copies
1031         my $volids = $self->{online_local_volumes};
1032
1033         foreach my $volid (@$volids) {
1034             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1035             if (my $err = $@) {
1036                 $self->log('err', "removing local copy of '$volid' failed - $err");
1037                 $self->{errors} = 1;
1038                 last if $err =~ /^interrupted by signal$/;
1039             }
1040         }
1041
1042     }
1043
1044     # clear migrate lock
1045     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1046     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1047 }
1048
1049 sub final_cleanup {
1050     my ($self, $vmid) = @_;
1051
1052     # nothing to do
1053 }
1054
1055 sub round_powerof2 {
1056     return 1 if $_[0] < 2;
1057     return 2 << int(log($_[0]-1)/log(2));
1058 }
1059
1060 1;