PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuServer::Drive;
  21 use PVE::QemuServer::Helpers qw(min_version);
  22 use PVE::QemuServer::Machine;
  23 use PVE::QemuServer::Monitor qw(mon_cmd);
  24 use PVE::QemuServer;
  25
  26 use PVE::AbstractMigrate;
  27 use base qw(PVE::AbstractMigrate);
  28
  29 sub fork_command_pipe {
  30     my ($self, $cmd) = @_;
  31
  32     my $reader = IO::File->new();
  33     my $writer = IO::File->new();
  34
  35     my $orig_pid = $$;
  36
  37     my $cpid;
  38
  39     eval { $cpid = open2($reader, $writer, @$cmd); };
  40
  41     my $err = $@;
  42
  43     # catch exec errors
  44     if ($orig_pid != $$) {
  45         $self->log('err', "can't fork command pipe\n");
  46         POSIX::_exit(1);
  47         kill('KILL', $$);
  48     }
  49
  50     die $err if $err;
  51
  52     return { writer => $writer, reader => $reader, pid => $cpid };
  53 }
  54
  55 sub finish_command_pipe {
  56     my ($self, $cmdpipe, $timeout) = @_;
  57
  58     my $cpid = $cmdpipe->{pid};
  59     return if !defined($cpid);
  60
  61     my $writer = $cmdpipe->{writer};
  62     my $reader = $cmdpipe->{reader};
  63
  64     $writer->close();
  65     $reader->close();
  66
  67     my $collect_child_process = sub {
  68         my $res = waitpid($cpid, WNOHANG);
  69         if (defined($res) && ($res == $cpid)) {
  70             delete $cmdpipe->{cpid};
  71             return 1;
  72         } else {
  73             return 0;
  74         }
  75      };
  76
  77     if ($timeout) {
  78         for (my $i = 0; $i < $timeout; $i++) {
  79             return if &$collect_child_process();
  80             sleep(1);
  81         }
  82     }
  83
  84     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  85     kill(15, $cpid);
  86
  87     # wait again
  88     for (my $i = 0; $i < 10; $i++) {
  89         return if &$collect_child_process();
  90         sleep(1);
  91     }
  92
  93     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  94     kill 9, $cpid;
  95     sleep 1;
  96
  97     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  98         if !&$collect_child_process();
  99 }
 100
 101 sub read_tunnel {
 102     my ($self, $tunnel, $timeout) = @_;
 103
 104     $timeout = 60 if !defined($timeout);
 105
 106     my $reader = $tunnel->{reader};
 107
 108     my $output;
 109     eval {
 110         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 111     };
 112     die "reading from tunnel failed: $@\n" if $@;
 113
 114     chomp $output;
 115
 116     return $output;
 117 }
 118
 119 sub write_tunnel {
 120     my ($self, $tunnel, $timeout, $command) = @_;
 121
 122     $timeout = 60 if !defined($timeout);
 123
 124     my $writer = $tunnel->{writer};
 125
 126     eval {
 127         PVE::Tools::run_with_timeout($timeout, sub {
 128             print $writer "$command\n";
 129             $writer->flush();
 130         });
 131     };
 132     die "writing to tunnel failed: $@\n" if $@;
 133
 134     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 135         my $res = eval { $self->read_tunnel($tunnel, 10); };
 136         die "no reply to command '$command': $@\n" if $@;
 137
 138         if ($res eq 'OK') {
 139             return;
 140         } else {
 141             die "tunnel replied '$res' to command '$command'\n";
 142         }
 143     }
 144 }
 145
 146 sub fork_tunnel {
 147     my ($self, $tunnel_addr) = @_;
 148
 149     my @localtunnelinfo = ();
 150     foreach my $addr (@$tunnel_addr) {
 151         push @localtunnelinfo, '-L', $addr;
 152     }
 153
 154     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 155
 156     my $tunnel = $self->fork_command_pipe($cmd);
 157
 158     eval {
 159         my $helo = $self->read_tunnel($tunnel, 60);
 160         die "no reply\n" if !$helo;
 161         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 162         die "got strange reply from mtunnel ('$helo')\n"
 163             if $helo !~ m/^tunnel online$/;
 164     };
 165     my $err = $@;
 166
 167     eval {
 168         my $ver = $self->read_tunnel($tunnel, 10);
 169         if ($ver =~ /^ver (\d+)$/) {
 170             $tunnel->{version} = $1;
 171             $self->log('info', "ssh tunnel $ver\n");
 172         } else {
 173             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 174         }
 175     };
 176
 177     if ($err) {
 178         $self->finish_command_pipe($tunnel);
 179         die "can't open migration tunnel - $err";
 180     }
 181     return $tunnel;
 182 }
 183
 184 sub finish_tunnel {
 185     my ($self, $tunnel) = @_;
 186
 187     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 188     my $err = $@;
 189
 190     $self->finish_command_pipe($tunnel, 30);
 191
 192     if ($tunnel->{sock_addr}) {
 193         # ssh does not clean up on local host
 194         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 195         PVE::Tools::run_command($cmd);
 196
 197         # .. and just to be sure check on remote side
 198         unshift @{$cmd}, @{$self->{rem_ssh}};
 199         PVE::Tools::run_command($cmd);
 200     }
 201
 202     die $err if $err;
 203 }
 204
 205 sub lock_vm {
 206     my ($self, $vmid, $code, @param) = @_;
 207
 208     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 209 }
 210
 211 sub prepare {
 212     my ($self, $vmid) = @_;
 213
 214     my $online = $self->{opts}->{online};
 215
 216     $self->{storecfg} = PVE::Storage::config();
 217
 218     # test if VM exists
 219     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 220
 221     PVE::QemuConfig->check_lock($conf);
 222
 223     my $running = 0;
 224     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 225         die "can't migrate running VM without --online\n" if !$online;
 226         $running = $pid;
 227
 228         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 229
 230     }
 231     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 232     if (scalar @$loc_res) {
 233         if ($self->{running} || !$self->{opts}->{force}) {
 234             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 235         } else {
 236             $self->log('info', "migrating VM which uses local devices");
 237         }
 238     }
 239
 240     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 241
 242     my $need_activate = [];
 243     foreach my $volid (@$vollist) {
 244         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 245
 246         # check if storage is available on both nodes
 247         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 248
 249         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 250         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 251
 252         if ($scfg->{shared}) {
 253             # PVE::Storage::activate_storage checks this for non-shared storages
 254             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 255             warn "Used shared storage '$sid' is not online on source node!\n"
 256                 if !$plugin->check_connection($sid, $scfg);
 257         } else {
 258             # only activate if not shared
 259             next if ($volid =~ m/vm-\d+-cloudinit/);
 260             push @$need_activate, $volid;
 261         }
 262     }
 263
 264     # activate volumes
 265     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 266
 267     # test ssh connection
 268     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 269     eval { $self->cmd_quiet($cmd); };
 270     die "Can't connect to destination address using public key\n" if $@;
 271
 272     return $running;
 273 }
 274
 275 sub sync_disks {
 276     my ($self, $vmid) = @_;
 277
 278     my $conf = $self->{vmconf};
 279
 280     # local volumes which have been copied
 281     $self->{volumes} = [];
 282
 283     my $storecfg = $self->{storecfg};
 284     my $override_targetsid = $self->{opts}->{targetstorage};
 285
 286     if (defined($override_targetsid)) {
 287         my $scfg = PVE::Storage::storage_config($storecfg, $override_targetsid);
 288         die "content type 'images' is not available on storage '$override_targetsid'\n"
 289             if !$scfg->{content}->{images};
 290     }
 291
 292     eval {
 293
 294         # found local volumes and their origin
 295         my $local_volumes = {};
 296         my $local_volumes_errors = {};
 297         my $other_errors = [];
 298         my $abort = 0;
 299
 300         my $log_error = sub {
 301             my ($msg, $volid) = @_;
 302
 303             if (defined($volid)) {
 304                 $local_volumes_errors->{$volid} = $msg;
 305             } else {
 306                 push @$other_errors, $msg;
 307             }
 308             $abort = 1;
 309         };
 310
 311         my @sids = PVE::Storage::storage_ids($storecfg);
 312         foreach my $storeid (@sids) {
 313             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 314             next if $scfg->{shared};
 315             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 316
 317             # get list from PVE::Storage (for unused volumes)
 318             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 319
 320             next if @{$dl->{$storeid}} == 0;
 321
 322             my $targetsid = $override_targetsid // $storeid;
 323
 324             # check if storage is available on target node
 325             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 326
 327             PVE::Storage::foreach_volid($dl, sub {
 328                 my ($volid, $sid, $volinfo) = @_;
 329
 330                 $local_volumes->{$volid}->{ref} = 'storage';
 331
 332                 # If with_snapshots is not set for storage migrate, it tries to use
 333                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 334                 # back to qcow2 is currently not possible.
 335                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 336                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 337             });
 338         }
 339
 340         my $rep_cfg = PVE::ReplicationConfig->new();
 341         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 342         my $replicatable_volumes = !$replication_jobcfg ? {}
 343             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 344
 345         my $test_volid = sub {
 346             my ($volid, $attr) = @_;
 347
 348             if ($volid =~ m|^/|) {
 349                 return if $attr->{shared};
 350                 $local_volumes->{$volid}->{ref} = 'config';
 351                 die "local file/device\n";
 352             }
 353
 354             my $snaprefs = $attr->{referenced_in_snapshot};
 355
 356             if ($attr->{cdrom}) {
 357                 if ($volid eq 'cdrom') {
 358                     my $msg = "can't migrate local cdrom drive";
 359                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 360                         my $snapnames = join(', ', sort keys %$snaprefs);
 361                         $msg .= " (referenced in snapshot - $snapnames)";
 362                     }
 363                     &$log_error("$msg\n");
 364                     return;
 365                 }
 366                 return if $volid eq 'none';
 367             }
 368
 369             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 370
 371             my $targetsid = $override_targetsid // $sid;
 372             # check if storage is available on both nodes
 373             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 374             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 375
 376             return if $scfg->{shared};
 377
 378             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 379
 380             if ($attr->{cdrom}) {
 381                 if ($volid =~ /vm-\d+-cloudinit/) {
 382                     $local_volumes->{$volid}->{ref} = 'generated';
 383                     return;
 384                 }
 385                 die "local cdrom image\n";
 386             }
 387
 388             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 389
 390             die "owned by other VM (owner = VM $owner)\n"
 391                 if !$owner || ($owner != $vmid);
 392
 393             if (defined($snaprefs)) {
 394                 $local_volumes->{$volid}->{snapshots} = 1;
 395
 396                 # we cannot migrate shapshots on local storage
 397                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 398
 399                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 400                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 401                     die "non-migratable snapshot exists\n";
 402                 }
 403             }
 404
 405             die "referenced by linked clone(s)\n"
 406                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 407         };
 408
 409         PVE::QemuServer::foreach_volid($conf, sub {
 410             my ($volid, $attr) = @_;
 411             eval { $test_volid->($volid, $attr); };
 412             if (my $err = $@) {
 413                 &$log_error($err, $volid);
 414             }
 415         });
 416
 417         foreach my $vol (sort keys %$local_volumes) {
 418             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 419             my $ref = $local_volumes->{$vol}->{ref};
 420             if ($ref eq 'storage') {
 421                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 422             } elsif ($ref eq 'config') {
 423                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 424                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 425                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 426             } elsif ($ref eq 'snapshot') {
 427                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 428             } elsif ($ref eq 'generated') {
 429                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 430             } else {
 431                 $self->log('info', "found $type disk '$vol'\n");
 432             }
 433         }
 434
 435         foreach my $vol (sort keys %$local_volumes_errors) {
 436             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 437         }
 438         foreach my $err (@$other_errors) {
 439             $self->log('warn', "$err");
 440         }
 441
 442         if ($abort) {
 443             die "can't migrate VM - check log\n";
 444         }
 445
 446         # additional checks for local storage
 447         foreach my $volid (keys %$local_volumes) {
 448             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 449             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 450
 451             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 452
 453             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 454                 if !$migratable;
 455
 456             # image is a linked clone on local storage, se we can't migrate.
 457             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 458                 die "can't migrate '$volid' as it's a clone of '$basename'";
 459             }
 460         }
 461
 462         if ($replication_jobcfg) {
 463             if ($self->{running}) {
 464
 465                 my $version = PVE::QemuServer::kvm_user_version();
 466                 if (!min_version($version, 4, 2)) {
 467                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 468                 }
 469
 470                 my $live_replicatable_volumes = {};
 471                 PVE::QemuServer::foreach_drive($conf, sub {
 472                     my ($ds, $drive) = @_;
 473
 474                     my $volid = $drive->{file};
 475                     $live_replicatable_volumes->{$ds} = $volid
 476                         if defined($replicatable_volumes->{$volid});
 477                 });
 478                 foreach my $drive (keys %$live_replicatable_volumes) {
 479                     my $volid = $live_replicatable_volumes->{$drive};
 480
 481                     my $bitmap = "repl_$drive";
 482
 483                     # start tracking before replication to get full delta + a few duplicates
 484                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 485                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 486
 487                     # other info comes from target node in phase 2
 488                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 489                 }
 490             }
 491             $self->log('info', "replicating disk images");
 492
 493             my $start_time = time();
 494             my $logfunc = sub { $self->log('info', shift) };
 495             $self->{replicated_volumes} = PVE::Replication::run_replication(
 496                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 497         }
 498
 499         # sizes in config have to be accurate for remote node to correctly
 500         # allocate disks, rescan to be sure
 501         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 502         PVE::QemuServer::foreach_drive($conf, sub {
 503             my ($key, $drive) = @_;
 504             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 505             if (defined($updated)) {
 506                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 507                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 508             }
 509         });
 510
 511         # we want to set the efidisk size in the config to the size of the
 512         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 513         if (defined($conf->{efidisk0})) {
 514             PVE::QemuServer::update_efidisk_size($conf);
 515         }
 516
 517         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 518
 519         foreach my $volid (keys %$local_volumes) {
 520             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 521             my $targetsid = $override_targetsid // $sid;
 522             my $ref = $local_volumes->{$volid}->{ref};
 523             if ($self->{running} && $ref eq 'config') {
 524                 push @{$self->{online_local_volumes}}, $volid;
 525             } elsif ($ref eq 'generated') {
 526                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 527                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 528                 push @{$self->{volumes}}, $volid;
 529                 next;
 530             } else {
 531                 next if $self->{replicated_volumes}->{$volid};
 532                 push @{$self->{volumes}}, $volid;
 533                 my $opts = $self->{opts};
 534                 my $insecure = $opts->{migration_type} eq 'insecure';
 535                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 536                 # use 'migrate' limit for transfer to other node
 537                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 538                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 539                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 540
 541                 PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info}, $targetsid,
 542                                               undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 543             }
 544         }
 545     };
 546     die "Failed to sync data - $@" if $@;
 547 }
 548
 549 sub cleanup_remotedisks {
 550     my ($self) = @_;
 551
 552     foreach my $target_drive (keys %{$self->{target_drive}}) {
 553         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
 554
 555         # don't clean up replicated disks!
 556         next if defined($self->{replicated_volumes}->{$drive->{file}});
 557
 558         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 559
 560         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 561
 562         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 563         if (my $err = $@) {
 564             $self->log('err', $err);
 565             $self->{errors} = 1;
 566         }
 567     }
 568 }
 569
 570 sub cleanup_bitmaps {
 571     my ($self) = @_;
 572     foreach my $drive (keys %{$self->{target_drive}}) {
 573         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 574         next if !$bitmap;
 575         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 576         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 577     }
 578 }
 579
 580 sub phase1 {
 581     my ($self, $vmid) = @_;
 582
 583     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 584
 585     my $conf = $self->{vmconf};
 586
 587     # set migrate lock in config file
 588     $conf->{lock} = 'migrate';
 589     PVE::QemuConfig->write_config($vmid, $conf);
 590
 591     sync_disks($self, $vmid);
 592
 593     # sync_disks fixes disk sizes to match their actual size, write changes so
 594     # target allocates correct volumes
 595     PVE::QemuConfig->write_config($vmid, $conf);
 596 };
 597
 598 sub phase1_cleanup {
 599     my ($self, $vmid, $err) = @_;
 600
 601     $self->log('info', "aborting phase 1 - cleanup resources");
 602
 603     my $conf = $self->{vmconf};
 604     delete $conf->{lock};
 605     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 606     if (my $err = $@) {
 607         $self->log('err', $err);
 608     }
 609
 610     if ($self->{volumes}) {
 611         foreach my $volid (@{$self->{volumes}}) {
 612             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 613             # fixme: try to remove ?
 614         }
 615     }
 616
 617     eval { $self->cleanup_bitmaps() };
 618     if (my $err =$@) {
 619         $self->log('err', $err);
 620     }
 621
 622 }
 623
 624 sub phase2 {
 625     my ($self, $vmid) = @_;
 626
 627     my $conf = $self->{vmconf};
 628
 629     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 630
 631     my $raddr;
 632     my $rport;
 633     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 634     my $nodename = PVE::INotify::nodename();
 635
 636     ## start on remote node
 637     my $cmd = [@{$self->{rem_ssh}}];
 638
 639     my $spice_ticket;
 640     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 641         my $res = mon_cmd($vmid, 'query-spice');
 642         $spice_ticket = $res->{ticket};
 643     }
 644
 645     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 646
 647     my $migration_type = $self->{opts}->{migration_type};
 648
 649     push @$cmd, '--migration_type', $migration_type;
 650
 651     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 652       if $self->{opts}->{migration_network};
 653
 654     if ($migration_type eq 'insecure') {
 655         push @$cmd, '--stateuri', 'tcp';
 656     } else {
 657         push @$cmd, '--stateuri', 'unix';
 658     }
 659
 660     if ($self->{forcemachine}) {
 661         push @$cmd, '--machine', $self->{forcemachine};
 662     }
 663
 664     if ($self->{online_local_volumes}) {
 665         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 666     }
 667
 668     my $spice_port;
 669     my $tunnel_addr = [];
 670     my $sock_addr = [];
 671     # version > 0 for unix socket support
 672     my $nbd_protocol_version = 1;
 673     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 674     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 675     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 676     foreach my $volid (keys %{$self->{replicated_volumes}}) {
 677         $input .= "replicated_volume: $volid\n";
 678     }
 679
 680     my $target_replicated_volumes = {};
 681
 682     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 683     # instead we pipe it through STDIN
 684     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 685         my $line = shift;
 686
 687         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 688             $raddr = $1;
 689             $rport = int($2);
 690             $ruri = "tcp:$raddr:$rport";
 691         }
 692         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 693             $raddr = $1;
 694             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 695             $ruri = "unix:$raddr";
 696         }
 697         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 698             $raddr = "localhost";
 699             $rport = int($1);
 700             $ruri = "tcp:$raddr:$rport";
 701         }
 702         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 703             $spice_port = int($1);
 704         }
 705         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 706             my $drivestr = $4;
 707             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 708             my $targetdrive = $3;
 709             $targetdrive =~ s/drive-//g;
 710
 711             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 712             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 713         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 714             my $drivestr = $4;
 715             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 716             my $nbd_unix_addr = $1;
 717             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 718             my $targetdrive = $3;
 719             $targetdrive =~ s/drive-//g;
 720
 721             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 722             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 723             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 724             push @$sock_addr, $nbd_unix_addr;
 725         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 726             my $drive = $1;
 727             my $volid = $2;
 728             $target_replicated_volumes->{$volid} = $drive;
 729         } elsif ($line =~ m/^QEMU: (.*)$/) {
 730             $self->log('info', "[$self->{node}] $1\n");
 731         }
 732     }, errfunc => sub {
 733         my $line = shift;
 734         $self->log('info', "[$self->{node}] $line");
 735     }, noerr => 1);
 736
 737     die "remote command failed with exit code $exitcode\n" if $exitcode;
 738
 739     die "unable to detect remote migration address\n" if !$raddr;
 740
 741     if (scalar(keys %$target_replicated_volumes) != scalar(keys %{$self->{replicated_volumes}})) {
 742         die "number of replicated disks on source and target node do not match - target node too old?\n"
 743     }
 744
 745     $self->log('info', "start remote tunnel");
 746
 747     if ($migration_type eq 'secure') {
 748
 749         if ($ruri =~ /^unix:/) {
 750             unlink $raddr;
 751             push @$tunnel_addr, "$raddr:$raddr";
 752             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 753             push @$sock_addr, $raddr;
 754
 755             my $unix_socket_try = 0; # wait for the socket to become ready
 756             while ($unix_socket_try <= 100) {
 757                 $unix_socket_try++;
 758                 my $available = 0;
 759                 foreach my $sock (@$sock_addr) {
 760                     if (-S $sock) {
 761                         $available++;
 762                     }
 763                 }
 764
 765                 if ($available == @$sock_addr) {
 766                     last;
 767                 }
 768
 769                 usleep(50000);
 770             }
 771             if ($unix_socket_try > 100) {
 772                 $self->{errors} = 1;
 773                 $self->finish_tunnel($self->{tunnel});
 774                 die "Timeout, migration socket $ruri did not get ready";
 775             }
 776
 777         } elsif ($ruri =~ /^tcp:/) {
 778             my $tunnel_addr;
 779             if ($raddr eq "localhost") {
 780                 # for backwards compatibility with older qemu-server versions
 781                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 782                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 783                 $tunnel_addr = "$lport:localhost:$rport";
 784             }
 785
 786             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 787
 788         } else {
 789             die "unsupported protocol in migration URI: $ruri\n";
 790         }
 791     } else {
 792         #fork tunnel for insecure migration, to send faster commands like resume
 793         $self->{tunnel} = $self->fork_tunnel();
 794     }
 795     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 796
 797     my $start = time();
 798
 799     my $opt_bwlimit = $self->{opts}->{bwlimit};
 800
 801     if (defined($self->{online_local_volumes})) {
 802         $self->{storage_migration} = 1;
 803         $self->{storage_migration_jobs} = {};
 804         $self->log('info', "starting storage migration");
 805
 806         die "The number of local disks does not match between the source and the destination.\n"
 807             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 808         foreach my $drive (keys %{$self->{target_drive}}){
 809             my $target = $self->{target_drive}->{$drive};
 810             my $nbd_uri = $target->{nbd_uri};
 811
 812             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 813             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 814
 815             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_drive->{file});
 816             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_drive->{file});
 817
 818             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 819             my $bitmap = $target->{bitmap};
 820
 821             $self->log('info', "$drive: start migration to $nbd_uri");
 822             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 823         }
 824     }
 825
 826     $self->log('info', "starting online/live migration on $ruri");
 827     $self->{livemigration} = 1;
 828
 829     # load_defaults
 830     my $defaults = PVE::QemuServer::load_defaults();
 831
 832     $self->log('info', "set migration_caps");
 833     eval {
 834         PVE::QemuServer::set_migration_caps($vmid);
 835     };
 836     warn $@ if $@;
 837
 838     my $qemu_migrate_params = {};
 839
 840     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 841     # migrate_speed parameter in qm.conf - take the lower of the two.
 842     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 843     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 844     # migrate_speed is in MB/s, bwlimit in KB/s
 845     $migrate_speed *= 1024;
 846
 847     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 848
 849     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 850     # default of 8192m which is basically unlimited
 851     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 852
 853     # qmp takes migrate_speed in B/s.
 854     $migrate_speed *= 1024;
 855     $self->log('info', "migration speed limit: $migrate_speed B/s");
 856     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 857
 858     my $migrate_downtime = $defaults->{migrate_downtime};
 859     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 860     if (defined($migrate_downtime)) {
 861         # migrate-set-parameters expects limit in ms
 862         $migrate_downtime *= 1000;
 863         $self->log('info', "migration downtime limit: $migrate_downtime ms");
 864         $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 865     }
 866
 867     # set cachesize to 10% of the total memory
 868     my $memory =  $conf->{memory} || $defaults->{memory};
 869     my $cachesize = int($memory * 1048576 / 10);
 870     $cachesize = round_powerof2($cachesize);
 871
 872     $self->log('info', "migration cachesize: $cachesize B");
 873     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 874
 875     $self->log('info', "set migration parameters");
 876     eval {
 877         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 878     };
 879     $self->log('info', "migrate-set-parameters error: $@") if $@;
 880
 881     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 882         my $rpcenv = PVE::RPCEnvironment::get();
 883         my $authuser = $rpcenv->get_user();
 884
 885         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 886
 887         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 888         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 889
 890         $self->log('info', "spice client_migrate_info");
 891
 892         eval {
 893             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 894                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 895                                                 'cert-subject' => $subject);
 896         };
 897         $self->log('info', "client_migrate_info error: $@") if $@;
 898
 899     }
 900
 901     $self->log('info', "start migrate command to $ruri");
 902     eval {
 903         mon_cmd($vmid, "migrate", uri => $ruri);
 904     };
 905     my $merr = $@;
 906     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 907
 908     my $lstat = 0;
 909     my $usleep = 1000000;
 910     my $i = 0;
 911     my $err_count = 0;
 912     my $lastrem = undef;
 913     my $downtimecounter = 0;
 914     while (1) {
 915         $i++;
 916         my $avglstat = $lstat/$i if $lstat;
 917
 918         usleep($usleep);
 919         my $stat;
 920         eval {
 921             $stat = mon_cmd($vmid, "query-migrate");
 922         };
 923         if (my $err = $@) {
 924             $err_count++;
 925             warn "query migrate failed: $err\n";
 926             $self->log('info', "query migrate failed: $err");
 927             if ($err_count <= 5) {
 928                 usleep(1000000);
 929                 next;
 930             }
 931             die "too many query migrate failures - aborting\n";
 932         }
 933
 934         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 935             sleep(1);
 936             next;
 937         }
 938
 939         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 940             $merr = undef;
 941             $err_count = 0;
 942             if ($stat->{status} eq 'completed') {
 943                 my $delay = time() - $start;
 944                 if ($delay > 0) {
 945                     my $mbps = sprintf "%.2f", $memory / $delay;
 946                     my $downtime = $stat->{downtime} || 0;
 947                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 948                 }
 949             }
 950
 951             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 952                 $self->log('info', "migration status error: $stat->{status}");
 953                 die "aborting\n"
 954             }
 955
 956             if ($stat->{status} ne 'active') {
 957                 $self->log('info', "migration status: $stat->{status}");
 958                 last;
 959             }
 960
 961             if ($stat->{ram}->{transferred} ne $lstat) {
 962                 my $trans = $stat->{ram}->{transferred} || 0;
 963                 my $rem = $stat->{ram}->{remaining} || 0;
 964                 my $total = $stat->{ram}->{total} || 0;
 965                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 966                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 967                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 968                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 969                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 970                 # reduce sleep if remainig memory is lower than the average transfer speed
 971                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 972
 973                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 974                            "remaining ${rem}), total ${total})");
 975
 976                 if (${xbzrlecachesize}) {
 977                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 978                 }
 979
 980                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 981                     $downtimecounter++;
 982                 }
 983                 $lastrem = $rem;
 984
 985                 if ($downtimecounter > 5) {
 986                     $downtimecounter = 0;
 987                     $migrate_downtime *= 2;
 988                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 989                     eval {
 990                         mon_cmd($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 991                     };
 992                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 993                 }
 994
 995             }
 996
 997
 998             $lstat = $stat->{ram}->{transferred};
 999
1000         } else {
1001             die $merr if $merr;
1002             die "unable to parse migration status '$stat->{status}' - aborting\n";
1003         }
1004     }
1005 }
1006
1007 sub phase2_cleanup {
1008     my ($self, $vmid, $err) = @_;
1009
1010     return if !$self->{errors};
1011     $self->{phase2errors} = 1;
1012
1013     $self->log('info', "aborting phase 2 - cleanup resources");
1014
1015     $self->log('info', "migrate_cancel");
1016     eval {
1017         mon_cmd($vmid, "migrate_cancel");
1018     };
1019     $self->log('info', "migrate_cancel error: $@") if $@;
1020
1021     my $conf = $self->{vmconf};
1022     delete $conf->{lock};
1023     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1024     if (my $err = $@) {
1025         $self->log('err', $err);
1026     }
1027
1028     # cleanup ressources on target host
1029     if ($self->{storage_migration}) {
1030         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1031         if (my $err = $@) {
1032             $self->log('err', $err);
1033         }
1034     }
1035
1036     eval { $self->cleanup_bitmaps() };
1037     if (my $err =$@) {
1038         $self->log('err', $err);
1039     }
1040
1041     my $nodename = PVE::INotify::nodename();
1042
1043     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1044     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1045     if (my $err = $@) {
1046         $self->log('err', $err);
1047         $self->{errors} = 1;
1048     }
1049
1050     # cleanup after stopping, otherwise disks might be in-use by target VM!
1051     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1052     if (my $err = $@) {
1053         $self->log('err', $err);
1054     }
1055
1056
1057     if ($self->{tunnel}) {
1058         eval { finish_tunnel($self, $self->{tunnel});  };
1059         if (my $err = $@) {
1060             $self->log('err', $err);
1061             $self->{errors} = 1;
1062         }
1063     }
1064 }
1065
1066 sub phase3 {
1067     my ($self, $vmid) = @_;
1068
1069     my $volids = $self->{volumes};
1070     return if $self->{phase2errors};
1071
1072     # destroy local copies
1073     foreach my $volid (@$volids) {
1074         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1075         if (my $err = $@) {
1076             $self->log('err', "removing local copy of '$volid' failed - $err");
1077             $self->{errors} = 1;
1078             last if $err =~ /^interrupted by signal$/;
1079         }
1080     }
1081 }
1082
1083 sub phase3_cleanup {
1084     my ($self, $vmid, $err) = @_;
1085
1086     my $conf = $self->{vmconf};
1087     return if $self->{phase2errors};
1088
1089     my $tunnel = $self->{tunnel};
1090
1091     if ($self->{storage_migration}) {
1092         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1093         # to avoid it trying to re-establish it. We are in blockjob ready state,
1094         # thus, this command changes to it to blockjob complete (see qapi docs)
1095         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1096
1097         if (my $err = $@) {
1098             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1099             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1100             die "Failed to complete storage migration: $err\n";
1101         } else {
1102             foreach my $target_drive (keys %{$self->{target_drive}}) {
1103                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
1104                 $conf->{$target_drive} = PVE::QemuServer::print_drive($drive);
1105                 PVE::QemuConfig->write_config($vmid, $conf);
1106             }
1107         }
1108     }
1109
1110     # transfer replication state before move config
1111     $self->transfer_replication_state() if $self->{replicated_volumes};
1112
1113     # move config to remote node
1114     my $conffile = PVE::QemuConfig->config_file($vmid);
1115     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1116
1117     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1118         if !rename($conffile, $newconffile);
1119
1120     $self->switch_replication_job_target() if $self->{replicated_volumes};
1121
1122     if ($self->{livemigration}) {
1123         if ($self->{storage_migration}) {
1124             # stop nbd server on remote vm - requirement for resume since 2.9
1125             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1126
1127             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1128             if (my $err = $@) {
1129                 $self->log('err', $err);
1130                 $self->{errors} = 1;
1131             }
1132         }
1133
1134         # config moved and nbd server stopped - now we can resume vm on target
1135         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1136             eval {
1137                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1138             };
1139             if (my $err = $@) {
1140                 $self->log('err', $err);
1141                 $self->{errors} = 1;
1142             }
1143         } else {
1144             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1145             my $logf = sub {
1146                 my $line = shift;
1147                 $self->log('err', $line);
1148             };
1149             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1150             if (my $err = $@) {
1151                 $self->log('err', $err);
1152                 $self->{errors} = 1;
1153             }
1154         }
1155
1156         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1157             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1158             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1159         }
1160     }
1161
1162     # close tunnel on successful migration, on error phase2_cleanup closed it
1163     if ($tunnel) {
1164         eval { finish_tunnel($self, $tunnel);  };
1165         if (my $err = $@) {
1166             $self->log('err', $err);
1167             $self->{errors} = 1;
1168         }
1169     }
1170
1171     eval {
1172         my $timer = 0;
1173         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1174             $self->log('info', "Waiting for spice server migration");
1175             while (1) {
1176                 my $res = mon_cmd($vmid, 'query-spice');
1177                 last if int($res->{'migrated'}) == 1;
1178                 last if $timer > 50;
1179                 $timer ++;
1180                 usleep(200000);
1181             }
1182         }
1183     };
1184
1185     # always stop local VM
1186     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1187     if (my $err = $@) {
1188         $self->log('err', "stopping vm failed - $err");
1189         $self->{errors} = 1;
1190     }
1191
1192     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1193     eval {
1194         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1195         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1196     };
1197     if (my $err = $@) {
1198         $self->log('err', $err);
1199         $self->{errors} = 1;
1200     }
1201
1202     if($self->{storage_migration}) {
1203         # destroy local copies
1204         my $volids = $self->{online_local_volumes};
1205
1206         foreach my $volid (@$volids) {
1207             # keep replicated volumes!
1208             next if $self->{replicated_volumes}->{$volid};
1209
1210             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1211             if (my $err = $@) {
1212                 $self->log('err', "removing local copy of '$volid' failed - $err");
1213                 $self->{errors} = 1;
1214                 last if $err =~ /^interrupted by signal$/;
1215             }
1216         }
1217
1218     }
1219
1220     # clear migrate lock
1221     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1222     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1223 }
1224
1225 sub final_cleanup {
1226     my ($self, $vmid) = @_;
1227
1228     # nothing to do
1229 }
1230
1231 sub round_powerof2 {
1232     return 1 if $_[0] < 2;
1233     return 2 << int(log($_[0]-1)/log(2));
1234 }
1235
1236 1;