PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Format qw(render_bytes);
  12 use PVE::Cluster;
  13 use PVE::GuestHelpers qw(safe_boolean_ne safe_string_ne);
  14 use PVE::INotify;
  15 use PVE::RPCEnvironment;
  16 use PVE::Replication;
  17 use PVE::ReplicationConfig;
  18 use PVE::ReplicationState;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21
  22 use PVE::QemuConfig;
  23 use PVE::QemuServer::CPUConfig;
  24 use PVE::QemuServer::Drive;
  25 use PVE::QemuServer::Helpers qw(min_version);
  26 use PVE::QemuServer::Machine;
  27 use PVE::QemuServer::Monitor qw(mon_cmd);
  28 use PVE::QemuServer;
  29
  30 use PVE::AbstractMigrate;
  31 use base qw(PVE::AbstractMigrate);
  32
  33 sub fork_command_pipe {
  34     my ($self, $cmd) = @_;
  35
  36     my $reader = IO::File->new();
  37     my $writer = IO::File->new();
  38
  39     my $orig_pid = $$;
  40
  41     my $cpid;
  42
  43     eval { $cpid = open2($reader, $writer, @$cmd); };
  44
  45     my $err = $@;
  46
  47     # catch exec errors
  48     if ($orig_pid != $$) {
  49         $self->log('err', "can't fork command pipe\n");
  50         POSIX::_exit(1);
  51         kill('KILL', $$);
  52     }
  53
  54     die $err if $err;
  55
  56     return { writer => $writer, reader => $reader, pid => $cpid };
  57 }
  58
  59 sub finish_command_pipe {
  60     my ($self, $cmdpipe, $timeout) = @_;
  61
  62     my $cpid = $cmdpipe->{pid};
  63     return if !defined($cpid);
  64
  65     my $writer = $cmdpipe->{writer};
  66     my $reader = $cmdpipe->{reader};
  67
  68     $writer->close();
  69     $reader->close();
  70
  71     my $collect_child_process = sub {
  72         my $res = waitpid($cpid, WNOHANG);
  73         if (defined($res) && ($res == $cpid)) {
  74             delete $cmdpipe->{cpid};
  75             return 1;
  76         } else {
  77             return 0;
  78         }
  79      };
  80
  81     if ($timeout) {
  82         for (my $i = 0; $i < $timeout; $i++) {
  83             return if &$collect_child_process();
  84             sleep(1);
  85         }
  86     }
  87
  88     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  89     kill(15, $cpid);
  90
  91     # wait again
  92     for (my $i = 0; $i < 10; $i++) {
  93         return if &$collect_child_process();
  94         sleep(1);
  95     }
  96
  97     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  98     kill 9, $cpid;
  99     sleep 1;
 100
 101     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 102         if !&$collect_child_process();
 103 }
 104
 105 sub read_tunnel {
 106     my ($self, $tunnel, $timeout) = @_;
 107
 108     $timeout = 60 if !defined($timeout);
 109
 110     my $reader = $tunnel->{reader};
 111
 112     my $output;
 113     eval {
 114         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 115     };
 116     die "reading from tunnel failed: $@\n" if $@;
 117
 118     chomp $output;
 119
 120     return $output;
 121 }
 122
 123 sub write_tunnel {
 124     my ($self, $tunnel, $timeout, $command) = @_;
 125
 126     $timeout = 60 if !defined($timeout);
 127
 128     my $writer = $tunnel->{writer};
 129
 130     eval {
 131         PVE::Tools::run_with_timeout($timeout, sub {
 132             print $writer "$command\n";
 133             $writer->flush();
 134         });
 135     };
 136     die "writing to tunnel failed: $@\n" if $@;
 137
 138     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 139         my $res = eval { $self->read_tunnel($tunnel, 10); };
 140         die "no reply to command '$command': $@\n" if $@;
 141
 142         if ($res eq 'OK') {
 143             return;
 144         } else {
 145             die "tunnel replied '$res' to command '$command'\n";
 146         }
 147     }
 148 }
 149
 150 sub fork_tunnel {
 151     my ($self, $ssh_forward_info) = @_;
 152
 153     my @localtunnelinfo = ();
 154     foreach my $addr (@$ssh_forward_info) {
 155         push @localtunnelinfo, '-L', $addr;
 156     }
 157
 158     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 159
 160     my $tunnel = $self->fork_command_pipe($cmd);
 161
 162     eval {
 163         my $helo = $self->read_tunnel($tunnel, 60);
 164         die "no reply\n" if !$helo;
 165         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 166         die "got strange reply from mtunnel ('$helo')\n"
 167             if $helo !~ m/^tunnel online$/;
 168     };
 169     my $err = $@;
 170
 171     eval {
 172         my $ver = $self->read_tunnel($tunnel, 10);
 173         if ($ver =~ /^ver (\d+)$/) {
 174             $tunnel->{version} = $1;
 175             $self->log('info', "ssh tunnel $ver\n");
 176         } else {
 177             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 178         }
 179     };
 180
 181     if ($err) {
 182         $self->finish_command_pipe($tunnel);
 183         die "can't open migration tunnel - $err";
 184     }
 185     return $tunnel;
 186 }
 187
 188 sub finish_tunnel {
 189     my ($self, $tunnel) = @_;
 190
 191     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 192     my $err = $@;
 193
 194     $self->finish_command_pipe($tunnel, 30);
 195
 196     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 197         # ssh does not clean up on local host
 198         my $cmd = ['rm', '-f', @$unix_sockets];
 199         PVE::Tools::run_command($cmd);
 200
 201         # .. and just to be sure check on remote side
 202         unshift @{$cmd}, @{$self->{rem_ssh}};
 203         PVE::Tools::run_command($cmd);
 204     }
 205
 206     die $err if $err;
 207 }
 208
 209 sub start_remote_tunnel {
 210     my ($self, $raddr, $rport, $ruri, $unix_socket_info) = @_;
 211
 212     my $nodename = PVE::INotify::nodename();
 213     my $migration_type = $self->{opts}->{migration_type};
 214
 215     if ($migration_type eq 'secure') {
 216
 217         if ($ruri =~ /^unix:/) {
 218             my $ssh_forward_info = ["$raddr:$raddr"];
 219             $unix_socket_info->{$raddr} = 1;
 220
 221             my $unix_sockets = [ keys %$unix_socket_info ];
 222             for my $sock (@$unix_sockets) {
 223                 push @$ssh_forward_info, "$sock:$sock";
 224                 unlink $sock;
 225             }
 226
 227             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 228
 229             my $unix_socket_try = 0; # wait for the socket to become ready
 230             while ($unix_socket_try <= 100) {
 231                 $unix_socket_try++;
 232                 my $available = 0;
 233                 foreach my $sock (@$unix_sockets) {
 234                     if (-S $sock) {
 235                         $available++;
 236                     }
 237                 }
 238
 239                 if ($available == @$unix_sockets) {
 240                     last;
 241                 }
 242
 243                 usleep(50000);
 244             }
 245             if ($unix_socket_try > 100) {
 246                 $self->{errors} = 1;
 247                 $self->finish_tunnel($self->{tunnel});
 248                 die "Timeout, migration socket $ruri did not get ready";
 249             }
 250             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 251
 252         } elsif ($ruri =~ /^tcp:/) {
 253             my $ssh_forward_info = [];
 254             if ($raddr eq "localhost") {
 255                 # for backwards compatibility with older qemu-server versions
 256                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 257                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 258                 push @$ssh_forward_info, "$lport:localhost:$rport";
 259             }
 260
 261             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 262
 263         } else {
 264             die "unsupported protocol in migration URI: $ruri\n";
 265         }
 266     } else {
 267         #fork tunnel for insecure migration, to send faster commands like resume
 268         $self->{tunnel} = $self->fork_tunnel();
 269     }
 270 }
 271
 272 sub lock_vm {
 273     my ($self, $vmid, $code, @param) = @_;
 274
 275     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 276 }
 277
 278 sub prepare {
 279     my ($self, $vmid) = @_;
 280
 281     my $online = $self->{opts}->{online};
 282
 283     my $storecfg = $self->{storecfg} = PVE::Storage::config();
 284
 285     # test if VM exists
 286     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 287
 288     my $repl_conf = PVE::ReplicationConfig->new();
 289     $self->{replication_jobcfg} = $repl_conf->find_local_replication_job($vmid, $self->{node});
 290     $self->{is_replicated} = $repl_conf->check_for_existing_jobs($vmid, 1);
 291
 292     if ($self->{replication_jobcfg} && defined($self->{replication_jobcfg}->{remove_job})) {
 293         die "refusing to migrate replicated VM whose replication job is marked for removal\n";
 294     }
 295
 296     PVE::QemuConfig->check_lock($conf);
 297
 298     my $running = 0;
 299     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 300         die "can't migrate running VM without --online\n" if !$online;
 301         $running = $pid;
 302
 303         if ($self->{is_replicated} && !$self->{replication_jobcfg}) {
 304             if ($self->{opts}->{force}) {
 305                 $self->log('warn', "WARNING: Node '$self->{node}' is not a replication target. Existing " .
 306                                    "replication jobs will fail after migration!\n");
 307             } else {
 308                 die "Cannot live-migrate replicated VM to node '$self->{node}' - not a replication " .
 309                     "target. Use 'force' to override.\n";
 310             }
 311         }
 312
 313         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 314
 315         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 316         # Since the parameter itself contains no reference to a custom model,
 317         # this makes migration independent of changes to "cpu-models.conf".
 318         if ($conf->{cpu}) {
 319             my $cpuconf = PVE::JSONSchema::parse_property_string('pve-cpu-conf', $conf->{cpu});
 320             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 321                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 322             }
 323         }
 324     }
 325
 326     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 327     if (scalar @$loc_res) {
 328         if ($self->{running} || !$self->{opts}->{force}) {
 329             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 330         } else {
 331             $self->log('info', "migrating VM which uses local devices");
 332         }
 333     }
 334
 335     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 336     foreach my $volid (@$vollist) {
 337         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 338
 339         # check if storage is available on both nodes
 340         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 341
 342         my $scfg = PVE::Storage::storage_check_enabled($storecfg, $sid);
 343         my $target_scfg = PVE::Storage::storage_check_enabled(
 344             $storecfg,
 345             $targetsid,
 346             $self->{node},
 347         );
 348         my ($vtype) = PVE::Storage::parse_volname($storecfg, $volid);
 349
 350         die "$volid: content type '$vtype' is not available on storage '$targetsid'\n"
 351             if !$target_scfg->{content}->{$vtype};
 352
 353         if ($scfg->{shared}) {
 354             # PVE::Storage::activate_storage checks this for non-shared storages
 355             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 356             warn "Used shared storage '$sid' is not online on source node!\n"
 357                 if !$plugin->check_connection($sid, $scfg);
 358         }
 359     }
 360
 361     # test ssh connection
 362     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 363     eval { $self->cmd_quiet($cmd); };
 364     die "Can't connect to destination address using public key\n" if $@;
 365
 366     return $running;
 367 }
 368
 369 sub scan_local_volumes {
 370     my ($self, $vmid) = @_;
 371
 372     my $conf = $self->{vmconf};
 373
 374     # local volumes which have been copied
 375     # and their old_id => new_id pairs
 376     $self->{volume_map} = {};
 377     $self->{local_volumes} = {};
 378
 379     my $storecfg = $self->{storecfg};
 380     eval {
 381
 382         # found local volumes and their origin
 383         my $local_volumes = $self->{local_volumes};
 384         my $local_volumes_errors = {};
 385         my $other_errors = [];
 386         my $abort = 0;
 387
 388         my $log_error = sub {
 389             my ($msg, $volid) = @_;
 390
 391             if (defined($volid)) {
 392                 $local_volumes_errors->{$volid} = $msg;
 393             } else {
 394                 push @$other_errors, $msg;
 395             }
 396             $abort = 1;
 397         };
 398
 399         my @sids = PVE::Storage::storage_ids($storecfg);
 400         foreach my $storeid (@sids) {
 401             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 402             next if $scfg->{shared};
 403             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 404
 405             # get list from PVE::Storage (for unused volumes)
 406             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid, undef, 'images');
 407
 408             next if @{$dl->{$storeid}} == 0;
 409
 410             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 411             # check if storage is available on target node
 412             my $target_scfg = PVE::Storage::storage_check_enabled(
 413                 $storecfg,
 414                 $targetsid,
 415                 $self->{node},
 416             );
 417
 418             die "content type 'images' is not available on storage '$targetsid'\n"
 419                 if !$target_scfg->{content}->{images};
 420
 421             my $bwlimit = PVE::Storage::get_bandwidth_limit(
 422                 'migration',
 423                 [$targetsid, $storeid],
 424                 $self->{opts}->{bwlimit},
 425             );
 426
 427             PVE::Storage::foreach_volid($dl, sub {
 428                 my ($volid, $sid, $volinfo) = @_;
 429
 430                 $local_volumes->{$volid}->{ref} = 'storage';
 431                 $local_volumes->{$volid}->{size} = $volinfo->{size};
 432                 $local_volumes->{$volid}->{targetsid} = $targetsid;
 433                 $local_volumes->{$volid}->{bwlimit} = $bwlimit;
 434
 435                 # If with_snapshots is not set for storage migrate, it tries to use
 436                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 437                 # back to qcow2 is currently not possible.
 438                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 439                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 440             });
 441         }
 442
 443         my $replicatable_volumes = !$self->{replication_jobcfg} ? {}
 444             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 445         foreach my $volid (keys %{$replicatable_volumes}) {
 446             $local_volumes->{$volid}->{replicated} = 1;
 447         }
 448
 449         my $test_volid = sub {
 450             my ($volid, $attr) = @_;
 451
 452             if ($volid =~ m|^/|) {
 453                 return if $attr->{shared};
 454                 $local_volumes->{$volid}->{ref} = 'config';
 455                 die "local file/device\n";
 456             }
 457
 458             my $snaprefs = $attr->{referenced_in_snapshot};
 459
 460             if ($attr->{cdrom}) {
 461                 if ($volid eq 'cdrom') {
 462                     my $msg = "can't migrate local cdrom drive";
 463                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 464                         my $snapnames = join(', ', sort keys %$snaprefs);
 465                         $msg .= " (referenced in snapshot - $snapnames)";
 466                     }
 467                     &$log_error("$msg\n");
 468                     return;
 469                 }
 470                 return if $volid eq 'none';
 471             }
 472
 473             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 474
 475             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 476             # check if storage is available on both nodes
 477             my $scfg = PVE::Storage::storage_check_enabled($storecfg, $sid);
 478             PVE::Storage::storage_check_enabled($storecfg, $targetsid, $self->{node});
 479
 480             return if $scfg->{shared};
 481
 482             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 483             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 484
 485             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 486
 487             $local_volumes->{$volid}->{drivename} = $attr->{drivename}
 488                 if $attr->{drivename};
 489
 490             if ($attr->{cdrom}) {
 491                 if ($volid =~ /vm-\d+-cloudinit/) {
 492                     $local_volumes->{$volid}->{ref} = 'generated';
 493                     return;
 494                 }
 495                 die "local cdrom image\n";
 496             }
 497
 498             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 499
 500             die "owned by other VM (owner = VM $owner)\n"
 501                 if !$owner || ($owner != $vmid);
 502
 503             return if $attr->{is_vmstate};
 504
 505             if (defined($snaprefs)) {
 506                 $local_volumes->{$volid}->{snapshots} = 1;
 507
 508                 # we cannot migrate shapshots on local storage
 509                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 510
 511                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 512                 if (!($scfg->{type} eq 'zfspool'
 513                     || ($scfg->{type} eq 'btrfs' && $local_volumes->{$volid}->{format} eq 'raw')
 514                     || $local_volumes->{$volid}->{format} eq 'qcow2'
 515                 )) {
 516                     die "non-migratable snapshot exists\n";
 517                 }
 518             }
 519
 520             die "referenced by linked clone(s)\n"
 521                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 522         };
 523
 524         PVE::QemuServer::foreach_volid($conf, sub {
 525             my ($volid, $attr) = @_;
 526             eval { $test_volid->($volid, $attr); };
 527             if (my $err = $@) {
 528                 &$log_error($err, $volid);
 529             }
 530         });
 531
 532         foreach my $vol (sort keys %$local_volumes) {
 533             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 534             my $ref = $local_volumes->{$vol}->{ref};
 535             if ($ref eq 'storage') {
 536                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 537             } elsif ($ref eq 'config') {
 538                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 539                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 540                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 541             } elsif ($ref eq 'snapshot') {
 542                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 543             } elsif ($ref eq 'generated') {
 544                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 545             } else {
 546                 $self->log('info', "found $type disk '$vol'\n");
 547             }
 548         }
 549
 550         foreach my $vol (sort keys %$local_volumes_errors) {
 551             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 552         }
 553         foreach my $err (@$other_errors) {
 554             $self->log('warn', "$err");
 555         }
 556
 557         if ($abort) {
 558             die "can't migrate VM - check log\n";
 559         }
 560
 561         # additional checks for local storage
 562         foreach my $volid (keys %$local_volumes) {
 563             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 564             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 565
 566             my $migratable = $scfg->{type} =~ /^(?:dir|btrfs|zfspool|lvmthin|lvm)$/;
 567
 568             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 569                 if !$migratable;
 570
 571             # image is a linked clone on local storage, se we can't migrate.
 572             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 573                 die "can't migrate '$volid' as it's a clone of '$basename'";
 574             }
 575         }
 576
 577         foreach my $volid (sort keys %$local_volumes) {
 578             my $ref = $local_volumes->{$volid}->{ref};
 579             if ($self->{running} && $ref eq 'config') {
 580                 $local_volumes->{$volid}->{migration_mode} = 'online';
 581             } elsif ($self->{running} && $ref eq 'generated') {
 582                 # offline migrate the cloud-init ISO and don't regenerate on VM start
 583                 $local_volumes->{$volid}->{migration_mode} = 'offline';
 584             } else {
 585                 $local_volumes->{$volid}->{migration_mode} = 'offline';
 586             }
 587         }
 588     };
 589     die "Problem found while scanning volumes - $@" if $@;
 590 }
 591
 592 sub handle_replication {
 593     my ($self, $vmid) = @_;
 594
 595     my $conf = $self->{vmconf};
 596     my $local_volumes = $self->{local_volumes};
 597
 598     return if !$self->{replication_jobcfg};
 599     if ($self->{running}) {
 600
 601         my $version = PVE::QemuServer::kvm_user_version();
 602         if (!min_version($version, 4, 2)) {
 603             die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 604         }
 605
 606         my @live_replicatable_volumes = $self->filter_local_volumes('online', 1);
 607         foreach my $volid (@live_replicatable_volumes) {
 608             my $drive = $local_volumes->{$volid}->{drivename};
 609             die "internal error - no drive for '$volid'\n" if !defined($drive);
 610
 611             my $bitmap = "repl_$drive";
 612
 613             # start tracking before replication to get full delta + a few duplicates
 614             $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 615             mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 616
 617             # other info comes from target node in phase 2
 618             $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 619         }
 620     }
 621     $self->log('info', "replicating disk images");
 622
 623     my $start_time = time();
 624     my $logfunc = sub { $self->log('info', shift) };
 625     my $actual_replicated_volumes = PVE::Replication::run_replication(
 626        'PVE::QemuConfig', $self->{replication_jobcfg}, $start_time, $start_time, $logfunc);
 627
 628     # extra safety check
 629     my @replicated_volumes = $self->filter_local_volumes(undef, 1);
 630     foreach my $volid (@replicated_volumes) {
 631         die "expected volume '$volid' to get replicated, but it wasn't\n"
 632             if !$actual_replicated_volumes->{$volid};
 633     }
 634 }
 635
 636 sub config_update_local_disksizes {
 637     my ($self) = @_;
 638
 639     my $conf = $self->{vmconf};
 640     my $local_volumes = $self->{local_volumes};
 641
 642     PVE::QemuConfig->foreach_volume($conf, sub {
 643         my ($key, $drive) = @_;
 644         return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 645
 646         my $volid = $drive->{file};
 647         return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 648
 649         my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $local_volumes->{$volid}->{size});
 650         if (defined($updated)) {
 651             $conf->{$key} = PVE::QemuServer::print_drive($updated);
 652             $self->log('info', "drive '$key': $msg");
 653         }
 654     });
 655
 656     # we want to set the efidisk size in the config to the size of the
 657     # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 658     if (defined($conf->{efidisk0})) {
 659         PVE::QemuServer::update_efidisk_size($conf);
 660     }
 661 }
 662
 663 sub filter_local_volumes {
 664     my ($self, $migration_mode, $replicated) = @_;
 665
 666     my $volumes = $self->{local_volumes};
 667     my @filtered_volids;
 668
 669     foreach my $volid (sort keys %{$volumes}) {
 670         next if defined($migration_mode) && safe_string_ne($volumes->{$volid}->{migration_mode}, $migration_mode);
 671         next if defined($replicated) && safe_boolean_ne($volumes->{$volid}->{replicated}, $replicated);
 672         push @filtered_volids, $volid;
 673     }
 674
 675     return @filtered_volids;
 676 }
 677
 678 sub sync_offline_local_volumes {
 679     my ($self) = @_;
 680
 681     my $local_volumes = $self->{local_volumes};
 682     my @volids = $self->filter_local_volumes('offline', 0);
 683
 684     my $storecfg = $self->{storecfg};
 685     my $opts = $self->{opts};
 686
 687     $self->log('info', "copying local disk images") if scalar(@volids);
 688
 689     foreach my $volid (@volids) {
 690         my $targetsid = $local_volumes->{$volid}->{targetsid};
 691         my $bwlimit = $local_volumes->{$volid}->{bwlimit};
 692         $bwlimit = $bwlimit * 1024 if defined($bwlimit); # storage_migrate uses bps
 693
 694         my $storage_migrate_opts = {
 695             'ratelimit_bps' => $bwlimit,
 696             'insecure' => $opts->{migration_type} eq 'insecure',
 697             'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 698             'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 699         };
 700
 701         my $logfunc = sub { $self->log('info', $_[0]); };
 702         my $new_volid = eval {
 703             PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 704                                           $targetsid, $storage_migrate_opts, $logfunc);
 705         };
 706         if (my $err = $@) {
 707             die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 708         }
 709
 710         $self->{volume_map}->{$volid} = $new_volid;
 711         $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 712
 713         eval { PVE::Storage::deactivate_volumes($storecfg, [$volid]); };
 714         if (my $err = $@) {
 715             $self->log('warn', $err);
 716         }
 717     }
 718 }
 719
 720 sub cleanup_remotedisks {
 721     my ($self) = @_;
 722
 723     my $local_volumes = $self->{local_volumes};
 724
 725     foreach my $volid (values %{$self->{volume_map}}) {
 726         # don't clean up replicated disks!
 727         next if $local_volumes->{$volid}->{replicated};
 728
 729         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
 730
 731         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 732
 733         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 734         if (my $err = $@) {
 735             $self->log('err', $err);
 736             $self->{errors} = 1;
 737         }
 738     }
 739 }
 740
 741 sub cleanup_bitmaps {
 742     my ($self) = @_;
 743     foreach my $drive (keys %{$self->{target_drive}}) {
 744         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 745         next if !$bitmap;
 746         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 747         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 748     }
 749 }
 750
 751 sub phase1 {
 752     my ($self, $vmid) = @_;
 753
 754     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 755
 756     my $conf = $self->{vmconf};
 757
 758     # set migrate lock in config file
 759     $conf->{lock} = 'migrate';
 760     PVE::QemuConfig->write_config($vmid, $conf);
 761
 762     $self->scan_local_volumes($vmid);
 763
 764     # fix disk sizes to match their actual size and write changes,
 765     # so that the target allocates the correct volumes
 766     $self->config_update_local_disksizes();
 767     PVE::QemuConfig->write_config($vmid, $conf);
 768
 769     $self->handle_replication($vmid);
 770
 771     $self->sync_offline_local_volumes();
 772 };
 773
 774 sub phase1_cleanup {
 775     my ($self, $vmid, $err) = @_;
 776
 777     $self->log('info', "aborting phase 1 - cleanup resources");
 778
 779     my $conf = $self->{vmconf};
 780     delete $conf->{lock};
 781     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 782     if (my $err = $@) {
 783         $self->log('err', $err);
 784     }
 785
 786     eval { $self->cleanup_remotedisks() };
 787     if (my $err = $@) {
 788         $self->log('err', $err);
 789     }
 790
 791     eval { $self->cleanup_bitmaps() };
 792     if (my $err =$@) {
 793         $self->log('err', $err);
 794     }
 795 }
 796
 797 sub phase2 {
 798     my ($self, $vmid) = @_;
 799
 800     my $conf = $self->{vmconf};
 801     my $local_volumes = $self->{local_volumes};
 802     my @online_local_volumes = $self->filter_local_volumes('online');
 803
 804     $self->{storage_migration} = 1 if scalar(@online_local_volumes);
 805
 806     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 807
 808     my $raddr;
 809     my $rport;
 810     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 811     my $nodename = PVE::INotify::nodename();
 812
 813     ## start on remote node
 814     my $cmd = [@{$self->{rem_ssh}}];
 815
 816     my $spice_ticket;
 817     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 818         my $res = mon_cmd($vmid, 'query-spice');
 819         $spice_ticket = $res->{ticket};
 820     }
 821
 822     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 823
 824     my $migration_type = $self->{opts}->{migration_type};
 825
 826     push @$cmd, '--migration_type', $migration_type;
 827
 828     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 829       if $self->{opts}->{migration_network};
 830
 831     if ($migration_type eq 'insecure') {
 832         push @$cmd, '--stateuri', 'tcp';
 833     } else {
 834         push @$cmd, '--stateuri', 'unix';
 835     }
 836
 837     if ($self->{forcemachine}) {
 838         push @$cmd, '--machine', $self->{forcemachine};
 839     }
 840
 841     if ($self->{forcecpu}) {
 842         push @$cmd, '--force-cpu', $self->{forcecpu};
 843     }
 844
 845     if ($self->{storage_migration}) {
 846         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 847     }
 848
 849     my $spice_port;
 850     my $unix_socket_info = {};
 851     # version > 0 for unix socket support
 852     my $nbd_protocol_version = 1;
 853     my $input = "nbd_protocol_version: $nbd_protocol_version\n";
 854     $input .= "spice_ticket: $spice_ticket\n" if $spice_ticket;
 855
 856     my @online_replicated_volumes = $self->filter_local_volumes('online', 1);
 857     foreach my $volid (@online_replicated_volumes) {
 858         $input .= "replicated_volume: $volid\n";
 859     }
 860
 861     my $handle_storage_migration_listens = sub {
 862         my ($drive_key, $drivestr, $nbd_uri) = @_;
 863
 864         $self->{stopnbd} = 1;
 865         $self->{target_drive}->{$drive_key}->{drivestr} = $drivestr;
 866         $self->{target_drive}->{$drive_key}->{nbd_uri} = $nbd_uri;
 867
 868         my $source_drive = PVE::QemuServer::parse_drive($drive_key, $conf->{$drive_key});
 869         my $target_drive = PVE::QemuServer::parse_drive($drive_key, $drivestr);
 870         my $source_volid = $source_drive->{file};
 871         my $target_volid = $target_drive->{file};
 872
 873         $self->{volume_map}->{$source_volid} = $target_volid;
 874         $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 875     };
 876
 877     my $target_replicated_volumes = {};
 878
 879     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 880     # instead we pipe it through STDIN
 881     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 882         my $line = shift;
 883
 884         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 885             $raddr = $1;
 886             $rport = int($2);
 887             $ruri = "tcp:$raddr:$rport";
 888         }
 889         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 890             $raddr = $1;
 891             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 892             $ruri = "unix:$raddr";
 893         }
 894         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 895             $raddr = "localhost";
 896             $rport = int($1);
 897             $ruri = "tcp:$raddr:$rport";
 898         }
 899         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 900             $spice_port = int($1);
 901         }
 902         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 903             my $drivestr = $4;
 904             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 905             my $targetdrive = $3;
 906             $targetdrive =~ s/drive-//g;
 907
 908             $handle_storage_migration_listens->($targetdrive, $drivestr, $nbd_uri);
 909         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 910             my $drivestr = $4;
 911             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 912             my $nbd_unix_addr = $1;
 913             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 914             my $targetdrive = $3;
 915             $targetdrive =~ s/drive-//g;
 916
 917             $handle_storage_migration_listens->($targetdrive, $drivestr, $nbd_uri);
 918             $unix_socket_info->{$nbd_unix_addr} = 1;
 919         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 920             my $drive = $1;
 921             my $volid = $2;
 922             $target_replicated_volumes->{$volid} = $drive;
 923         } elsif ($line =~ m/^QEMU: (.*)$/) {
 924             $self->log('info', "[$self->{node}] $1\n");
 925         }
 926     }, errfunc => sub {
 927         my $line = shift;
 928         $self->log('info', "[$self->{node}] $line");
 929     }, noerr => 1);
 930
 931     die "remote command failed with exit code $exitcode\n" if $exitcode;
 932
 933     die "unable to detect remote migration address\n" if !$raddr;
 934
 935     if (scalar(keys %$target_replicated_volumes) != scalar(@online_replicated_volumes)) {
 936         die "number of replicated disks on source and target node do not match - target node too old?\n"
 937     }
 938
 939     $self->log('info', "start remote tunnel");
 940     $self->start_remote_tunnel($raddr, $rport, $ruri, $unix_socket_info);
 941
 942     if ($self->{storage_migration}) {
 943         $self->{storage_migration_jobs} = {};
 944         $self->log('info', "starting storage migration");
 945
 946         die "The number of local disks does not match between the source and the destination.\n"
 947             if (scalar(keys %{$self->{target_drive}}) != scalar(@online_local_volumes));
 948         foreach my $drive (keys %{$self->{target_drive}}){
 949             my $target = $self->{target_drive}->{$drive};
 950             my $nbd_uri = $target->{nbd_uri};
 951
 952             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 953             my $source_volid = $source_drive->{file};
 954
 955             my $bwlimit = $local_volumes->{$source_volid}->{bwlimit};
 956             my $bitmap = $target->{bitmap};
 957
 958             $self->log('info', "$drive: start migration to $nbd_uri");
 959             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 960         }
 961     }
 962
 963     $self->log('info', "starting online/live migration on $ruri");
 964     $self->{livemigration} = 1;
 965
 966     # load_defaults
 967     my $defaults = PVE::QemuServer::load_defaults();
 968
 969     $self->log('info', "set migration capabilities");
 970     eval { PVE::QemuServer::set_migration_caps($vmid) };
 971     warn $@ if $@;
 972
 973     my $qemu_migrate_params = {};
 974
 975     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 976     # migrate_speed parameter in qm.conf - take the lower of the two.
 977     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $self->{opts}->{bwlimit}) // 0;
 978     my $migrate_speed = $conf->{migrate_speed} // 0;
 979     $migrate_speed *= 1024; # migrate_speed is in MB/s, bwlimit in KB/s
 980
 981     if ($bwlimit && $migrate_speed) {
 982         $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 983     } else {
 984         $migrate_speed ||= $bwlimit;
 985     }
 986     $migrate_speed ||= ($defaults->{migrate_speed} || 0) * 1024;
 987
 988     if ($migrate_speed) {
 989         $migrate_speed *= 1024; # qmp takes migrate_speed in B/s.
 990         $self->log('info', "migration speed limit: ". render_bytes($migrate_speed, 1) ."/s");
 991     } else {
 992         # always set migrate speed as QEMU default to 128 MiBps == 1 Gbps, use 16 GiBps == 128 Gbps
 993         $migrate_speed = (16 << 30);
 994     }
 995     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 996
 997     my $migrate_downtime = $defaults->{migrate_downtime};
 998     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 999     # migrate-set-parameters expects limit in ms
1000     $migrate_downtime *= 1000;
1001     $self->log('info', "migration downtime limit: $migrate_downtime ms");
1002     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
1003
1004     # set cachesize to 10% of the total memory
1005     my $memory =  $conf->{memory} || $defaults->{memory};
1006     my $cachesize = int($memory * 1048576 / 10);
1007     $cachesize = round_powerof2($cachesize);
1008
1009     $self->log('info', "migration cachesize: " . render_bytes($cachesize, 1));
1010     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
1011
1012     $self->log('info', "set migration parameters");
1013     eval {
1014         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
1015     };
1016     $self->log('info', "migrate-set-parameters error: $@") if $@;
1017
1018     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
1019         my $rpcenv = PVE::RPCEnvironment::get();
1020         my $authuser = $rpcenv->get_user();
1021
1022         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
1023
1024         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
1025         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
1026
1027         $self->log('info', "spice client_migrate_info");
1028
1029         eval {
1030             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
1031                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
1032                                                 'cert-subject' => $subject);
1033         };
1034         $self->log('info', "client_migrate_info error: $@") if $@;
1035
1036     }
1037
1038     my $start = time();
1039
1040     $self->log('info', "start migrate command to $ruri");
1041     eval {
1042         mon_cmd($vmid, "migrate", uri => $ruri);
1043     };
1044     my $merr = $@;
1045     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
1046
1047     my $last_mem_transferred = 0;
1048     my $usleep = 1000000;
1049     my $i = 0;
1050     my $err_count = 0;
1051     my $lastrem = undef;
1052     my $downtimecounter = 0;
1053     while (1) {
1054         $i++;
1055         my $avglstat = $last_mem_transferred ? $last_mem_transferred / $i : 0;
1056
1057         usleep($usleep);
1058
1059         my $stat = eval { mon_cmd($vmid, "query-migrate") };
1060         if (my $err = $@) {
1061             $err_count++;
1062             warn "query migrate failed: $err\n";
1063             $self->log('info', "query migrate failed: $err");
1064             if ($err_count <= 5) {
1065                 usleep(1_000_000);
1066                 next;
1067             }
1068             die "too many query migrate failures - aborting\n";
1069         }
1070
1071         my $status = $stat->{status};
1072         if (defined($status) && $status =~ m/^(setup)$/im) {
1073             sleep(1);
1074             next;
1075         }
1076
1077         if (!defined($status) || $status !~ m/^(active|completed|failed|cancelled)$/im) {
1078             die $merr if $merr;
1079             die "unable to parse migration status '$status' - aborting\n";
1080         }
1081         $merr = undef;
1082         $err_count = 0;
1083
1084         my $memstat = $stat->{ram};
1085
1086         if ($status eq 'completed') {
1087             my $delay = time() - $start;
1088             if ($delay > 0) {
1089                 my $total = $memstat->{total} || 0;
1090                 my $avg_speed = render_bytes($total / $delay, 1);
1091                 my $downtime = $stat->{downtime} || 0;
1092                 $self->log('info', "average migration speed: $avg_speed/s - downtime $downtime ms");
1093             }
1094         }
1095
1096         if ($status eq 'failed' || $status eq 'cancelled') {
1097             $self->log('info', "migration status error: $status");
1098             die "aborting\n"
1099         }
1100
1101         if ($status ne 'active') {
1102             $self->log('info', "migration status: $status");
1103             last;
1104         }
1105
1106         if ($memstat->{transferred} ne $last_mem_transferred) {
1107             my $trans = $memstat->{transferred} || 0;
1108             my $rem = $memstat->{remaining} || 0;
1109             my $total = $memstat->{total} || 0;
1110             my $speed = ($memstat->{'pages-per-second'} // 0) * ($memstat->{'page-size'} // 0);
1111             my $dirty_rate = ($memstat->{'dirty-pages-rate'} // 0) * ($memstat->{'page-size'} // 0);
1112
1113             # reduce sleep if remainig memory is lower than the average transfer speed
1114             $usleep = 100_000 if $avglstat && $rem < $avglstat;
1115
1116             # also reduce loggin if we poll more frequent
1117             my $should_log = $usleep > 100_000 ? 1 : ($i % 10) == 0;
1118
1119             my $total_h = render_bytes($total, 1);
1120             my $transferred_h = render_bytes($trans, 1);
1121             my $speed_h = render_bytes($speed, 1);
1122
1123             my $progress = "transferred $transferred_h of $total_h VM-state, ${speed_h}/s";
1124
1125             if ($dirty_rate > $speed) {
1126                 my $dirty_rate_h = render_bytes($dirty_rate, 1);
1127                 $progress .= ", VM dirties lots of memory: $dirty_rate_h/s";
1128             }
1129
1130             $self->log('info', "migration $status, $progress") if $should_log;
1131
1132             my $xbzrle = $stat->{"xbzrle-cache"} || {};
1133             my ($xbzrlebytes, $xbzrlepages) = $xbzrle->@{'bytes', 'pages'};
1134             if ($xbzrlebytes || $xbzrlepages) {
1135                 my $bytes_h = render_bytes($xbzrlebytes, 1);
1136
1137                 my $msg = "send updates to $xbzrlepages pages in $bytes_h encoded memory";
1138
1139                 $msg .= sprintf(", cache-miss %.2f%%", $xbzrle->{'cache-miss-rate'} * 100)
1140                     if $xbzrle->{'cache-miss-rate'};
1141
1142                 $msg .= ", overflow $xbzrle->{overflow}" if $xbzrle->{overflow};
1143
1144                 $self->log('info', "xbzrle: $msg") if $should_log;
1145             }
1146
1147             if (($lastrem && $rem > $lastrem) || ($rem == 0)) {
1148                 $downtimecounter++;
1149             }
1150             $lastrem = $rem;
1151
1152             if ($downtimecounter > 5) {
1153                 $downtimecounter = 0;
1154                 $migrate_downtime *= 2;
1155                 $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1156                 eval {
1157                     # migrate-set-parameters does not touch values not
1158                     # specified, so this only changes downtime-limit
1159                     mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1160                 };
1161                 $self->log('info', "migrate-set-parameters error: $@") if $@;
1162             }
1163         }
1164
1165         $last_mem_transferred = $memstat->{transferred};
1166     }
1167
1168     if ($self->{storage_migration}) {
1169         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1170         # to avoid it trying to re-establish it. We are in blockjob ready state,
1171         # thus, this command changes to it to blockjob complete (see qapi docs)
1172         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1173         if (my $err = $@) {
1174             die "Failed to complete storage migration: $err\n";
1175         }
1176     }
1177 }
1178
1179 sub phase2_cleanup {
1180     my ($self, $vmid, $err) = @_;
1181
1182     return if !$self->{errors};
1183     $self->{phase2errors} = 1;
1184
1185     $self->log('info', "aborting phase 2 - cleanup resources");
1186
1187     $self->log('info', "migrate_cancel");
1188     eval {
1189         mon_cmd($vmid, "migrate_cancel");
1190     };
1191     $self->log('info', "migrate_cancel error: $@") if $@;
1192
1193     my $conf = $self->{vmconf};
1194     delete $conf->{lock};
1195     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1196     if (my $err = $@) {
1197         $self->log('err', $err);
1198     }
1199
1200     # cleanup ressources on target host
1201     if ($self->{storage_migration}) {
1202         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1203         if (my $err = $@) {
1204             $self->log('err', $err);
1205         }
1206     }
1207
1208     eval { $self->cleanup_bitmaps() };
1209     if (my $err =$@) {
1210         $self->log('err', $err);
1211     }
1212
1213     my $nodename = PVE::INotify::nodename();
1214
1215     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1216     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1217     if (my $err = $@) {
1218         $self->log('err', $err);
1219         $self->{errors} = 1;
1220     }
1221
1222     # cleanup after stopping, otherwise disks might be in-use by target VM!
1223     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1224     if (my $err = $@) {
1225         $self->log('err', $err);
1226     }
1227
1228
1229     if ($self->{tunnel}) {
1230         eval { finish_tunnel($self, $self->{tunnel});  };
1231         if (my $err = $@) {
1232             $self->log('err', $err);
1233             $self->{errors} = 1;
1234         }
1235     }
1236 }
1237
1238 sub phase3 {
1239     my ($self, $vmid) = @_;
1240
1241     return;
1242 }
1243
1244 sub phase3_cleanup {
1245     my ($self, $vmid, $err) = @_;
1246
1247     my $conf = $self->{vmconf};
1248     return if $self->{phase2errors};
1249
1250     my $tunnel = $self->{tunnel};
1251
1252     if ($self->{volume_map}) {
1253         my $target_drives = $self->{target_drive};
1254
1255         # FIXME: for NBD storage migration we now only update the volid, and
1256         # not the full drivestr from the target node. Workaround that until we
1257         # got some real rescan, to avoid things like wrong format in the drive
1258         delete $conf->{$_} for keys %$target_drives;
1259         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1260
1261         for my $drive (keys %$target_drives) {
1262             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1263         }
1264         PVE::QemuConfig->write_config($vmid, $conf);
1265     }
1266
1267     # transfer replication state before move config
1268     $self->transfer_replication_state() if $self->{is_replicated};
1269     PVE::QemuConfig->move_config_to_node($vmid, $self->{node});
1270     $self->switch_replication_job_target() if $self->{is_replicated};
1271
1272     if ($self->{livemigration}) {
1273         if ($self->{stopnbd}) {
1274             $self->log('info', "stopping NBD storage migration server on target.");
1275             # stop nbd server on remote vm - requirement for resume since 2.9
1276             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1277
1278             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1279             if (my $err = $@) {
1280                 $self->log('err', $err);
1281                 $self->{errors} = 1;
1282             }
1283         }
1284
1285         # config moved and nbd server stopped - now we can resume vm on target
1286         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1287             eval {
1288                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1289             };
1290             if (my $err = $@) {
1291                 $self->log('err', $err);
1292                 $self->{errors} = 1;
1293             }
1294         } else {
1295             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1296             my $logf = sub {
1297                 my $line = shift;
1298                 $self->log('err', $line);
1299             };
1300             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1301             if (my $err = $@) {
1302                 $self->log('err', $err);
1303                 $self->{errors} = 1;
1304             }
1305         }
1306
1307         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1308             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1309             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1310         }
1311     }
1312
1313     # close tunnel on successful migration, on error phase2_cleanup closed it
1314     if ($tunnel) {
1315         eval { finish_tunnel($self, $tunnel);  };
1316         if (my $err = $@) {
1317             $self->log('err', $err);
1318             $self->{errors} = 1;
1319         }
1320     }
1321
1322     eval {
1323         my $timer = 0;
1324         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1325             $self->log('info', "Waiting for spice server migration");
1326             while (1) {
1327                 my $res = mon_cmd($vmid, 'query-spice');
1328                 last if int($res->{'migrated'}) == 1;
1329                 last if $timer > 50;
1330                 $timer ++;
1331                 usleep(200000);
1332             }
1333         }
1334     };
1335
1336     # always stop local VM
1337     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1338     if (my $err = $@) {
1339         $self->log('err', "stopping vm failed - $err");
1340         $self->{errors} = 1;
1341     }
1342
1343     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1344     eval {
1345         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1346         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1347     };
1348     if (my $err = $@) {
1349         $self->log('err', $err);
1350         $self->{errors} = 1;
1351     }
1352
1353     my @not_replicated_volumes = $self->filter_local_volumes(undef, 0);
1354
1355     # destroy local copies
1356     foreach my $volid (@not_replicated_volumes) {
1357         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1358         if (my $err = $@) {
1359             $self->log('err', "removing local copy of '$volid' failed - $err");
1360             $self->{errors} = 1;
1361             last if $err =~ /^interrupted by signal$/;
1362         }
1363     }
1364
1365     # clear migrate lock
1366     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1367     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1368 }
1369
1370 sub final_cleanup {
1371     my ($self, $vmid) = @_;
1372
1373     # nothing to do
1374 }
1375
1376 sub round_powerof2 {
1377     return 1 if $_[0] < 2;
1378     return 2 << int(log($_[0]-1)/log(2));
1379 }
1380
1381 1;