PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use PVE::INotify;
   9 use PVE::Tools;
  10 use PVE::Cluster;
  11 use PVE::Storage;
  12 use PVE::QemuServer;
  13 use Time::HiRes qw( usleep );
  14
  15 use base qw(PVE::AbstractMigrate);
  16
  17 sub fork_command_pipe {
  18     my ($self, $cmd) = @_;
  19
  20     my $reader = IO::File->new();
  21     my $writer = IO::File->new();
  22
  23     my $orig_pid = $$;
  24
  25     my $cpid;
  26
  27     eval { $cpid = open2($reader, $writer, @$cmd); };
  28
  29     my $err = $@;
  30
  31     # catch exec errors
  32     if ($orig_pid != $$) {
  33         $self->log('err', "can't fork command pipe\n");
  34         POSIX::_exit(1);
  35         kill('KILL', $$);
  36     }
  37
  38     die $err if $err;
  39
  40     return { writer => $writer, reader => $reader, pid => $cpid };
  41 }
  42
  43 sub finish_command_pipe {
  44     my ($self, $cmdpipe, $timeout) = @_;
  45
  46     my $writer = $cmdpipe->{writer};
  47     my $reader = $cmdpipe->{reader};
  48
  49     $writer->close();
  50     $reader->close();
  51
  52     my $cpid = $cmdpipe->{pid};
  53
  54     if ($timeout) {
  55         for (my $i = 0; $i < $timeout; $i++) {
  56             return if !PVE::ProcFSTools::check_process_running($cpid);
  57             sleep(1);
  58         }
  59     }
  60
  61     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  62     kill(15, $cpid);
  63
  64     # wait again
  65     for (my $i = 0; $i < 10; $i++) {
  66         return if !PVE::ProcFSTools::check_process_running($cpid);
  67         sleep(1);
  68     }
  69
  70     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  71     kill 9, $cpid;
  72     sleep 1;
  73 }
  74
  75 sub fork_tunnel {
  76     my ($self, $nodeip, $lport, $rport) = @_;
  77
  78     my $cmd = [@{$self->{rem_ssh}}, '-L', "$lport:localhost:$rport",
  79                'qm', 'mtunnel' ];
  80
  81     my $tunnel = $self->fork_command_pipe($cmd);
  82
  83     my $reader = $tunnel->{reader};
  84
  85     my $helo;
  86     eval {
  87         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
  88         die "no reply\n" if !$helo;
  89         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
  90         die "got strange reply from mtunnel ('$helo')\n"
  91             if $helo !~ m/^tunnel online$/;
  92     };
  93     my $err = $@;
  94
  95     if ($err) {
  96         $self->finish_command_pipe($tunnel);
  97         die "can't open migration tunnel - $err";
  98     }
  99     return $tunnel;
 100 }
 101
 102 sub finish_tunnel {
 103     my ($self, $tunnel) = @_;
 104
 105     my $writer = $tunnel->{writer};
 106
 107     eval {
 108         PVE::Tools::run_with_timeout(30, sub {
 109             print $writer "quit\n";
 110             $writer->flush();
 111         });
 112     };
 113     my $err = $@;
 114
 115     $self->finish_command_pipe($tunnel, 30);
 116
 117     die $err if $err;
 118 }
 119
 120 sub lock_vm {
 121     my ($self, $vmid, $code, @param) = @_;
 122
 123     return PVE::QemuServer::lock_config($vmid, $code, @param);
 124 }
 125
 126 sub prepare {
 127     my ($self, $vmid) = @_;
 128
 129     my $online = $self->{opts}->{online};
 130
 131     $self->{storecfg} = PVE::Storage::config();
 132
 133     # test is VM exist
 134     my $conf = $self->{vmconf} = PVE::QemuServer::load_config($vmid);
 135
 136     PVE::QemuServer::check_lock($conf);
 137
 138     my $running = 0;
 139     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 140         die "cant migrate running VM without --online\n" if !$online;
 141         $running = $pid;
 142         $self->{forcemachine} = PVE::QemuServer::get_current_qemu_machine($vmid);
 143     }
 144
 145     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 146         if ($self->{running} || !$self->{opts}->{force}) {
 147             die "can't migrate VM which uses local devices\n";
 148         } else {
 149             $self->log('info', "migrating VM which uses local devices");
 150         }
 151     }
 152
 153     # activate volumes
 154     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 155     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 156
 157     # fixme: check if storage is available on both nodes
 158
 159     # test ssh connection
 160     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 161     eval { $self->cmd_quiet($cmd); };
 162     die "Can't connect to destination address using public key\n" if $@;
 163
 164     return $running;
 165 }
 166
 167 sub sync_disks {
 168     my ($self, $vmid) = @_;
 169
 170     $self->log('info', "copying disk images");
 171
 172     my $conf = $self->{vmconf};
 173
 174     $self->{volumes} = [];
 175
 176     my $res = [];
 177
 178     eval {
 179
 180         my $volhash = {};
 181         my $cdromhash = {};
 182
 183         my $sharedvm = 1;
 184
 185         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 186         foreach my $storeid (@sids) {
 187             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 188             next if $scfg->{shared};
 189             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 190
 191             # get list from PVE::Storage (for unused volumes)
 192             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 193             PVE::Storage::foreach_volid($dl, sub {
 194                 my ($volid, $sid, $volname) = @_;
 195
 196                 # check if storage is available on target node
 197                 PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 198
 199                 $volhash->{$volid} = 1;
 200                 $sharedvm = 0; # there is a non-shared disk
 201             });
 202         }
 203
 204         # and add used, owned/non-shared disks (just to be sure we have all)
 205
 206         PVE::QemuServer::foreach_volid($conf, sub {
 207             my ($volid, $is_cdrom) = @_;
 208
 209             return if !$volid;
 210
 211             die "cant migrate local file/device '$volid'\n" if $volid =~ m|^/|;
 212
 213             if ($is_cdrom) {
 214                 die "cant migrate local cdrom drive\n" if $volid eq 'cdrom';
 215                 return if $volid eq 'none';
 216                 $cdromhash->{$volid} = 1;
 217             }
 218
 219             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 220
 221             # check if storage is available on both nodes
 222             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 223             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 224
 225             return if $scfg->{shared};
 226
 227             die "can't migrate local cdrom '$volid'\n" if $cdromhash->{$volid};
 228
 229             $sharedvm = 0;
 230
 231             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 232
 233             die "can't migrate volume '$volid' - owned by other VM (owner = VM $owner)\n"
 234                 if !$owner || ($owner != $self->{vmid});
 235
 236             $volhash->{$volid} = 1;
 237         });
 238
 239         if ($self->{running} && !$sharedvm) {
 240             die "can't do online migration - VM uses local disks\n";
 241         }
 242
 243         # do some checks first
 244         foreach my $volid (keys %$volhash) {
 245             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 246             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 247
 248             die "can't migrate '$volid' - storagy type '$scfg->{type}' not supported\n"
 249                 if $scfg->{type} ne 'dir';
 250
 251             # if file, check if a backing file exist
 252             if (($scfg->{type} eq 'dir') && (!$sharedvm)) {
 253                 my (undef, undef, undef, $parent) = PVE::Storage::volume_size_info($self->{storecfg}, $volid, 1);
 254                 die "can't migrate '$volid' as it's a clone of '$parent'" if $parent;
 255             }
 256         }
 257
 258         foreach my $volid (keys %$volhash) {
 259             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 260             push @{$self->{volumes}}, $volid;
 261             PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 262         }
 263     };
 264     die "Failed to sync data - $@" if $@;
 265 }
 266
 267 sub phase1 {
 268     my ($self, $vmid) = @_;
 269
 270     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 271
 272     my $conf = $self->{vmconf};
 273
 274     # set migrate lock in config file
 275     $conf->{lock} = 'migrate';
 276     PVE::QemuServer::update_config_nolock($vmid, $conf, 1);
 277
 278     sync_disks($self, $vmid);
 279
 280 };
 281
 282 sub phase1_cleanup {
 283     my ($self, $vmid, $err) = @_;
 284
 285     $self->log('info', "aborting phase 1 - cleanup resources");
 286
 287     my $conf = $self->{vmconf};
 288     delete $conf->{lock};
 289     eval { PVE::QemuServer::update_config_nolock($vmid, $conf, 1) };
 290     if (my $err = $@) {
 291         $self->log('err', $err);
 292     }
 293
 294     if ($self->{volumes}) {
 295         foreach my $volid (@{$self->{volumes}}) {
 296             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 297             # fixme: try to remove ?
 298         }
 299     }
 300 }
 301
 302 sub phase2 {
 303     my ($self, $vmid) = @_;
 304
 305     my $conf = $self->{vmconf};
 306
 307     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 308
 309     my $rport;
 310
 311     my $nodename = PVE::INotify::nodename();
 312
 313     ## start on remote node
 314     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'start',
 315                $vmid, '--stateuri', 'tcp', '--skiplock', '--migratedfrom', $nodename];
 316
 317     if ($self->{forcemachine}) {
 318         push @$cmd, '--machine', $self->{forcemachine};
 319     }
 320
 321     PVE::Tools::run_command($cmd, outfunc => sub {
 322         my $line = shift;
 323
 324         if ($line =~ m/^migration listens on port (\d+)$/) {
 325             $rport = $1;
 326         }
 327     }, errfunc => sub {
 328         my $line = shift;
 329         $self->log('info', $line);
 330     });
 331
 332     die "unable to detect remote migration port\n" if !$rport;
 333
 334     $self->log('info', "starting migration tunnel");
 335
 336     ## create tunnel to remote port
 337     my $lport = PVE::Tools::next_migrate_port();
 338     $self->{tunnel} = $self->fork_tunnel($self->{nodeip}, $lport, $rport);
 339
 340     $self->log('info', "starting online/live migration on port $lport");
 341     # start migration
 342
 343     my $start = time();
 344
 345     # load_defaults
 346     my $defaults = PVE::QemuServer::load_defaults();
 347
 348     # always set migrate speed (overwrite kvm default of 32m)
 349     # we set a very hight default of 8192m which is basically unlimited
 350     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 351     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 352     $migrate_speed = $migrate_speed * 1048576;
 353     $self->log('info', "migrate_set_speed: $migrate_speed");
 354     eval {
 355         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 356     };
 357     $self->log('info', "migrate_set_speed error: $@") if $@;
 358
 359     my $migrate_downtime = $defaults->{migrate_downtime};
 360     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 361     if (defined($migrate_downtime)) {
 362         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 363         eval {
 364             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 365         };
 366         $self->log('info', "migrate_set_downtime error: $@") if $@;
 367     }
 368
 369     my $capabilities = {};
 370     $capabilities->{capability} =  "xbzrle";
 371     $capabilities->{state} = JSON::false;
 372
 373     eval {
 374         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-capabilities", capabilities => [$capabilities]);
 375     };
 376
 377     #set cachesize 10% of the total memory
 378     my $cachesize = int($conf->{memory}*1048576/10);
 379     eval {
 380         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => $cachesize);
 381     };
 382
 383     eval {
 384         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => "tcp:localhost:$lport");
 385     };
 386     my $merr = $@;
 387
 388     my $lstat = 0;
 389     my $usleep = 2000000;
 390     my $i = 0;
 391     my $err_count = 0;
 392     my $lastrem = undef;
 393     my $downtimecounter = 0;
 394     while (1) {
 395         $i++;
 396         my $avglstat = $lstat/$i if $lstat;
 397
 398         usleep($usleep);
 399         my $stat;
 400         eval {
 401             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 402         };
 403         if (my $err = $@) {
 404             $err_count++;
 405             warn "query migrate failed: $err\n";
 406             if ($err_count <= 5) {
 407                 usleep(1000000);
 408                 next;
 409             }
 410             die "too many query migrate failures - aborting\n";
 411         }
 412         if ($stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 413             $merr = undef;
 414             $err_count = 0;
 415             if ($stat->{status} eq 'completed') {
 416                 my $delay = time() - $start;
 417                 if ($delay > 0) {
 418                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 419                     my $downtime = $stat->{downtime} || 0;
 420                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 421                 }
 422             }
 423
 424             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 425                 die "aborting\n"
 426             }
 427
 428             if ($stat->{status} ne 'active') {
 429                 $self->log('info', "migration status: $stat->{status}");
 430                 last;
 431             }
 432
 433             if ($stat->{ram}->{transferred} ne $lstat) {
 434                 my $trans = $stat->{ram}->{transferred} || 0;
 435                 my $rem = $stat->{ram}->{remaining} || 0;
 436                 my $total = $stat->{ram}->{total} || 0;
 437                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 438                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 439                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 440                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 441                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 442                 #reduce sleep if remainig memory if lower than the everage transfert
 443                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 444
 445                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 446                            "remaining ${rem}), total ${total})");
 447
 448                 #$self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 449                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 450                     $downtimecounter++;
 451                 }
 452                 $lastrem = $rem;
 453
 454                 if ($downtimecounter > 5) {
 455                     $downtimecounter = 0;
 456                     $migrate_downtime *= 2;
 457                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 458                     eval {
 459                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 460                     };
 461                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 462                 }
 463
 464             }
 465
 466
 467             $lstat = $stat->{ram}->{transferred};
 468
 469         } else {
 470             die $merr if $merr;
 471             die "unable to parse migration status '$stat->{status}' - aborting\n";
 472         }
 473     }
 474 }
 475
 476 sub phase2_cleanup {
 477     my ($self, $vmid, $err) = @_;
 478
 479     return if !$self->{errors};
 480     $self->{phase2errors} = 1;
 481
 482     $self->log('info', "aborting phase 2 - cleanup resources");
 483
 484     $self->log('info', "migrate_cancel");
 485     eval {
 486         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 487     };
 488     $self->log('info', "migrate_cancel error: $@") if $@;
 489
 490     my $conf = $self->{vmconf};
 491     delete $conf->{lock};
 492     eval { PVE::QemuServer::update_config_nolock($vmid, $conf, 1) };
 493     if (my $err = $@) {
 494         $self->log('err', $err);
 495     }
 496
 497     # cleanup ressources on target host
 498     my $nodename = PVE::INotify::nodename();
 499
 500     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 501     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 502     if (my $err = $@) {
 503         $self->log('err', $err);
 504         $self->{errors} = 1;
 505     }
 506 }
 507
 508 sub phase3 {
 509     my ($self, $vmid) = @_;
 510
 511     my $volids = $self->{volumes};
 512     return if $self->{phase2errors};
 513
 514     # destroy local copies
 515     foreach my $volid (@$volids) {
 516         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 517         if (my $err = $@) {
 518             $self->log('err', "removing local copy of '$volid' failed - $err");
 519             $self->{errors} = 1;
 520             last if $err =~ /^interrupted by signal$/;
 521         }
 522     }
 523 }
 524
 525 sub phase3_cleanup {
 526     my ($self, $vmid, $err) = @_;
 527
 528     my $conf = $self->{vmconf};
 529     return if $self->{phase2errors};
 530
 531     # move config to remote node
 532     my $conffile = PVE::QemuServer::config_file($vmid);
 533     my $newconffile = PVE::QemuServer::config_file($vmid, $self->{node});
 534
 535     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 536         if !rename($conffile, $newconffile);
 537
 538     # now that config file is move, we can resume vm on target if livemigrate
 539     if ($self->{tunnel}) {
 540         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock'];
 541         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 542                 errfunc => sub {
 543                     my $line = shift;
 544                     $self->log('err', $line);
 545                 });
 546         };
 547         if (my $err = $@) {
 548             $self->log('err', $err);
 549             $self->{errors} = 1;
 550         }
 551     }
 552
 553     # always stop local VM
 554     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 555     if (my $err = $@) {
 556         $self->log('err', "stopping vm failed - $err");
 557         $self->{errors} = 1;
 558     }
 559
 560     if ($self->{tunnel}) {
 561         eval { finish_tunnel($self, $self->{tunnel});  };
 562         if (my $err = $@) {
 563             $self->log('err', $err);
 564             $self->{errors} = 1;
 565         }
 566     }
 567
 568     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 569     eval {
 570         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 571         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 572     };
 573     if (my $err = $@) {
 574         $self->log('err', $err);
 575         $self->{errors} = 1;
 576     }
 577
 578     # clear migrate lock
 579     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 580     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 581 }
 582
 583 sub final_cleanup {
 584     my ($self, $vmid) = @_;
 585
 586     # nothing to do
 587 }
 588
 589 1;