PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::ReplicationState;
  18 use PVE::Replication;
  19
  20 use base qw(PVE::AbstractMigrate);
  21
  22 sub fork_command_pipe {
  23     my ($self, $cmd) = @_;
  24
  25     my $reader = IO::File->new();
  26     my $writer = IO::File->new();
  27
  28     my $orig_pid = $$;
  29
  30     my $cpid;
  31
  32     eval { $cpid = open2($reader, $writer, @$cmd); };
  33
  34     my $err = $@;
  35
  36     # catch exec errors
  37     if ($orig_pid != $$) {
  38         $self->log('err', "can't fork command pipe\n");
  39         POSIX::_exit(1);
  40         kill('KILL', $$);
  41     }
  42
  43     die $err if $err;
  44
  45     return { writer => $writer, reader => $reader, pid => $cpid };
  46 }
  47
  48 sub finish_command_pipe {
  49     my ($self, $cmdpipe, $timeout) = @_;
  50
  51     my $cpid = $cmdpipe->{pid};
  52     return if !defined($cpid);
  53
  54     my $writer = $cmdpipe->{writer};
  55     my $reader = $cmdpipe->{reader};
  56
  57     $writer->close();
  58     $reader->close();
  59
  60     my $collect_child_process = sub {
  61         my $res = waitpid($cpid, WNOHANG);
  62         if (defined($res) && ($res == $cpid)) {
  63             delete $cmdpipe->{cpid};
  64             return 1;
  65         } else {
  66             return 0;
  67         }
  68      };
  69
  70     if ($timeout) {
  71         for (my $i = 0; $i < $timeout; $i++) {
  72             return if &$collect_child_process();
  73             sleep(1);
  74         }
  75     }
  76
  77     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  78     kill(15, $cpid);
  79
  80     # wait again
  81     for (my $i = 0; $i < 10; $i++) {
  82         return if &$collect_child_process();
  83         sleep(1);
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  87     kill 9, $cpid;
  88     sleep 1;
  89
  90     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  91         if !&$collect_child_process();
  92 }
  93
  94 sub read_tunnel {
  95     my ($self, $tunnel, $timeout) = @_;
  96
  97     $timeout = 60 if !defined($timeout);
  98
  99     my $reader = $tunnel->{reader};
 100
 101     my $output;
 102     eval {
 103         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 104     };
 105     die "reading from tunnel failed: $@\n" if $@;
 106
 107     chomp $output;
 108
 109     return $output;
 110 }
 111
 112 sub write_tunnel {
 113     my ($self, $tunnel, $timeout, $command) = @_;
 114
 115     $timeout = 60 if !defined($timeout);
 116
 117     my $writer = $tunnel->{writer};
 118
 119     eval {
 120         PVE::Tools::run_with_timeout($timeout, sub {
 121             print $writer "$command\n";
 122             $writer->flush();
 123         });
 124     };
 125     die "writing to tunnel failed: $@\n" if $@;
 126 }
 127
 128 sub fork_tunnel {
 129     my ($self, $tunnel_addr) = @_;
 130
 131     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
 132
 133     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 134
 135     my $tunnel = $self->fork_command_pipe($cmd);
 136
 137     eval {
 138         my $helo = $self->read_tunnel($tunnel, 60);
 139         die "no reply\n" if !$helo;
 140         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 141         die "got strange reply from mtunnel ('$helo')\n"
 142             if $helo !~ m/^tunnel online$/;
 143     };
 144     my $err = $@;
 145
 146     eval {
 147         my $ver = $self->read_tunnel($tunnel, 10);
 148         if ($ver =~ /^ver (\d+)$/) {
 149             $tunnel->{version} = $1;
 150             $self->log('info', "ssh tunnel $ver\n");
 151         } else {
 152             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 153         }
 154     };
 155
 156     if ($err) {
 157         $self->finish_command_pipe($tunnel);
 158         die "can't open migration tunnel - $err";
 159     }
 160     return $tunnel;
 161 }
 162
 163 sub finish_tunnel {
 164     my ($self, $tunnel) = @_;
 165
 166     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 167     my $err = $@;
 168
 169     $self->finish_command_pipe($tunnel, 30);
 170
 171     if ($tunnel->{sock_addr}) {
 172         # ssh does not clean up on local host
 173         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 174         PVE::Tools::run_command($cmd);
 175
 176         # .. and just to be sure check on remote side
 177         unshift @{$cmd}, @{$self->{rem_ssh}};
 178         PVE::Tools::run_command($cmd);
 179     }
 180
 181     die $err if $err;
 182 }
 183
 184 sub lock_vm {
 185     my ($self, $vmid, $code, @param) = @_;
 186
 187     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 188 }
 189
 190 sub prepare {
 191     my ($self, $vmid) = @_;
 192
 193     my $online = $self->{opts}->{online};
 194
 195     $self->{storecfg} = PVE::Storage::config();
 196
 197     # test if VM exists
 198     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 199
 200     PVE::QemuConfig->check_lock($conf);
 201
 202     my $running = 0;
 203     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 204         die "can't migrate running VM without --online\n" if !$online;
 205         $running = $pid;
 206
 207         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 208
 209     }
 210
 211     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 212         if ($self->{running} || !$self->{opts}->{force}) {
 213             die "can't migrate VM which uses local devices\n";
 214         } else {
 215             $self->log('info', "migrating VM which uses local devices");
 216         }
 217     }
 218
 219     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 220
 221     my $need_activate = [];
 222     foreach my $volid (@$vollist) {
 223         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 224
 225         # check if storage is available on both nodes
 226         my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 227
 228         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 229         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 230
 231         if ($scfg->{shared}) {
 232             # PVE::Storage::activate_storage checks this for non-shared storages
 233             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 234             warn "Used shared storage '$sid' is not online on source node!\n"
 235                 if !$plugin->check_connection($sid, $scfg);
 236         } else {
 237             # only activate if not shared
 238             push @$need_activate, $volid;
 239         }
 240     }
 241
 242     # activate volumes
 243     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 244
 245     # test ssh connection
 246     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 247     eval { $self->cmd_quiet($cmd); };
 248     die "Can't connect to destination address using public key\n" if $@;
 249
 250     return $running;
 251 }
 252
 253 sub sync_disks {
 254     my ($self, $vmid) = @_;
 255
 256     my $conf = $self->{vmconf};
 257
 258     # local volumes which have been copied
 259     $self->{volumes} = [];
 260
 261     my $res = [];
 262
 263     eval {
 264
 265         # found local volumes and their origin
 266         my $local_volumes = {};
 267         my $local_volumes_errors = {};
 268         my $other_errors = [];
 269         my $abort = 0;
 270
 271         my $sharedvm = 1;
 272
 273         my $log_error = sub {
 274             my ($msg, $volid) = @_;
 275
 276             if (defined($volid)) {
 277                 $local_volumes_errors->{$volid} = $msg;
 278             } else {
 279                 push @$other_errors, $msg;
 280             }
 281             $abort = 1;
 282         };
 283
 284         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 285         foreach my $storeid (@sids) {
 286             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 287             next if $scfg->{shared};
 288             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 289
 290             # get list from PVE::Storage (for unused volumes)
 291             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 292
 293             next if @{$dl->{$storeid}} == 0;
 294
 295             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $storeid;
 296
 297             # check if storage is available on target node
 298             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 299             $sharedvm = 0; # there is a non-shared disk
 300
 301             PVE::Storage::foreach_volid($dl, sub {
 302                 my ($volid, $sid, $volname) = @_;
 303
 304                 $local_volumes->{$volid}->{ref} = 'storage';
 305             });
 306         }
 307
 308         my $test_volid = sub {
 309             my ($volid, $attr) = @_;
 310
 311             if ($volid =~ m|^/|) {
 312                 $local_volumes->{$volid}->{ref} = 'config';
 313                 die "local file/device\n";
 314             }
 315
 316             my $snaprefs = $attr->{referenced_in_snapshot};
 317
 318             if ($attr->{cdrom}) {
 319                 if ($volid eq 'cdrom') {
 320                     my $msg = "can't migrate local cdrom drive";
 321                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 322                         my $snapnames = join(', ', sort keys %$snaprefs);
 323                         $msg .= " (referenced in snapshot - $snapnames)";
 324                     }
 325                     &$log_error("$msg\n");
 326                     return;
 327                 }
 328                 return if $volid eq 'none';
 329             }
 330
 331             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 332
 333             my $targetsid = $self->{opts}->{targetstorage} ? $self->{opts}->{targetstorage} : $sid;
 334             # check if storage is available on both nodes
 335             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 336             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 337
 338             return if $scfg->{shared};
 339
 340             $sharedvm = 0;
 341
 342             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 343
 344             die "local cdrom image\n" if $attr->{cdrom};
 345
 346             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 347
 348             die "owned by other VM (owner = VM $owner)\n"
 349                 if !$owner || ($owner != $self->{vmid});
 350
 351             my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 352             $local_volumes->{$volid}->{snapshots} = defined($snaprefs) || ($format =~ /^(?:qcow2|vmdk)$/);
 353             if (defined($snaprefs)) {
 354                 # we cannot migrate shapshots on local storage
 355                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 356
 357                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 358                 if (!($scfg->{type} eq 'zfspool' || $format eq 'qcow2')) {
 359                     die "non-migratable snapshot exists\n";
 360                 }
 361             }
 362
 363             die "referenced by linked clone(s)\n"
 364                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 365         };
 366
 367         PVE::QemuServer::foreach_volid($conf, sub {
 368             my ($volid, $attr) = @_;
 369             eval { $test_volid->($volid, $attr); };
 370             if (my $err = $@) {
 371                 &$log_error($err, $volid);
 372             }
 373         });
 374
 375         foreach my $vol (sort keys %$local_volumes) {
 376             my $ref = $local_volumes->{$vol}->{ref};
 377             if ($ref eq 'storage') {
 378                 $self->log('info', "found local disk '$vol' (via storage)\n");
 379             } elsif ($ref eq 'config') {
 380                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 381                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 382                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 383             } elsif ($ref eq 'snapshot') {
 384                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 385             } else {
 386                 $self->log('info', "found local disk '$vol'\n");
 387             }
 388         }
 389
 390         foreach my $vol (sort keys %$local_volumes_errors) {
 391             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 392         }
 393         foreach my $err (@$other_errors) {
 394             $self->log('warn', "$err");
 395         }
 396
 397         if ($self->{running} && !$sharedvm && !$self->{opts}->{targetstorage}) {
 398             $self->{opts}->{targetstorage} = 1; #use same sid for remote local
 399         }
 400
 401         if ($abort) {
 402             die "can't migrate VM - check log\n";
 403         }
 404
 405         # additional checks for local storage
 406         foreach my $volid (keys %$local_volumes) {
 407             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 408             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 409
 410             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 411                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 412
 413             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 414                 if !$migratable;
 415
 416             # image is a linked clone on local storage, se we can't migrate.
 417             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 418                 die "can't migrate '$volid' as it's a clone of '$basename'";
 419             }
 420         }
 421
 422         my $rep_volumes;
 423
 424         $self->log('info', "copying disk images");
 425
 426         my $rep_cfg = PVE::ReplicationConfig->new();
 427
 428         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 429             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 430             my $start_time = time();
 431             my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 432             $rep_volumes = PVE::Replication::run_replication(
 433                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 434         }
 435
 436         foreach my $volid (keys %$local_volumes) {
 437             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 438             if ($self->{running} && $self->{opts}->{targetstorage} && $local_volumes->{$volid}->{ref} eq 'config') {
 439                 push @{$self->{online_local_volumes}}, $volid;
 440             } else {
 441                 next if $rep_volumes->{$volid};
 442                 push @{$self->{volumes}}, $volid;
 443                 my $insecure = $self->{opts}->{migration_type} eq 'insecure';
 444                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 445                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid,
 446                                               undef, undef, undef, undef, $insecure, $with_snapshots);
 447             }
 448         }
 449     };
 450     die "Failed to sync data - $@" if $@;
 451 }
 452
 453 sub cleanup_remotedisks {
 454     my ($self) = @_;
 455
 456     foreach my $target_drive (keys %{$self->{target_drive}}) {
 457
 458         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 459         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 460
 461         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 462
 463         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 464         if (my $err = $@) {
 465             $self->log('err', $err);
 466             $self->{errors} = 1;
 467         }
 468     }
 469 }
 470
 471 sub phase1 {
 472     my ($self, $vmid) = @_;
 473
 474     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 475
 476     my $conf = $self->{vmconf};
 477
 478     # set migrate lock in config file
 479     $conf->{lock} = 'migrate';
 480     PVE::QemuConfig->write_config($vmid, $conf);
 481
 482     sync_disks($self, $vmid);
 483
 484 };
 485
 486 sub phase1_cleanup {
 487     my ($self, $vmid, $err) = @_;
 488
 489     $self->log('info', "aborting phase 1 - cleanup resources");
 490
 491     my $conf = $self->{vmconf};
 492     delete $conf->{lock};
 493     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 494     if (my $err = $@) {
 495         $self->log('err', $err);
 496     }
 497
 498     if ($self->{volumes}) {
 499         foreach my $volid (@{$self->{volumes}}) {
 500             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 501             # fixme: try to remove ?
 502         }
 503     }
 504 }
 505
 506 sub phase2 {
 507     my ($self, $vmid) = @_;
 508
 509     my $conf = $self->{vmconf};
 510
 511     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 512
 513     my $raddr;
 514     my $rport;
 515     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 516     my $nodename = PVE::INotify::nodename();
 517
 518     ## start on remote node
 519     my $cmd = [@{$self->{rem_ssh}}];
 520
 521     my $spice_ticket;
 522     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 523         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 524         $spice_ticket = $res->{ticket};
 525     }
 526
 527     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 528
 529     my $migration_type = $self->{opts}->{migration_type};
 530
 531     push @$cmd, '--migration_type', $migration_type;
 532
 533     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 534       if $self->{opts}->{migration_network};
 535
 536     if ($migration_type eq 'insecure') {
 537         push @$cmd, '--stateuri', 'tcp';
 538     } else {
 539         push @$cmd, '--stateuri', 'unix';
 540     }
 541
 542     if ($self->{forcemachine}) {
 543         push @$cmd, '--machine', $self->{forcemachine};
 544     }
 545
 546     if ($self->{opts}->{targetstorage}) {
 547         push @$cmd, '--targetstorage', $self->{opts}->{targetstorage};
 548     }
 549
 550     my $spice_port;
 551
 552     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 553     # instead we pipe it through STDIN
 554     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 555         my $line = shift;
 556
 557         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 558             $raddr = $1;
 559             $rport = int($2);
 560             $ruri = "tcp:$raddr:$rport";
 561         }
 562         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 563             $raddr = $1;
 564             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 565             $ruri = "unix:$raddr";
 566         }
 567         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 568             $raddr = "localhost";
 569             $rport = int($1);
 570             $ruri = "tcp:$raddr:$rport";
 571         }
 572         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 573             $spice_port = int($1);
 574         }
 575         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 576             my $volid = $4;
 577             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 578             my $targetdrive = $3;
 579             $targetdrive =~ s/drive-//g;
 580
 581             $self->{target_drive}->{$targetdrive}->{volid} = $volid;
 582             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 583
 584         }
 585     }, errfunc => sub {
 586         my $line = shift;
 587         $self->log('info', $line);
 588     });
 589
 590     die "unable to detect remote migration address\n" if !$raddr;
 591
 592     if ($migration_type eq 'secure') {
 593         $self->log('info', "start remote tunnel");
 594
 595         if ($ruri =~ /^unix:/) {
 596             unlink $raddr;
 597             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 598             $self->{tunnel}->{sock_addr} = $raddr;
 599
 600             my $unix_socket_try = 0; # wait for the socket to become ready
 601             while (! -S $raddr) {
 602                 $unix_socket_try++;
 603                 if ($unix_socket_try > 100) {
 604                     $self->{errors} = 1;
 605                     $self->finish_tunnel($self->{tunnel});
 606                     die "Timeout, migration socket $ruri did not get ready";
 607                 }
 608
 609                 usleep(50000);
 610             }
 611
 612         } elsif ($ruri =~ /^tcp:/) {
 613             my $tunnel_addr;
 614             if ($raddr eq "localhost") {
 615                 # for backwards compatibility with older qemu-server versions
 616                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 617                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 618                 $tunnel_addr = "$lport:localhost:$rport";
 619             }
 620
 621             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 622
 623         } else {
 624             die "unsupported protocol in migration URI: $ruri\n";
 625         }
 626     }
 627
 628     my $start = time();
 629
 630     if ($self->{opts}->{targetstorage} && defined($self->{online_local_volumes})) {
 631         $self->{storage_migration} = 1;
 632         $self->{storage_migration_jobs} = {};
 633         $self->log('info', "starting storage migration");
 634
 635         die "The number of local disks does not match between the source and the destination.\n"
 636             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 637         foreach my $drive (keys %{$self->{target_drive}}){
 638             my $nbd_uri = $self->{target_drive}->{$drive}->{nbd_uri};
 639             $self->log('info', "$drive: start migration to to $nbd_uri");
 640             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 1);
 641         }
 642     }
 643
 644     $self->log('info', "starting online/live migration on $ruri");
 645     $self->{livemigration} = 1;
 646
 647     # load_defaults
 648     my $defaults = PVE::QemuServer::load_defaults();
 649
 650     # always set migrate speed (overwrite kvm default of 32m)
 651     # we set a very hight default of 8192m which is basically unlimited
 652     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 653     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 654     $migrate_speed = $migrate_speed * 1048576;
 655     $self->log('info', "migrate_set_speed: $migrate_speed");
 656     eval {
 657         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 658     };
 659     $self->log('info', "migrate_set_speed error: $@") if $@;
 660
 661     my $migrate_downtime = $defaults->{migrate_downtime};
 662     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 663     if (defined($migrate_downtime)) {
 664         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 665         eval {
 666             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 667         };
 668         $self->log('info', "migrate_set_downtime error: $@") if $@;
 669     }
 670
 671     $self->log('info', "set migration_caps");
 672     eval {
 673         PVE::QemuServer::set_migration_caps($vmid);
 674     };
 675     warn $@ if $@;
 676
 677     # set cachesize to 10% of the total memory
 678     my $memory =  $conf->{memory} || $defaults->{memory};
 679     my $cachesize = int($memory * 1048576 / 10);
 680     $self->log('info', "set cachesize: $cachesize");
 681     eval {
 682         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 683     };
 684     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 685
 686     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 687         my $rpcenv = PVE::RPCEnvironment::get();
 688         my $authuser = $rpcenv->get_user();
 689
 690         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 691
 692         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 693         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 694
 695         $self->log('info', "spice client_migrate_info");
 696
 697         eval {
 698             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 699                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 700                                                 'cert-subject' => $subject);
 701         };
 702         $self->log('info', "client_migrate_info error: $@") if $@;
 703
 704     }
 705
 706     $self->log('info', "start migrate command to $ruri");
 707     eval {
 708         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 709     };
 710     my $merr = $@;
 711     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 712
 713     my $lstat = 0;
 714     my $usleep = 2000000;
 715     my $i = 0;
 716     my $err_count = 0;
 717     my $lastrem = undef;
 718     my $downtimecounter = 0;
 719     while (1) {
 720         $i++;
 721         my $avglstat = $lstat/$i if $lstat;
 722
 723         usleep($usleep);
 724         my $stat;
 725         eval {
 726             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 727         };
 728         if (my $err = $@) {
 729             $err_count++;
 730             warn "query migrate failed: $err\n";
 731             $self->log('info', "query migrate failed: $err");
 732             if ($err_count <= 5) {
 733                 usleep(1000000);
 734                 next;
 735             }
 736             die "too many query migrate failures - aborting\n";
 737         }
 738
 739         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 740             sleep(1);
 741             next;
 742         }
 743
 744         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 745             $merr = undef;
 746             $err_count = 0;
 747             if ($stat->{status} eq 'completed') {
 748                 my $delay = time() - $start;
 749                 if ($delay > 0) {
 750                     my $mbps = sprintf "%.2f", $memory / $delay;
 751                     my $downtime = $stat->{downtime} || 0;
 752                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 753                 }
 754             }
 755
 756             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 757                 $self->log('info', "migration status error: $stat->{status}");
 758                 die "aborting\n"
 759             }
 760
 761             if ($stat->{status} ne 'active') {
 762                 $self->log('info', "migration status: $stat->{status}");
 763                 last;
 764             }
 765
 766             if ($stat->{ram}->{transferred} ne $lstat) {
 767                 my $trans = $stat->{ram}->{transferred} || 0;
 768                 my $rem = $stat->{ram}->{remaining} || 0;
 769                 my $total = $stat->{ram}->{total} || 0;
 770                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 771                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 772                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 773                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 774                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 775                 #reduce sleep if remainig memory if lower than the everage transfert
 776                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 777
 778                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 779                            "remaining ${rem}), total ${total})");
 780
 781                 if (${xbzrlecachesize}) {
 782                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 783                 }
 784
 785                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 786                     $downtimecounter++;
 787                 }
 788                 $lastrem = $rem;
 789
 790                 if ($downtimecounter > 5) {
 791                     $downtimecounter = 0;
 792                     $migrate_downtime *= 2;
 793                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 794                     eval {
 795                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 796                     };
 797                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 798                 }
 799
 800             }
 801
 802
 803             $lstat = $stat->{ram}->{transferred};
 804
 805         } else {
 806             die $merr if $merr;
 807             die "unable to parse migration status '$stat->{status}' - aborting\n";
 808         }
 809     }
 810
 811     # just to be sure that the tunnel gets closed on successful migration, on error
 812     # phase2_cleanup closes it *after* stopping the remote waiting VM
 813     if (!$self->{errors} && $self->{tunnel}) {
 814         eval { finish_tunnel($self, $self->{tunnel});  };
 815         if (my $err = $@) {
 816             $self->log('err', $err);
 817             $self->{errors} = 1;
 818         }
 819     }
 820 }
 821
 822 sub phase2_cleanup {
 823     my ($self, $vmid, $err) = @_;
 824
 825     return if !$self->{errors};
 826     $self->{phase2errors} = 1;
 827
 828     $self->log('info', "aborting phase 2 - cleanup resources");
 829
 830     $self->log('info', "migrate_cancel");
 831     eval {
 832         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 833     };
 834     $self->log('info', "migrate_cancel error: $@") if $@;
 835
 836     my $conf = $self->{vmconf};
 837     delete $conf->{lock};
 838     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 839     if (my $err = $@) {
 840         $self->log('err', $err);
 841     }
 842
 843     # cleanup ressources on target host
 844     if ($self->{storage_migration}) {
 845
 846         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 847         if (my $err = $@) {
 848             $self->log('err', $err);
 849         }
 850
 851         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 852         if (my $err = $@) {
 853             $self->log('err', $err);
 854         }
 855     }
 856
 857     my $nodename = PVE::INotify::nodename();
 858
 859     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 860     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 861     if (my $err = $@) {
 862         $self->log('err', $err);
 863         $self->{errors} = 1;
 864     }
 865
 866     if ($self->{tunnel}) {
 867         eval { finish_tunnel($self, $self->{tunnel});  };
 868         if (my $err = $@) {
 869             $self->log('err', $err);
 870             $self->{errors} = 1;
 871         }
 872     }
 873 }
 874
 875 sub phase3 {
 876     my ($self, $vmid) = @_;
 877
 878     my $volids = $self->{volumes};
 879     return if $self->{phase2errors};
 880
 881     # destroy local copies
 882     foreach my $volid (@$volids) {
 883         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 884         if (my $err = $@) {
 885             $self->log('err', "removing local copy of '$volid' failed - $err");
 886             $self->{errors} = 1;
 887             last if $err =~ /^interrupted by signal$/;
 888         }
 889     }
 890 }
 891
 892 sub phase3_cleanup {
 893     my ($self, $vmid, $err) = @_;
 894
 895     my $conf = $self->{vmconf};
 896     return if $self->{phase2errors};
 897
 898     if ($self->{storage_migration}) {
 899         # finish block-job
 900         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}); };
 901
 902         if (my $err = $@) {
 903             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 904             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 905             die "Failed to completed storage migration\n";
 906         } else {
 907             foreach my $target_drive (keys %{$self->{target_drive}}) {
 908                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{volid});
 909                 $conf->{$target_drive} = PVE::QemuServer::print_drive($vmid, $drive);
 910                 PVE::QemuConfig->write_config($vmid, $conf);
 911             }
 912         }
 913     }
 914
 915     # transfer replication state before move config
 916     $self->transfer_replication_state();
 917
 918     # move config to remote node
 919     my $conffile = PVE::QemuConfig->config_file($vmid);
 920     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 921
 922     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 923         if !rename($conffile, $newconffile);
 924
 925     $self->switch_replication_job_target();
 926
 927     if ($self->{livemigration}) {
 928         if ($self->{storage_migration}) {
 929             # remove drives referencing the nbd server from source
 930             # otherwise vm_stop might hang later on
 931             foreach my $drive (keys %{$self->{target_drive}}){
 932                 PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "device_del", id => $drive);
 933             }
 934             # stop nbd server on remote vm - requirement for resume since 2.9
 935             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
 936
 937             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 938             if (my $err = $@) {
 939                 $self->log('err', $err);
 940                 $self->{errors} = 1;
 941             }
 942         }
 943         # config moved and nbd server stopped - now we can resume vm on target
 944         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 945         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 946                 errfunc => sub {
 947                     my $line = shift;
 948                     $self->log('err', $line);
 949                 });
 950         };
 951         if (my $err = $@) {
 952             $self->log('err', $err);
 953             $self->{errors} = 1;
 954         }
 955     }
 956
 957     eval {
 958         my $timer = 0;
 959         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 960             $self->log('info', "Waiting for spice server migration");
 961             while (1) {
 962                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 963                 last if int($res->{'migrated'}) == 1;
 964                 last if $timer > 50;
 965                 $timer ++;
 966                 usleep(200000);
 967             }
 968         }
 969     };
 970
 971     # always stop local VM
 972     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 973     if (my $err = $@) {
 974         $self->log('err', "stopping vm failed - $err");
 975         $self->{errors} = 1;
 976     }
 977
 978     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 979     eval {
 980         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 981         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 982     };
 983     if (my $err = $@) {
 984         $self->log('err', $err);
 985         $self->{errors} = 1;
 986     }
 987
 988     if($self->{storage_migration}) {
 989         # destroy local copies
 990         my $volids = $self->{online_local_volumes};
 991
 992         foreach my $volid (@$volids) {
 993             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 994             if (my $err = $@) {
 995                 $self->log('err', "removing local copy of '$volid' failed - $err");
 996                 $self->{errors} = 1;
 997                 last if $err =~ /^interrupted by signal$/;
 998             }
 999         }
1000
1001     }
1002
1003     # clear migrate lock
1004     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1005     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1006 }
1007
1008 sub final_cleanup {
1009     my ($self, $vmid) = @_;
1010
1011     # nothing to do
1012 }
1013
1014 1;