PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use Time::HiRes qw( usleep );
  15 use PVE::RPCEnvironment;
  16
  17 use base qw(PVE::AbstractMigrate);
  18
  19 sub fork_command_pipe {
  20     my ($self, $cmd) = @_;
  21
  22     my $reader = IO::File->new();
  23     my $writer = IO::File->new();
  24
  25     my $orig_pid = $$;
  26
  27     my $cpid;
  28
  29     eval { $cpid = open2($reader, $writer, @$cmd); };
  30
  31     my $err = $@;
  32
  33     # catch exec errors
  34     if ($orig_pid != $$) {
  35         $self->log('err', "can't fork command pipe\n");
  36         POSIX::_exit(1);
  37         kill('KILL', $$);
  38     }
  39
  40     die $err if $err;
  41
  42     return { writer => $writer, reader => $reader, pid => $cpid };
  43 }
  44
  45 sub finish_command_pipe {
  46     my ($self, $cmdpipe, $timeout) = @_;
  47
  48     my $cpid = $cmdpipe->{pid};
  49     return if !defined($cpid);
  50
  51     my $writer = $cmdpipe->{writer};
  52     my $reader = $cmdpipe->{reader};
  53
  54     $writer->close();
  55     $reader->close();
  56
  57     my $collect_child_process = sub {
  58         my $res = waitpid($cpid, WNOHANG);
  59         if (defined($res) && ($res == $cpid)) {
  60             delete $cmdpipe->{cpid};
  61             return 1;
  62         } else {
  63             return 0;
  64         }
  65      };
  66
  67     if ($timeout) {
  68         for (my $i = 0; $i < $timeout; $i++) {
  69             return if &$collect_child_process();
  70             sleep(1);
  71         }
  72     }
  73
  74     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  75     kill(15, $cpid);
  76
  77     # wait again
  78     for (my $i = 0; $i < 10; $i++) {
  79         return if &$collect_child_process();
  80         sleep(1);
  81     }
  82
  83     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  84     kill 9, $cpid;
  85     sleep 1;
  86
  87     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  88         if !&$collect_child_process();
  89 }
  90
  91 sub fork_tunnel {
  92     my ($self, $tunnel_addr) = @_;
  93
  94     my @localtunnelinfo = defined($tunnel_addr) ? ('-L' , $tunnel_addr ) : ();
  95
  96     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, 'qm', 'mtunnel' ];
  97
  98     my $tunnel = $self->fork_command_pipe($cmd);
  99
 100     my $reader = $tunnel->{reader};
 101
 102     my $helo;
 103     eval {
 104         PVE::Tools::run_with_timeout(60, sub { $helo = <$reader>; });
 105         die "no reply\n" if !$helo;
 106         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 107         die "got strange reply from mtunnel ('$helo')\n"
 108             if $helo !~ m/^tunnel online$/;
 109     };
 110     my $err = $@;
 111
 112     if ($err) {
 113         $self->finish_command_pipe($tunnel);
 114         die "can't open migration tunnel - $err";
 115     }
 116     return $tunnel;
 117 }
 118
 119 sub finish_tunnel {
 120     my ($self, $tunnel) = @_;
 121
 122     my $writer = $tunnel->{writer};
 123
 124     eval {
 125         PVE::Tools::run_with_timeout(30, sub {
 126             print $writer "quit\n";
 127             $writer->flush();
 128         });
 129     };
 130     my $err = $@;
 131
 132     $self->finish_command_pipe($tunnel, 30);
 133
 134     if ($tunnel->{sock_addr}) {
 135         # ssh does not clean up on local host
 136         my $cmd = ['rm', '-f', $tunnel->{sock_addr}]; #
 137         PVE::Tools::run_command($cmd);
 138
 139         # .. and just to be sure check on remote side
 140         unshift @{$cmd}, @{$self->{rem_ssh}};
 141         PVE::Tools::run_command($cmd);
 142     }
 143
 144     die $err if $err;
 145 }
 146
 147 sub lock_vm {
 148     my ($self, $vmid, $code, @param) = @_;
 149
 150     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 151 }
 152
 153 sub prepare {
 154     my ($self, $vmid) = @_;
 155
 156     my $online = $self->{opts}->{online};
 157
 158     $self->{storecfg} = PVE::Storage::config();
 159
 160     # test if VM exists
 161     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 162
 163     PVE::QemuConfig->check_lock($conf);
 164
 165     my $running = 0;
 166     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 167         die "can't migrate running VM without --online\n" if !$online;
 168         $running = $pid;
 169
 170         $self->{forcemachine} = PVE::QemuServer::qemu_machine_pxe($vmid, $conf);
 171
 172     }
 173
 174     if (my $loc_res = PVE::QemuServer::check_local_resources($conf, 1)) {
 175         if ($self->{running} || !$self->{opts}->{force}) {
 176             die "can't migrate VM which uses local devices\n";
 177         } else {
 178             $self->log('info', "migrating VM which uses local devices");
 179         }
 180     }
 181
 182     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 183
 184     my $need_activate = [];
 185     foreach my $volid (@$vollist) {
 186         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 187
 188         # check if storage is available on both nodes
 189         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 190         PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 191
 192         if ($scfg->{shared}) {
 193             # PVE::Storage::activate_storage checks this for non-shared storages
 194             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195             warn "Used shared storage '$sid' is not online on source node!\n"
 196                 if !$plugin->check_connection($sid, $scfg);
 197         } else {
 198             # only activate if not shared
 199             push @$need_activate, $volid;
 200         }
 201     }
 202
 203     # activate volumes
 204     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 205
 206     # test ssh connection
 207     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 208     eval { $self->cmd_quiet($cmd); };
 209     die "Can't connect to destination address using public key\n" if $@;
 210
 211     return $running;
 212 }
 213
 214 sub sync_disks {
 215     my ($self, $vmid) = @_;
 216
 217     $self->log('info', "copying disk images");
 218
 219     my $conf = $self->{vmconf};
 220
 221     $self->{volumes} = [];
 222
 223     my $res = [];
 224
 225     eval {
 226
 227         my $volhash = {};
 228         my $cdromhash = {};
 229
 230         my $sharedvm = 1;
 231
 232         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 233         foreach my $storeid (@sids) {
 234             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 235             next if $scfg->{shared};
 236             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 237
 238             # get list from PVE::Storage (for unused volumes)
 239             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 240
 241             next if @{$dl->{$storeid}} == 0;
 242
 243             # check if storage is available on target node
 244             PVE::Storage::storage_check_node($self->{storecfg}, $storeid, $self->{node});
 245             $sharedvm = 0; # there is a non-shared disk
 246
 247             PVE::Storage::foreach_volid($dl, sub {
 248                 my ($volid, $sid, $volname) = @_;
 249
 250                 $volhash->{$volid} = 1;
 251             });
 252         }
 253
 254         my $test_volid = sub {
 255             my ($volid, $is_cdrom, $snapname) = @_;
 256
 257             return if !$volid;
 258
 259             die "can't migrate local file/device '$volid'\n" if $volid =~ m|^/|;
 260
 261             if ($is_cdrom) {
 262                 die "can't migrate local cdrom drive\n" if $volid eq 'cdrom';
 263                 return if $volid eq 'none';
 264                 $cdromhash->{$volid} = 1;
 265             }
 266
 267             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 268
 269             # check if storage is available on both nodes
 270             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 271             PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 272
 273             return if $scfg->{shared};
 274
 275             $sharedvm = 0;
 276
 277             die "can't migrate local cdrom '$volid'\n" if $cdromhash->{$volid};
 278
 279             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 280
 281             die "can't migrate volume '$volid' - owned by other VM (owner = VM $owner)\n"
 282                 if !$owner || ($owner != $self->{vmid});
 283
 284             if (defined($snapname)) {
 285                 # we cannot migrate shapshots on local storage
 286                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 287
 288                 my $format = PVE::QemuServer::qemu_img_format($scfg, $volname);
 289
 290                 if (($scfg->{type} eq 'zfspool') || ($format eq 'qcow2')) {
 291                     $volhash->{$volid} = 1;
 292                     return;
 293                 }
 294
 295                 die "can't migrate snapshot of local volume '$volid'\n";
 296
 297             } else {
 298                 $volhash->{$volid} = 1;
 299             }
 300         };
 301
 302         my $test_drive = sub {
 303             my ($ds, $drive, $snapname) = @_;
 304
 305             &$test_volid($drive->{file}, PVE::QemuServer::drive_is_cdrom($drive), $snapname);
 306         };
 307
 308         PVE::QemuServer::foreach_drive($conf, $test_drive);
 309         foreach my $snapname (keys %{$conf->{snapshots}}) {
 310             &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 311                 if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 312             PVE::QemuServer::foreach_drive($conf->{snapshots}->{$snapname}, $test_drive, $snapname);
 313         }
 314
 315         if ($self->{running} && !$sharedvm) {
 316             die "can't do online migration - VM uses local disks\n";
 317         }
 318
 319         # additional checks for local storage
 320         foreach my $volid (keys %$volhash) {
 321             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 322             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 323
 324             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 325                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 326
 327             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 328                 if !$migratable;
 329
 330             # image is a linked clone on local storage, se we can't migrate.
 331             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 332                 die "can't migrate '$volid' as it's a clone of '$basename'";
 333             }
 334         }
 335
 336         foreach my $volid (keys %$volhash) {
 337             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 338             push @{$self->{volumes}}, $volid;
 339             PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{nodeip}, $sid);
 340         }
 341     };
 342     die "Failed to sync data - $@" if $@;
 343 }
 344
 345 sub phase1 {
 346     my ($self, $vmid) = @_;
 347
 348     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 349
 350     my $conf = $self->{vmconf};
 351
 352     # set migrate lock in config file
 353     $conf->{lock} = 'migrate';
 354     PVE::QemuConfig->write_config($vmid, $conf);
 355
 356     sync_disks($self, $vmid);
 357
 358 };
 359
 360 sub phase1_cleanup {
 361     my ($self, $vmid, $err) = @_;
 362
 363     $self->log('info', "aborting phase 1 - cleanup resources");
 364
 365     my $conf = $self->{vmconf};
 366     delete $conf->{lock};
 367     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 368     if (my $err = $@) {
 369         $self->log('err', $err);
 370     }
 371
 372     if ($self->{volumes}) {
 373         foreach my $volid (@{$self->{volumes}}) {
 374             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 375             # fixme: try to remove ?
 376         }
 377     }
 378 }
 379
 380 sub phase2 {
 381     my ($self, $vmid) = @_;
 382
 383     my $conf = $self->{vmconf};
 384
 385     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 386
 387     my $raddr;
 388     my $rport;
 389     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 390     my $nodename = PVE::INotify::nodename();
 391
 392     ## start on remote node
 393     my $cmd = [@{$self->{rem_ssh}}];
 394
 395     my $spice_ticket;
 396     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 397         my $res = PVE::QemuServer::vm_mon_cmd($vmid, 'query-spice');
 398         $spice_ticket = $res->{ticket};
 399     }
 400
 401     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 402
 403     # we use TCP only for unsecure migrations as TCP ssh forward tunnels often
 404     # did appeared to late (they are hard, if not impossible, to check for)
 405     # secure migration use UNIX sockets now, this *breaks* compatibilty when trying
 406     # to migrate from new to old but *not* from old to new.
 407     my $datacenterconf = PVE::Cluster::cfs_read_file('datacenter.cfg');
 408     my $secure_migration = ($datacenterconf->{migration_unsecure}) ? 0 : 1;
 409
 410     if (!$secure_migration) {
 411         push @$cmd, '--stateuri', 'tcp';
 412     } else {
 413         push @$cmd, '--stateuri', 'unix';
 414     }
 415
 416     if ($self->{forcemachine}) {
 417         push @$cmd, '--machine', $self->{forcemachine};
 418     }
 419
 420     my $spice_port;
 421
 422     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 423     # instead we pipe it through STDIN
 424     PVE::Tools::run_command($cmd, input => $spice_ticket, outfunc => sub {
 425         my $line = shift;
 426
 427         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 428             $raddr = $1;
 429             $rport = int($2);
 430             $ruri = "tcp:$raddr:$rport";
 431         }
 432         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 433             $raddr = $1;
 434             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 435             $ruri = "unix:$raddr";
 436         }
 437         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 438             $raddr = "localhost";
 439             $rport = int($1);
 440             $ruri = "tcp:$raddr:$rport";
 441         }
 442         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 443             $spice_port = int($1);
 444         }
 445     }, errfunc => sub {
 446         my $line = shift;
 447         $self->log('info', $line);
 448     });
 449
 450     die "unable to detect remote migration address\n" if !$raddr;
 451
 452     if ($secure_migration) {
 453         $self->log('info', "start remote tunnel");
 454
 455         if ($ruri =~ /^unix:/) {
 456             unlink $raddr;
 457             $self->{tunnel} = $self->fork_tunnel("$raddr:$raddr");
 458             $self->{tunnel}->{sock_addr} = $raddr;
 459
 460             my $unix_socket_try = 0; # wait for the socket to become ready
 461             while (! -S $raddr) {
 462                 $unix_socket_try++;
 463                 if ($unix_socket_try > 100) {
 464                     $self->{errors} = 1;
 465                     $self->finish_tunnel($self->{tunnel});
 466                     die "Timeout, migration socket $ruri did not get ready";
 467                 }
 468
 469                 usleep(50000);
 470             }
 471
 472         } elsif ($ruri =~ /^tcp:/) {
 473             my $tunnel_addr;
 474             if ($raddr eq "localhost") {
 475                 # for backwards compatibility with older qemu-server versions
 476                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 477                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 478                 $tunnel_addr = "$lport:localhost:$rport";
 479             }
 480
 481             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 482
 483         } else {
 484             die "unsupported protocol in migration URI: $ruri\n";
 485         }
 486     }
 487
 488     my $start = time();
 489     $self->log('info', "starting online/live migration on $ruri");
 490     $self->{livemigration} = 1;
 491
 492     # load_defaults
 493     my $defaults = PVE::QemuServer::load_defaults();
 494
 495     # always set migrate speed (overwrite kvm default of 32m)
 496     # we set a very hight default of 8192m which is basically unlimited
 497     my $migrate_speed = $defaults->{migrate_speed} || 8192;
 498     $migrate_speed = $conf->{migrate_speed} || $migrate_speed;
 499     $migrate_speed = $migrate_speed * 1048576;
 500     $self->log('info', "migrate_set_speed: $migrate_speed");
 501     eval {
 502         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_speed", value => int($migrate_speed));
 503     };
 504     $self->log('info', "migrate_set_speed error: $@") if $@;
 505
 506     my $migrate_downtime = $defaults->{migrate_downtime};
 507     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 508     if (defined($migrate_downtime)) {
 509         $self->log('info', "migrate_set_downtime: $migrate_downtime");
 510         eval {
 511             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 512         };
 513         $self->log('info', "migrate_set_downtime error: $@") if $@;
 514     }
 515
 516     $self->log('info', "set migration_caps");
 517     eval {
 518         PVE::QemuServer::set_migration_caps($vmid);
 519     };
 520     warn $@ if $@;
 521
 522     #set cachesize 10% of the total memory
 523     my $cachesize = int($conf->{memory}*1048576/10);
 524     $self->log('info', "set cachesize: $cachesize");
 525     eval {
 526         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate-set-cache-size", value => int($cachesize));
 527     };
 528     $self->log('info', "migrate-set-cache-size error: $@") if $@;
 529
 530     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 531         my $rpcenv = PVE::RPCEnvironment::get();
 532         my $authuser = $rpcenv->get_user();
 533
 534         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 535
 536         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 537         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 538
 539         $self->log('info', "spice client_migrate_info");
 540
 541         eval {
 542             PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "client_migrate_info", protocol => 'spice',
 543                                                 hostname => $proxyticket, 'tls-port' => $spice_port,
 544                                                 'cert-subject' => $subject);
 545         };
 546         $self->log('info', "client_migrate_info error: $@") if $@;
 547
 548     }
 549
 550     $self->log('info', "start migrate command to $ruri");
 551     eval {
 552         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate", uri => $ruri);
 553     };
 554     my $merr = $@;
 555     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 556
 557     my $lstat = 0;
 558     my $usleep = 2000000;
 559     my $i = 0;
 560     my $err_count = 0;
 561     my $lastrem = undef;
 562     my $downtimecounter = 0;
 563     while (1) {
 564         $i++;
 565         my $avglstat = $lstat/$i if $lstat;
 566
 567         usleep($usleep);
 568         my $stat;
 569         eval {
 570             $stat = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "query-migrate");
 571         };
 572         if (my $err = $@) {
 573             $err_count++;
 574             warn "query migrate failed: $err\n";
 575             $self->log('info', "query migrate failed: $err");
 576             if ($err_count <= 5) {
 577                 usleep(1000000);
 578                 next;
 579             }
 580             die "too many query migrate failures - aborting\n";
 581         }
 582
 583         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 584             sleep(1);
 585             next;
 586         }
 587
 588         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 589             $merr = undef;
 590             $err_count = 0;
 591             if ($stat->{status} eq 'completed') {
 592                 my $delay = time() - $start;
 593                 if ($delay > 0) {
 594                     my $mbps = sprintf "%.2f", $conf->{memory}/$delay;
 595                     my $downtime = $stat->{downtime} || 0;
 596                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 597                 }
 598             }
 599
 600             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 601                 $self->log('info', "migration status error: $stat->{status}");
 602                 die "aborting\n"
 603             }
 604
 605             if ($stat->{status} ne 'active') {
 606                 $self->log('info', "migration status: $stat->{status}");
 607                 last;
 608             }
 609
 610             if ($stat->{ram}->{transferred} ne $lstat) {
 611                 my $trans = $stat->{ram}->{transferred} || 0;
 612                 my $rem = $stat->{ram}->{remaining} || 0;
 613                 my $total = $stat->{ram}->{total} || 0;
 614                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 615                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 616                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 617                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 618                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 619                 #reduce sleep if remainig memory if lower than the everage transfert
 620                 $usleep = 300000 if $avglstat && $rem < $avglstat;
 621
 622                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 623                            "remaining ${rem}), total ${total})");
 624
 625                 if (${xbzrlecachesize}) {
 626                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 627                 }
 628
 629                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 630                     $downtimecounter++;
 631                 }
 632                 $lastrem = $rem;
 633
 634                 if ($downtimecounter > 5) {
 635                     $downtimecounter = 0;
 636                     $migrate_downtime *= 2;
 637                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 638                     eval {
 639                         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 640                     };
 641                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 642                 }
 643
 644             }
 645
 646
 647             $lstat = $stat->{ram}->{transferred};
 648
 649         } else {
 650             die $merr if $merr;
 651             die "unable to parse migration status '$stat->{status}' - aborting\n";
 652         }
 653     }
 654
 655     # just to be sure that the tunnel gets closed on successful migration, on error
 656     # phase2_cleanup closes it *after* stopping the remote waiting VM
 657     if (!$self->{errors} && $self->{tunnel}) {
 658         eval { finish_tunnel($self, $self->{tunnel});  };
 659         if (my $err = $@) {
 660             $self->log('err', $err);
 661             $self->{errors} = 1;
 662         }
 663     }
 664 }
 665
 666 sub phase2_cleanup {
 667     my ($self, $vmid, $err) = @_;
 668
 669     return if !$self->{errors};
 670     $self->{phase2errors} = 1;
 671
 672     $self->log('info', "aborting phase 2 - cleanup resources");
 673
 674     $self->log('info', "migrate_cancel");
 675     eval {
 676         PVE::QemuServer::vm_mon_cmd_nocheck($vmid, "migrate_cancel");
 677     };
 678     $self->log('info', "migrate_cancel error: $@") if $@;
 679
 680     my $conf = $self->{vmconf};
 681     delete $conf->{lock};
 682     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 683     if (my $err = $@) {
 684         $self->log('err', $err);
 685     }
 686
 687     # cleanup ressources on target host
 688     my $nodename = PVE::INotify::nodename();
 689
 690     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 691     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 692     if (my $err = $@) {
 693         $self->log('err', $err);
 694         $self->{errors} = 1;
 695     }
 696
 697     if ($self->{tunnel}) {
 698         eval { finish_tunnel($self, $self->{tunnel});  };
 699         if (my $err = $@) {
 700             $self->log('err', $err);
 701             $self->{errors} = 1;
 702         }
 703     }
 704 }
 705
 706 sub phase3 {
 707     my ($self, $vmid) = @_;
 708
 709     my $volids = $self->{volumes};
 710     return if $self->{phase2errors};
 711
 712     # destroy local copies
 713     foreach my $volid (@$volids) {
 714         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 715         if (my $err = $@) {
 716             $self->log('err', "removing local copy of '$volid' failed - $err");
 717             $self->{errors} = 1;
 718             last if $err =~ /^interrupted by signal$/;
 719         }
 720     }
 721 }
 722
 723 sub phase3_cleanup {
 724     my ($self, $vmid, $err) = @_;
 725
 726     my $conf = $self->{vmconf};
 727     return if $self->{phase2errors};
 728
 729     # move config to remote node
 730     my $conffile = PVE::QemuConfig->config_file($vmid);
 731     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
 732
 733     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 734         if !rename($conffile, $newconffile);
 735
 736     if ($self->{livemigration}) {
 737         # now that config file is move, we can resume vm on target if livemigrate
 738         my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
 739         eval{ PVE::Tools::run_command($cmd, outfunc => sub {},
 740                 errfunc => sub {
 741                     my $line = shift;
 742                     $self->log('err', $line);
 743                 });
 744         };
 745         if (my $err = $@) {
 746             $self->log('err', $err);
 747             $self->{errors} = 1;
 748         }
 749     }
 750
 751     eval {
 752
 753         my $timer = 0;
 754         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
 755             $self->log('info', "Waiting for spice server migration");
 756             while (1) {
 757                 my $res = PVE::QemuServer::vm_mon_cmd_nocheck($vmid, 'query-spice');
 758                 last if int($res->{'migrated'}) == 1;
 759                 last if $timer > 50;
 760                 $timer ++;
 761                 usleep(200000);
 762             }
 763         }
 764     };
 765
 766     # always stop local VM
 767     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
 768     if (my $err = $@) {
 769         $self->log('err', "stopping vm failed - $err");
 770         $self->{errors} = 1;
 771     }
 772
 773     # always deactivate volumes - avoid lvm LVs to be active on several nodes
 774     eval {
 775         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 776         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 777     };
 778     if (my $err = $@) {
 779         $self->log('err', $err);
 780         $self->{errors} = 1;
 781     }
 782
 783     # clear migrate lock
 784     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
 785     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 786 }
 787
 788 sub final_cleanup {
 789     my ($self, $vmid) = @_;
 790
 791     # nothing to do
 792 }
 793
 794 1;