PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use PVE::QemuServer::Drive;
  15 use PVE::QemuServer::Machine;
  16 use PVE::QemuServer::Monitor qw(mon_cmd);
  17 use Time::HiRes qw( usleep );
  18 use PVE::RPCEnvironment;
  19 use PVE::ReplicationConfig;
  20 use PVE::ReplicationState;
  21 use PVE::Replication;
  22
  23 use base qw(PVE::AbstractMigrate);
  24
  25 sub fork_command_pipe {
  26     my ($self, $cmd) = @_;
  27
  28     my $reader = IO::File->new();
  29     my $writer = IO::File->new();
  30
  31     my $orig_pid = $$;
  32
  33     my $cpid;
  34
  35     eval { $cpid = open2($reader, $writer, @$cmd); };
  36
  37     my $err = $@;
  38
  39     # catch exec errors
  40     if ($orig_pid != $$) {
  41         $self->log('err', "can't fork command pipe\n");
  42         POSIX::_exit(1);
  43         kill('KILL', $$);
  44     }
  45
  46     die $err if $err;
  47
  48     return { writer => $writer, reader => $reader, pid => $cpid };
  49 }
  50
  51 sub finish_command_pipe {
  52     my ($self, $cmdpipe, $timeout) = @_;
  53
  54     my $cpid = $cmdpipe->{pid};
  55     return if !defined($cpid);
  56
  57     my $writer = $cmdpipe->{writer};
  58     my $reader = $cmdpipe->{reader};
  59
  60     $writer->close();
  61     $reader->close();
  62
  63     my $collect_child_process = sub {
  64         my $res = waitpid($cpid, WNOHANG);
  65         if (defined($res) && ($res == $cpid)) {
  66             delete $cmdpipe->{cpid};
  67             return 1;
  68         } else {
  69             return 0;
  70         }
  71      };
  72
  73     if ($timeout) {
  74         for (my $i = 0; $i < $timeout; $i++) {
  75             return if &$collect_child_process();
  76             sleep(1);
  77         }
  78     }
  79
  80     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  81     kill(15, $cpid);
  82
  83     # wait again
  84     for (my $i = 0; $i < 10; $i++) {
  85         return if &$collect_child_process();
  86         sleep(1);
  87     }
  88
  89     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  90     kill 9, $cpid;
  91     sleep 1;
  92
  93     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  94         if !&$collect_child_process();
  95 }
  96
  97 sub read_tunnel {
  98     my ($self, $tunnel, $timeout) = @_;
  99
 100     $timeout = 60 if !defined($timeout);
 101
 102     my $reader = $tunnel->{reader};
 103
 104     my $output;
 105     eval {
 106         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 107     };
 108     die "reading from tunnel failed: $@\n" if $@;
 109
 110     chomp $output;
 111
 112     return $output;
 113 }
 114
 115 sub write_tunnel {
 116     my ($self, $tunnel, $timeout, $command) = @_;
 117
 118     $timeout = 60 if !defined($timeout);
 119
 120     my $writer = $tunnel->{writer};
 121
 122     eval {
 123         PVE::Tools::run_with_timeout($timeout, sub {
 124             print $writer "$command\n";
 125             $writer->flush();
 126         });
 127     };
 128     die "writing to tunnel failed: $@\n" if $@;
 129
 130     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 131         my $res = eval { $self->read_tunnel($tunnel, 10); };
 132         die "no reply to command '$command': $@\n" if $@;
 133
 134         if ($res eq 'OK') {
 135             return;
 136         } else {
 137             die "tunnel replied '$res' to command '$command'\n";
 138         }
 139     }
 140 }
 141
 142 sub fork_tunnel {
 143     my ($self, $tunnel_addr) = @_;
 144
 145     my @localtunnelinfo = ();
 146     foreach my $addr (@$tunnel_addr) {
 147         push @localtunnelinfo, '-L', $addr;
 148     }
 149
 150     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 151
 152     my $tunnel = $self->fork_command_pipe($cmd);
 153
 154     eval {
 155         my $helo = $self->read_tunnel($tunnel, 60);
 156         die "no reply\n" if !$helo;
 157         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 158         die "got strange reply from mtunnel ('$helo')\n"
 159             if $helo !~ m/^tunnel online$/;
 160     };
 161     my $err = $@;
 162
 163     eval {
 164         my $ver = $self->read_tunnel($tunnel, 10);
 165         if ($ver =~ /^ver (\d+)$/) {
 166             $tunnel->{version} = $1;
 167             $self->log('info', "ssh tunnel $ver\n");
 168         } else {
 169             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 170         }
 171     };
 172
 173     if ($err) {
 174         $self->finish_command_pipe($tunnel);
 175         die "can't open migration tunnel - $err";
 176     }
 177     return $tunnel;
 178 }
 179
 180 sub finish_tunnel {
 181     my ($self, $tunnel) = @_;
 182
 183     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 184     my $err = $@;
 185
 186     $self->finish_command_pipe($tunnel, 30);
 187
 188     if ($tunnel->{sock_addr}) {
 189         # ssh does not clean up on local host
 190         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 191         PVE::Tools::run_command($cmd);
 192
 193         # .. and just to be sure check on remote side
 194         unshift @{$cmd}, @{$self->{rem_ssh}};
 195         PVE::Tools::run_command($cmd);
 196     }
 197
 198     die $err if $err;
 199 }
 200
 201 sub lock_vm {
 202     my ($self, $vmid, $code, @param) = @_;
 203
 204     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 205 }
 206
 207 sub prepare {
 208     my ($self, $vmid) = @_;
 209
 210     my $online = $self->{opts}->{online};
 211
 212     $self->{storecfg} = PVE::Storage::config();
 213
 214     # test if VM exists
 215     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 216
 217     PVE::QemuConfig->check_lock($conf);
 218
 219     my $running = 0;
 220     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 221         die "can't migrate running VM without --online\n" if !$online;
 222         $running = $pid;
 223
 224         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 225
 226     }
 227     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 228     if (scalar @$loc_res) {
 229         if ($self->{running} || !$self->{opts}->{force}) {
 230             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 231         } else {
 232             $self->log('info', "migrating VM which uses local devices");
 233         }
 234     }
 235
 236     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 237
 238     my $need_activate = [];
 239     foreach my $volid (@$vollist) {
 240         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 241
 242         # check if storage is available on both nodes
 243         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 244
 245         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 246         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 247
 248         if ($scfg->{shared}) {
 249             # PVE::Storage::activate_storage checks this for non-shared storages
 250             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 251             warn "Used shared storage '$sid' is not online on source node!\n"
 252                 if !$plugin->check_connection($sid, $scfg);
 253         } else {
 254             # only activate if not shared
 255             next if ($volid =~ m/vm-\d+-cloudinit/);
 256             push @$need_activate, $volid;
 257         }
 258     }
 259
 260     # activate volumes
 261     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 262
 263     # test ssh connection
 264     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 265     eval { $self->cmd_quiet($cmd); };
 266     die "Can't connect to destination address using public key\n" if $@;
 267
 268     return $running;
 269 }
 270
 271 sub sync_disks {
 272     my ($self, $vmid) = @_;
 273
 274     my $conf = $self->{vmconf};
 275
 276     # local volumes which have been copied
 277     $self->{volumes} = [];
 278
 279     my $override_targetsid = $self->{opts}->{targetstorage};
 280
 281     eval {
 282
 283         # found local volumes and their origin
 284         my $local_volumes = {};
 285         my $local_volumes_errors = {};
 286         my $other_errors = [];
 287         my $abort = 0;
 288
 289         my $log_error = sub {
 290             my ($msg, $volid) = @_;
 291
 292             if (defined($volid)) {
 293                 $local_volumes_errors->{$volid} = $msg;
 294             } else {
 295                 push @$other_errors, $msg;
 296             }
 297             $abort = 1;
 298         };
 299
 300         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 301         foreach my $storeid (@sids) {
 302             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 303             next if $scfg->{shared};
 304             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 305
 306             # get list from PVE::Storage (for unused volumes)
 307             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 308
 309             next if @{$dl->{$storeid}} == 0;
 310
 311             my $targetsid = $override_targetsid // $storeid;
 312
 313             # check if storage is available on target node
 314             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 315
 316             PVE::Storage::foreach_volid($dl, sub {
 317                 my ($volid, $sid, $volinfo) = @_;
 318
 319                 $local_volumes->{$volid}->{ref} = 'storage';
 320
 321                 # If with_snapshots is not set for storage migrate, it tries to use
 322                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 323                 # back to qcow2 is currently not possible.
 324                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 325                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 326             });
 327         }
 328
 329         my $replicatable_volumes = PVE::QemuConfig->get_replicatable_volumes($self->{storecfg}, $self->{vmid}, $conf);
 330
 331         my $test_volid = sub {
 332             my ($volid, $attr) = @_;
 333
 334             if ($volid =~ m|^/|) {
 335                 return if $attr->{shared};
 336                 $local_volumes->{$volid}->{ref} = 'config';
 337                 die "local file/device\n";
 338             }
 339
 340             my $snaprefs = $attr->{referenced_in_snapshot};
 341
 342             if ($attr->{cdrom}) {
 343                 if ($volid eq 'cdrom') {
 344                     my $msg = "can't migrate local cdrom drive";
 345                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 346                         my $snapnames = join(', ', sort keys %$snaprefs);
 347                         $msg .= " (referenced in snapshot - $snapnames)";
 348                     }
 349                     &$log_error("$msg\n");
 350                     return;
 351                 }
 352                 return if $volid eq 'none';
 353             }
 354
 355             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 356
 357             my $targetsid = $override_targetsid // $sid;
 358             # check if storage is available on both nodes
 359             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 360             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 361
 362             return if $scfg->{shared};
 363
 364             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 365
 366             if ($attr->{cdrom}) {
 367                 if ($volid =~ /vm-\d+-cloudinit/) {
 368                     $local_volumes->{$volid}->{ref} = 'generated';
 369                     return;
 370                 }
 371                 die "local cdrom image\n";
 372             }
 373
 374             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 375
 376             die "owned by other VM (owner = VM $owner)\n"
 377                 if !$owner || ($owner != $self->{vmid});
 378
 379             if (defined($snaprefs)) {
 380                 $local_volumes->{$volid}->{snapshots} = 1;
 381
 382                 # we cannot migrate shapshots on local storage
 383                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 384
 385                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 386                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 387                     die "non-migratable snapshot exists\n";
 388                 }
 389             }
 390
 391             die "referenced by linked clone(s)\n"
 392                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 393         };
 394
 395         PVE::QemuServer::foreach_volid($conf, sub {
 396             my ($volid, $attr) = @_;
 397             eval { $test_volid->($volid, $attr); };
 398             if (my $err = $@) {
 399                 &$log_error($err, $volid);
 400             }
 401         });
 402
 403         foreach my $vol (sort keys %$local_volumes) {
 404             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 405             my $ref = $local_volumes->{$vol}->{ref};
 406             if ($ref eq 'storage') {
 407                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 408             } elsif ($ref eq 'config') {
 409                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 410                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 411                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 412             } elsif ($ref eq 'snapshot') {
 413                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 414             } elsif ($ref eq 'generated') {
 415                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 416             } else {
 417                 $self->log('info', "found $type disk '$vol'\n");
 418             }
 419         }
 420
 421         foreach my $vol (sort keys %$local_volumes_errors) {
 422             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 423         }
 424         foreach my $err (@$other_errors) {
 425             $self->log('warn', "$err");
 426         }
 427
 428         if ($abort) {
 429             die "can't migrate VM - check log\n";
 430         }
 431
 432         # additional checks for local storage
 433         foreach my $volid (keys %$local_volumes) {
 434             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 435             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 436
 437             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 438
 439             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 440                 if !$migratable;
 441
 442             # image is a linked clone on local storage, se we can't migrate.
 443             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 444                 die "can't migrate '$volid' as it's a clone of '$basename'";
 445             }
 446         }
 447
 448         my $rep_cfg = PVE::ReplicationConfig->new();
 449         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 450             if ($self->{running}) {
 451                 my $live_replicatable_volumes = {};
 452                 PVE::QemuServer::foreach_drive($conf, sub {
 453                     my ($ds, $drive) = @_;
 454
 455                     my $volid = $drive->{file};
 456                     $live_replicatable_volumes->{$ds} = $volid
 457                         if defined($replicatable_volumes->{$volid});
 458                 });
 459                 foreach my $drive (keys %$live_replicatable_volumes) {
 460                     my $volid = $live_replicatable_volumes->{$drive};
 461
 462                     my $bitmap = "repl_$drive";
 463
 464                     # start tracking before replication to get full delta + a few duplicates
 465                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 466                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 467
 468                     # other info comes from target node in phase 2
 469                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 470                 }
 471             }
 472             $self->log('info', "replicating disk images");
 473
 474             my $start_time = time();
 475             my $logfunc = sub { $self->log('info', shift) };
 476             $self->{replicated_volumes} = PVE::Replication::run_replication(
 477                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 478         }
 479
 480         # sizes in config have to be accurate for remote node to correctly
 481         # allocate disks, rescan to be sure
 482         my $volid_hash = PVE::QemuServer::scan_volids($self->{storecfg}, $vmid);
 483         PVE::QemuServer::foreach_drive($conf, sub {
 484             my ($key, $drive) = @_;
 485             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 486             if (defined($updated)) {
 487                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 488                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 489             }
 490         });
 491
 492         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 493
 494         foreach my $volid (keys %$local_volumes) {
 495             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 496             my $targetsid = $override_targetsid // $sid;
 497             my $ref = $local_volumes->{$volid}->{ref};
 498             if ($self->{running} && $ref eq 'config') {
 499                 push @{$self->{online_local_volumes}}, $volid;
 500             } elsif ($ref eq 'generated') {
 501                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 502                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 503                 push @{$self->{volumes}}, $volid;
 504                 next;
 505             } else {
 506                 next if $self->{replicated_volumes}->{$volid};
 507                 push @{$self->{volumes}}, $volid;
 508                 my $opts = $self->{opts};
 509                 my $insecure = $opts->{migration_type} eq 'insecure';
 510                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 511                 # use 'migrate' limit for transfer to other node
 512                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 513                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 514                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 515
 516                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $targetsid,
 517                                               undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 518             }
 519         }
 520     };
 521     die "Failed to sync data - $@" if $@;
 522 }
 523
 524 sub cleanup_remotedisks {
 525     my ($self) = @_;
 526
 527     foreach my $target_drive (keys %{$self->{target_drive}}) {
 528         # don't clean up replicated disks!
 529         next if defined($self->{target_drive}->{$target_drive}->{bitmap});
 530
 531         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
 532         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 533
 534         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 535
 536         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 537         if (my $err = $@) {
 538             $self->log('err', $err);
 539             $self->{errors} = 1;
 540         }
 541     }
 542 }
 543
 544 sub cleanup_bitmaps {
 545     my ($self) = @_;
 546     foreach my $drive (%{$self->{target_drive}}) {
 547         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 548         next if !$bitmap;
 549         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 550         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 551     }
 552 }
 553
 554 sub phase1 {
 555     my ($self, $vmid) = @_;
 556
 557     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 558
 559     my $conf = $self->{vmconf};
 560
 561     # set migrate lock in config file
 562     $conf->{lock} = 'migrate';
 563     PVE::QemuConfig->write_config($vmid, $conf);
 564
 565     sync_disks($self, $vmid);
 566
 567     # sync_disks fixes disk sizes to match their actual size, write changes so
 568     # target allocates correct volumes
 569     PVE::QemuConfig->write_config($vmid, $conf);
 570 };
 571
 572 sub phase1_cleanup {
 573     my ($self, $vmid, $err) = @_;
 574
 575     $self->log('info', "aborting phase 1 - cleanup resources");
 576
 577     my $conf = $self->{vmconf};
 578     delete $conf->{lock};
 579     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 580     if (my $err = $@) {
 581         $self->log('err', $err);
 582     }
 583
 584     if ($self->{volumes}) {
 585         foreach my $volid (@{$self->{volumes}}) {
 586             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 587             # fixme: try to remove ?
 588         }
 589     }
 590
 591     eval { $self->cleanup_bitmaps() };
 592     if (my $err =$@) {
 593         $self->log('err', $err);
 594     }
 595
 596 }
 597
 598 sub phase2 {
 599     my ($self, $vmid) = @_;
 600
 601     my $conf = $self->{vmconf};
 602
 603     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 604
 605     my $raddr;
 606     my $rport;
 607     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 608     my $nodename = PVE::INotify::nodename();
 609
 610     ## start on remote node
 611     my $cmd = [@{$self->{rem_ssh}}];
 612
 613     my $spice_ticket;
 614     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 615         my $res = mon_cmd($vmid, 'query-spice');
 616         $spice_ticket = $res->{ticket};
 617     }
 618
 619     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 620
 621     my $migration_type = $self->{opts}->{migration_type};
 622
 623     push @$cmd, '--migration_type', $migration_type;
 624
 625     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 626       if $self->{opts}->{migration_network};
 627
 628     if ($migration_type eq 'insecure') {
 629         push @$cmd, '--stateuri', 'tcp';
 630     } else {
 631         push @$cmd, '--stateuri', 'unix';
 632     }
 633
 634     if ($self->{forcemachine}) {
 635         push @$cmd, '--machine', $self->{forcemachine};
 636     }
 637
 638     if ($self->{online_local_volumes}) {
 639         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 640     }
 641
 642     my $spice_port;
 643     my $tunnel_addr = [];
 644     my $sock_addr = [];
 645     # version > 0 for unix socket support
 646     my $nbd_protocol_version = 1;
 647     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 648     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 649     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 650
 651     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 652     # instead we pipe it through STDIN
 653     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 654         my $line = shift;
 655
 656         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 657             $raddr = $1;
 658             $rport = int($2);
 659             $ruri = "tcp:$raddr:$rport";
 660         }
 661         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 662             $raddr = $1;
 663             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 664             $ruri = "unix:$raddr";
 665         }
 666         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 667             $raddr = "localhost";
 668             $rport = int($1);
 669             $ruri = "tcp:$raddr:$rport";
 670         }
 671         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 672             $spice_port = int($1);
 673         }
 674         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 675             my $drivestr = $4;
 676             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 677             my $targetdrive = $3;
 678             $targetdrive =~ s/drive-//g;
 679
 680             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 681             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 682         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 683             my $drivestr = $4;
 684             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 685             my $nbd_unix_addr = $1;
 686             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 687             my $targetdrive = $3;
 688             $targetdrive =~ s/drive-//g;
 689
 690             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 691             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 692             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 693             push @$sock_addr, $nbd_unix_addr;
 694         } elsif ($line =~ m/^QEMU: (.*)$/) {
 695             $self->log('info', "[$self->{node}] $1\n");
 696         }
 697     }, errfunc => sub {
 698         my $line = shift;
 699         $self->log('info', "[$self->{node}] $line");
 700     }, noerr => 1);
 701
 702     die "remote command failed with exit code $exitcode\n" if $exitcode;
 703
 704     die "unable to detect remote migration address\n" if !$raddr;
 705
 706     $self->log('info', "start remote tunnel");
 707
 708     if ($migration_type eq 'secure') {
 709
 710         if ($ruri =~ /^unix:/) {
 711             unlink $raddr;
 712             push @$tunnel_addr, "$raddr:$raddr";
 713             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 714             push @$sock_addr, $raddr;
 715
 716             my $unix_socket_try = 0; # wait for the socket to become ready
 717             while ($unix_socket_try <= 100) {
 718                 $unix_socket_try++;
 719                 my $available = 0;
 720                 foreach my $sock (@$sock_addr) {
 721                     if (-S $sock) {
 722                         $available++;
 723                     }
 724                 }
 725
 726                 if ($available == @$sock_addr) {
 727                     last;
 728                 }
 729
 730                 usleep(50000);
 731             }
 732             if ($unix_socket_try > 100) {
 733                 $self->{errors} = 1;
 734                 $self->finish_tunnel($self->{tunnel});
 735                 die "Timeout, migration socket $ruri did not get ready";
 736             }
 737
 738         } elsif ($ruri =~ /^tcp:/) {
 739             my $tunnel_addr;
 740             if ($raddr eq "localhost") {
 741                 # for backwards compatibility with older qemu-server versions
 742                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 743                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 744                 $tunnel_addr = "$lport:localhost:$rport";
 745             }
 746
 747             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 748
 749         } else {
 750             die "unsupported protocol in migration URI: $ruri\n";
 751         }
 752     } else {
 753         #fork tunnel for insecure migration, to send faster commands like resume
 754         $self->{tunnel} = $self->fork_tunnel();
 755     }
 756     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 757
 758     my $start = time();
 759
 760     my $opt_bwlimit = $self->{opts}->{bwlimit};
 761
 762     if (defined($self->{online_local_volumes})) {
 763         $self->{storage_migration} = 1;
 764         $self->{storage_migration_jobs} = {};
 765         $self->log('info', "starting storage migration");
 766
 767         die "The number of local disks does not match between the source and the destination.\n"
 768             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 769         foreach my $drive (keys %{$self->{target_drive}}){
 770             my $target = $self->{target_drive}->{$drive};
 771             my $nbd_uri = $target->{nbd_uri};
 772
 773             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 774             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 775
 776             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_drive->{file});
 777             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_drive->{file});
 778
 779             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 780             my $bitmap = $target->{bitmap};
 781
 782             $self->log('info', "$drive: start migration to $nbd_uri");
 783             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 784         }
 785     }
 786
 787     $self->log('info', "starting online/live migration on $ruri");
 788     $self->{livemigration} = 1;
 789
 790     # load_defaults
 791     my $defaults = PVE::QemuServer::load_defaults();
 792
 793     $self->log('info', "set migration_caps");
 794     eval {
 795         PVE::QemuServer::set_migration_caps($vmid);
 796     };
 797     warn $@ if $@;
 798
 799     my $qemu_migrate_params = {};
 800
 801     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 802     # migrate_speed parameter in qm.conf - take the lower of the two.
 803     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 804     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 805     # migrate_speed is in MB/s, bwlimit in KB/s
 806     $migrate_speed *= 1024;
 807
 808     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 809
 810     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 811     # default of 8192m which is basically unlimited
 812     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 813
 814     # qmp takes migrate_speed in B/s.
 815     $migrate_speed *= 1024;
 816     $self->log('info', "migration speed limit: $migrate_speed B/s");
 817     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 818
 819     my $migrate_downtime = $defaults->{migrate_downtime};
 820     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 821     if (defined($migrate_downtime)) {
 822         # migrate-set-parameters expects limit in ms
 823         $migrate_downtime *= 1000;
 824         $self->log('info', "migration downtime limit: $migrate_downtime ms");
 825         $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 826     }
 827
 828     # set cachesize to 10% of the total memory
 829     my $memory =  $conf->{memory} || $defaults->{memory};
 830     my $cachesize = int($memory * 1048576 / 10);
 831     $cachesize = round_powerof2($cachesize);
 832
 833     $self->log('info', "migration cachesize: $cachesize B");
 834     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 835
 836     $self->log('info', "set migration parameters");
 837     eval {
 838         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 839     };
 840     $self->log('info', "migrate-set-parameters error: $@") if $@;
 841
 842     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 843         my $rpcenv = PVE::RPCEnvironment::get();
 844         my $authuser = $rpcenv->get_user();
 845
 846         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 847
 848         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 849         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 850
 851         $self->log('info', "spice client_migrate_info");
 852
 853         eval {
 854             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 855                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 856                                                 'cert-subject' => $subject);
 857         };
 858         $self->log('info', "client_migrate_info error: $@") if $@;
 859
 860     }
 861
 862     $self->log('info', "start migrate command to $ruri");
 863     eval {
 864         mon_cmd($vmid, "migrate", uri => $ruri);
 865     };
 866     my $merr = $@;
 867     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 868
 869     my $lstat = 0;
 870     my $usleep = 1000000;
 871     my $i = 0;
 872     my $err_count = 0;
 873     my $lastrem = undef;
 874     my $downtimecounter = 0;
 875     while (1) {
 876         $i++;
 877         my $avglstat = $lstat/$i if $lstat;
 878
 879         usleep($usleep);
 880         my $stat;
 881         eval {
 882             $stat = mon_cmd($vmid, "query-migrate");
 883         };
 884         if (my $err = $@) {
 885             $err_count++;
 886             warn "query migrate failed: $err\n";
 887             $self->log('info', "query migrate failed: $err");
 888             if ($err_count <= 5) {
 889                 usleep(1000000);
 890                 next;
 891             }
 892             die "too many query migrate failures - aborting\n";
 893         }
 894
 895         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 896             sleep(1);
 897             next;
 898         }
 899
 900         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 901             $merr = undef;
 902             $err_count = 0;
 903             if ($stat->{status} eq 'completed') {
 904                 my $delay = time() - $start;
 905                 if ($delay > 0) {
 906                     my $mbps = sprintf "%.2f", $memory / $delay;
 907                     my $downtime = $stat->{downtime} || 0;
 908                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 909                 }
 910             }
 911
 912             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 913                 $self->log('info', "migration status error: $stat->{status}");
 914                 die "aborting\n"
 915             }
 916
 917             if ($stat->{status} ne 'active') {
 918                 $self->log('info', "migration status: $stat->{status}");
 919                 last;
 920             }
 921
 922             if ($stat->{ram}->{transferred} ne $lstat) {
 923                 my $trans = $stat->{ram}->{transferred} || 0;
 924                 my $rem = $stat->{ram}->{remaining} || 0;
 925                 my $total = $stat->{ram}->{total} || 0;
 926                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 927                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 928                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 929                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 930                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 931                 # reduce sleep if remainig memory is lower than the average transfer speed
 932                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 933
 934                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 935                            "remaining ${rem}), total ${total})");
 936
 937                 if (${xbzrlecachesize}) {
 938                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 939                 }
 940
 941                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 942                     $downtimecounter++;
 943                 }
 944                 $lastrem = $rem;
 945
 946                 if ($downtimecounter > 5) {
 947                     $downtimecounter = 0;
 948                     $migrate_downtime *= 2;
 949                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 950                     eval {
 951                         mon_cmd($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 952                     };
 953                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 954                 }
 955
 956             }
 957
 958
 959             $lstat = $stat->{ram}->{transferred};
 960
 961         } else {
 962             die $merr if $merr;
 963             die "unable to parse migration status '$stat->{status}' - aborting\n";
 964         }
 965     }
 966 }
 967
 968 sub phase2_cleanup {
 969     my ($self, $vmid, $err) = @_;
 970
 971     return if !$self->{errors};
 972     $self->{phase2errors} = 1;
 973
 974     $self->log('info', "aborting phase 2 - cleanup resources");
 975
 976     $self->log('info', "migrate_cancel");
 977     eval {
 978         mon_cmd($vmid, "migrate_cancel");
 979     };
 980     $self->log('info', "migrate_cancel error: $@") if $@;
 981
 982     my $conf = $self->{vmconf};
 983     delete $conf->{lock};
 984     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 985     if (my $err = $@) {
 986         $self->log('err', $err);
 987     }
 988
 989     # cleanup ressources on target host
 990     if ($self->{storage_migration}) {
 991
 992         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 993         if (my $err = $@) {
 994             $self->log('err', $err);
 995         }
 996
 997         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 998         if (my $err = $@) {
 999             $self->log('err', $err);
1000         }
1001         eval { $self->cleanup_bitmaps() };
1002         if (my $err =$@) {
1003             $self->log('err', $err);
1004         }
1005     }
1006
1007     my $nodename = PVE::INotify::nodename();
1008
1009     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1010     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1011     if (my $err = $@) {
1012         $self->log('err', $err);
1013         $self->{errors} = 1;
1014     }
1015
1016     if ($self->{tunnel}) {
1017         eval { finish_tunnel($self, $self->{tunnel});  };
1018         if (my $err = $@) {
1019             $self->log('err', $err);
1020             $self->{errors} = 1;
1021         }
1022     }
1023 }
1024
1025 sub phase3 {
1026     my ($self, $vmid) = @_;
1027
1028     my $volids = $self->{volumes};
1029     return if $self->{phase2errors};
1030
1031     # destroy local copies
1032     foreach my $volid (@$volids) {
1033         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1034         if (my $err = $@) {
1035             $self->log('err', "removing local copy of '$volid' failed - $err");
1036             $self->{errors} = 1;
1037             last if $err =~ /^interrupted by signal$/;
1038         }
1039     }
1040 }
1041
1042 sub phase3_cleanup {
1043     my ($self, $vmid, $err) = @_;
1044
1045     my $conf = $self->{vmconf};
1046     return if $self->{phase2errors};
1047
1048     my $tunnel = $self->{tunnel};
1049
1050     if ($self->{storage_migration}) {
1051         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1052         # to avoid it trying to re-establish it. We are in blockjob ready state,
1053         # thus, this command changes to it to blockjob complete (see qapi docs)
1054         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1055
1056         if (my $err = $@) {
1057             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1058             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1059             die "Failed to complete storage migration: $err\n";
1060         } else {
1061             foreach my $target_drive (keys %{$self->{target_drive}}) {
1062                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
1063                 $conf->{$target_drive} = PVE::QemuServer::print_drive($drive);
1064                 PVE::QemuConfig->write_config($vmid, $conf);
1065             }
1066         }
1067     }
1068
1069     # transfer replication state before move config
1070     $self->transfer_replication_state() if $self->{replicated_volumes};
1071
1072     # move config to remote node
1073     my $conffile = PVE::QemuConfig->config_file($vmid);
1074     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1075
1076     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1077         if !rename($conffile, $newconffile);
1078
1079     $self->switch_replication_job_target() if $self->{replicated_volumes};
1080
1081     if ($self->{livemigration}) {
1082         if ($self->{storage_migration}) {
1083             # stop nbd server on remote vm - requirement for resume since 2.9
1084             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1085
1086             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1087             if (my $err = $@) {
1088                 $self->log('err', $err);
1089                 $self->{errors} = 1;
1090             }
1091         }
1092
1093         # config moved and nbd server stopped - now we can resume vm on target
1094         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1095             eval {
1096                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1097             };
1098             if (my $err = $@) {
1099                 $self->log('err', $err);
1100                 $self->{errors} = 1;
1101             }
1102         } else {
1103             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1104             my $logf = sub {
1105                 my $line = shift;
1106                 $self->log('err', $line);
1107             };
1108             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1109             if (my $err = $@) {
1110                 $self->log('err', $err);
1111                 $self->{errors} = 1;
1112             }
1113         }
1114
1115         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1116             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1117             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1118         }
1119     }
1120
1121     # close tunnel on successful migration, on error phase2_cleanup closed it
1122     if ($tunnel) {
1123         eval { finish_tunnel($self, $tunnel);  };
1124         if (my $err = $@) {
1125             $self->log('err', $err);
1126             $self->{errors} = 1;
1127         }
1128     }
1129
1130     eval {
1131         my $timer = 0;
1132         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1133             $self->log('info', "Waiting for spice server migration");
1134             while (1) {
1135                 my $res = mon_cmd($vmid, 'query-spice');
1136                 last if int($res->{'migrated'}) == 1;
1137                 last if $timer > 50;
1138                 $timer ++;
1139                 usleep(200000);
1140             }
1141         }
1142     };
1143
1144     # always stop local VM
1145     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1146     if (my $err = $@) {
1147         $self->log('err', "stopping vm failed - $err");
1148         $self->{errors} = 1;
1149     }
1150
1151     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1152     eval {
1153         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1154         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1155     };
1156     if (my $err = $@) {
1157         $self->log('err', $err);
1158         $self->{errors} = 1;
1159     }
1160
1161     if($self->{storage_migration}) {
1162         # destroy local copies
1163         my $volids = $self->{online_local_volumes};
1164
1165         foreach my $volid (@$volids) {
1166             # keep replicated volumes!
1167             next if $self->{replicated_volumes}->{$volid};
1168
1169             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1170             if (my $err = $@) {
1171                 $self->log('err', "removing local copy of '$volid' failed - $err");
1172                 $self->{errors} = 1;
1173                 last if $err =~ /^interrupted by signal$/;
1174             }
1175         }
1176
1177     }
1178
1179     # clear migrate lock
1180     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1181     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1182 }
1183
1184 sub final_cleanup {
1185     my ($self, $vmid) = @_;
1186
1187     # nothing to do
1188 }
1189
1190 sub round_powerof2 {
1191     return 1 if $_[0] < 2;
1192     return 2 << int(log($_[0]-1)/log(2));
1193 }
1194
1195 1;