PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuServer::Drive;
  21 use PVE::QemuServer::Helpers qw(min_version);
  22 use PVE::QemuServer::Machine;
  23 use PVE::QemuServer::Monitor qw(mon_cmd);
  24 use PVE::QemuServer;
  25
  26 use PVE::AbstractMigrate;
  27 use base qw(PVE::AbstractMigrate);
  28
  29 sub fork_command_pipe {
  30     my ($self, $cmd) = @_;
  31
  32     my $reader = IO::File->new();
  33     my $writer = IO::File->new();
  34
  35     my $orig_pid = $$;
  36
  37     my $cpid;
  38
  39     eval { $cpid = open2($reader, $writer, @$cmd); };
  40
  41     my $err = $@;
  42
  43     # catch exec errors
  44     if ($orig_pid != $$) {
  45         $self->log('err', "can't fork command pipe\n");
  46         POSIX::_exit(1);
  47         kill('KILL', $$);
  48     }
  49
  50     die $err if $err;
  51
  52     return { writer => $writer, reader => $reader, pid => $cpid };
  53 }
  54
  55 sub finish_command_pipe {
  56     my ($self, $cmdpipe, $timeout) = @_;
  57
  58     my $cpid = $cmdpipe->{pid};
  59     return if !defined($cpid);
  60
  61     my $writer = $cmdpipe->{writer};
  62     my $reader = $cmdpipe->{reader};
  63
  64     $writer->close();
  65     $reader->close();
  66
  67     my $collect_child_process = sub {
  68         my $res = waitpid($cpid, WNOHANG);
  69         if (defined($res) && ($res == $cpid)) {
  70             delete $cmdpipe->{cpid};
  71             return 1;
  72         } else {
  73             return 0;
  74         }
  75      };
  76
  77     if ($timeout) {
  78         for (my $i = 0; $i < $timeout; $i++) {
  79             return if &$collect_child_process();
  80             sleep(1);
  81         }
  82     }
  83
  84     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  85     kill(15, $cpid);
  86
  87     # wait again
  88     for (my $i = 0; $i < 10; $i++) {
  89         return if &$collect_child_process();
  90         sleep(1);
  91     }
  92
  93     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  94     kill 9, $cpid;
  95     sleep 1;
  96
  97     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  98         if !&$collect_child_process();
  99 }
 100
 101 sub read_tunnel {
 102     my ($self, $tunnel, $timeout) = @_;
 103
 104     $timeout = 60 if !defined($timeout);
 105
 106     my $reader = $tunnel->{reader};
 107
 108     my $output;
 109     eval {
 110         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 111     };
 112     die "reading from tunnel failed: $@\n" if $@;
 113
 114     chomp $output;
 115
 116     return $output;
 117 }
 118
 119 sub write_tunnel {
 120     my ($self, $tunnel, $timeout, $command) = @_;
 121
 122     $timeout = 60 if !defined($timeout);
 123
 124     my $writer = $tunnel->{writer};
 125
 126     eval {
 127         PVE::Tools::run_with_timeout($timeout, sub {
 128             print $writer "$command\n";
 129             $writer->flush();
 130         });
 131     };
 132     die "writing to tunnel failed: $@\n" if $@;
 133
 134     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 135         my $res = eval { $self->read_tunnel($tunnel, 10); };
 136         die "no reply to command '$command': $@\n" if $@;
 137
 138         if ($res eq 'OK') {
 139             return;
 140         } else {
 141             die "tunnel replied '$res' to command '$command'\n";
 142         }
 143     }
 144 }
 145
 146 sub fork_tunnel {
 147     my ($self, $tunnel_addr) = @_;
 148
 149     my @localtunnelinfo = ();
 150     foreach my $addr (@$tunnel_addr) {
 151         push @localtunnelinfo, '-L', $addr;
 152     }
 153
 154     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 155
 156     my $tunnel = $self->fork_command_pipe($cmd);
 157
 158     eval {
 159         my $helo = $self->read_tunnel($tunnel, 60);
 160         die "no reply\n" if !$helo;
 161         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 162         die "got strange reply from mtunnel ('$helo')\n"
 163             if $helo !~ m/^tunnel online$/;
 164     };
 165     my $err = $@;
 166
 167     eval {
 168         my $ver = $self->read_tunnel($tunnel, 10);
 169         if ($ver =~ /^ver (\d+)$/) {
 170             $tunnel->{version} = $1;
 171             $self->log('info', "ssh tunnel $ver\n");
 172         } else {
 173             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 174         }
 175     };
 176
 177     if ($err) {
 178         $self->finish_command_pipe($tunnel);
 179         die "can't open migration tunnel - $err";
 180     }
 181     return $tunnel;
 182 }
 183
 184 sub finish_tunnel {
 185     my ($self, $tunnel) = @_;
 186
 187     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 188     my $err = $@;
 189
 190     $self->finish_command_pipe($tunnel, 30);
 191
 192     if ($tunnel->{sock_addr}) {
 193         # ssh does not clean up on local host
 194         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 195         PVE::Tools::run_command($cmd);
 196
 197         # .. and just to be sure check on remote side
 198         unshift @{$cmd}, @{$self->{rem_ssh}};
 199         PVE::Tools::run_command($cmd);
 200     }
 201
 202     die $err if $err;
 203 }
 204
 205 sub lock_vm {
 206     my ($self, $vmid, $code, @param) = @_;
 207
 208     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 209 }
 210
 211 sub prepare {
 212     my ($self, $vmid) = @_;
 213
 214     my $online = $self->{opts}->{online};
 215
 216     $self->{storecfg} = PVE::Storage::config();
 217
 218     # test if VM exists
 219     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 220
 221     PVE::QemuConfig->check_lock($conf);
 222
 223     my $running = 0;
 224     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 225         die "can't migrate running VM without --online\n" if !$online;
 226         $running = $pid;
 227
 228         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 229
 230     }
 231     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 232     if (scalar @$loc_res) {
 233         if ($self->{running} || !$self->{opts}->{force}) {
 234             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 235         } else {
 236             $self->log('info', "migrating VM which uses local devices");
 237         }
 238     }
 239
 240     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 241
 242     my $need_activate = [];
 243     foreach my $volid (@$vollist) {
 244         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 245
 246         # check if storage is available on both nodes
 247         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 248
 249         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 250         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 251
 252         if ($scfg->{shared}) {
 253             # PVE::Storage::activate_storage checks this for non-shared storages
 254             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 255             warn "Used shared storage '$sid' is not online on source node!\n"
 256                 if !$plugin->check_connection($sid, $scfg);
 257         } else {
 258             # only activate if not shared
 259             next if ($volid =~ m/vm-\d+-cloudinit/);
 260             push @$need_activate, $volid;
 261         }
 262     }
 263
 264     # activate volumes
 265     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 266
 267     # test ssh connection
 268     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 269     eval { $self->cmd_quiet($cmd); };
 270     die "Can't connect to destination address using public key\n" if $@;
 271
 272     return $running;
 273 }
 274
 275 sub sync_disks {
 276     my ($self, $vmid) = @_;
 277
 278     my $conf = $self->{vmconf};
 279
 280     # local volumes which have been copied
 281     $self->{volumes} = [];
 282
 283     my $storecfg = $self->{storecfg};
 284     my $override_targetsid = $self->{opts}->{targetstorage};
 285
 286     eval {
 287
 288         # found local volumes and their origin
 289         my $local_volumes = {};
 290         my $local_volumes_errors = {};
 291         my $other_errors = [];
 292         my $abort = 0;
 293
 294         my $log_error = sub {
 295             my ($msg, $volid) = @_;
 296
 297             if (defined($volid)) {
 298                 $local_volumes_errors->{$volid} = $msg;
 299             } else {
 300                 push @$other_errors, $msg;
 301             }
 302             $abort = 1;
 303         };
 304
 305         my @sids = PVE::Storage::storage_ids($storecfg);
 306         foreach my $storeid (@sids) {
 307             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 308             next if $scfg->{shared};
 309             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 310
 311             # get list from PVE::Storage (for unused volumes)
 312             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 313
 314             next if @{$dl->{$storeid}} == 0;
 315
 316             my $targetsid = $override_targetsid // $storeid;
 317
 318             # check if storage is available on target node
 319             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 320
 321             PVE::Storage::foreach_volid($dl, sub {
 322                 my ($volid, $sid, $volinfo) = @_;
 323
 324                 $local_volumes->{$volid}->{ref} = 'storage';
 325
 326                 # If with_snapshots is not set for storage migrate, it tries to use
 327                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 328                 # back to qcow2 is currently not possible.
 329                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 330                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 331             });
 332         }
 333
 334         my $rep_cfg = PVE::ReplicationConfig->new();
 335         my $replication_jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node});
 336         my $replicatable_volumes = $replication_jobcfg ? PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1) : {};
 337
 338         my $test_volid = sub {
 339             my ($volid, $attr) = @_;
 340
 341             if ($volid =~ m|^/|) {
 342                 return if $attr->{shared};
 343                 $local_volumes->{$volid}->{ref} = 'config';
 344                 die "local file/device\n";
 345             }
 346
 347             my $snaprefs = $attr->{referenced_in_snapshot};
 348
 349             if ($attr->{cdrom}) {
 350                 if ($volid eq 'cdrom') {
 351                     my $msg = "can't migrate local cdrom drive";
 352                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 353                         my $snapnames = join(', ', sort keys %$snaprefs);
 354                         $msg .= " (referenced in snapshot - $snapnames)";
 355                     }
 356                     &$log_error("$msg\n");
 357                     return;
 358                 }
 359                 return if $volid eq 'none';
 360             }
 361
 362             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 363
 364             my $targetsid = $override_targetsid // $sid;
 365             # check if storage is available on both nodes
 366             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 367             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 368
 369             return if $scfg->{shared};
 370
 371             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 372
 373             if ($attr->{cdrom}) {
 374                 if ($volid =~ /vm-\d+-cloudinit/) {
 375                     $local_volumes->{$volid}->{ref} = 'generated';
 376                     return;
 377                 }
 378                 die "local cdrom image\n";
 379             }
 380
 381             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 382
 383             die "owned by other VM (owner = VM $owner)\n"
 384                 if !$owner || ($owner != $vmid);
 385
 386             if (defined($snaprefs)) {
 387                 $local_volumes->{$volid}->{snapshots} = 1;
 388
 389                 # we cannot migrate shapshots on local storage
 390                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 391
 392                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 393                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 394                     die "non-migratable snapshot exists\n";
 395                 }
 396             }
 397
 398             die "referenced by linked clone(s)\n"
 399                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 400         };
 401
 402         PVE::QemuServer::foreach_volid($conf, sub {
 403             my ($volid, $attr) = @_;
 404             eval { $test_volid->($volid, $attr); };
 405             if (my $err = $@) {
 406                 &$log_error($err, $volid);
 407             }
 408         });
 409
 410         foreach my $vol (sort keys %$local_volumes) {
 411             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 412             my $ref = $local_volumes->{$vol}->{ref};
 413             if ($ref eq 'storage') {
 414                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 415             } elsif ($ref eq 'config') {
 416                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 417                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 418                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 419             } elsif ($ref eq 'snapshot') {
 420                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 421             } elsif ($ref eq 'generated') {
 422                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 423             } else {
 424                 $self->log('info', "found $type disk '$vol'\n");
 425             }
 426         }
 427
 428         foreach my $vol (sort keys %$local_volumes_errors) {
 429             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 430         }
 431         foreach my $err (@$other_errors) {
 432             $self->log('warn', "$err");
 433         }
 434
 435         if ($abort) {
 436             die "can't migrate VM - check log\n";
 437         }
 438
 439         # additional checks for local storage
 440         foreach my $volid (keys %$local_volumes) {
 441             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 442             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 443
 444             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 445
 446             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 447                 if !$migratable;
 448
 449             # image is a linked clone on local storage, se we can't migrate.
 450             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 451                 die "can't migrate '$volid' as it's a clone of '$basename'";
 452             }
 453         }
 454
 455         if ($replication_jobcfg) {
 456             if ($self->{running}) {
 457
 458                 my $version = PVE::QemuServer::kvm_user_version();
 459                 if (!min_version($version, 4, 2)) {
 460                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 461                 }
 462
 463                 my $live_replicatable_volumes = {};
 464                 PVE::QemuServer::foreach_drive($conf, sub {
 465                     my ($ds, $drive) = @_;
 466
 467                     my $volid = $drive->{file};
 468                     $live_replicatable_volumes->{$ds} = $volid
 469                         if defined($replicatable_volumes->{$volid});
 470                 });
 471                 foreach my $drive (keys %$live_replicatable_volumes) {
 472                     my $volid = $live_replicatable_volumes->{$drive};
 473
 474                     my $bitmap = "repl_$drive";
 475
 476                     # start tracking before replication to get full delta + a few duplicates
 477                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 478                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 479
 480                     # other info comes from target node in phase 2
 481                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 482                 }
 483             }
 484             $self->log('info', "replicating disk images");
 485
 486             my $start_time = time();
 487             my $logfunc = sub { $self->log('info', shift) };
 488             $self->{replicated_volumes} = PVE::Replication::run_replication(
 489                'PVE::QemuConfig', $replication_jobcfg, $start_time, $start_time, $logfunc);
 490         }
 491
 492         # sizes in config have to be accurate for remote node to correctly
 493         # allocate disks, rescan to be sure
 494         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 495         PVE::QemuServer::foreach_drive($conf, sub {
 496             my ($key, $drive) = @_;
 497             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 498             if (defined($updated)) {
 499                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 500                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 501             }
 502         });
 503
 504         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 505
 506         foreach my $volid (keys %$local_volumes) {
 507             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 508             my $targetsid = $override_targetsid // $sid;
 509             my $ref = $local_volumes->{$volid}->{ref};
 510             if ($self->{running} && $ref eq 'config') {
 511                 push @{$self->{online_local_volumes}}, $volid;
 512             } elsif ($ref eq 'generated') {
 513                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 514                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 515                 push @{$self->{volumes}}, $volid;
 516                 next;
 517             } else {
 518                 next if $self->{replicated_volumes}->{$volid};
 519                 push @{$self->{volumes}}, $volid;
 520                 my $opts = $self->{opts};
 521                 my $insecure = $opts->{migration_type} eq 'insecure';
 522                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 523                 # use 'migrate' limit for transfer to other node
 524                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 525                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 526                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 527
 528                 PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info}, $targetsid,
 529                                               undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 530             }
 531         }
 532     };
 533     die "Failed to sync data - $@" if $@;
 534 }
 535
 536 sub cleanup_remotedisks {
 537     my ($self) = @_;
 538
 539     foreach my $target_drive (keys %{$self->{target_drive}}) {
 540         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
 541
 542         # don't clean up replicated disks!
 543         next if defined($self->{replicated_volumes}->{$drive->{file}});
 544
 545         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 546
 547         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 548
 549         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 550         if (my $err = $@) {
 551             $self->log('err', $err);
 552             $self->{errors} = 1;
 553         }
 554     }
 555 }
 556
 557 sub cleanup_bitmaps {
 558     my ($self) = @_;
 559     foreach my $drive (keys %{$self->{target_drive}}) {
 560         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 561         next if !$bitmap;
 562         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 563         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 564     }
 565 }
 566
 567 sub phase1 {
 568     my ($self, $vmid) = @_;
 569
 570     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 571
 572     my $conf = $self->{vmconf};
 573
 574     # set migrate lock in config file
 575     $conf->{lock} = 'migrate';
 576     PVE::QemuConfig->write_config($vmid, $conf);
 577
 578     sync_disks($self, $vmid);
 579
 580     # sync_disks fixes disk sizes to match their actual size, write changes so
 581     # target allocates correct volumes
 582     PVE::QemuConfig->write_config($vmid, $conf);
 583 };
 584
 585 sub phase1_cleanup {
 586     my ($self, $vmid, $err) = @_;
 587
 588     $self->log('info', "aborting phase 1 - cleanup resources");
 589
 590     my $conf = $self->{vmconf};
 591     delete $conf->{lock};
 592     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 593     if (my $err = $@) {
 594         $self->log('err', $err);
 595     }
 596
 597     if ($self->{volumes}) {
 598         foreach my $volid (@{$self->{volumes}}) {
 599             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 600             # fixme: try to remove ?
 601         }
 602     }
 603
 604     eval { $self->cleanup_bitmaps() };
 605     if (my $err =$@) {
 606         $self->log('err', $err);
 607     }
 608
 609 }
 610
 611 sub phase2 {
 612     my ($self, $vmid) = @_;
 613
 614     my $conf = $self->{vmconf};
 615
 616     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 617
 618     my $raddr;
 619     my $rport;
 620     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 621     my $nodename = PVE::INotify::nodename();
 622
 623     ## start on remote node
 624     my $cmd = [@{$self->{rem_ssh}}];
 625
 626     my $spice_ticket;
 627     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 628         my $res = mon_cmd($vmid, 'query-spice');
 629         $spice_ticket = $res->{ticket};
 630     }
 631
 632     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 633
 634     my $migration_type = $self->{opts}->{migration_type};
 635
 636     push @$cmd, '--migration_type', $migration_type;
 637
 638     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 639       if $self->{opts}->{migration_network};
 640
 641     if ($migration_type eq 'insecure') {
 642         push @$cmd, '--stateuri', 'tcp';
 643     } else {
 644         push @$cmd, '--stateuri', 'unix';
 645     }
 646
 647     if ($self->{forcemachine}) {
 648         push @$cmd, '--machine', $self->{forcemachine};
 649     }
 650
 651     if ($self->{online_local_volumes}) {
 652         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 653     }
 654
 655     my $spice_port;
 656     my $tunnel_addr = [];
 657     my $sock_addr = [];
 658     # version > 0 for unix socket support
 659     my $nbd_protocol_version = 1;
 660     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 661     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 662     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 663     foreach my $volid (keys %{$self->{replicated_volumes}}) {
 664         $input .= "replicated_volume: $volid\n";
 665     }
 666
 667     my $target_replicated_volumes = {};
 668
 669     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 670     # instead we pipe it through STDIN
 671     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 672         my $line = shift;
 673
 674         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 675             $raddr = $1;
 676             $rport = int($2);
 677             $ruri = "tcp:$raddr:$rport";
 678         }
 679         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 680             $raddr = $1;
 681             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 682             $ruri = "unix:$raddr";
 683         }
 684         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 685             $raddr = "localhost";
 686             $rport = int($1);
 687             $ruri = "tcp:$raddr:$rport";
 688         }
 689         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 690             $spice_port = int($1);
 691         }
 692         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 693             my $drivestr = $4;
 694             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 695             my $targetdrive = $3;
 696             $targetdrive =~ s/drive-//g;
 697
 698             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 699             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 700         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 701             my $drivestr = $4;
 702             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 703             my $nbd_unix_addr = $1;
 704             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 705             my $targetdrive = $3;
 706             $targetdrive =~ s/drive-//g;
 707
 708             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 709             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 710             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 711             push @$sock_addr, $nbd_unix_addr;
 712         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 713             my $drive = $1;
 714             my $volid = $2;
 715             $target_replicated_volumes->{$volid} = $drive;
 716         } elsif ($line =~ m/^QEMU: (.*)$/) {
 717             $self->log('info', "[$self->{node}] $1\n");
 718         }
 719     }, errfunc => sub {
 720         my $line = shift;
 721         $self->log('info', "[$self->{node}] $line");
 722     }, noerr => 1);
 723
 724     die "remote command failed with exit code $exitcode\n" if $exitcode;
 725
 726     die "unable to detect remote migration address\n" if !$raddr;
 727
 728     if (scalar(keys %$target_replicated_volumes) != scalar(keys %{$self->{replicated_volumes}})) {
 729         die "number of replicated disks on source and target node do not match - target node too old?\n"
 730     }
 731
 732     $self->log('info', "start remote tunnel");
 733
 734     if ($migration_type eq 'secure') {
 735
 736         if ($ruri =~ /^unix:/) {
 737             unlink $raddr;
 738             push @$tunnel_addr, "$raddr:$raddr";
 739             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 740             push @$sock_addr, $raddr;
 741
 742             my $unix_socket_try = 0; # wait for the socket to become ready
 743             while ($unix_socket_try <= 100) {
 744                 $unix_socket_try++;
 745                 my $available = 0;
 746                 foreach my $sock (@$sock_addr) {
 747                     if (-S $sock) {
 748                         $available++;
 749                     }
 750                 }
 751
 752                 if ($available == @$sock_addr) {
 753                     last;
 754                 }
 755
 756                 usleep(50000);
 757             }
 758             if ($unix_socket_try > 100) {
 759                 $self->{errors} = 1;
 760                 $self->finish_tunnel($self->{tunnel});
 761                 die "Timeout, migration socket $ruri did not get ready";
 762             }
 763
 764         } elsif ($ruri =~ /^tcp:/) {
 765             my $tunnel_addr;
 766             if ($raddr eq "localhost") {
 767                 # for backwards compatibility with older qemu-server versions
 768                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 769                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 770                 $tunnel_addr = "$lport:localhost:$rport";
 771             }
 772
 773             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 774
 775         } else {
 776             die "unsupported protocol in migration URI: $ruri\n";
 777         }
 778     } else {
 779         #fork tunnel for insecure migration, to send faster commands like resume
 780         $self->{tunnel} = $self->fork_tunnel();
 781     }
 782     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 783
 784     my $start = time();
 785
 786     my $opt_bwlimit = $self->{opts}->{bwlimit};
 787
 788     if (defined($self->{online_local_volumes})) {
 789         $self->{storage_migration} = 1;
 790         $self->{storage_migration_jobs} = {};
 791         $self->log('info', "starting storage migration");
 792
 793         die "The number of local disks does not match between the source and the destination.\n"
 794             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 795         foreach my $drive (keys %{$self->{target_drive}}){
 796             my $target = $self->{target_drive}->{$drive};
 797             my $nbd_uri = $target->{nbd_uri};
 798
 799             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 800             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 801
 802             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_drive->{file});
 803             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_drive->{file});
 804
 805             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 806             my $bitmap = $target->{bitmap};
 807
 808             $self->log('info', "$drive: start migration to $nbd_uri");
 809             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 810         }
 811     }
 812
 813     $self->log('info', "starting online/live migration on $ruri");
 814     $self->{livemigration} = 1;
 815
 816     # load_defaults
 817     my $defaults = PVE::QemuServer::load_defaults();
 818
 819     $self->log('info', "set migration_caps");
 820     eval {
 821         PVE::QemuServer::set_migration_caps($vmid);
 822     };
 823     warn $@ if $@;
 824
 825     my $qemu_migrate_params = {};
 826
 827     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 828     # migrate_speed parameter in qm.conf - take the lower of the two.
 829     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 830     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 831     # migrate_speed is in MB/s, bwlimit in KB/s
 832     $migrate_speed *= 1024;
 833
 834     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 835
 836     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 837     # default of 8192m which is basically unlimited
 838     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 839
 840     # qmp takes migrate_speed in B/s.
 841     $migrate_speed *= 1024;
 842     $self->log('info', "migration speed limit: $migrate_speed B/s");
 843     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 844
 845     my $migrate_downtime = $defaults->{migrate_downtime};
 846     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 847     if (defined($migrate_downtime)) {
 848         # migrate-set-parameters expects limit in ms
 849         $migrate_downtime *= 1000;
 850         $self->log('info', "migration downtime limit: $migrate_downtime ms");
 851         $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 852     }
 853
 854     # set cachesize to 10% of the total memory
 855     my $memory =  $conf->{memory} || $defaults->{memory};
 856     my $cachesize = int($memory * 1048576 / 10);
 857     $cachesize = round_powerof2($cachesize);
 858
 859     $self->log('info', "migration cachesize: $cachesize B");
 860     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 861
 862     $self->log('info', "set migration parameters");
 863     eval {
 864         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 865     };
 866     $self->log('info', "migrate-set-parameters error: $@") if $@;
 867
 868     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 869         my $rpcenv = PVE::RPCEnvironment::get();
 870         my $authuser = $rpcenv->get_user();
 871
 872         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 873
 874         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 875         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 876
 877         $self->log('info', "spice client_migrate_info");
 878
 879         eval {
 880             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 881                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 882                                                 'cert-subject' => $subject);
 883         };
 884         $self->log('info', "client_migrate_info error: $@") if $@;
 885
 886     }
 887
 888     $self->log('info', "start migrate command to $ruri");
 889     eval {
 890         mon_cmd($vmid, "migrate", uri => $ruri);
 891     };
 892     my $merr = $@;
 893     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 894
 895     my $lstat = 0;
 896     my $usleep = 1000000;
 897     my $i = 0;
 898     my $err_count = 0;
 899     my $lastrem = undef;
 900     my $downtimecounter = 0;
 901     while (1) {
 902         $i++;
 903         my $avglstat = $lstat/$i if $lstat;
 904
 905         usleep($usleep);
 906         my $stat;
 907         eval {
 908             $stat = mon_cmd($vmid, "query-migrate");
 909         };
 910         if (my $err = $@) {
 911             $err_count++;
 912             warn "query migrate failed: $err\n";
 913             $self->log('info', "query migrate failed: $err");
 914             if ($err_count <= 5) {
 915                 usleep(1000000);
 916                 next;
 917             }
 918             die "too many query migrate failures - aborting\n";
 919         }
 920
 921         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 922             sleep(1);
 923             next;
 924         }
 925
 926         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 927             $merr = undef;
 928             $err_count = 0;
 929             if ($stat->{status} eq 'completed') {
 930                 my $delay = time() - $start;
 931                 if ($delay > 0) {
 932                     my $mbps = sprintf "%.2f", $memory / $delay;
 933                     my $downtime = $stat->{downtime} || 0;
 934                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 935                 }
 936             }
 937
 938             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 939                 $self->log('info', "migration status error: $stat->{status}");
 940                 die "aborting\n"
 941             }
 942
 943             if ($stat->{status} ne 'active') {
 944                 $self->log('info', "migration status: $stat->{status}");
 945                 last;
 946             }
 947
 948             if ($stat->{ram}->{transferred} ne $lstat) {
 949                 my $trans = $stat->{ram}->{transferred} || 0;
 950                 my $rem = $stat->{ram}->{remaining} || 0;
 951                 my $total = $stat->{ram}->{total} || 0;
 952                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 953                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 954                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 955                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 956                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 957                 # reduce sleep if remainig memory is lower than the average transfer speed
 958                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 959
 960                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 961                            "remaining ${rem}), total ${total})");
 962
 963                 if (${xbzrlecachesize}) {
 964                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 965                 }
 966
 967                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 968                     $downtimecounter++;
 969                 }
 970                 $lastrem = $rem;
 971
 972                 if ($downtimecounter > 5) {
 973                     $downtimecounter = 0;
 974                     $migrate_downtime *= 2;
 975                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 976                     eval {
 977                         mon_cmd($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 978                     };
 979                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 980                 }
 981
 982             }
 983
 984
 985             $lstat = $stat->{ram}->{transferred};
 986
 987         } else {
 988             die $merr if $merr;
 989             die "unable to parse migration status '$stat->{status}' - aborting\n";
 990         }
 991     }
 992 }
 993
 994 sub phase2_cleanup {
 995     my ($self, $vmid, $err) = @_;
 996
 997     return if !$self->{errors};
 998     $self->{phase2errors} = 1;
 999
1000     $self->log('info', "aborting phase 2 - cleanup resources");
1001
1002     $self->log('info', "migrate_cancel");
1003     eval {
1004         mon_cmd($vmid, "migrate_cancel");
1005     };
1006     $self->log('info', "migrate_cancel error: $@") if $@;
1007
1008     my $conf = $self->{vmconf};
1009     delete $conf->{lock};
1010     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1011     if (my $err = $@) {
1012         $self->log('err', $err);
1013     }
1014
1015     # cleanup ressources on target host
1016     if ($self->{storage_migration}) {
1017         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1018         if (my $err = $@) {
1019             $self->log('err', $err);
1020         }
1021     }
1022
1023     eval { $self->cleanup_bitmaps() };
1024     if (my $err =$@) {
1025         $self->log('err', $err);
1026     }
1027
1028     my $nodename = PVE::INotify::nodename();
1029
1030     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1031     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1032     if (my $err = $@) {
1033         $self->log('err', $err);
1034         $self->{errors} = 1;
1035     }
1036
1037     # cleanup after stopping, otherwise disks might be in-use by target VM!
1038     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1039     if (my $err = $@) {
1040         $self->log('err', $err);
1041     }
1042
1043
1044     if ($self->{tunnel}) {
1045         eval { finish_tunnel($self, $self->{tunnel});  };
1046         if (my $err = $@) {
1047             $self->log('err', $err);
1048             $self->{errors} = 1;
1049         }
1050     }
1051 }
1052
1053 sub phase3 {
1054     my ($self, $vmid) = @_;
1055
1056     my $volids = $self->{volumes};
1057     return if $self->{phase2errors};
1058
1059     # destroy local copies
1060     foreach my $volid (@$volids) {
1061         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1062         if (my $err = $@) {
1063             $self->log('err', "removing local copy of '$volid' failed - $err");
1064             $self->{errors} = 1;
1065             last if $err =~ /^interrupted by signal$/;
1066         }
1067     }
1068 }
1069
1070 sub phase3_cleanup {
1071     my ($self, $vmid, $err) = @_;
1072
1073     my $conf = $self->{vmconf};
1074     return if $self->{phase2errors};
1075
1076     my $tunnel = $self->{tunnel};
1077
1078     if ($self->{storage_migration}) {
1079         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1080         # to avoid it trying to re-establish it. We are in blockjob ready state,
1081         # thus, this command changes to it to blockjob complete (see qapi docs)
1082         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1083
1084         if (my $err = $@) {
1085             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1086             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1087             die "Failed to complete storage migration: $err\n";
1088         } else {
1089             foreach my $target_drive (keys %{$self->{target_drive}}) {
1090                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
1091                 $conf->{$target_drive} = PVE::QemuServer::print_drive($drive);
1092                 PVE::QemuConfig->write_config($vmid, $conf);
1093             }
1094         }
1095     }
1096
1097     # transfer replication state before move config
1098     $self->transfer_replication_state() if $self->{replicated_volumes};
1099
1100     # move config to remote node
1101     my $conffile = PVE::QemuConfig->config_file($vmid);
1102     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1103
1104     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1105         if !rename($conffile, $newconffile);
1106
1107     $self->switch_replication_job_target() if $self->{replicated_volumes};
1108
1109     if ($self->{livemigration}) {
1110         if ($self->{storage_migration}) {
1111             # stop nbd server on remote vm - requirement for resume since 2.9
1112             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1113
1114             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1115             if (my $err = $@) {
1116                 $self->log('err', $err);
1117                 $self->{errors} = 1;
1118             }
1119         }
1120
1121         # config moved and nbd server stopped - now we can resume vm on target
1122         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1123             eval {
1124                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1125             };
1126             if (my $err = $@) {
1127                 $self->log('err', $err);
1128                 $self->{errors} = 1;
1129             }
1130         } else {
1131             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1132             my $logf = sub {
1133                 my $line = shift;
1134                 $self->log('err', $line);
1135             };
1136             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1137             if (my $err = $@) {
1138                 $self->log('err', $err);
1139                 $self->{errors} = 1;
1140             }
1141         }
1142
1143         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1144             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1145             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1146         }
1147     }
1148
1149     # close tunnel on successful migration, on error phase2_cleanup closed it
1150     if ($tunnel) {
1151         eval { finish_tunnel($self, $tunnel);  };
1152         if (my $err = $@) {
1153             $self->log('err', $err);
1154             $self->{errors} = 1;
1155         }
1156     }
1157
1158     eval {
1159         my $timer = 0;
1160         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1161             $self->log('info', "Waiting for spice server migration");
1162             while (1) {
1163                 my $res = mon_cmd($vmid, 'query-spice');
1164                 last if int($res->{'migrated'}) == 1;
1165                 last if $timer > 50;
1166                 $timer ++;
1167                 usleep(200000);
1168             }
1169         }
1170     };
1171
1172     # always stop local VM
1173     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1174     if (my $err = $@) {
1175         $self->log('err', "stopping vm failed - $err");
1176         $self->{errors} = 1;
1177     }
1178
1179     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1180     eval {
1181         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1182         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1183     };
1184     if (my $err = $@) {
1185         $self->log('err', $err);
1186         $self->{errors} = 1;
1187     }
1188
1189     if($self->{storage_migration}) {
1190         # destroy local copies
1191         my $volids = $self->{online_local_volumes};
1192
1193         foreach my $volid (@$volids) {
1194             # keep replicated volumes!
1195             next if $self->{replicated_volumes}->{$volid};
1196
1197             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1198             if (my $err = $@) {
1199                 $self->log('err', "removing local copy of '$volid' failed - $err");
1200                 $self->{errors} = 1;
1201                 last if $err =~ /^interrupted by signal$/;
1202             }
1203         }
1204
1205     }
1206
1207     # clear migrate lock
1208     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1209     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1210 }
1211
1212 sub final_cleanup {
1213     my ($self, $vmid) = @_;
1214
1215     # nothing to do
1216 }
1217
1218 sub round_powerof2 {
1219     return 1 if $_[0] < 2;
1220     return 2 << int(log($_[0]-1)/log(2));
1221 }
1222
1223 1;