PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use Time::HiRes qw( usleep );
  10
  11 use PVE::Cluster;
  12 use PVE::INotify;
  13 use PVE::RPCEnvironment;
  14 use PVE::Replication;
  15 use PVE::ReplicationConfig;
  16 use PVE::ReplicationState;
  17 use PVE::Storage;
  18 use PVE::Tools;
  19
  20 use PVE::QemuConfig;
  21 use PVE::QemuServer::CPUConfig;
  22 use PVE::QemuServer::Drive;
  23 use PVE::QemuServer::Helpers qw(min_version);
  24 use PVE::QemuServer::Machine;
  25 use PVE::QemuServer::Monitor qw(mon_cmd);
  26 use PVE::QemuServer;
  27
  28 use PVE::AbstractMigrate;
  29 use base qw(PVE::AbstractMigrate);
  30
  31 sub fork_command_pipe {
  32     my ($self, $cmd) = @_;
  33
  34     my $reader = IO::File->new();
  35     my $writer = IO::File->new();
  36
  37     my $orig_pid = $$;
  38
  39     my $cpid;
  40
  41     eval { $cpid = open2($reader, $writer, @$cmd); };
  42
  43     my $err = $@;
  44
  45     # catch exec errors
  46     if ($orig_pid != $$) {
  47         $self->log('err', "can't fork command pipe\n");
  48         POSIX::_exit(1);
  49         kill('KILL', $$);
  50     }
  51
  52     die $err if $err;
  53
  54     return { writer => $writer, reader => $reader, pid => $cpid };
  55 }
  56
  57 sub finish_command_pipe {
  58     my ($self, $cmdpipe, $timeout) = @_;
  59
  60     my $cpid = $cmdpipe->{pid};
  61     return if !defined($cpid);
  62
  63     my $writer = $cmdpipe->{writer};
  64     my $reader = $cmdpipe->{reader};
  65
  66     $writer->close();
  67     $reader->close();
  68
  69     my $collect_child_process = sub {
  70         my $res = waitpid($cpid, WNOHANG);
  71         if (defined($res) && ($res == $cpid)) {
  72             delete $cmdpipe->{cpid};
  73             return 1;
  74         } else {
  75             return 0;
  76         }
  77      };
  78
  79     if ($timeout) {
  80         for (my $i = 0; $i < $timeout; $i++) {
  81             return if &$collect_child_process();
  82             sleep(1);
  83         }
  84     }
  85
  86     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  87     kill(15, $cpid);
  88
  89     # wait again
  90     for (my $i = 0; $i < 10; $i++) {
  91         return if &$collect_child_process();
  92         sleep(1);
  93     }
  94
  95     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  96     kill 9, $cpid;
  97     sleep 1;
  98
  99     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
 100         if !&$collect_child_process();
 101 }
 102
 103 sub read_tunnel {
 104     my ($self, $tunnel, $timeout) = @_;
 105
 106     $timeout = 60 if !defined($timeout);
 107
 108     my $reader = $tunnel->{reader};
 109
 110     my $output;
 111     eval {
 112         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 113     };
 114     die "reading from tunnel failed: $@\n" if $@;
 115
 116     chomp $output;
 117
 118     return $output;
 119 }
 120
 121 sub write_tunnel {
 122     my ($self, $tunnel, $timeout, $command) = @_;
 123
 124     $timeout = 60 if !defined($timeout);
 125
 126     my $writer = $tunnel->{writer};
 127
 128     eval {
 129         PVE::Tools::run_with_timeout($timeout, sub {
 130             print $writer "$command\n";
 131             $writer->flush();
 132         });
 133     };
 134     die "writing to tunnel failed: $@\n" if $@;
 135
 136     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 137         my $res = eval { $self->read_tunnel($tunnel, 10); };
 138         die "no reply to command '$command': $@\n" if $@;
 139
 140         if ($res eq 'OK') {
 141             return;
 142         } else {
 143             die "tunnel replied '$res' to command '$command'\n";
 144         }
 145     }
 146 }
 147
 148 sub fork_tunnel {
 149     my ($self, $ssh_forward_info) = @_;
 150
 151     my @localtunnelinfo = ();
 152     foreach my $addr (@$ssh_forward_info) {
 153         push @localtunnelinfo, '-L', $addr;
 154     }
 155
 156     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 157
 158     my $tunnel = $self->fork_command_pipe($cmd);
 159
 160     eval {
 161         my $helo = $self->read_tunnel($tunnel, 60);
 162         die "no reply\n" if !$helo;
 163         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 164         die "got strange reply from mtunnel ('$helo')\n"
 165             if $helo !~ m/^tunnel online$/;
 166     };
 167     my $err = $@;
 168
 169     eval {
 170         my $ver = $self->read_tunnel($tunnel, 10);
 171         if ($ver =~ /^ver (\d+)$/) {
 172             $tunnel->{version} = $1;
 173             $self->log('info', "ssh tunnel $ver\n");
 174         } else {
 175             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 176         }
 177     };
 178
 179     if ($err) {
 180         $self->finish_command_pipe($tunnel);
 181         die "can't open migration tunnel - $err";
 182     }
 183     return $tunnel;
 184 }
 185
 186 sub finish_tunnel {
 187     my ($self, $tunnel) = @_;
 188
 189     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 190     my $err = $@;
 191
 192     $self->finish_command_pipe($tunnel, 30);
 193
 194     if (my $unix_sockets = $tunnel->{unix_sockets}) {
 195         # ssh does not clean up on local host
 196         my $cmd = ['rm', '-f', @$unix_sockets];
 197         PVE::Tools::run_command($cmd);
 198
 199         # .. and just to be sure check on remote side
 200         unshift @{$cmd}, @{$self->{rem_ssh}};
 201         PVE::Tools::run_command($cmd);
 202     }
 203
 204     die $err if $err;
 205 }
 206
 207 sub lock_vm {
 208     my ($self, $vmid, $code, @param) = @_;
 209
 210     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 211 }
 212
 213 sub prepare {
 214     my ($self, $vmid) = @_;
 215
 216     my $online = $self->{opts}->{online};
 217
 218     $self->{storecfg} = PVE::Storage::config();
 219
 220     # test if VM exists
 221     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 222
 223     my $repl_conf = PVE::ReplicationConfig->new();
 224     $self->{replication_jobcfg} = $repl_conf->find_local_replication_job($vmid, $self->{node});
 225     $self->{is_replicated} = $repl_conf->check_for_existing_jobs($vmid, 1);
 226
 227     PVE::QemuConfig->check_lock($conf);
 228
 229     my $running = 0;
 230     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 231         die "can't migrate running VM without --online\n" if !$online;
 232         $running = $pid;
 233
 234         if ($self->{is_replicated} && !$self->{replication_jobcfg}) {
 235             if ($self->{opts}->{force}) {
 236                 $self->log('warn', "WARNING: Node '$self->{node}' is not a replication target. Existing " .
 237                                    "replication jobs will fail after migration!\n");
 238             } else {
 239                 die "Cannot live-migrate replicated VM to node '$self->{node}' - not a replication " .
 240                     "target. Use 'force' to override.\n";
 241             }
 242         }
 243
 244         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 245
 246         # To support custom CPU types, we keep QEMU's "-cpu" parameter intact.
 247         # Since the parameter itself contains no reference to a custom model,
 248         # this makes migration independent of changes to "cpu-models.conf".
 249         if ($conf->{cpu}) {
 250             my $cpuconf = PVE::JSONSchema::parse_property_string('pve-cpu-conf', $conf->{cpu});
 251             if ($cpuconf && PVE::QemuServer::CPUConfig::is_custom_model($cpuconf->{cputype})) {
 252                 $self->{forcecpu} = PVE::QemuServer::CPUConfig::get_cpu_from_running_vm($pid);
 253             }
 254         }
 255     }
 256
 257     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 258     if (scalar @$loc_res) {
 259         if ($self->{running} || !$self->{opts}->{force}) {
 260             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 261         } else {
 262             $self->log('info', "migrating VM which uses local devices");
 263         }
 264     }
 265
 266     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 267
 268     my $need_activate = [];
 269     foreach my $volid (@$vollist) {
 270         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 271
 272         # check if storage is available on both nodes
 273         my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 274
 275         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 276         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 277
 278         if ($scfg->{shared}) {
 279             # PVE::Storage::activate_storage checks this for non-shared storages
 280             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 281             warn "Used shared storage '$sid' is not online on source node!\n"
 282                 if !$plugin->check_connection($sid, $scfg);
 283         } else {
 284             # only activate if not shared
 285             next if ($volid =~ m/vm-\d+-cloudinit/);
 286             push @$need_activate, $volid;
 287         }
 288     }
 289
 290     # activate volumes
 291     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 292
 293     # test ssh connection
 294     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 295     eval { $self->cmd_quiet($cmd); };
 296     die "Can't connect to destination address using public key\n" if $@;
 297
 298     return $running;
 299 }
 300
 301 sub sync_disks {
 302     my ($self, $vmid) = @_;
 303
 304     my $conf = $self->{vmconf};
 305
 306     # local volumes which have been copied
 307     # and their old_id => new_id pairs
 308     $self->{volumes} = [];
 309     $self->{volume_map} = {};
 310
 311     my $storecfg = $self->{storecfg};
 312     eval {
 313
 314         # found local volumes and their origin
 315         my $local_volumes = {};
 316         my $local_volumes_errors = {};
 317         my $other_errors = [];
 318         my $abort = 0;
 319
 320         my $log_error = sub {
 321             my ($msg, $volid) = @_;
 322
 323             if (defined($volid)) {
 324                 $local_volumes_errors->{$volid} = $msg;
 325             } else {
 326                 push @$other_errors, $msg;
 327             }
 328             $abort = 1;
 329         };
 330
 331         my @sids = PVE::Storage::storage_ids($storecfg);
 332         foreach my $storeid (@sids) {
 333             my $scfg = PVE::Storage::storage_config($storecfg, $storeid);
 334             next if $scfg->{shared};
 335             next if !PVE::Storage::storage_check_enabled($storecfg, $storeid, undef, 1);
 336
 337             # get list from PVE::Storage (for unused volumes)
 338             my $dl = PVE::Storage::vdisk_list($storecfg, $storeid, $vmid);
 339
 340             next if @{$dl->{$storeid}} == 0;
 341
 342             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $storeid);
 343             # check if storage is available on target node
 344             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 345
 346             # grandfather in existing mismatches
 347             if ($targetsid ne $storeid) {
 348                 my $target_scfg = PVE::Storage::storage_config($storecfg, $targetsid);
 349                 die "content type 'images' is not available on storage '$targetsid'\n"
 350                     if !$target_scfg->{content}->{images};
 351             }
 352
 353             PVE::Storage::foreach_volid($dl, sub {
 354                 my ($volid, $sid, $volinfo) = @_;
 355
 356                 $local_volumes->{$volid}->{ref} = 'storage';
 357
 358                 # If with_snapshots is not set for storage migrate, it tries to use
 359                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 360                 # back to qcow2 is currently not possible.
 361                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 362                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 363             });
 364         }
 365
 366         my $replicatable_volumes = !$self->{replication_jobcfg} ? {}
 367             : PVE::QemuConfig->get_replicatable_volumes($storecfg, $vmid, $conf, 0, 1);
 368
 369         my $test_volid = sub {
 370             my ($volid, $attr) = @_;
 371
 372             if ($volid =~ m|^/|) {
 373                 return if $attr->{shared};
 374                 $local_volumes->{$volid}->{ref} = 'config';
 375                 die "local file/device\n";
 376             }
 377
 378             my $snaprefs = $attr->{referenced_in_snapshot};
 379
 380             if ($attr->{cdrom}) {
 381                 if ($volid eq 'cdrom') {
 382                     my $msg = "can't migrate local cdrom drive";
 383                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 384                         my $snapnames = join(', ', sort keys %$snaprefs);
 385                         $msg .= " (referenced in snapshot - $snapnames)";
 386                     }
 387                     &$log_error("$msg\n");
 388                     return;
 389                 }
 390                 return if $volid eq 'none';
 391             }
 392
 393             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 394
 395             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 396             # check if storage is available on both nodes
 397             my $scfg = PVE::Storage::storage_check_node($storecfg, $sid);
 398             PVE::Storage::storage_check_node($storecfg, $targetsid, $self->{node});
 399
 400             return if $scfg->{shared};
 401
 402             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 403             $local_volumes->{$volid}->{ref} = 'storage' if $attr->{is_unused};
 404
 405             $local_volumes->{$volid}->{is_vmstate} = $attr->{is_vmstate} ? 1 : 0;
 406
 407             if ($attr->{cdrom}) {
 408                 if ($volid =~ /vm-\d+-cloudinit/) {
 409                     $local_volumes->{$volid}->{ref} = 'generated';
 410                     return;
 411                 }
 412                 die "local cdrom image\n";
 413             }
 414
 415             my ($path, $owner) = PVE::Storage::path($storecfg, $volid);
 416
 417             die "owned by other VM (owner = VM $owner)\n"
 418                 if !$owner || ($owner != $vmid);
 419
 420             return if $attr->{is_vmstate};
 421
 422             if (defined($snaprefs)) {
 423                 $local_volumes->{$volid}->{snapshots} = 1;
 424
 425                 # we cannot migrate shapshots on local storage
 426                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 427
 428                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 429                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 430                     die "non-migratable snapshot exists\n";
 431                 }
 432             }
 433
 434             die "referenced by linked clone(s)\n"
 435                 if PVE::Storage::volume_is_base_and_used($storecfg, $volid);
 436         };
 437
 438         PVE::QemuServer::foreach_volid($conf, sub {
 439             my ($volid, $attr) = @_;
 440             eval { $test_volid->($volid, $attr); };
 441             if (my $err = $@) {
 442                 &$log_error($err, $volid);
 443             }
 444         });
 445
 446         foreach my $vol (sort keys %$local_volumes) {
 447             my $type = $replicatable_volumes->{$vol} ? 'local, replicated' : 'local';
 448             my $ref = $local_volumes->{$vol}->{ref};
 449             if ($ref eq 'storage') {
 450                 $self->log('info', "found $type disk '$vol' (via storage)\n");
 451             } elsif ($ref eq 'config') {
 452                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 453                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 454                 $self->log('info', "found $type disk '$vol' (in current VM config)\n");
 455             } elsif ($ref eq 'snapshot') {
 456                 $self->log('info', "found $type disk '$vol' (referenced by snapshot(s))\n");
 457             } elsif ($ref eq 'generated') {
 458                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 459             } else {
 460                 $self->log('info', "found $type disk '$vol'\n");
 461             }
 462         }
 463
 464         foreach my $vol (sort keys %$local_volumes_errors) {
 465             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 466         }
 467         foreach my $err (@$other_errors) {
 468             $self->log('warn', "$err");
 469         }
 470
 471         if ($abort) {
 472             die "can't migrate VM - check log\n";
 473         }
 474
 475         # additional checks for local storage
 476         foreach my $volid (keys %$local_volumes) {
 477             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 478             my $scfg =  PVE::Storage::storage_config($storecfg, $sid);
 479
 480             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 481
 482             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 483                 if !$migratable;
 484
 485             # image is a linked clone on local storage, se we can't migrate.
 486             if (my $basename = (PVE::Storage::parse_volname($storecfg, $volid))[3]) {
 487                 die "can't migrate '$volid' as it's a clone of '$basename'";
 488             }
 489         }
 490
 491         if ($self->{replication_jobcfg}) {
 492             if ($self->{running}) {
 493
 494                 my $version = PVE::QemuServer::kvm_user_version();
 495                 if (!min_version($version, 4, 2)) {
 496                     die "can't live migrate VM with replicated volumes, pve-qemu to old (< 4.2)!\n"
 497                 }
 498
 499                 my $live_replicatable_volumes = {};
 500                 PVE::QemuConfig->foreach_volume($conf, sub {
 501                     my ($ds, $drive) = @_;
 502
 503                     my $volid = $drive->{file};
 504                     $live_replicatable_volumes->{$ds} = $volid
 505                         if defined($replicatable_volumes->{$volid});
 506                 });
 507                 foreach my $drive (keys %$live_replicatable_volumes) {
 508                     my $volid = $live_replicatable_volumes->{$drive};
 509
 510                     my $bitmap = "repl_$drive";
 511
 512                     # start tracking before replication to get full delta + a few duplicates
 513                     $self->log('info', "$drive: start tracking writes using block-dirty-bitmap '$bitmap'");
 514                     mon_cmd($vmid, 'block-dirty-bitmap-add', node => "drive-$drive", name => $bitmap);
 515
 516                     # other info comes from target node in phase 2
 517                     $self->{target_drive}->{$drive}->{bitmap} = $bitmap;
 518                 }
 519             }
 520             $self->log('info', "replicating disk images");
 521
 522             my $start_time = time();
 523             my $logfunc = sub { $self->log('info', shift) };
 524             $self->{replicated_volumes} = PVE::Replication::run_replication(
 525                'PVE::QemuConfig', $self->{replication_jobcfg}, $start_time, $start_time, $logfunc);
 526         }
 527
 528         # sizes in config have to be accurate for remote node to correctly
 529         # allocate disks, rescan to be sure
 530         my $volid_hash = PVE::QemuServer::scan_volids($storecfg, $vmid);
 531         PVE::QemuConfig->foreach_volume($conf, sub {
 532             my ($key, $drive) = @_;
 533             return if $key eq 'efidisk0'; # skip efidisk, will be handled later
 534
 535             my $volid = $drive->{file};
 536             return if !defined($local_volumes->{$volid}); # only update sizes for local volumes
 537             return if !defined($volid_hash->{$volid});
 538
 539             my ($updated, $msg) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash->{$volid}->{size});
 540             if (defined($updated)) {
 541                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 542                 $self->log('info', "drive '$key': $msg");
 543             }
 544         });
 545
 546         # we want to set the efidisk size in the config to the size of the
 547         # real OVMF_VARS.fd image, else we can create a too big image, which does not work
 548         if (defined($conf->{efidisk0})) {
 549             PVE::QemuServer::update_efidisk_size($conf);
 550         }
 551
 552         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 553
 554         foreach my $volid (keys %$local_volumes) {
 555             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 556             my $targetsid = PVE::QemuServer::map_storage($self->{opts}->{storagemap}, $sid);
 557             my $ref = $local_volumes->{$volid}->{ref};
 558             if ($self->{running} && $ref eq 'config') {
 559                 push @{$self->{online_local_volumes}}, $volid;
 560             } elsif ($ref eq 'generated') {
 561                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 562                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 563                 push @{$self->{volumes}}, $volid;
 564                 next;
 565             } else {
 566                 next if $self->{replicated_volumes}->{$volid};
 567                 push @{$self->{volumes}}, $volid;
 568                 my $opts = $self->{opts};
 569                 # use 'migrate' limit for transfer to other node
 570                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 571                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 572                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 573
 574                 my $storage_migrate_opts = {
 575                     'ratelimit_bps' => $bwlimit,
 576                     'insecure' => $opts->{migration_type} eq 'insecure',
 577                     'with_snapshots' => $local_volumes->{$volid}->{snapshots},
 578                     'allow_rename' => !$local_volumes->{$volid}->{is_vmstate},
 579                 };
 580
 581                 my $logfunc = sub { $self->log('info', $_[0]); };
 582                 my $new_volid = eval {
 583                     PVE::Storage::storage_migrate($storecfg, $volid, $self->{ssh_info},
 584                                                   $targetsid, $storage_migrate_opts, $logfunc);
 585                 };
 586                 if (my $err = $@) {
 587                     die "storage migration for '$volid' to storage '$targetsid' failed - $err\n";
 588                 }
 589
 590                 $self->{volume_map}->{$volid} = $new_volid;
 591                 $self->log('info', "volume '$volid' is '$new_volid' on the target\n");
 592             }
 593         }
 594     };
 595     die "Failed to sync data - $@" if $@;
 596 }
 597
 598 sub cleanup_remotedisks {
 599     my ($self) = @_;
 600
 601     foreach my $target_drive (keys %{$self->{target_drive}}) {
 602         my $drivestr = $self->{target_drive}->{$target_drive}->{drivestr};
 603         next if !defined($drivestr);
 604
 605         my $drive = PVE::QemuServer::parse_drive($target_drive, $drivestr);
 606
 607         # don't clean up replicated disks!
 608         next if defined($self->{replicated_volumes}->{$drive->{file}});
 609
 610         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 611
 612         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 613
 614         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 615         if (my $err = $@) {
 616             $self->log('err', $err);
 617             $self->{errors} = 1;
 618         }
 619     }
 620 }
 621
 622 sub cleanup_bitmaps {
 623     my ($self) = @_;
 624     foreach my $drive (keys %{$self->{target_drive}}) {
 625         my $bitmap = $self->{target_drive}->{$drive}->{bitmap};
 626         next if !$bitmap;
 627         $self->log('info', "$drive: removing block-dirty-bitmap '$bitmap'");
 628         mon_cmd($self->{vmid}, 'block-dirty-bitmap-remove', node => "drive-$drive", name => $bitmap);
 629     }
 630 }
 631
 632 sub phase1 {
 633     my ($self, $vmid) = @_;
 634
 635     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 636
 637     my $conf = $self->{vmconf};
 638
 639     # set migrate lock in config file
 640     $conf->{lock} = 'migrate';
 641     PVE::QemuConfig->write_config($vmid, $conf);
 642
 643     sync_disks($self, $vmid);
 644
 645     # sync_disks fixes disk sizes to match their actual size, write changes so
 646     # target allocates correct volumes
 647     PVE::QemuConfig->write_config($vmid, $conf);
 648 };
 649
 650 sub phase1_cleanup {
 651     my ($self, $vmid, $err) = @_;
 652
 653     $self->log('info', "aborting phase 1 - cleanup resources");
 654
 655     my $conf = $self->{vmconf};
 656     delete $conf->{lock};
 657     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 658     if (my $err = $@) {
 659         $self->log('err', $err);
 660     }
 661
 662     if ($self->{volumes}) {
 663         foreach my $volid (@{$self->{volumes}}) {
 664             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 665             # fixme: try to remove ?
 666         }
 667     }
 668
 669     eval { $self->cleanup_bitmaps() };
 670     if (my $err =$@) {
 671         $self->log('err', $err);
 672     }
 673
 674 }
 675
 676 sub phase2 {
 677     my ($self, $vmid) = @_;
 678
 679     my $conf = $self->{vmconf};
 680
 681     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 682
 683     my $raddr;
 684     my $rport;
 685     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 686     my $nodename = PVE::INotify::nodename();
 687
 688     ## start on remote node
 689     my $cmd = [@{$self->{rem_ssh}}];
 690
 691     my $spice_ticket;
 692     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 693         my $res = mon_cmd($vmid, 'query-spice');
 694         $spice_ticket = $res->{ticket};
 695     }
 696
 697     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 698
 699     my $migration_type = $self->{opts}->{migration_type};
 700
 701     push @$cmd, '--migration_type', $migration_type;
 702
 703     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 704       if $self->{opts}->{migration_network};
 705
 706     if ($migration_type eq 'insecure') {
 707         push @$cmd, '--stateuri', 'tcp';
 708     } else {
 709         push @$cmd, '--stateuri', 'unix';
 710     }
 711
 712     if ($self->{forcemachine}) {
 713         push @$cmd, '--machine', $self->{forcemachine};
 714     }
 715
 716     if ($self->{forcecpu}) {
 717         push @$cmd, '--force-cpu', $self->{forcecpu};
 718     }
 719
 720     if ($self->{online_local_volumes}) {
 721         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 722     }
 723
 724     my $spice_port;
 725     my $unix_socket_info = {};
 726     # version > 0 for unix socket support
 727     my $nbd_protocol_version = 1;
 728     # TODO change to 'spice_ticket: <ticket>\n' in 7.0
 729     my $input = $spice_ticket ? "$spice_ticket\n" : "\n";
 730     $input .= "nbd_protocol_version: $nbd_protocol_version\n";
 731
 732     my $number_of_online_replicated_volumes = 0;
 733
 734     # prevent auto-vivification
 735     if ($self->{online_local_volumes}) {
 736         foreach my $volid (@{$self->{online_local_volumes}}) {
 737             next if !$self->{replicated_volumes}->{$volid};
 738             $number_of_online_replicated_volumes++;
 739             $input .= "replicated_volume: $volid\n";
 740         }
 741     }
 742
 743     my $target_replicated_volumes = {};
 744
 745     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 746     # instead we pipe it through STDIN
 747     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 748         my $line = shift;
 749
 750         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 751             $raddr = $1;
 752             $rport = int($2);
 753             $ruri = "tcp:$raddr:$rport";
 754         }
 755         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 756             $raddr = $1;
 757             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 758             $ruri = "unix:$raddr";
 759         }
 760         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 761             $raddr = "localhost";
 762             $rport = int($1);
 763             $ruri = "tcp:$raddr:$rport";
 764         }
 765         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 766             $spice_port = int($1);
 767         }
 768         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 769             my $drivestr = $4;
 770             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 771             my $targetdrive = $3;
 772             $targetdrive =~ s/drive-//g;
 773
 774             $self->{stopnbd} = 1;
 775             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 776             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 777         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 778             my $drivestr = $4;
 779             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 780             my $nbd_unix_addr = $1;
 781             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 782             my $targetdrive = $3;
 783             $targetdrive =~ s/drive-//g;
 784
 785             $self->{stopnbd} = 1;
 786             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 787             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 788             $unix_socket_info->{$nbd_unix_addr} = 1;
 789         } elsif ($line =~ m/^re-using replicated volume: (\S+) - (.*)$/) {
 790             my $drive = $1;
 791             my $volid = $2;
 792             $target_replicated_volumes->{$volid} = $drive;
 793         } elsif ($line =~ m/^QEMU: (.*)$/) {
 794             $self->log('info', "[$self->{node}] $1\n");
 795         }
 796     }, errfunc => sub {
 797         my $line = shift;
 798         $self->log('info', "[$self->{node}] $line");
 799     }, noerr => 1);
 800
 801     die "remote command failed with exit code $exitcode\n" if $exitcode;
 802
 803     die "unable to detect remote migration address\n" if !$raddr;
 804
 805     if (scalar(keys %$target_replicated_volumes) != $number_of_online_replicated_volumes) {
 806         die "number of replicated disks on source and target node do not match - target node too old?\n"
 807     }
 808
 809     $self->log('info', "start remote tunnel");
 810
 811     if ($migration_type eq 'secure') {
 812
 813         if ($ruri =~ /^unix:/) {
 814             my $ssh_forward_info = ["$raddr:$raddr"];
 815             $unix_socket_info->{$raddr} = 1;
 816
 817             my $unix_sockets = [ keys %$unix_socket_info ];
 818             for my $sock (@$unix_sockets) {
 819                 push @$ssh_forward_info, "$sock:$sock";
 820                 unlink $sock;
 821             }
 822
 823             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 824
 825             my $unix_socket_try = 0; # wait for the socket to become ready
 826             while ($unix_socket_try <= 100) {
 827                 $unix_socket_try++;
 828                 my $available = 0;
 829                 foreach my $sock (@$unix_sockets) {
 830                     if (-S $sock) {
 831                         $available++;
 832                     }
 833                 }
 834
 835                 if ($available == @$unix_sockets) {
 836                     last;
 837                 }
 838
 839                 usleep(50000);
 840             }
 841             if ($unix_socket_try > 100) {
 842                 $self->{errors} = 1;
 843                 $self->finish_tunnel($self->{tunnel});
 844                 die "Timeout, migration socket $ruri did not get ready";
 845             }
 846             $self->{tunnel}->{unix_sockets} = $unix_sockets if (@$unix_sockets);
 847
 848         } elsif ($ruri =~ /^tcp:/) {
 849             my $ssh_forward_info = [];
 850             if ($raddr eq "localhost") {
 851                 # for backwards compatibility with older qemu-server versions
 852                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 853                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 854                 push @$ssh_forward_info, "$lport:localhost:$rport";
 855             }
 856
 857             $self->{tunnel} = $self->fork_tunnel($ssh_forward_info);
 858
 859         } else {
 860             die "unsupported protocol in migration URI: $ruri\n";
 861         }
 862     } else {
 863         #fork tunnel for insecure migration, to send faster commands like resume
 864         $self->{tunnel} = $self->fork_tunnel();
 865     }
 866     my $start = time();
 867
 868     my $opt_bwlimit = $self->{opts}->{bwlimit};
 869
 870     if (defined($self->{online_local_volumes})) {
 871         $self->{storage_migration} = 1;
 872         $self->{storage_migration_jobs} = {};
 873         $self->log('info', "starting storage migration");
 874
 875         die "The number of local disks does not match between the source and the destination.\n"
 876             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 877         foreach my $drive (keys %{$self->{target_drive}}){
 878             my $target = $self->{target_drive}->{$drive};
 879             my $nbd_uri = $target->{nbd_uri};
 880
 881             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 882             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 883
 884             my $source_volid = $source_drive->{file};
 885             my $target_volid = $target_drive->{file};
 886
 887             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_volid);
 888             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_volid);
 889
 890             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 891             my $bitmap = $target->{bitmap};
 892
 893             $self->log('info', "$drive: start migration to $nbd_uri");
 894             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit, $bitmap);
 895
 896             $self->{volume_map}->{$source_volid} = $target_volid;
 897             $self->log('info', "volume '$source_volid' is '$target_volid' on the target\n");
 898         }
 899     }
 900
 901     $self->log('info', "starting online/live migration on $ruri");
 902     $self->{livemigration} = 1;
 903
 904     # load_defaults
 905     my $defaults = PVE::QemuServer::load_defaults();
 906
 907     $self->log('info', "set migration_caps");
 908     eval {
 909         PVE::QemuServer::set_migration_caps($vmid);
 910     };
 911     warn $@ if $@;
 912
 913     my $qemu_migrate_params = {};
 914
 915     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 916     # migrate_speed parameter in qm.conf - take the lower of the two.
 917     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 918     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 919     # migrate_speed is in MB/s, bwlimit in KB/s
 920     $migrate_speed *= 1024;
 921
 922     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 923
 924     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 925     # default of 8192m which is basically unlimited
 926     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 927
 928     # qmp takes migrate_speed in B/s.
 929     $migrate_speed *= 1024;
 930     $self->log('info', "migration speed limit: $migrate_speed B/s");
 931     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 932
 933     my $migrate_downtime = $defaults->{migrate_downtime};
 934     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 935     # migrate-set-parameters expects limit in ms
 936     $migrate_downtime *= 1000;
 937     $self->log('info', "migration downtime limit: $migrate_downtime ms");
 938     $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 939
 940     # set cachesize to 10% of the total memory
 941     my $memory =  $conf->{memory} || $defaults->{memory};
 942     my $cachesize = int($memory * 1048576 / 10);
 943     $cachesize = round_powerof2($cachesize);
 944
 945     $self->log('info', "migration cachesize: $cachesize B");
 946     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 947
 948     $self->log('info', "set migration parameters");
 949     eval {
 950         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 951     };
 952     $self->log('info', "migrate-set-parameters error: $@") if $@;
 953
 954     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 955         my $rpcenv = PVE::RPCEnvironment::get();
 956         my $authuser = $rpcenv->get_user();
 957
 958         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 959
 960         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 961         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 962
 963         $self->log('info', "spice client_migrate_info");
 964
 965         eval {
 966             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 967                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 968                                                 'cert-subject' => $subject);
 969         };
 970         $self->log('info', "client_migrate_info error: $@") if $@;
 971
 972     }
 973
 974     $self->log('info', "start migrate command to $ruri");
 975     eval {
 976         mon_cmd($vmid, "migrate", uri => $ruri);
 977     };
 978     my $merr = $@;
 979     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 980
 981     my $lstat = 0;
 982     my $usleep = 1000000;
 983     my $i = 0;
 984     my $err_count = 0;
 985     my $lastrem = undef;
 986     my $downtimecounter = 0;
 987     while (1) {
 988         $i++;
 989         my $avglstat = $lstat ? $lstat / $i : 0;
 990
 991         usleep($usleep);
 992         my $stat;
 993         eval {
 994             $stat = mon_cmd($vmid, "query-migrate");
 995         };
 996         if (my $err = $@) {
 997             $err_count++;
 998             warn "query migrate failed: $err\n";
 999             $self->log('info', "query migrate failed: $err");
1000             if ($err_count <= 5) {
1001                 usleep(1000000);
1002                 next;
1003             }
1004             die "too many query migrate failures - aborting\n";
1005         }
1006
1007         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
1008             sleep(1);
1009             next;
1010         }
1011
1012         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
1013             $merr = undef;
1014             $err_count = 0;
1015             if ($stat->{status} eq 'completed') {
1016                 my $delay = time() - $start;
1017                 if ($delay > 0) {
1018                     my $mbps = sprintf "%.2f", $memory / $delay;
1019                     my $downtime = $stat->{downtime} || 0;
1020                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
1021                 }
1022             }
1023
1024             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
1025                 $self->log('info', "migration status error: $stat->{status}");
1026                 die "aborting\n"
1027             }
1028
1029             if ($stat->{status} ne 'active') {
1030                 $self->log('info', "migration status: $stat->{status}");
1031                 last;
1032             }
1033
1034             if ($stat->{ram}->{transferred} ne $lstat) {
1035                 my $trans = $stat->{ram}->{transferred} || 0;
1036                 my $rem = $stat->{ram}->{remaining} || 0;
1037                 my $total = $stat->{ram}->{total} || 0;
1038                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
1039                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
1040                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
1041                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
1042                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
1043                 # reduce sleep if remainig memory is lower than the average transfer speed
1044                 $usleep = 100000 if $avglstat && $rem < $avglstat;
1045
1046                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
1047                            "remaining ${rem}), total ${total})");
1048
1049                 if (${xbzrlecachesize}) {
1050                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
1051                 }
1052
1053                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
1054                     $downtimecounter++;
1055                 }
1056                 $lastrem = $rem;
1057
1058                 if ($downtimecounter > 5) {
1059                     $downtimecounter = 0;
1060                     $migrate_downtime *= 2;
1061                     $self->log('info', "auto-increased downtime to continue migration: $migrate_downtime ms");
1062                     eval {
1063                         # migrate-set-parameters does not touch values not
1064                         # specified, so this only changes downtime-limit
1065                         mon_cmd($vmid, "migrate-set-parameters", 'downtime-limit' => int($migrate_downtime));
1066                     };
1067                     $self->log('info', "migrate-set-parameters error: $@") if $@;
1068                 }
1069
1070             }
1071
1072
1073             $lstat = $stat->{ram}->{transferred};
1074
1075         } else {
1076             die $merr if $merr;
1077             die "unable to parse migration status '$stat->{status}' - aborting\n";
1078         }
1079     }
1080 }
1081
1082 sub phase2_cleanup {
1083     my ($self, $vmid, $err) = @_;
1084
1085     return if !$self->{errors};
1086     $self->{phase2errors} = 1;
1087
1088     $self->log('info', "aborting phase 2 - cleanup resources");
1089
1090     $self->log('info', "migrate_cancel");
1091     eval {
1092         mon_cmd($vmid, "migrate_cancel");
1093     };
1094     $self->log('info', "migrate_cancel error: $@") if $@;
1095
1096     my $conf = $self->{vmconf};
1097     delete $conf->{lock};
1098     eval { PVE::QemuConfig->write_config($vmid, $conf) };
1099     if (my $err = $@) {
1100         $self->log('err', $err);
1101     }
1102
1103     # cleanup ressources on target host
1104     if ($self->{storage_migration}) {
1105         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1106         if (my $err = $@) {
1107             $self->log('err', $err);
1108         }
1109     }
1110
1111     eval { $self->cleanup_bitmaps() };
1112     if (my $err =$@) {
1113         $self->log('err', $err);
1114     }
1115
1116     my $nodename = PVE::INotify::nodename();
1117
1118     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
1119     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1120     if (my $err = $@) {
1121         $self->log('err', $err);
1122         $self->{errors} = 1;
1123     }
1124
1125     # cleanup after stopping, otherwise disks might be in-use by target VM!
1126     eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1127     if (my $err = $@) {
1128         $self->log('err', $err);
1129     }
1130
1131
1132     if ($self->{tunnel}) {
1133         eval { finish_tunnel($self, $self->{tunnel});  };
1134         if (my $err = $@) {
1135             $self->log('err', $err);
1136             $self->{errors} = 1;
1137         }
1138     }
1139 }
1140
1141 sub phase3 {
1142     my ($self, $vmid) = @_;
1143
1144     my $volids = $self->{volumes};
1145     return if $self->{phase2errors};
1146
1147     # destroy local copies
1148     foreach my $volid (@$volids) {
1149         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1150         if (my $err = $@) {
1151             $self->log('err', "removing local copy of '$volid' failed - $err");
1152             $self->{errors} = 1;
1153             last if $err =~ /^interrupted by signal$/;
1154         }
1155     }
1156 }
1157
1158 sub phase3_cleanup {
1159     my ($self, $vmid, $err) = @_;
1160
1161     my $conf = $self->{vmconf};
1162     return if $self->{phase2errors};
1163
1164     my $tunnel = $self->{tunnel};
1165
1166     if ($self->{storage_migration}) {
1167         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1168         # to avoid it trying to re-establish it. We are in blockjob ready state,
1169         # thus, this command changes to it to blockjob complete (see qapi docs)
1170         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1171
1172         if (my $err = $@) {
1173             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1174             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1175             die "Failed to complete storage migration: $err\n";
1176         }
1177     }
1178
1179     if ($self->{volume_map}) {
1180         my $target_drives = $self->{target_drive};
1181
1182         # FIXME: for NBD storage migration we now only update the volid, and
1183         # not the full drivestr from the target node. Workaround that until we
1184         # got some real rescan, to avoid things like wrong format in the drive
1185         delete $conf->{$_} for keys %$target_drives;
1186         PVE::QemuConfig->update_volume_ids($conf, $self->{volume_map});
1187
1188         for my $drive (keys %$target_drives) {
1189             $conf->{$drive} = $target_drives->{$drive}->{drivestr};
1190         }
1191         PVE::QemuConfig->write_config($vmid, $conf);
1192     }
1193
1194     # transfer replication state before move config
1195     $self->transfer_replication_state() if $self->{is_replicated};
1196
1197     # move config to remote node
1198     my $conffile = PVE::QemuConfig->config_file($vmid);
1199     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1200
1201     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1202         if !rename($conffile, $newconffile);
1203
1204     $self->switch_replication_job_target() if $self->{is_replicated};
1205
1206     if ($self->{livemigration}) {
1207         if ($self->{stopnbd}) {
1208             $self->log('info', "stopping NBD storage migration server on target.");
1209             # stop nbd server on remote vm - requirement for resume since 2.9
1210             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1211
1212             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1213             if (my $err = $@) {
1214                 $self->log('err', $err);
1215                 $self->{errors} = 1;
1216             }
1217         }
1218
1219         # config moved and nbd server stopped - now we can resume vm on target
1220         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1221             eval {
1222                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1223             };
1224             if (my $err = $@) {
1225                 $self->log('err', $err);
1226                 $self->{errors} = 1;
1227             }
1228         } else {
1229             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1230             my $logf = sub {
1231                 my $line = shift;
1232                 $self->log('err', $line);
1233             };
1234             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1235             if (my $err = $@) {
1236                 $self->log('err', $err);
1237                 $self->{errors} = 1;
1238             }
1239         }
1240
1241         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1242             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1243             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1244         }
1245     }
1246
1247     # close tunnel on successful migration, on error phase2_cleanup closed it
1248     if ($tunnel) {
1249         eval { finish_tunnel($self, $tunnel);  };
1250         if (my $err = $@) {
1251             $self->log('err', $err);
1252             $self->{errors} = 1;
1253         }
1254     }
1255
1256     eval {
1257         my $timer = 0;
1258         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1259             $self->log('info', "Waiting for spice server migration");
1260             while (1) {
1261                 my $res = mon_cmd($vmid, 'query-spice');
1262                 last if int($res->{'migrated'}) == 1;
1263                 last if $timer > 50;
1264                 $timer ++;
1265                 usleep(200000);
1266             }
1267         }
1268     };
1269
1270     # always stop local VM
1271     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1272     if (my $err = $@) {
1273         $self->log('err', "stopping vm failed - $err");
1274         $self->{errors} = 1;
1275     }
1276
1277     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1278     eval {
1279         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1280         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1281     };
1282     if (my $err = $@) {
1283         $self->log('err', $err);
1284         $self->{errors} = 1;
1285     }
1286
1287     if($self->{storage_migration}) {
1288         # destroy local copies
1289         my $volids = $self->{online_local_volumes};
1290
1291         foreach my $volid (@$volids) {
1292             # keep replicated volumes!
1293             next if $self->{replicated_volumes}->{$volid};
1294
1295             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1296             if (my $err = $@) {
1297                 $self->log('err', "removing local copy of '$volid' failed - $err");
1298                 $self->{errors} = 1;
1299                 last if $err =~ /^interrupted by signal$/;
1300             }
1301         }
1302
1303     }
1304
1305     # clear migrate lock
1306     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1307     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1308 }
1309
1310 sub final_cleanup {
1311     my ($self, $vmid) = @_;
1312
1313     # nothing to do
1314 }
1315
1316 sub round_powerof2 {
1317     return 1 if $_[0] < 2;
1318     return 2 << int(log($_[0]-1)/log(2));
1319 }
1320
1321 1;