PVE/QemuMigrate.pm

   1 package PVE::QemuMigrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use IO::File;
   7 use IPC::Open2;
   8 use POSIX qw( WNOHANG );
   9 use PVE::INotify;
  10 use PVE::Tools;
  11 use PVE::Cluster;
  12 use PVE::Storage;
  13 use PVE::QemuServer;
  14 use PVE::QemuServer::Drive;
  15 use PVE::QemuServer::Machine;
  16 use PVE::QemuServer::Monitor qw(mon_cmd);
  17 use Time::HiRes qw( usleep );
  18 use PVE::RPCEnvironment;
  19 use PVE::ReplicationConfig;
  20 use PVE::ReplicationState;
  21 use PVE::Replication;
  22
  23 use base qw(PVE::AbstractMigrate);
  24
  25 sub fork_command_pipe {
  26     my ($self, $cmd) = @_;
  27
  28     my $reader = IO::File->new();
  29     my $writer = IO::File->new();
  30
  31     my $orig_pid = $$;
  32
  33     my $cpid;
  34
  35     eval { $cpid = open2($reader, $writer, @$cmd); };
  36
  37     my $err = $@;
  38
  39     # catch exec errors
  40     if ($orig_pid != $$) {
  41         $self->log('err', "can't fork command pipe\n");
  42         POSIX::_exit(1);
  43         kill('KILL', $$);
  44     }
  45
  46     die $err if $err;
  47
  48     return { writer => $writer, reader => $reader, pid => $cpid };
  49 }
  50
  51 sub finish_command_pipe {
  52     my ($self, $cmdpipe, $timeout) = @_;
  53
  54     my $cpid = $cmdpipe->{pid};
  55     return if !defined($cpid);
  56
  57     my $writer = $cmdpipe->{writer};
  58     my $reader = $cmdpipe->{reader};
  59
  60     $writer->close();
  61     $reader->close();
  62
  63     my $collect_child_process = sub {
  64         my $res = waitpid($cpid, WNOHANG);
  65         if (defined($res) && ($res == $cpid)) {
  66             delete $cmdpipe->{cpid};
  67             return 1;
  68         } else {
  69             return 0;
  70         }
  71      };
  72
  73     if ($timeout) {
  74         for (my $i = 0; $i < $timeout; $i++) {
  75             return if &$collect_child_process();
  76             sleep(1);
  77         }
  78     }
  79
  80     $self->log('info', "ssh tunnel still running - terminating now with SIGTERM\n");
  81     kill(15, $cpid);
  82
  83     # wait again
  84     for (my $i = 0; $i < 10; $i++) {
  85         return if &$collect_child_process();
  86         sleep(1);
  87     }
  88
  89     $self->log('info', "ssh tunnel still running - terminating now with SIGKILL\n");
  90     kill 9, $cpid;
  91     sleep 1;
  92
  93     $self->log('err', "ssh tunnel child process (PID $cpid) couldn't be collected\n")
  94         if !&$collect_child_process();
  95 }
  96
  97 sub read_tunnel {
  98     my ($self, $tunnel, $timeout) = @_;
  99
 100     $timeout = 60 if !defined($timeout);
 101
 102     my $reader = $tunnel->{reader};
 103
 104     my $output;
 105     eval {
 106         PVE::Tools::run_with_timeout($timeout, sub { $output = <$reader>; });
 107     };
 108     die "reading from tunnel failed: $@\n" if $@;
 109
 110     chomp $output;
 111
 112     return $output;
 113 }
 114
 115 sub write_tunnel {
 116     my ($self, $tunnel, $timeout, $command) = @_;
 117
 118     $timeout = 60 if !defined($timeout);
 119
 120     my $writer = $tunnel->{writer};
 121
 122     eval {
 123         PVE::Tools::run_with_timeout($timeout, sub {
 124             print $writer "$command\n";
 125             $writer->flush();
 126         });
 127     };
 128     die "writing to tunnel failed: $@\n" if $@;
 129
 130     if ($tunnel->{version} && $tunnel->{version} >= 1) {
 131         my $res = eval { $self->read_tunnel($tunnel, 10); };
 132         die "no reply to command '$command': $@\n" if $@;
 133
 134         if ($res eq 'OK') {
 135             return;
 136         } else {
 137             die "tunnel replied '$res' to command '$command'\n";
 138         }
 139     }
 140 }
 141
 142 sub fork_tunnel {
 143     my ($self, $tunnel_addr) = @_;
 144
 145     my @localtunnelinfo = ();
 146     foreach my $addr (@$tunnel_addr) {
 147         push @localtunnelinfo, '-L', $addr;
 148     }
 149
 150     my $cmd = [@{$self->{rem_ssh}}, '-o ExitOnForwardFailure=yes', @localtunnelinfo, '/usr/sbin/qm', 'mtunnel' ];
 151
 152     my $tunnel = $self->fork_command_pipe($cmd);
 153
 154     eval {
 155         my $helo = $self->read_tunnel($tunnel, 60);
 156         die "no reply\n" if !$helo;
 157         die "no quorum on target node\n" if $helo =~ m/^no quorum$/;
 158         die "got strange reply from mtunnel ('$helo')\n"
 159             if $helo !~ m/^tunnel online$/;
 160     };
 161     my $err = $@;
 162
 163     eval {
 164         my $ver = $self->read_tunnel($tunnel, 10);
 165         if ($ver =~ /^ver (\d+)$/) {
 166             $tunnel->{version} = $1;
 167             $self->log('info', "ssh tunnel $ver\n");
 168         } else {
 169             $err = "received invalid tunnel version string '$ver'\n" if !$err;
 170         }
 171     };
 172
 173     if ($err) {
 174         $self->finish_command_pipe($tunnel);
 175         die "can't open migration tunnel - $err";
 176     }
 177     return $tunnel;
 178 }
 179
 180 sub finish_tunnel {
 181     my ($self, $tunnel) = @_;
 182
 183     eval { $self->write_tunnel($tunnel, 30, 'quit'); };
 184     my $err = $@;
 185
 186     $self->finish_command_pipe($tunnel, 30);
 187
 188     if ($tunnel->{sock_addr}) {
 189         # ssh does not clean up on local host
 190         my $cmd = ['rm', '-f', @{$tunnel->{sock_addr}}]; #
 191         PVE::Tools::run_command($cmd);
 192
 193         # .. and just to be sure check on remote side
 194         unshift @{$cmd}, @{$self->{rem_ssh}};
 195         PVE::Tools::run_command($cmd);
 196     }
 197
 198     die $err if $err;
 199 }
 200
 201 sub lock_vm {
 202     my ($self, $vmid, $code, @param) = @_;
 203
 204     return PVE::QemuConfig->lock_config($vmid, $code, @param);
 205 }
 206
 207 sub prepare {
 208     my ($self, $vmid) = @_;
 209
 210     my $online = $self->{opts}->{online};
 211
 212     $self->{storecfg} = PVE::Storage::config();
 213
 214     # test if VM exists
 215     my $conf = $self->{vmconf} = PVE::QemuConfig->load_config($vmid);
 216
 217     PVE::QemuConfig->check_lock($conf);
 218
 219     my $running = 0;
 220     if (my $pid = PVE::QemuServer::check_running($vmid)) {
 221         die "can't migrate running VM without --online\n" if !$online;
 222         $running = $pid;
 223
 224         $self->{forcemachine} = PVE::QemuServer::Machine::qemu_machine_pxe($vmid, $conf);
 225
 226     }
 227     my $loc_res = PVE::QemuServer::check_local_resources($conf, 1);
 228     if (scalar @$loc_res) {
 229         if ($self->{running} || !$self->{opts}->{force}) {
 230             die "can't migrate VM which uses local devices: " . join(", ", @$loc_res) . "\n";
 231         } else {
 232             $self->log('info', "migrating VM which uses local devices");
 233         }
 234     }
 235
 236     my $vollist = PVE::QemuServer::get_vm_volumes($conf);
 237
 238     my $need_activate = [];
 239     foreach my $volid (@$vollist) {
 240         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 241
 242         # check if storage is available on both nodes
 243         my $targetsid = $self->{opts}->{targetstorage} // $sid;
 244
 245         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 246         PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 247
 248         if ($scfg->{shared}) {
 249             # PVE::Storage::activate_storage checks this for non-shared storages
 250             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 251             warn "Used shared storage '$sid' is not online on source node!\n"
 252                 if !$plugin->check_connection($sid, $scfg);
 253         } else {
 254             # only activate if not shared
 255             next if ($volid =~ m/vm-\d+-cloudinit/);
 256             push @$need_activate, $volid;
 257         }
 258     }
 259
 260     # activate volumes
 261     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
 262
 263     # test ssh connection
 264     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
 265     eval { $self->cmd_quiet($cmd); };
 266     die "Can't connect to destination address using public key\n" if $@;
 267
 268     return $running;
 269 }
 270
 271 sub sync_disks {
 272     my ($self, $vmid) = @_;
 273
 274     my $conf = $self->{vmconf};
 275
 276     # local volumes which have been copied
 277     $self->{volumes} = [];
 278
 279     my $override_targetsid = $self->{opts}->{targetstorage};
 280
 281     eval {
 282
 283         # found local volumes and their origin
 284         my $local_volumes = {};
 285         my $local_volumes_errors = {};
 286         my $other_errors = [];
 287         my $abort = 0;
 288
 289         my $log_error = sub {
 290             my ($msg, $volid) = @_;
 291
 292             if (defined($volid)) {
 293                 $local_volumes_errors->{$volid} = $msg;
 294             } else {
 295                 push @$other_errors, $msg;
 296             }
 297             $abort = 1;
 298         };
 299
 300         my @sids = PVE::Storage::storage_ids($self->{storecfg});
 301         foreach my $storeid (@sids) {
 302             my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 303             next if $scfg->{shared};
 304             next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 305
 306             # get list from PVE::Storage (for unused volumes)
 307             my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 308
 309             next if @{$dl->{$storeid}} == 0;
 310
 311             my $targetsid = $override_targetsid // $storeid;
 312
 313             # check if storage is available on target node
 314             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 315
 316             PVE::Storage::foreach_volid($dl, sub {
 317                 my ($volid, $sid, $volinfo) = @_;
 318
 319                 $local_volumes->{$volid}->{ref} = 'storage';
 320
 321                 # If with_snapshots is not set for storage migrate, it tries to use
 322                 # a raw+size stream, but on-the-fly conversion from qcow2 to raw+size
 323                 # back to qcow2 is currently not possible.
 324                 $local_volumes->{$volid}->{snapshots} = ($volinfo->{format} =~ /^(?:qcow2|vmdk)$/);
 325                 $local_volumes->{$volid}->{format} = $volinfo->{format};
 326             });
 327         }
 328
 329         my $test_volid = sub {
 330             my ($volid, $attr) = @_;
 331
 332             if ($volid =~ m|^/|) {
 333                 return if $attr->{shared};
 334                 $local_volumes->{$volid}->{ref} = 'config';
 335                 die "local file/device\n";
 336             }
 337
 338             my $snaprefs = $attr->{referenced_in_snapshot};
 339
 340             if ($attr->{cdrom}) {
 341                 if ($volid eq 'cdrom') {
 342                     my $msg = "can't migrate local cdrom drive";
 343                     if (defined($snaprefs) && !$attr->{referenced_in_config}) {
 344                         my $snapnames = join(', ', sort keys %$snaprefs);
 345                         $msg .= " (referenced in snapshot - $snapnames)";
 346                     }
 347                     &$log_error("$msg\n");
 348                     return;
 349                 }
 350                 return if $volid eq 'none';
 351             }
 352
 353             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 354
 355             my $targetsid = $override_targetsid // $sid;
 356             # check if storage is available on both nodes
 357             my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 358             PVE::Storage::storage_check_node($self->{storecfg}, $targetsid, $self->{node});
 359
 360             return if $scfg->{shared};
 361
 362             $local_volumes->{$volid}->{ref} = $attr->{referenced_in_config} ? 'config' : 'snapshot';
 363
 364             if ($attr->{cdrom}) {
 365                 if ($volid =~ /vm-\d+-cloudinit/) {
 366                     $local_volumes->{$volid}->{ref} = 'generated';
 367                     return;
 368                 }
 369                 die "local cdrom image\n";
 370             }
 371
 372             my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 373
 374             die "owned by other VM (owner = VM $owner)\n"
 375                 if !$owner || ($owner != $self->{vmid});
 376
 377             if (defined($snaprefs)) {
 378                 $local_volumes->{$volid}->{snapshots} = 1;
 379
 380                 # we cannot migrate shapshots on local storage
 381                 # exceptions: 'zfspool' or 'qcow2' files (on directory storage)
 382
 383                 die "online storage migration not possible if snapshot exists\n" if $self->{running};
 384                 if (!($scfg->{type} eq 'zfspool' || $local_volumes->{$volid}->{format} eq 'qcow2')) {
 385                     die "non-migratable snapshot exists\n";
 386                 }
 387             }
 388
 389             die "referenced by linked clone(s)\n"
 390                 if PVE::Storage::volume_is_base_and_used($self->{storecfg}, $volid);
 391         };
 392
 393         PVE::QemuServer::foreach_volid($conf, sub {
 394             my ($volid, $attr) = @_;
 395             eval { $test_volid->($volid, $attr); };
 396             if (my $err = $@) {
 397                 &$log_error($err, $volid);
 398             }
 399         });
 400
 401         foreach my $vol (sort keys %$local_volumes) {
 402             my $ref = $local_volumes->{$vol}->{ref};
 403             if ($ref eq 'storage') {
 404                 $self->log('info', "found local disk '$vol' (via storage)\n");
 405             } elsif ($ref eq 'config') {
 406                 &$log_error("can't live migrate attached local disks without with-local-disks option\n", $vol)
 407                     if $self->{running} && !$self->{opts}->{"with-local-disks"};
 408                 $self->log('info', "found local disk '$vol' (in current VM config)\n");
 409             } elsif ($ref eq 'snapshot') {
 410                 $self->log('info', "found local disk '$vol' (referenced by snapshot(s))\n");
 411             } elsif ($ref eq 'generated') {
 412                 $self->log('info', "found generated disk '$vol' (in current VM config)\n");
 413             } else {
 414                 $self->log('info', "found local disk '$vol'\n");
 415             }
 416         }
 417
 418         foreach my $vol (sort keys %$local_volumes_errors) {
 419             $self->log('warn', "can't migrate local disk '$vol': $local_volumes_errors->{$vol}");
 420         }
 421         foreach my $err (@$other_errors) {
 422             $self->log('warn', "$err");
 423         }
 424
 425         if ($abort) {
 426             die "can't migrate VM - check log\n";
 427         }
 428
 429         # additional checks for local storage
 430         foreach my $volid (keys %$local_volumes) {
 431             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 432             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 433
 434             my $migratable = $scfg->{type} =~ /^(?:dir|zfspool|lvmthin|lvm)$/;
 435
 436             die "can't migrate '$volid' - storage type '$scfg->{type}' not supported\n"
 437                 if !$migratable;
 438
 439             # image is a linked clone on local storage, se we can't migrate.
 440             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 441                 die "can't migrate '$volid' as it's a clone of '$basename'";
 442             }
 443         }
 444
 445         my $rep_cfg = PVE::ReplicationConfig->new();
 446         if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 447             die "can't live migrate VM with replicated volumes\n" if $self->{running};
 448             $self->log('info', "replicating disk images");
 449             my $start_time = time();
 450             my $logfunc = sub { $self->log('info', shift) };
 451             $self->{replicated_volumes} = PVE::Replication::run_replication(
 452                'PVE::QemuConfig', $jobcfg, $start_time, $start_time, $logfunc);
 453         }
 454
 455         # sizes in config have to be accurate for remote node to correctly
 456         # allocate disks, rescan to be sure
 457         my $volid_hash = PVE::QemuServer::scan_volids($self->{storecfg}, $vmid);
 458         PVE::QemuServer::foreach_drive($conf, sub {
 459             my ($key, $drive) = @_;
 460             my ($updated, $old_size, $new_size) = PVE::QemuServer::Drive::update_disksize($drive, $volid_hash);
 461             if (defined($updated)) {
 462                 $conf->{$key} = PVE::QemuServer::print_drive($updated);
 463                 $self->log('info', "size of disk '$updated->{file}' ($key) updated from $old_size to $new_size\n");
 464             }
 465         });
 466
 467         $self->log('info', "copying local disk images") if scalar(%$local_volumes);
 468
 469         foreach my $volid (keys %$local_volumes) {
 470             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 471             my $targetsid = $override_targetsid // $sid;
 472             my $ref = $local_volumes->{$volid}->{ref};
 473             if ($self->{running} && $ref eq 'config') {
 474                 push @{$self->{online_local_volumes}}, $volid;
 475             } elsif ($ref eq 'generated') {
 476                 die "can't live migrate VM with local cloudinit disk. use a shared storage instead\n" if $self->{running};
 477                 # skip all generated volumes but queue them for deletion in phase3_cleanup
 478                 push @{$self->{volumes}}, $volid;
 479                 next;
 480             } else {
 481                 next if $self->{replicated_volumes}->{$volid};
 482                 push @{$self->{volumes}}, $volid;
 483                 my $opts = $self->{opts};
 484                 my $insecure = $opts->{migration_type} eq 'insecure';
 485                 my $with_snapshots = $local_volumes->{$volid}->{snapshots};
 486                 # use 'migrate' limit for transfer to other node
 487                 my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$targetsid, $sid], $opts->{bwlimit});
 488                 # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 489                 $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 490
 491                 PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $targetsid,
 492                                               undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 493             }
 494         }
 495     };
 496     die "Failed to sync data - $@" if $@;
 497 }
 498
 499 sub cleanup_remotedisks {
 500     my ($self) = @_;
 501
 502     foreach my $target_drive (keys %{$self->{target_drive}}) {
 503
 504         my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
 505         my ($storeid, $volname) = PVE::Storage::parse_volume_id($drive->{file});
 506
 507         my $cmd = [@{$self->{rem_ssh}}, 'pvesm', 'free', "$storeid:$volname"];
 508
 509         eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 510         if (my $err = $@) {
 511             $self->log('err', $err);
 512             $self->{errors} = 1;
 513         }
 514     }
 515 }
 516
 517 sub phase1 {
 518     my ($self, $vmid) = @_;
 519
 520     $self->log('info', "starting migration of VM $vmid to node '$self->{node}' ($self->{nodeip})");
 521
 522     my $conf = $self->{vmconf};
 523
 524     # set migrate lock in config file
 525     $conf->{lock} = 'migrate';
 526     PVE::QemuConfig->write_config($vmid, $conf);
 527
 528     sync_disks($self, $vmid);
 529
 530     # sync_disks fixes disk sizes to match their actual size, write changes so
 531     # target allocates correct volumes
 532     PVE::QemuConfig->write_config($vmid, $conf);
 533 };
 534
 535 sub phase1_cleanup {
 536     my ($self, $vmid, $err) = @_;
 537
 538     $self->log('info', "aborting phase 1 - cleanup resources");
 539
 540     my $conf = $self->{vmconf};
 541     delete $conf->{lock};
 542     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 543     if (my $err = $@) {
 544         $self->log('err', $err);
 545     }
 546
 547     if ($self->{volumes}) {
 548         foreach my $volid (@{$self->{volumes}}) {
 549             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 550             # fixme: try to remove ?
 551         }
 552     }
 553 }
 554
 555 sub phase2 {
 556     my ($self, $vmid) = @_;
 557
 558     my $conf = $self->{vmconf};
 559
 560     $self->log('info', "starting VM $vmid on remote node '$self->{node}'");
 561
 562     my $raddr;
 563     my $rport;
 564     my $ruri; # the whole migration dst. URI (protocol:address[:port])
 565     my $nodename = PVE::INotify::nodename();
 566
 567     ## start on remote node
 568     my $cmd = [@{$self->{rem_ssh}}];
 569
 570     my $spice_ticket;
 571     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 572         my $res = mon_cmd($vmid, 'query-spice');
 573         $spice_ticket = $res->{ticket};
 574     }
 575
 576     push @$cmd , 'qm', 'start', $vmid, '--skiplock', '--migratedfrom', $nodename;
 577
 578     my $migration_type = $self->{opts}->{migration_type};
 579
 580     push @$cmd, '--migration_type', $migration_type;
 581
 582     push @$cmd, '--migration_network', $self->{opts}->{migration_network}
 583       if $self->{opts}->{migration_network};
 584
 585     if ($migration_type eq 'insecure') {
 586         push @$cmd, '--stateuri', 'tcp';
 587     } else {
 588         push @$cmd, '--stateuri', 'unix';
 589     }
 590
 591     if ($self->{forcemachine}) {
 592         push @$cmd, '--machine', $self->{forcemachine};
 593     }
 594
 595     if ($self->{online_local_volumes}) {
 596         push @$cmd, '--targetstorage', ($self->{opts}->{targetstorage} // '1');
 597     }
 598
 599     my $spice_port;
 600     my $tunnel_addr = [];
 601     my $sock_addr = [];
 602     # version > 0 for unix socket support
 603     my $nbd_protocol_version = 1;
 604     my $input = "nbd_protocol_version: $nbd_protocol_version\n";
 605     $input .= "spice_ticket: $spice_ticket\n" if $spice_ticket;
 606
 607     # Note: We try to keep $spice_ticket secret (do not pass via command line parameter)
 608     # instead we pipe it through STDIN
 609     my $exitcode = PVE::Tools::run_command($cmd, input => $input, outfunc => sub {
 610         my $line = shift;
 611
 612         if ($line =~ m/^migration listens on tcp:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+)$/) {
 613             $raddr = $1;
 614             $rport = int($2);
 615             $ruri = "tcp:$raddr:$rport";
 616         }
 617         elsif ($line =~ m!^migration listens on unix:(/run/qemu-server/(\d+)\.migrate)$!) {
 618             $raddr = $1;
 619             die "Destination UNIX sockets VMID does not match source VMID" if $vmid ne $2;
 620             $ruri = "unix:$raddr";
 621         }
 622         elsif ($line =~ m/^migration listens on port (\d+)$/) {
 623             $raddr = "localhost";
 624             $rport = int($1);
 625             $ruri = "tcp:$raddr:$rport";
 626         }
 627         elsif ($line =~ m/^spice listens on port (\d+)$/) {
 628             $spice_port = int($1);
 629         }
 630         elsif ($line =~ m/^storage migration listens on nbd:(localhost|[\d\.]+|\[[\d\.:a-fA-F]+\]):(\d+):exportname=(\S+) volume:(\S+)$/) {
 631             my $drivestr = $4;
 632             my $nbd_uri = "nbd:$1:$2:exportname=$3";
 633             my $targetdrive = $3;
 634             $targetdrive =~ s/drive-//g;
 635
 636             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 637             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 638         } elsif ($line =~ m!^storage migration listens on nbd:unix:(/run/qemu-server/(\d+)_nbd\.migrate):exportname=(\S+) volume:(\S+)$!) {
 639             my $drivestr = $4;
 640             die "Destination UNIX socket's VMID does not match source VMID" if $vmid ne $2;
 641             my $nbd_unix_addr = $1;
 642             my $nbd_uri = "nbd:unix:$nbd_unix_addr:exportname=$3";
 643             my $targetdrive = $3;
 644             $targetdrive =~ s/drive-//g;
 645
 646             $self->{target_drive}->{$targetdrive}->{drivestr} = $drivestr;
 647             $self->{target_drive}->{$targetdrive}->{nbd_uri} = $nbd_uri;
 648             push @$tunnel_addr, "$nbd_unix_addr:$nbd_unix_addr";
 649             push @$sock_addr, $nbd_unix_addr;
 650         } elsif ($line =~ m/^QEMU: (.*)$/) {
 651             $self->log('info', "[$self->{node}] $1\n");
 652         }
 653     }, errfunc => sub {
 654         my $line = shift;
 655         $self->log('info', "[$self->{node}] $line");
 656     }, noerr => 1);
 657
 658     die "remote command failed with exit code $exitcode\n" if $exitcode;
 659
 660     die "unable to detect remote migration address\n" if !$raddr;
 661
 662     $self->log('info', "start remote tunnel");
 663
 664     if ($migration_type eq 'secure') {
 665
 666         if ($ruri =~ /^unix:/) {
 667             unlink $raddr;
 668             push @$tunnel_addr, "$raddr:$raddr";
 669             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 670             push @$sock_addr, $raddr;
 671
 672             my $unix_socket_try = 0; # wait for the socket to become ready
 673             while ($unix_socket_try <= 100) {
 674                 $unix_socket_try++;
 675                 my $available = 0;
 676                 foreach my $sock (@$sock_addr) {
 677                     if (-S $sock) {
 678                         $available++;
 679                     }
 680                 }
 681
 682                 if ($available == @$sock_addr) {
 683                     last;
 684                 }
 685
 686                 usleep(50000);
 687             }
 688             if ($unix_socket_try > 100) {
 689                 $self->{errors} = 1;
 690                 $self->finish_tunnel($self->{tunnel});
 691                 die "Timeout, migration socket $ruri did not get ready";
 692             }
 693
 694         } elsif ($ruri =~ /^tcp:/) {
 695             my $tunnel_addr;
 696             if ($raddr eq "localhost") {
 697                 # for backwards compatibility with older qemu-server versions
 698                 my $pfamily = PVE::Tools::get_host_address_family($nodename);
 699                 my $lport = PVE::Tools::next_migrate_port($pfamily);
 700                 $tunnel_addr = "$lport:localhost:$rport";
 701             }
 702
 703             $self->{tunnel} = $self->fork_tunnel($tunnel_addr);
 704
 705         } else {
 706             die "unsupported protocol in migration URI: $ruri\n";
 707         }
 708     } else {
 709         #fork tunnel for insecure migration, to send faster commands like resume
 710         $self->{tunnel} = $self->fork_tunnel();
 711     }
 712     $self->{tunnel}->{sock_addr} = $sock_addr if (@$sock_addr);
 713
 714     my $start = time();
 715
 716     my $opt_bwlimit = $self->{opts}->{bwlimit};
 717
 718     if (defined($self->{online_local_volumes})) {
 719         $self->{storage_migration} = 1;
 720         $self->{storage_migration_jobs} = {};
 721         $self->log('info', "starting storage migration");
 722
 723         die "The number of local disks does not match between the source and the destination.\n"
 724             if (scalar(keys %{$self->{target_drive}}) != scalar @{$self->{online_local_volumes}});
 725         foreach my $drive (keys %{$self->{target_drive}}){
 726             my $target = $self->{target_drive}->{$drive};
 727             my $nbd_uri = $target->{nbd_uri};
 728
 729             my $source_drive = PVE::QemuServer::parse_drive($drive, $conf->{$drive});
 730             my $target_drive = PVE::QemuServer::parse_drive($drive, $target->{drivestr});
 731
 732             my $source_sid = PVE::Storage::Plugin::parse_volume_id($source_drive->{file});
 733             my $target_sid = PVE::Storage::Plugin::parse_volume_id($target_drive->{file});
 734
 735             my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$source_sid, $target_sid], $opt_bwlimit);
 736
 737             $self->log('info', "$drive: start migration to $nbd_uri");
 738             PVE::QemuServer::qemu_drive_mirror($vmid, $drive, $nbd_uri, $vmid, undef, $self->{storage_migration_jobs}, 'skip', undef, $bwlimit);
 739         }
 740     }
 741
 742     $self->log('info', "starting online/live migration on $ruri");
 743     $self->{livemigration} = 1;
 744
 745     # load_defaults
 746     my $defaults = PVE::QemuServer::load_defaults();
 747
 748     $self->log('info', "set migration_caps");
 749     eval {
 750         PVE::QemuServer::set_migration_caps($vmid);
 751     };
 752     warn $@ if $@;
 753
 754     my $qemu_migrate_params = {};
 755
 756     # migrate speed can be set via bwlimit (datacenter.cfg and API) and via the
 757     # migrate_speed parameter in qm.conf - take the lower of the two.
 758     my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', undef, $opt_bwlimit) // 0;
 759     my $migrate_speed = $conf->{migrate_speed} // $bwlimit;
 760     # migrate_speed is in MB/s, bwlimit in KB/s
 761     $migrate_speed *= 1024;
 762
 763     $migrate_speed = ($bwlimit < $migrate_speed) ? $bwlimit : $migrate_speed;
 764
 765     # always set migrate speed (overwrite kvm default of 32m) we set a very high
 766     # default of 8192m which is basically unlimited
 767     $migrate_speed ||= ($defaults->{migrate_speed} || 8192) * 1024;
 768
 769     # qmp takes migrate_speed in B/s.
 770     $migrate_speed *= 1024;
 771     $self->log('info', "migration speed limit: $migrate_speed B/s");
 772     $qemu_migrate_params->{'max-bandwidth'} = int($migrate_speed);
 773
 774     my $migrate_downtime = $defaults->{migrate_downtime};
 775     $migrate_downtime = $conf->{migrate_downtime} if defined($conf->{migrate_downtime});
 776     if (defined($migrate_downtime)) {
 777         # migrate-set-parameters expects limit in ms
 778         $migrate_downtime *= 1000;
 779         $self->log('info', "migration downtime limit: $migrate_downtime ms");
 780         $qemu_migrate_params->{'downtime-limit'} = int($migrate_downtime);
 781     }
 782
 783     # set cachesize to 10% of the total memory
 784     my $memory =  $conf->{memory} || $defaults->{memory};
 785     my $cachesize = int($memory * 1048576 / 10);
 786     $cachesize = round_powerof2($cachesize);
 787
 788     $self->log('info', "migration cachesize: $cachesize B");
 789     $qemu_migrate_params->{'xbzrle-cache-size'} = int($cachesize);
 790
 791     $self->log('info', "set migration parameters");
 792     eval {
 793         mon_cmd($vmid, "migrate-set-parameters", %{$qemu_migrate_params});
 794     };
 795     $self->log('info', "migrate-set-parameters error: $@") if $@;
 796
 797     if (PVE::QemuServer::vga_conf_has_spice($conf->{vga})) {
 798         my $rpcenv = PVE::RPCEnvironment::get();
 799         my $authuser = $rpcenv->get_user();
 800
 801         my (undef, $proxyticket) = PVE::AccessControl::assemble_spice_ticket($authuser, $vmid, $self->{node});
 802
 803         my $filename = "/etc/pve/nodes/$self->{node}/pve-ssl.pem";
 804         my $subject =  PVE::AccessControl::read_x509_subject_spice($filename);
 805
 806         $self->log('info', "spice client_migrate_info");
 807
 808         eval {
 809             mon_cmd($vmid, "client_migrate_info", protocol => 'spice',
 810                                                 hostname => $proxyticket, 'port' => 0, 'tls-port' => $spice_port,
 811                                                 'cert-subject' => $subject);
 812         };
 813         $self->log('info', "client_migrate_info error: $@") if $@;
 814
 815     }
 816
 817     $self->log('info', "start migrate command to $ruri");
 818     eval {
 819         mon_cmd($vmid, "migrate", uri => $ruri);
 820     };
 821     my $merr = $@;
 822     $self->log('info', "migrate uri => $ruri failed: $merr") if $merr;
 823
 824     my $lstat = 0;
 825     my $usleep = 1000000;
 826     my $i = 0;
 827     my $err_count = 0;
 828     my $lastrem = undef;
 829     my $downtimecounter = 0;
 830     while (1) {
 831         $i++;
 832         my $avglstat = $lstat/$i if $lstat;
 833
 834         usleep($usleep);
 835         my $stat;
 836         eval {
 837             $stat = mon_cmd($vmid, "query-migrate");
 838         };
 839         if (my $err = $@) {
 840             $err_count++;
 841             warn "query migrate failed: $err\n";
 842             $self->log('info', "query migrate failed: $err");
 843             if ($err_count <= 5) {
 844                 usleep(1000000);
 845                 next;
 846             }
 847             die "too many query migrate failures - aborting\n";
 848         }
 849
 850         if (defined($stat->{status}) && $stat->{status} =~ m/^(setup)$/im) {
 851             sleep(1);
 852             next;
 853         }
 854
 855         if (defined($stat->{status}) && $stat->{status} =~ m/^(active|completed|failed|cancelled)$/im) {
 856             $merr = undef;
 857             $err_count = 0;
 858             if ($stat->{status} eq 'completed') {
 859                 my $delay = time() - $start;
 860                 if ($delay > 0) {
 861                     my $mbps = sprintf "%.2f", $memory / $delay;
 862                     my $downtime = $stat->{downtime} || 0;
 863                     $self->log('info', "migration speed: $mbps MB/s - downtime $downtime ms");
 864                 }
 865             }
 866
 867             if ($stat->{status} eq 'failed' || $stat->{status} eq 'cancelled') {
 868                 $self->log('info', "migration status error: $stat->{status}");
 869                 die "aborting\n"
 870             }
 871
 872             if ($stat->{status} ne 'active') {
 873                 $self->log('info', "migration status: $stat->{status}");
 874                 last;
 875             }
 876
 877             if ($stat->{ram}->{transferred} ne $lstat) {
 878                 my $trans = $stat->{ram}->{transferred} || 0;
 879                 my $rem = $stat->{ram}->{remaining} || 0;
 880                 my $total = $stat->{ram}->{total} || 0;
 881                 my $xbzrlecachesize = $stat->{"xbzrle-cache"}->{"cache-size"} || 0;
 882                 my $xbzrlebytes = $stat->{"xbzrle-cache"}->{"bytes"} || 0;
 883                 my $xbzrlepages = $stat->{"xbzrle-cache"}->{"pages"} || 0;
 884                 my $xbzrlecachemiss = $stat->{"xbzrle-cache"}->{"cache-miss"} || 0;
 885                 my $xbzrleoverflow = $stat->{"xbzrle-cache"}->{"overflow"} || 0;
 886                 # reduce sleep if remainig memory is lower than the average transfer speed
 887                 $usleep = 100000 if $avglstat && $rem < $avglstat;
 888
 889                 $self->log('info', "migration status: $stat->{status} (transferred ${trans}, " .
 890                            "remaining ${rem}), total ${total})");
 891
 892                 if (${xbzrlecachesize}) {
 893                     $self->log('info', "migration xbzrle cachesize: ${xbzrlecachesize} transferred ${xbzrlebytes} pages ${xbzrlepages} cachemiss ${xbzrlecachemiss} overflow ${xbzrleoverflow}");
 894                 }
 895
 896                 if (($lastrem  && $rem > $lastrem ) || ($rem == 0)) {
 897                     $downtimecounter++;
 898                 }
 899                 $lastrem = $rem;
 900
 901                 if ($downtimecounter > 5) {
 902                     $downtimecounter = 0;
 903                     $migrate_downtime *= 2;
 904                     $self->log('info', "migrate_set_downtime: $migrate_downtime");
 905                     eval {
 906                         mon_cmd($vmid, "migrate_set_downtime", value => int($migrate_downtime*100)/100);
 907                     };
 908                     $self->log('info', "migrate_set_downtime error: $@") if $@;
 909                 }
 910
 911             }
 912
 913
 914             $lstat = $stat->{ram}->{transferred};
 915
 916         } else {
 917             die $merr if $merr;
 918             die "unable to parse migration status '$stat->{status}' - aborting\n";
 919         }
 920     }
 921 }
 922
 923 sub phase2_cleanup {
 924     my ($self, $vmid, $err) = @_;
 925
 926     return if !$self->{errors};
 927     $self->{phase2errors} = 1;
 928
 929     $self->log('info', "aborting phase 2 - cleanup resources");
 930
 931     $self->log('info', "migrate_cancel");
 932     eval {
 933         mon_cmd($vmid, "migrate_cancel");
 934     };
 935     $self->log('info', "migrate_cancel error: $@") if $@;
 936
 937     my $conf = $self->{vmconf};
 938     delete $conf->{lock};
 939     eval { PVE::QemuConfig->write_config($vmid, $conf) };
 940     if (my $err = $@) {
 941         $self->log('err', $err);
 942     }
 943
 944     # cleanup ressources on target host
 945     if ($self->{storage_migration}) {
 946
 947         eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
 948         if (my $err = $@) {
 949             $self->log('err', $err);
 950         }
 951
 952         eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
 953         if (my $err = $@) {
 954             $self->log('err', $err);
 955         }
 956     }
 957
 958     my $nodename = PVE::INotify::nodename();
 959
 960     my $cmd = [@{$self->{rem_ssh}}, 'qm', 'stop', $vmid, '--skiplock', '--migratedfrom', $nodename];
 961     eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
 962     if (my $err = $@) {
 963         $self->log('err', $err);
 964         $self->{errors} = 1;
 965     }
 966
 967     if ($self->{tunnel}) {
 968         eval { finish_tunnel($self, $self->{tunnel});  };
 969         if (my $err = $@) {
 970             $self->log('err', $err);
 971             $self->{errors} = 1;
 972         }
 973     }
 974 }
 975
 976 sub phase3 {
 977     my ($self, $vmid) = @_;
 978
 979     my $volids = $self->{volumes};
 980     return if $self->{phase2errors};
 981
 982     # destroy local copies
 983     foreach my $volid (@$volids) {
 984         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 985         if (my $err = $@) {
 986             $self->log('err', "removing local copy of '$volid' failed - $err");
 987             $self->{errors} = 1;
 988             last if $err =~ /^interrupted by signal$/;
 989         }
 990     }
 991 }
 992
 993 sub phase3_cleanup {
 994     my ($self, $vmid, $err) = @_;
 995
 996     my $conf = $self->{vmconf};
 997     return if $self->{phase2errors};
 998
 999     my $tunnel = $self->{tunnel};
1000
1001     if ($self->{storage_migration}) {
1002         # finish block-job with block-job-cancel, to disconnect source VM from NBD
1003         eval { PVE::QemuServer::qemu_drive_mirror_monitor($vmid, undef, $self->{storage_migration_jobs}, 'cancel'); };
1004
1005         if (my $err = $@) {
1006             eval { PVE::QemuServer::qemu_blockjobs_cancel($vmid, $self->{storage_migration_jobs}) };
1007             eval { PVE::QemuMigrate::cleanup_remotedisks($self) };
1008             die "Failed to complete storage migration: $err\n";
1009         } else {
1010             foreach my $target_drive (keys %{$self->{target_drive}}) {
1011                 my $drive = PVE::QemuServer::parse_drive($target_drive, $self->{target_drive}->{$target_drive}->{drivestr});
1012                 $conf->{$target_drive} = PVE::QemuServer::print_drive($drive);
1013                 PVE::QemuConfig->write_config($vmid, $conf);
1014             }
1015         }
1016     }
1017
1018     # transfer replication state before move config
1019     $self->transfer_replication_state() if $self->{replicated_volumes};
1020
1021     # move config to remote node
1022     my $conffile = PVE::QemuConfig->config_file($vmid);
1023     my $newconffile = PVE::QemuConfig->config_file($vmid, $self->{node});
1024
1025     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
1026         if !rename($conffile, $newconffile);
1027
1028     $self->switch_replication_job_target() if $self->{replicated_volumes};
1029
1030     if ($self->{livemigration}) {
1031         if ($self->{storage_migration}) {
1032             # stop nbd server on remote vm - requirement for resume since 2.9
1033             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'nbdstop', $vmid];
1034
1035             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1036             if (my $err = $@) {
1037                 $self->log('err', $err);
1038                 $self->{errors} = 1;
1039             }
1040         }
1041
1042         # config moved and nbd server stopped - now we can resume vm on target
1043         if ($tunnel && $tunnel->{version} && $tunnel->{version} >= 1) {
1044             eval {
1045                 $self->write_tunnel($tunnel, 30, "resume $vmid");
1046             };
1047             if (my $err = $@) {
1048                 $self->log('err', $err);
1049                 $self->{errors} = 1;
1050             }
1051         } else {
1052             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'resume', $vmid, '--skiplock', '--nocheck'];
1053             my $logf = sub {
1054                 my $line = shift;
1055                 $self->log('err', $line);
1056             };
1057             eval { PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => $logf); };
1058             if (my $err = $@) {
1059                 $self->log('err', $err);
1060                 $self->{errors} = 1;
1061             }
1062         }
1063
1064         if ($self->{storage_migration} && PVE::QemuServer::parse_guest_agent($conf)->{fstrim_cloned_disks} && $self->{running}) {
1065             my $cmd = [@{$self->{rem_ssh}}, 'qm', 'guest', 'cmd', $vmid, 'fstrim'];
1066             eval{ PVE::Tools::run_command($cmd, outfunc => sub {}, errfunc => sub {}) };
1067         }
1068     }
1069
1070     # close tunnel on successful migration, on error phase2_cleanup closed it
1071     if ($tunnel) {
1072         eval { finish_tunnel($self, $tunnel);  };
1073         if (my $err = $@) {
1074             $self->log('err', $err);
1075             $self->{errors} = 1;
1076         }
1077     }
1078
1079     eval {
1080         my $timer = 0;
1081         if (PVE::QemuServer::vga_conf_has_spice($conf->{vga}) && $self->{running}) {
1082             $self->log('info', "Waiting for spice server migration");
1083             while (1) {
1084                 my $res = mon_cmd($vmid, 'query-spice');
1085                 last if int($res->{'migrated'}) == 1;
1086                 last if $timer > 50;
1087                 $timer ++;
1088                 usleep(200000);
1089             }
1090         }
1091     };
1092
1093     # always stop local VM
1094     eval { PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1, 1); };
1095     if (my $err = $@) {
1096         $self->log('err', "stopping vm failed - $err");
1097         $self->{errors} = 1;
1098     }
1099
1100     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1101     eval {
1102         my $vollist = PVE::QemuServer::get_vm_volumes($conf);
1103         PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
1104     };
1105     if (my $err = $@) {
1106         $self->log('err', $err);
1107         $self->{errors} = 1;
1108     }
1109
1110     if($self->{storage_migration}) {
1111         # destroy local copies
1112         my $volids = $self->{online_local_volumes};
1113
1114         foreach my $volid (@$volids) {
1115             eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
1116             if (my $err = $@) {
1117                 $self->log('err', "removing local copy of '$volid' failed - $err");
1118                 $self->{errors} = 1;
1119                 last if $err =~ /^interrupted by signal$/;
1120             }
1121         }
1122
1123     }
1124
1125     # clear migrate lock
1126     my $cmd = [ @{$self->{rem_ssh}}, 'qm', 'unlock', $vmid ];
1127     $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
1128 }
1129
1130 sub final_cleanup {
1131     my ($self, $vmid) = @_;
1132
1133     # nothing to do
1134 }
1135
1136 sub round_powerof2 {
1137     return 1 if $_[0] < 2;
1138     return 2 << int(log($_[0]-1)/log(2));
1139 }
1140
1141 1;