PVE/Report.pm

   1 package PVE::Report;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools;
   7
   8 # output the content of all the files of a directory
   9 my sub dir2text {
  10     my ($target_dir, $regexp) = @_;
  11
  12     print STDERR "dir2text '${target_dir}${regexp}'...";
  13     my $text = '';
  14     PVE::Tools::dir_glob_foreach($target_dir, $regexp, sub {
  15         my ($file) = @_;
  16         $text .=  "\n# cat $target_dir$file\n";
  17         $text .= PVE::Tools::file_get_contents($target_dir.$file)."\n";
  18     });
  19     return $text;
  20 }
  21
  22 # command -v is the posix equivalent of 'which'
  23 my sub cmd_exists { system("command -v '$_[0]' > /dev/null 2>&1") == 0 }
  24
  25 my $init_report_cmds = sub {
  26     my $report_def = {
  27         general => {
  28             title => 'general system info',
  29             order => 10,
  30             cmds => [
  31                 'hostname',
  32                 'pveversion --verbose',
  33                 'cat /etc/hosts',
  34                 'pvesubscription get',
  35                 'cat /etc/apt/sources.list',
  36                 sub { dir2text('/etc/apt/sources.list.d/', '.*list') },
  37                 sub { dir2text('/etc/apt/sources.list.d/', '.*sources') },
  38                 'lscpu',
  39                 'pvesh get /cluster/resources --type node --output-format=yaml',
  40             ],
  41         },
  42         'system-load' => {
  43             title => 'overall system load info',
  44             order => 20,
  45             cmds => [
  46                 'top -b -c -w512 -n 1 -o TIME | head -n 30',
  47                 'head /proc/pressure/*',
  48             ],
  49         },
  50         storage => {
  51             order => 30,
  52             cmds => [
  53                 'cat /etc/pve/storage.cfg',
  54                 'pvesm status',
  55                 'cat /etc/fstab',
  56                 'findmnt --ascii',
  57                 'df --human -T',
  58                 'proxmox-boot-tool status',
  59             ],
  60         },
  61         'virtual guests' => {
  62             order => 40,
  63             cmds => [
  64                 'qm list',
  65                 sub { dir2text('/etc/pve/qemu-server/', '\d.*conf') },
  66                 'pct list',
  67                 sub { dir2text('/etc/pve/lxc/', '\d.*conf') },
  68             ],
  69         },
  70         network => {
  71             order => 45,
  72             cmds => [
  73                 'ip -details -statistics address',
  74                 'ip -details -4 route show',
  75                 'ip -details -6 route show',
  76                 'cat /etc/network/interfaces',
  77             ],
  78         },
  79         firewall => {
  80             order => 50,
  81             cmds => [
  82                 sub { dir2text('/etc/pve/firewall/', '.*fw') },
  83                 'cat /etc/pve/local/host.fw',
  84                 'iptables-save',
  85             ],
  86         },
  87         cluster => {
  88             order => 60,
  89             cmds => [
  90                 'pvecm nodes',
  91                 'pvecm status',
  92                 'cat /etc/pve/corosync.conf 2>/dev/null',
  93                 'ha-manager status',
  94             ],
  95         },
  96         hardware => {
  97             order => 70,
  98             cmds => [
  99                 'dmidecode -t bios',
 100                 'lspci -nnk',
 101             ],
 102         },
 103         'block devices' => {
 104             order => 80,
 105             cmds => [
 106                 'lsblk --ascii -M -o +HOTPLUG,ROTA,PHY-SEC,FSTYPE,MODEL,TRAN',
 107                 'ls -l /dev/disk/by-*/',
 108                 'iscsiadm -m node',
 109                 'iscsiadm -m session',
 110             ],
 111         },
 112         volumes => {
 113             order => 90,
 114             cmds => [
 115                 'pvs',
 116                 'lvs',
 117                 'vgs',
 118             ],
 119         },
 120     };
 121
 122     if (cmd_exists('zfs')) {
 123         push @{$report_def->{volumes}->{cmds}},
 124             'zpool status',
 125             'zpool list -v',
 126             'zfs list',
 127             ;
 128     }
 129
 130     if (-e '/etc/ceph/ceph.conf') {
 131         push @{$report_def->{volumes}->{cmds}},
 132             'pveceph status',
 133             'ceph osd status',
 134             'ceph df',
 135             'ceph osd df tree',
 136             'ceph device ls',
 137             'cat /etc/ceph/ceph.conf',
 138             'ceph config dump',
 139             'pveceph pool ls',
 140             'ceph versions',
 141             ;
 142     }
 143
 144     if (cmd_exists('multipath')) {
 145         push @{$report_def->{disks}->{cmds}},
 146             'cat /etc/multipath.conf',
 147             'cat /etc/multipath/wwids',
 148             'multipath -ll',
 149             ;
 150     }
 151
 152     return $report_def;
 153 };
 154
 155 sub generate {
 156     my $def = $init_report_cmds->();
 157
 158     my $report = '';
 159     my $record_output = sub {
 160         $report .= shift . "\n";
 161     };
 162
 163     local $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 164     my $cmd_timeout = 10; # generous timeout
 165
 166     my $run_cmd_params = {
 167         outfunc => $record_output,
 168         errfunc => $record_output,
 169         timeout => $cmd_timeout,
 170         noerr => 1, # avoid checking programs exit code
 171     };
 172
 173     my $sorter = sub { ($def->{$_[0]}->{order} // 1<<30) <=> ($def->{$_[1]}->{order} // 1<<30) };
 174
 175     for my $section ( sort { $sorter->($a, $b) } keys %$def) {
 176         my $s = $def->{$section};
 177         my $title = $s->{title} // "info about $section";
 178
 179         $report .= "\n==== $title ====\n";
 180         for my $command (@{$s->{cmds}}) {
 181             eval {
 182                 if (ref $command eq 'CODE') {
 183                     $report .= PVE::Tools::run_with_timeout($cmd_timeout, $command);
 184                 } else {
 185                     print STDERR "Process ".$command."...";
 186                     $report .= "\n# $command\n";
 187                     PVE::Tools::run_command($command, %$run_cmd_params);
 188                 }
 189                 print STDERR "OK";
 190             };
 191             print STDERR "\n";
 192             $report .= "\nERROR: $@\n" if $@;
 193         }
 194     }
 195
 196     return $report;
 197 }
 198
 199 1;