PVE/Report.pm

   1 package PVE::Report;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools;
   7
   8 $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
   9
  10 my $cmd_timeout = 10; # generous timeout
  11
  12 my $init_report_cmds = sub {
  13     # NOTE: always add new sections to the report_order array!
  14     my $report_def = {
  15         general => {
  16             title => 'general system info',
  17             cmds => [
  18                 'hostname',
  19                 'pveversion --verbose',
  20                 'cat /etc/hosts',
  21                 'top -b -n 1  | head -n 15',
  22                 'pvesubscription get',
  23                 'cat /etc/apt/sources.list',
  24                 sub { dir2text('/etc/apt/sources.list.d/', '.*list') },
  25                 sub { dir2text('/etc/apt/sources.list.d/', '.*sources') },
  26                 'lscpu',
  27                 'pvesh get /cluster/resources --type node --output-format=yaml',
  28             ],
  29         },
  30         storage => [
  31             'cat /etc/pve/storage.cfg',
  32             'pvesm status',
  33             'cat /etc/fstab',
  34             'findmnt --ascii',
  35             'df --human',
  36         ],
  37         'virtual guests' => [
  38            'qm list',
  39            sub { dir2text('/etc/pve/qemu-server/', '\d.*conf') },
  40            'pct list',
  41            sub { dir2text('/etc/pve/lxc/', '\d.*conf') },
  42         ],
  43         network => [
  44             'ip -details -statistics address',
  45             'ip -details -4 route show',
  46             'ip -details -6 route show',
  47             'cat /etc/network/interfaces',
  48         ],
  49         firewall => [
  50             sub { dir2text('/etc/pve/firewall/', '.*fw') },
  51             'cat /etc/pve/local/host.fw',
  52             'iptables-save',
  53         ],
  54         cluster => [
  55             'pvecm nodes',
  56             'pvecm status',
  57             'cat /etc/pve/corosync.conf 2>/dev/null',
  58             'ha-manager status',
  59         ],
  60         bios => [
  61             'dmidecode -t bios',
  62         ],
  63         pci => [
  64             'lspci -nnk',
  65         ],
  66         disks => [
  67             'lsblk --ascii',
  68             'ls -l /dev/disk/by-*/',
  69             'iscsiadm -m node',
  70             'iscsiadm -m session',
  71         ],
  72         volumes => [
  73             'pvs',
  74             'lvs',
  75             'vgs',
  76         ],
  77     };
  78
  79     push @{$report_def->{volumes}}, 'zpool status', 'zpool list -v', 'zfs list'
  80         if cmd_exists('zfs');
  81
  82     if (-e '/etc/ceph/ceph.conf') {
  83         push @{$report_def->{volumes}},
  84             'pveceph status',
  85             'ceph osd status',
  86             'ceph df',
  87             'ceph osd df tree',
  88             'cat /etc/ceph/ceph.conf',
  89             'ceph config dump',
  90             'pveceph pool ls',
  91             'ceph versions',
  92             ;
  93     }
  94
  95     push @{$report_def->{disks}}, 'multipath -ll', 'multipath -v3'
  96         if cmd_exists('multipath');
  97
  98     return $report_def;
  99 };
 100
 101 my $report;
 102 # output the content of all the files of a directory
 103 sub dir2text {
 104     my ($target_dir, $regexp) = @_;
 105
 106     PVE::Tools::dir_glob_foreach($target_dir, $regexp, sub {
 107         my ($file) = @_;
 108         $report .=  "\n# cat $target_dir$file\n";
 109         $report .= PVE::Tools::file_get_contents($target_dir.$file)."\n";
 110     });
 111 }
 112
 113 # command -v is the posix equivalent of 'which'
 114 sub cmd_exists { system("command -v '$_[0]' > /dev/null 2>&1") == 0 }
 115
 116 sub generate {
 117
 118     my $report_def = $init_report_cmds->();
 119
 120     my @report_order = ('general', 'storage', 'virtual guests', 'network',
 121     'firewall', 'cluster', 'bios', 'pci', 'disks', 'volumes');
 122
 123     $report = '';
 124     my $record_output = sub {
 125         $report .= shift . "\n";
 126     };
 127
 128     my $run_cmd_params = {
 129         outfunc => $record_output,
 130         errfunc => $record_output,
 131         timeout => $cmd_timeout,
 132         noerr => 1, # avoid checking programs exit code
 133     };
 134
 135     foreach my $section (@report_order) {
 136         my $s = $report_def->{$section};
 137
 138         my $title = "info about $section";
 139         my $commands = $s;
 140
 141         if (ref($s) eq 'HASH') {
 142             $commands = $s->{cmds};
 143             $title = $s->{title} if defined($s->{title});
 144         } elsif (ref($s) ne 'ARRAY') {
 145             die "unknown report definition in section '$section'!";
 146         }
 147
 148         $report .= "\n==== $title ====\n";
 149         foreach my $command (@$commands) {
 150             eval {
 151                 if (ref $command eq 'CODE') {
 152                     PVE::Tools::run_with_timeout($cmd_timeout, $command);
 153                 } else {
 154                     print STDERR "Process ".$command."...";
 155                     $report .= "\n# $command\n";
 156                     PVE::Tools::run_command($command, %$run_cmd_params);
 157                 }
 158                 print STDERR "OK";
 159             };
 160             print STDERR "\n";
 161             $report .= "\nERROR: $@\n" if $@;
 162         }
 163     }
 164
 165     return $report;
 166 }
 167
 168 1;