PVE/VZDump/QemuServer.pm

   1 package PVE::VZDump::QemuServer;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Basename;
   7 use File::Path;
   8 use IO::File;
   9 use IPC::Open3;
  10 use JSON;
  11
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::INotify;
  14 use PVE::IPCC;
  15 use PVE::JSONSchema;
  16 use PVE::QMPClient;
  17 use PVE::Storage::Plugin;
  18 use PVE::Storage::PBSPlugin;
  19 use PVE::Storage;
  20 use PVE::Tools;
  21 use PVE::VZDump;
  22
  23 use PVE::QemuConfig;
  24 use PVE::QemuServer;
  25 use PVE::QemuServer::Machine;
  26 use PVE::QemuServer::Monitor qw(mon_cmd);
  27
  28 use base qw (PVE::VZDump::Plugin);
  29
  30 sub new {
  31     my ($class, $vzdump) = @_;
  32
  33     PVE::VZDump::check_bin('qm');
  34
  35     my $self = bless { vzdump => $vzdump }, $class;
  36
  37     $self->{vmlist} = PVE::QemuServer::vzlist();
  38     $self->{storecfg} = PVE::Storage::config();
  39
  40     return $self;
  41 };
  42
  43 sub type {
  44     return 'qemu';
  45 }
  46
  47 sub vmlist {
  48     my ($self) = @_;
  49     return [ keys %{$self->{vmlist}} ];
  50 }
  51
  52 sub prepare {
  53     my ($self, $task, $vmid, $mode) = @_;
  54
  55     $task->{disks} = [];
  56
  57     my $conf = $self->{vmlist}->{$vmid} = PVE::QemuConfig->load_config($vmid);
  58
  59     $self->loginfo("VM Name: $conf->{name}")
  60         if defined($conf->{name});
  61
  62     $self->{vm_was_running} = 1;
  63     if (!PVE::QemuServer::check_running($vmid)) {
  64         $self->{vm_was_running} = 0;
  65     }
  66
  67     $task->{hostname} = $conf->{name};
  68
  69     my $hostname = PVE::INotify::nodename();
  70
  71     my $vollist = [];
  72     my $drivehash = {};
  73     my $backup_volumes = PVE::QemuConfig->get_backup_volumes($conf);
  74
  75     foreach my $volume (@{$backup_volumes}) {
  76         my $name = $volume->{key};
  77         my $volume_config = $volume->{volume_config};
  78         my $volid = $volume_config->{file};
  79
  80         if (!$volume->{included}) {
  81             $self->loginfo("exclude disk '$name' '$volid' ($volume->{reason})");
  82             next;
  83         } elsif ($self->{vm_was_running} && $volume_config->{iothread}) {
  84             if (!PVE::QemuServer::Machine::runs_at_least_qemu_version($vmid, 4, 0, 1)) {
  85                 die "disk '$name' '$volid' (iothread=on) can't use backup feature with running QEMU " .
  86                     "version < 4.0.1! Either set backup=no for this drive or upgrade QEMU and restart VM\n";
  87             }
  88         } else {
  89             my $log = "include disk '$name' '$volid'";
  90             if (defined(my $size = $volume_config->{size})) {
  91                 my $readable_size = PVE::JSONSchema::format_size($size);
  92                 $log .= " $readable_size";
  93             }
  94             $self->loginfo($log);
  95         }
  96
  97         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
  98         push @$vollist, $volid if $storeid;
  99         $drivehash->{$name} = $volume->{volume_config};
 100     }
 101
 102     PVE::Storage::activate_volumes($self->{storecfg}, $vollist);
 103
 104     foreach my $ds (sort keys %$drivehash) {
 105         my $drive = $drivehash->{$ds};
 106
 107         my $volid = $drive->{file};
 108         my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 109
 110         my $path = $volid;
 111         if ($storeid) {
 112             $path = PVE::Storage::path($self->{storecfg}, $volid);
 113         }
 114         next if !$path;
 115
 116         my ($size, $format) = eval { PVE::Storage::volume_size_info($self->{storecfg}, $volid, 5) };
 117         die "no such volume '$volid'\n" if $@;
 118
 119         my $diskinfo = {
 120             path => $path,
 121             volid => $volid,
 122             storeid => $storeid,
 123             format => $format,
 124             virtdev => $ds,
 125             qmdevice => "drive-$ds",
 126         };
 127
 128         if (-b $path) {
 129             $diskinfo->{type} = 'block';
 130         } else {
 131             $diskinfo->{type} = 'file';
 132         }
 133
 134         push @{$task->{disks}}, $diskinfo;
 135     }
 136 }
 137
 138 sub vm_status {
 139     my ($self, $vmid) = @_;
 140
 141     my $running = PVE::QemuServer::check_running($vmid) ? 1 : 0;
 142
 143     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
 144 }
 145
 146 sub lock_vm {
 147     my ($self, $vmid) = @_;
 148
 149     PVE::QemuConfig->set_lock($vmid, 'backup');
 150 }
 151
 152 sub unlock_vm {
 153     my ($self, $vmid) = @_;
 154
 155     PVE::QemuConfig->remove_lock($vmid, 'backup');
 156 }
 157
 158 sub stop_vm {
 159     my ($self, $task, $vmid) = @_;
 160
 161     my $opts = $self->{vzdump}->{opts};
 162
 163     my $wait = $opts->{stopwait} * 60;
 164     # send shutdown and wait
 165     $self->cmd ("qm shutdown $vmid --skiplock --keepActive --timeout $wait");
 166 }
 167
 168 sub start_vm {
 169     my ($self, $task, $vmid) = @_;
 170
 171     $self->cmd ("qm start $vmid --skiplock");
 172 }
 173
 174 sub suspend_vm {
 175     my ($self, $task, $vmid) = @_;
 176
 177     $self->cmd ("qm suspend $vmid --skiplock");
 178 }
 179
 180 sub resume_vm {
 181     my ($self, $task, $vmid) = @_;
 182
 183     $self->cmd ("qm resume $vmid --skiplock");
 184 }
 185
 186 sub assemble {
 187     my ($self, $task, $vmid) = @_;
 188
 189     my $conffile = PVE::QemuConfig->config_file($vmid);
 190
 191     my $outfile = "$task->{tmpdir}/qemu-server.conf";
 192     my $firewall_src = "/etc/pve/firewall/$vmid.fw";
 193     my $firewall_dest = "$task->{tmpdir}/qemu-server.fw";
 194
 195     my $outfd = IO::File->new (">$outfile") ||
 196         die "unable to open '$outfile'";
 197     my $conffd = IO::File->new ($conffile, 'r') ||
 198         die "unable open '$conffile'";
 199
 200     my $found_snapshot;
 201     my $found_pending;
 202     while (defined (my $line = <$conffd>)) {
 203         next if $line =~ m/^\#vzdump\#/; # just to be sure
 204         next if $line =~ m/^\#qmdump\#/; # just to be sure
 205         if ($line =~ m/^\[(.*)\]\s*$/) {
 206             if ($1 =~ m/PENDING/i) {
 207                 $found_pending = 1;
 208             } else {
 209                 $found_snapshot = 1;
 210             }
 211         }
 212         next if $found_snapshot || $found_pending; # skip all snapshots and pending changes config data
 213
 214         if ($line =~ m/^unused\d+:\s*(\S+)\s*/) {
 215             $self->loginfo("skip unused drive '$1' (not included into backup)");
 216             next;
 217         }
 218         next if $line =~ m/^lock:/ || $line =~ m/^parent:/;
 219
 220         print $outfd $line;
 221     }
 222
 223     foreach my $di (@{$task->{disks}}) {
 224         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 225             my $storeid = $di->{storeid} || '';
 226             my $format = $di->{format} || '';
 227             print $outfd "#qmdump#map:$di->{virtdev}:$di->{qmdevice}:$storeid:$format:\n";
 228         } else {
 229             die "internal error";
 230         }
 231     }
 232
 233     if ($found_snapshot) {
 234         $self->loginfo("snapshots found (not included into backup)");
 235     }
 236     if ($found_pending) {
 237         $self->loginfo("pending configuration changes found (not included into backup)");
 238     }
 239
 240     PVE::Tools::file_copy($firewall_src, $firewall_dest) if -f $firewall_src;
 241 }
 242
 243 sub archive {
 244     my ($self, $task, $vmid, $filename, $comp) = @_;
 245
 246     my $opts = $self->{vzdump}->{opts};
 247     my $scfg = $opts->{scfg};
 248
 249     if ($self->{vzdump}->{opts}->{pbs}) {
 250         $self->archive_pbs($task, $vmid);
 251     } else {
 252         $self->archive_vma($task, $vmid, $filename, $comp);
 253     }
 254 }
 255
 256 # number, [precision=1]
 257 my $num2str = sub {
 258     return sprintf( "%." . ( $_[1] || 1 ) . "f", $_[0] );
 259 };
 260 sub bytes_to_human {
 261     my ($bytes, $precission) = @_;
 262
 263     return $num2str->($bytes, $precission) . ' B' if $bytes < 1024;
 264     my $kb = $bytes/1024;
 265
 266     return $num2str->($kb, $precission) . " KiB" if $kb < 1024;
 267     my $mb = $kb/1024;
 268
 269     return $num2str->($mb, $precission) . " MiB" if $mb < 1024;
 270     my $gb = $mb/1024;
 271
 272     return $num2str->($gb, $precission) . " GiB" if $gb < 1024;
 273     my $tb = $gb/1024;
 274
 275     return $num2str->($tb, $precission) . " TiB";
 276 };
 277
 278 my $bitmap_action_to_human = sub {
 279     my ($info) = @_;
 280
 281     my $action = $info->{action};
 282
 283     if ($action eq "not-used") {
 284         return "disabled";
 285     } elsif ($action eq "not-used-removed") {
 286         return "disabled (old bitmap cleared)";
 287     } elsif ($action eq "new") {
 288         return "created new bitmap";
 289     } elsif ($action eq "used") {
 290         if ($info->{dirty} == 0) {
 291             return "OK, drive clean";
 292         } else {
 293             my $size = bytes_to_human($info->{size});
 294             my $dirty = bytes_to_human($info->{dirty});
 295             return "OK, $dirty of $size dirty";
 296         }
 297     } elsif ($action eq "invalid") {
 298         return "existing bitmap was invalid and has been cleared";
 299     } else {
 300         return "unknown";
 301     }
 302 };
 303
 304 my $query_backup_status_loop = sub {
 305     my ($self, $vmid, $job_uuid, $pbs_features) = @_;
 306
 307     my $starttime = time ();
 308     my $last_time = $starttime;
 309     my ($last_percent, $last_total, $last_target, $last_zero, $last_transferred) = (-1, 0, 0, 0, 0);
 310     my ($transferred, $reused);
 311
 312     my $get_mbps = sub {
 313         my ($mb, $delta) = @_;
 314         return "0 B/s" if $mb <= 0;
 315         my $bw = int(($mb / $delta));
 316         return bytes_to_human($bw) . "/s";
 317     };
 318
 319     my $target = 0;
 320     my $last_reused = 0;
 321     my $has_query_bitmap = 0;
 322     if (defined($pbs_features) && $pbs_features->{'query-bitmap-info'}) {
 323         $has_query_bitmap = 1;
 324         my $bitmap_info = mon_cmd($vmid, 'query-pbs-bitmap-info');
 325         $self->loginfo("Fast incremental status:");
 326         foreach my $info (@$bitmap_info) {
 327             my $text = $bitmap_action_to_human->($info);
 328             my $drive = $info->{drive};
 329             $drive =~ s/^drive-//; # for consistency
 330             $self->loginfo("$drive: $text");
 331             $target += $info->{dirty};
 332             $last_reused += $info->{size} - $info->{dirty};
 333         }
 334     }
 335
 336     while(1) {
 337         my $status = mon_cmd($vmid, 'query-backup');
 338
 339         my $total = $status->{total} || 0;
 340         $target = $total if !$has_query_bitmap;
 341         $transferred = $status->{transferred} || 0;
 342         $reused = $status->{reused};
 343         my $percent = $target ? int(($transferred * 100)/$target) : 100;
 344         my $zero = $status->{'zero-bytes'} || 0;
 345
 346         die "got unexpected uuid\n" if !$status->{uuid} || ($status->{uuid} ne $job_uuid);
 347
 348         my $ctime = time();
 349         my $duration = $ctime - $starttime;
 350
 351         my $rbytes = $transferred - $last_transferred;
 352         my $wbytes;
 353         if ($reused) {
 354             # reused includes zero bytes for PBS
 355             $wbytes = $rbytes - ($reused - $last_reused);
 356         } else {
 357             $wbytes = $rbytes - ($zero - $last_zero);
 358         }
 359
 360         my $timediff = ($ctime - $last_time) || 1; # fixme
 361         my $mbps_read = $get_mbps->($rbytes, $timediff);
 362         my $mbps_write = $get_mbps->($wbytes, $timediff);
 363         my $target_h = bytes_to_human($target);
 364         my $transferred_h = bytes_to_human($transferred);
 365
 366         my $statusline = "status: $percent% ($transferred_h of $target_h), duration $duration"
 367             .", read: $mbps_read, write: $mbps_write";
 368
 369         my $res = $status->{status} || 'unknown';
 370         if ($res ne 'active') {
 371             $self->loginfo($statusline);
 372             if ($res ne 'done') {
 373                 die (($status->{errmsg} || "unknown error") . "\n") if $res eq 'error';
 374                 die "got unexpected status '$res'\n";
 375             }
 376             $last_target = $target if $target;
 377             $last_total = $total if $total;
 378             $last_zero = $zero if $zero;
 379             $last_transferred = $transferred if $transferred;
 380             last;
 381         }
 382         if ($percent != $last_percent && ($timediff > 2)) {
 383             $self->loginfo($statusline);
 384             $last_percent = $percent;
 385             $last_target = $target if $target;
 386             $last_total = $total if $total;
 387             $last_zero = $zero if $zero;
 388             $last_transferred = $transferred if $transferred;
 389             $last_time = $ctime;
 390             $last_reused = $reused;
 391         }
 392         sleep(1);
 393     }
 394
 395     my $duration = time() - $starttime;
 396     if ($transferred && $duration) {
 397         my $transferred_h = bytes_to_human($transferred, 2);
 398         my $mbps = $get_mbps->($transferred, $duration);
 399         if ($reused) {
 400             my $reused_h = bytes_to_human($reused, 2);
 401             my $reuse_per = int($reused * 100 / $last_total);
 402             $self->loginfo("backup was done incrementally, reused $reused_h (${reuse_per}%)");
 403         }
 404         $self->loginfo("transferred $transferred_h in $duration seconds ($mbps)");
 405     }
 406
 407     if (!defined($pbs_features) && $last_zero) {
 408         my $zero_per = $last_target ? int(($last_zero * 100)/$last_target) : 0;
 409         my $zero_h = bytes_to_human($last_zero, 2);
 410         $self->loginfo("Backup is sparse: ${zero_per}% ($zero_h) zero data");
 411     }
 412
 413     return {
 414         total => $last_total,
 415         reused => $reused,
 416     };
 417 };
 418
 419 sub archive_pbs {
 420     my ($self, $task, $vmid) = @_;
 421
 422     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 423     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 424
 425     my $opts = $self->{vzdump}->{opts};
 426     my $scfg = $opts->{scfg};
 427
 428     my $starttime = time();
 429
 430     my $server = $scfg->{server};
 431     my $datastore = $scfg->{datastore};
 432     my $username = $scfg->{username} // 'root@pam';
 433     my $fingerprint = $scfg->{fingerprint};
 434
 435     my $repo = "$username\@$server:$datastore";
 436     my $password = PVE::Storage::PBSPlugin::pbs_get_password($scfg, $opts->{storage});
 437     my $keyfile = PVE::Storage::PBSPlugin::pbs_encryption_key_file_name($scfg, $opts->{storage});
 438
 439     my $diskcount = scalar(@{$task->{disks}});
 440     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 441         my @pathlist;
 442         # FIXME: accumulate disk sizes to use for backup job (email) log
 443         foreach my $di (@{$task->{disks}}) {
 444             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 445                 push @pathlist, "$di->{qmdevice}.img:$di->{path}";
 446             } else {
 447                 die "implement me (type $di->{type})";
 448             }
 449         }
 450
 451         if (!$diskcount) {
 452             $self->loginfo("backup contains no disks");
 453         }
 454
 455         local $ENV{PBS_PASSWORD} = $password;
 456         local $ENV{PBS_FINGERPRINT} = $fingerprint if defined($fingerprint);
 457         my $cmd = [
 458             '/usr/bin/proxmox-backup-client',
 459             'backup',
 460             '--repository', $repo,
 461             '--backup-type', 'vm',
 462             '--backup-id', "$vmid",
 463             '--backup-time', $task->{backup_time},
 464         ];
 465
 466         push @$cmd, "qemu-server.conf:$conffile";
 467         push @$cmd, "fw.conf:$firewall" if -e $firewall;
 468         push @$cmd, @pathlist if scalar(@pathlist);
 469
 470         $self->loginfo("starting template backup");
 471         $self->loginfo(join(' ', @$cmd));
 472
 473         $self->cmd($cmd);
 474
 475         return;
 476     }
 477
 478     # get list early so we die on unkown drive types before doing anything
 479     my $devlist = _get_task_devlist($task);
 480
 481     $self->enforce_vm_running_for_backup($vmid);
 482
 483     my $backup_job_uuid;
 484     eval {
 485         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 486             die "interrupted by signal\n";
 487         };
 488
 489         my $qemu_support = eval { mon_cmd($vmid, "query-proxmox-support") };
 490         if (!$qemu_support) {
 491             die "PBS backups are not supported by the running QEMU version. Please make "
 492               . "sure you've installed the latest version and the VM has been restarted.\n";
 493         }
 494
 495         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 496
 497         my $params = {
 498             format => "pbs",
 499             'backup-file' => $repo,
 500             'backup-id' => "$vmid",
 501             'backup-time' => $task->{backup_time},
 502             password => $password,
 503             devlist => $devlist,
 504             'config-file' => $conffile,
 505         };
 506         $params->{fingerprint} = $fingerprint if defined($fingerprint);
 507         $params->{'firewall-file'} = $firewall if -e $firewall;
 508         if (-e $keyfile) {
 509             $self->loginfo("enabling encryption");
 510             $params->{keyfile} = $keyfile;
 511             $params->{encrypt} = JSON::true;
 512         } else {
 513             $params->{encrypt} = JSON::false;
 514         }
 515
 516         $params->{'use-dirty-bitmap'} = JSON::true
 517             if $qemu_support->{'pbs-dirty-bitmap'} && $self->{vm_was_running};
 518
 519         $params->{timeout} = 60; # give some time to connect to the backup server
 520
 521         my $res = eval { mon_cmd($vmid, "backup", %$params) };
 522         my $qmperr = $@;
 523         $backup_job_uuid = $res->{UUID} if $res;
 524
 525         if ($fs_frozen) {
 526             $self->qga_fs_thaw($vmid);
 527         }
 528
 529         die $qmperr if $qmperr;
 530         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 531
 532         $self->loginfo("started backup task '$backup_job_uuid'");
 533
 534         $self->resume_vm_after_job_start($task, $vmid);
 535
 536         my $stat = $query_backup_status_loop->($self, $vmid, $backup_job_uuid, $qemu_support);
 537         $task->{size} = $stat->{total};
 538     };
 539     my $err = $@;
 540     if ($err) {
 541         $self->logerr($err);
 542         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 543     }
 544     $self->restore_vm_power_state($vmid);
 545
 546     die $err if $err;
 547 }
 548
 549 my $fork_compressor_pipe = sub {
 550     my ($self, $comp, $outfileno) = @_;
 551
 552     my @pipefd = POSIX::pipe();
 553     my $cpid = fork();
 554     die "unable to fork worker - $!" if !defined($cpid) || $cpid < 0;
 555     if ($cpid == 0) {
 556         eval {
 557             POSIX::close($pipefd[1]);
 558             # redirect STDIN
 559             my $fd = fileno(STDIN);
 560             close STDIN;
 561             POSIX::close(0) if $fd != 0;
 562             die "unable to redirect STDIN - $!"
 563                 if !open(STDIN, "<&", $pipefd[0]);
 564
 565             # redirect STDOUT
 566             $fd = fileno(STDOUT);
 567             close STDOUT;
 568             POSIX::close (1) if $fd != 1;
 569
 570             die "unable to redirect STDOUT - $!"
 571                 if !open(STDOUT, ">&", $outfileno);
 572
 573             exec($comp);
 574             die "fork compressor '$comp' failed\n";
 575         };
 576         if (my $err = $@) {
 577             $self->logerr($err);
 578             POSIX::_exit(1);
 579         }
 580         POSIX::_exit(0);
 581         kill(-9, $$);
 582     } else {
 583         POSIX::close($pipefd[0]);
 584         $outfileno = $pipefd[1];
 585     }
 586
 587     return ($cpid, $outfileno);
 588 };
 589
 590 sub archive_vma {
 591     my ($self, $task, $vmid, $filename, $comp) = @_;
 592
 593     my $conffile = "$task->{tmpdir}/qemu-server.conf";
 594     my $firewall = "$task->{tmpdir}/qemu-server.fw";
 595
 596     my $opts = $self->{vzdump}->{opts};
 597
 598     my $starttime = time();
 599
 600     my $speed = 0;
 601     if ($opts->{bwlimit}) {
 602         $speed = $opts->{bwlimit}*1024;
 603     }
 604
 605     my $diskcount = scalar(@{$task->{disks}});
 606     if (PVE::QemuConfig->is_template($self->{vmlist}->{$vmid}) || !$diskcount) {
 607         my @pathlist;
 608         foreach my $di (@{$task->{disks}}) {
 609             if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 610                 push @pathlist, "$di->{qmdevice}=$di->{path}";
 611             } else {
 612                 die "implement me";
 613             }
 614         }
 615
 616         if (!$diskcount) {
 617             $self->loginfo("backup contains no disks");
 618         }
 619
 620         my $outcmd;
 621         if ($comp) {
 622             $outcmd = "exec:$comp";
 623         } else {
 624             $outcmd = "exec:cat";
 625         }
 626
 627         $outcmd .= " > $filename" if !$opts->{stdout};
 628
 629         my $cmd = ['/usr/bin/vma', 'create', '-v', '-c', $conffile];
 630         push @$cmd, '-c', $firewall if -e $firewall;
 631         push @$cmd, $outcmd, @pathlist;
 632
 633         $self->loginfo("starting template backup");
 634         $self->loginfo(join(' ', @$cmd));
 635
 636         if ($opts->{stdout}) {
 637             $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 638         } else {
 639             $self->cmd($cmd);
 640         }
 641
 642         return;
 643     }
 644
 645     my $devlist = _get_task_devlist($task);
 646
 647     $self->enforce_vm_running_for_backup($vmid);
 648
 649     my $cpid;
 650     my $backup_job_uuid;
 651
 652     eval {
 653         $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = $SIG{PIPE} = sub {
 654             die "interrupted by signal\n";
 655         };
 656
 657         my $outfh;
 658         if ($opts->{stdout}) {
 659             $outfh = $opts->{stdout};
 660         } else {
 661             $outfh = IO::File->new($filename, "w") ||
 662                 die "unable to open file '$filename' - $!\n";
 663         }
 664         my $outfileno = fileno($outfh);
 665
 666         if ($comp) {
 667             ($cpid, $outfileno) = $fork_compressor_pipe->($self, $comp, $outfileno);
 668         }
 669
 670         my $qmpclient = PVE::QMPClient->new();
 671         my $backup_cb = sub {
 672             my ($vmid, $resp) = @_;
 673             $backup_job_uuid = $resp->{return}->{UUID};
 674         };
 675         my $add_fd_cb = sub {
 676             my ($vmid, $resp) = @_;
 677
 678             my $params = {
 679                 'backup-file' => "/dev/fdname/backup",
 680                 speed => $speed,
 681                 'config-file' => $conffile,
 682                 devlist => $devlist
 683             };
 684             $params->{'firewall-file'} = $firewall if -e $firewall;
 685
 686             $qmpclient->queue_cmd($vmid, $backup_cb, 'backup', %$params);
 687         };
 688
 689         $qmpclient->queue_cmd($vmid, $add_fd_cb, 'getfd', fd => $outfileno, fdname => "backup");
 690
 691         my $fs_frozen = $self->qga_fs_freeze($task, $vmid);
 692
 693         eval { $qmpclient->queue_execute(30) };
 694         my $qmperr = $@;
 695
 696         if ($fs_frozen) {
 697             $self->qga_fs_thaw($vmid);
 698         }
 699
 700         die $qmperr if $qmperr;
 701         die $qmpclient->{errors}->{$vmid} if $qmpclient->{errors}->{$vmid};
 702
 703         if ($cpid) {
 704             POSIX::close($outfileno) == 0 ||
 705                 die "close output file handle failed\n";
 706         }
 707
 708         die "got no uuid for backup task\n" if !defined($backup_job_uuid);
 709
 710         $self->loginfo("started backup task '$backup_job_uuid'");
 711
 712         $self->resume_vm_after_job_start($task, $vmid);
 713
 714         $query_backup_status_loop->($self, $vmid, $backup_job_uuid);
 715     };
 716     my $err = $@;
 717     if ($err) {
 718         $self->logerr($err);
 719         $self->mon_backup_cancel($vmid) if defined($backup_job_uuid);
 720     }
 721
 722     $self->restore_vm_power_state($vmid);
 723
 724     if ($err) {
 725         if ($cpid) {
 726             kill(9, $cpid);
 727             waitpid($cpid, 0);
 728         }
 729         die $err;
 730     }
 731
 732     if ($cpid && (waitpid($cpid, 0) > 0)) {
 733         my $stat = $?;
 734         my $ec = $stat >> 8;
 735         my $signal = $stat & 127;
 736         if ($ec || $signal) {
 737             die "$comp failed - wrong exit status $ec" .
 738                 ($signal ? " (signal $signal)\n" : "\n");
 739         }
 740     }
 741 }
 742
 743 sub _get_task_devlist {
 744     my ($task) = @_;
 745
 746     my $devlist = '';
 747     foreach my $di (@{$task->{disks}}) {
 748         if ($di->{type} eq 'block' || $di->{type} eq 'file') {
 749             $devlist .= ',' if $devlist;
 750             $devlist .= $di->{qmdevice};
 751         } else {
 752             die "implement me (type '$di->{type}')";
 753         }
 754     }
 755     return $devlist;
 756 }
 757
 758 sub qga_fs_freeze {
 759     my ($self, $task, $vmid) = @_;
 760     return if !$self->{vmlist}->{$vmid}->{agent} || $task->{mode} eq 'stop' || !$self->{vm_was_running};
 761
 762     if (!PVE::QemuServer::qga_check_running($vmid, 1)) {
 763         $self->loginfo("skipping guest-agent 'fs-freeze', agent configured but not running?");
 764         return;
 765     }
 766
 767     $self->loginfo("issuing guest-agent 'fs-freeze' command");
 768     eval { mon_cmd($vmid, "guest-fsfreeze-freeze") };
 769     $self->logerr($@) if $@;
 770
 771     return 1; # even on mon command error, ensure we always thaw again
 772 }
 773
 774 # only call if fs_freeze return 1
 775 sub qga_fs_thaw {
 776     my ($self, $vmid) = @_;
 777
 778     $self->loginfo("issuing guest-agent 'fs-thaw' command");
 779     eval { mon_cmd($vmid, "guest-fsfreeze-thaw") };
 780     $self->logerr($@) if $@;
 781 }
 782
 783 # we need a running QEMU/KVM process for backup, starts a paused (prelaunch)
 784 # one if VM isn't already running
 785 sub enforce_vm_running_for_backup {
 786     my ($self, $vmid) = @_;
 787
 788     if (PVE::QemuServer::check_running($vmid)) {
 789         $self->{vm_was_running} = 1;
 790         return;
 791     }
 792
 793     eval {
 794         $self->loginfo("starting kvm to execute backup task");
 795         # start with skiplock
 796         my $params = {
 797             skiplock => 1,
 798             paused => 1,
 799         };
 800         PVE::QemuServer::vm_start($self->{storecfg}, $vmid, $params);
 801     };
 802     die $@ if $@;
 803 }
 804
 805 # resume VM againe once we got in a clear state (stop mode backup of running VM)
 806 sub resume_vm_after_job_start {
 807     my ($self, $task, $vmid) = @_;
 808
 809     return if !$self->{vm_was_running};
 810
 811     if (my $stoptime = $task->{vmstoptime}) {
 812         my $delay = time() - $task->{vmstoptime};
 813         $task->{vmstoptime} = undef; # avoid printing 'online after ..' twice
 814         $self->loginfo("resuming VM again after $delay seconds");
 815     } else {
 816         $self->loginfo("resuming VM again");
 817     }
 818     mon_cmd($vmid, 'cont');
 819 }
 820
 821 # stop again if VM was not running before
 822 sub restore_vm_power_state {
 823     my ($self, $vmid) = @_;
 824
 825     # we always let VMs keep running
 826     return if $self->{vm_was_running};
 827
 828     eval {
 829         my $resp = mon_cmd($vmid, 'query-status');
 830         my $status = $resp && $resp->{status} ?  $resp->{status} : 'unknown';
 831         if ($status eq 'prelaunch') {
 832             $self->loginfo("stopping kvm after backup task");
 833             PVE::QemuServer::vm_stop($self->{storecfg}, $vmid, 1);
 834         } else {
 835             $self->loginfo("kvm status changed after backup ('$status') - keep VM running");
 836         }
 837     };
 838     warn $@ if $@;
 839 }
 840
 841 sub mon_backup_cancel {
 842     my ($self, $vmid) = @_;
 843
 844     $self->loginfo("aborting backup job");
 845     eval { mon_cmd($vmid, 'backup-cancel') };
 846     $self->logerr($@) if $@;
 847 }
 848
 849 sub snapshot {
 850     my ($self, $task, $vmid) = @_;
 851
 852     # nothing to do
 853 }
 854
 855 sub cleanup {
 856     my ($self, $task, $vmid) = @_;
 857
 858     # nothing to do ?
 859 }
 860
 861 1;