config/kernel-bio-failfast.m4

   1 dnl #
   2 dnl # Preferred interface for setting FAILFAST on a bio:
   3 dnl #   2.6.12-2.6.27: BIO_RW_FAILFAST
   4 dnl #   2.6.28-2.6.35: BIO_RW_FAILFAST_{DEV|TRANSPORT|DRIVER}
   5 dnl #   2.6.36-2.6.xx: REQ_FAILFAST_{DEV|TRANSPORT|DRIVER}
   6 dnl #
   7 AC_DEFUN([ZFS_AC_KERNEL_BIO_FAILFAST], [
   8         AC_MSG_CHECKING([whether BIO_RW_FAILFAST is defined])
   9         ZFS_LINUX_TRY_COMPILE([
  10                 #include <linux/bio.h>
  11         ],[
  12                 int flags __attribute__ ((unused));
  13                 flags = (1 << BIO_RW_FAILFAST);
  14         ],[
  15                 AC_MSG_RESULT(yes)
  16                 AC_DEFINE(HAVE_BIO_RW_FAILFAST, 1,
  17                           [BIO_RW_FAILFAST is defined])
  18         ],[
  19                 AC_MSG_RESULT(no)
  20         ])
  21 ])
  22
  23 AC_DEFUN([ZFS_AC_KERNEL_BIO_FAILFAST_DTD], [
  24         AC_MSG_CHECKING([whether BIO_RW_FAILFAST_* are defined])
  25         ZFS_LINUX_TRY_COMPILE([
  26                 #include <linux/bio.h>
  27         ],[
  28                 int flags __attribute__ ((unused));
  29                 flags = ((1 << BIO_RW_FAILFAST_DEV) |
  30                          (1 << BIO_RW_FAILFAST_TRANSPORT) |
  31                          (1 << BIO_RW_FAILFAST_DRIVER));
  32         ],[
  33                 AC_MSG_RESULT(yes)
  34                 AC_DEFINE(HAVE_BIO_RW_FAILFAST_DTD, 1,
  35                           [BIO_RW_FAILFAST_* are defined])
  36         ],[
  37                 AC_MSG_RESULT(no)
  38         ])
  39 ])
  40
  41 AC_DEFUN([ZFS_AC_KERNEL_REQ_FAILFAST_MASK], [
  42         AC_MSG_CHECKING([whether REQ_FAILFAST_MASK is defined])
  43         ZFS_LINUX_TRY_COMPILE([
  44                 #include <linux/bio.h>
  45         ],[
  46                 int flags __attribute__ ((unused));
  47                 flags = REQ_FAILFAST_MASK;
  48         ],[
  49                 AC_MSG_RESULT(yes)
  50                 AC_DEFINE(HAVE_BIO_REQ_FAILFAST_MASK, 1,
  51                           [REQ_FAILFAST_MASK is defined])
  52         ],[
  53                 AC_MSG_RESULT(no)
  54         ])
  55 ])