config/kernel-make-request-fn.m4

   1 dnl #
   2 dnl # Check for make_request_fn interface.
   3 dnl #
   4 AC_DEFUN([ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN], [
   5         ZFS_LINUX_TEST_SRC([make_request_fn_void], [
   6                 #include <linux/blkdev.h>
   7                 void make_request(struct request_queue *q,
   8                     struct bio *bio) { return; }
   9         ],[
  10                 blk_queue_make_request(NULL, &make_request);
  11         ])
  12
  13         ZFS_LINUX_TEST_SRC([make_request_fn_blk_qc_t], [
  14                 #include <linux/blkdev.h>
  15                 blk_qc_t make_request(struct request_queue *q,
  16                     struct bio *bio) { return (BLK_QC_T_NONE); }
  17         ],[
  18                 blk_queue_make_request(NULL, &make_request);
  19         ])
  20 ])
  21
  22 AC_DEFUN([ZFS_AC_KERNEL_MAKE_REQUEST_FN], [
  23         dnl #
  24         dnl # Linux 3.2 API Change
  25         dnl # make_request_fn returns void.
  26         dnl #
  27         AC_MSG_CHECKING([whether make_request_fn() returns void])
  28         ZFS_LINUX_TEST_RESULT([make_request_fn_void], [
  29                 AC_MSG_RESULT(yes)
  30                 AC_DEFINE(MAKE_REQUEST_FN_RET, void,
  31                     [make_request_fn() return type])
  32                 AC_DEFINE(HAVE_MAKE_REQUEST_FN_RET_VOID, 1,
  33                     [Noting that make_request_fn() returns void])
  34         ],[
  35                 AC_MSG_RESULT(no)
  36
  37                 dnl #
  38                 dnl # Linux 4.4 API Change
  39                 dnl # make_request_fn returns blk_qc_t.
  40                 dnl #
  41                 AC_MSG_CHECKING(
  42                     [whether make_request_fn() returns blk_qc_t])
  43                 ZFS_LINUX_TEST_RESULT([make_request_fn_blk_qc_t], [
  44                         AC_MSG_RESULT(yes)
  45                         AC_DEFINE(MAKE_REQUEST_FN_RET, blk_qc_t,
  46                             [make_request_fn() return type])
  47                         AC_DEFINE(HAVE_MAKE_REQUEST_FN_RET_QC, 1,
  48                             [Noting that make_request_fn() ]
  49                             [returns blk_qc_t])
  50                 ],[
  51                         ZFS_LINUX_TEST_ERROR([make_request_fn])
  52                 ])
  53         ])
  54 ])