config/kernel-security-inode-init.m4

   1 dnl #
   2 dnl # 2.6.39 API change
   3 dnl # The security_inode_init_security() function now takes an additional
   4 dnl # qstr argument which must be passed in from the dentry if available.
   5 dnl # Passing a NULL is safe when no qstr is available the relevant
   6 dnl # security checks will just be skipped.
   7 dnl #
   8 AC_DEFUN([ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY], [
   9         AC_MSG_CHECKING([whether security_inode_init_security wants 6 args])
  10         tmp_flags="$EXTRA_KCFLAGS"
  11         EXTRA_KCFLAGS="-Werror"
  12         ZFS_LINUX_TRY_COMPILE([
  13                 #include <linux/security.h>
  14         ],[
  15                 security_inode_init_security(NULL,NULL,NULL,NULL,NULL,NULL);
  16         ],[
  17                 AC_MSG_RESULT(yes)
  18                 AC_DEFINE(HAVE_6ARGS_SECURITY_INODE_INIT_SECURITY, 1,
  19                           [security_inode_init_security wants 6 args])
  20         ],[
  21                 AC_MSG_RESULT(no)
  22         ])
  23         EXTRA_KCFLAGS="$tmp_flags"
  24 ])