config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_QAT
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_MISC_MINOR
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_CTL_NAME
  12         ZFS_AC_KERNEL_PDE_DATA
  13         ZFS_AC_KERNEL_SET_FS_PWD_WITH_CONST
  14         ZFS_AC_KERNEL_2ARGS_VFS_FSYNC
  15         ZFS_AC_KERNEL_FS_STRUCT_SPINLOCK
  16         ZFS_AC_KERNEL_KUIDGID_T
  17         ZFS_AC_KERNEL_FALLOCATE
  18         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  19         ZFS_AC_KERNEL_RWSEM_SPINLOCK_IS_RAW
  20         ZFS_AC_KERNEL_RWSEM_ACTIVITY
  21         ZFS_AC_KERNEL_RWSEM_ATOMIC_LONG_COUNT
  22         ZFS_AC_KERNEL_SCHED_RT_HEADER
  23         ZFS_AC_KERNEL_SCHED_SIGNAL_HEADER
  24         ZFS_AC_KERNEL_IO_SCHEDULE_TIMEOUT
  25         ZFS_AC_KERNEL_4ARGS_VFS_GETATTR
  26         ZFS_AC_KERNEL_3ARGS_VFS_GETATTR
  27         ZFS_AC_KERNEL_2ARGS_VFS_GETATTR
  28         ZFS_AC_KERNEL_USLEEP_RANGE
  29         ZFS_AC_KERNEL_KMEM_CACHE_ALLOCFLAGS
  30         ZFS_AC_KERNEL_KMEM_CACHE_CREATE_USERCOPY
  31         ZFS_AC_KERNEL_WAIT_ON_BIT
  32         ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  33         ZFS_AC_KERNEL_WAIT_QUEUE_HEAD_ENTRY
  34         ZFS_AC_KERNEL_INODE_TIMES
  35         ZFS_AC_KERNEL_INODE_LOCK
  36         ZFS_AC_KERNEL_GROUP_INFO_GID
  37         ZFS_AC_KERNEL_WRITE
  38         ZFS_AC_KERNEL_READ
  39         ZFS_AC_KERNEL_TIMER_FUNCTION_TIMER_LIST
  40         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  41         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  42         ZFS_AC_KERNEL_SUPER_USER_NS
  43         ZFS_AC_KERNEL_SUBMIT_BIO
  44         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_CHECK_EVENTS
  45         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  46         ZFS_AC_KERNEL_TYPE_FMODE_T
  47         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  48         ZFS_AC_KERNEL_BLKDEV_REREAD_PART
  49         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  50         ZFS_AC_KERNEL_LOOKUP_BDEV
  51         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  52         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  53         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  54         ZFS_AC_KERNEL_BIO_BVEC_ITER
  55         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  56         ZFS_AC_KERNEL_BIO_SET_DEV
  57         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  58         ZFS_AC_KERNEL_REQ_OP_DISCARD
  59         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  60         ZFS_AC_KERNEL_REQ_OP_FLUSH
  61         ZFS_AC_KERNEL_BIO_BI_OPF
  62         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  63         ZFS_AC_KERNEL_BIO_BI_STATUS
  64         ZFS_AC_KERNEL_BIO_RW_BARRIER
  65         ZFS_AC_KERNEL_BIO_RW_DISCARD
  66         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  67         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_CLEAR
  68         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_SET
  69         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  70         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  71         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  72         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  73         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  74         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
  75         ZFS_AC_KERNEL_GET_DISK_RO
  76         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  77         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  78         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  79         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  80         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  81         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  82         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  83         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  84         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  85         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  86         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  87         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  88         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  89         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  90         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  91         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  92         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  93         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  94         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  95         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  96         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  97         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  98         ZFS_AC_KERNEL_INODE_SET_FLAGS
  99         ZFS_AC_KERNEL_INODE_SET_IVERSION
 100         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
 101         ZFS_AC_KERNEL_SHOW_OPTIONS
 102         ZFS_AC_KERNEL_FILE_INODE
 103         ZFS_AC_KERNEL_FILE_DENTRY
 104         ZFS_AC_KERNEL_FSYNC
 105         ZFS_AC_KERNEL_EVICT_INODE
 106         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
 107         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
 108         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
 109         ZFS_AC_KERNEL_FALLOCATE
 110         ZFS_AC_KERNEL_AIO_FSYNC
 111         ZFS_AC_KERNEL_MKDIR_UMODE_T
 112         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
 113         ZFS_AC_KERNEL_CREATE_NAMEIDATA
 114         ZFS_AC_KERNEL_GET_LINK
 115         ZFS_AC_KERNEL_PUT_LINK
 116         ZFS_AC_KERNEL_TMPFILE
 117         ZFS_AC_KERNEL_TRUNCATE_RANGE
 118         ZFS_AC_KERNEL_AUTOMOUNT
 119         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 120         ZFS_AC_KERNEL_COMMIT_METADATA
 121         ZFS_AC_KERNEL_CLEAR_INODE
 122         ZFS_AC_KERNEL_SETATTR_PREPARE
 123         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 124         ZFS_AC_KERNEL_D_MAKE_ROOT
 125         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
 126         ZFS_AC_KERNEL_D_PRUNE_ALIASES
 127         ZFS_AC_KERNEL_D_SET_D_OP
 128         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
 129         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
 130         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 131         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 132         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 133         ZFS_AC_KERNEL_FST_MOUNT
 134         ZFS_AC_KERNEL_SHRINK
 135         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 136         ZFS_AC_KERNEL_SHRINK_CONTROL_STRUCT
 137         ZFS_AC_KERNEL_SHRINKER_CALLBACK
 138         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 139         ZFS_AC_KERNEL_S_D_OP
 140         ZFS_AC_KERNEL_BDI
 141         ZFS_AC_KERNEL_SET_NLINK
 142         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 143         ZFS_AC_KERNEL_5ARG_SGET
 144         ZFS_AC_KERNEL_LSEEK_EXECUTE
 145         ZFS_AC_KERNEL_VFS_ITERATE
 146         ZFS_AC_KERNEL_VFS_RW_ITERATE
 147         ZFS_AC_KERNEL_VFS_DIRECT_IO
 148         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 149         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 150         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 151         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 152         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 153         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 154         ZFS_AC_KERNEL_FPU
 155         ZFS_AC_KERNEL_KUID_HELPERS
 156         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 157         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 158         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 159         ZFS_AC_KERNEL_CURRENT_TIME
 160         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 161         ZFS_AC_KERNEL_ACL_HAS_REFCOUNT
 162         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 163         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 164
 165         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 166                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 167         ])
 168
 169         AC_SUBST(KERNEL_MAKE)
 170 ])
 171
 172 dnl #
 173 dnl # Detect name used for Module.symvers file in kernel
 174 dnl #
 175 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 176         modpost=$LINUX/scripts/Makefile.modpost
 177         AC_MSG_CHECKING([kernel file name for module symbols])
 178         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 179                 AS_IF([grep -q Modules.symvers $modpost], [
 180                         LINUX_SYMBOLS=Modules.symvers
 181                 ], [
 182                         LINUX_SYMBOLS=Module.symvers
 183                 ])
 184
 185                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 186                         AC_MSG_ERROR([
 187         *** Please make sure the kernel devel package for your distribution
 188         *** is installed.  If you are building with a custom kernel, make sure the
 189         *** kernel is configured, built, and the '--with-linux=PATH' configure
 190         *** option refers to the location of the kernel source.])
 191                 ])
 192         ], [
 193                 LINUX_SYMBOLS=NONE
 194         ])
 195         AC_MSG_RESULT($LINUX_SYMBOLS)
 196         AC_SUBST(LINUX_SYMBOLS)
 197 ])
 198
 199 dnl #
 200 dnl # Detect the kernel to be built against
 201 dnl #
 202 AC_DEFUN([ZFS_AC_KERNEL], [
 203         AC_ARG_WITH([linux],
 204                 AS_HELP_STRING([--with-linux=PATH],
 205                 [Path to kernel source]),
 206                 [kernelsrc="$withval"])
 207
 208         AC_ARG_WITH(linux-obj,
 209                 AS_HELP_STRING([--with-linux-obj=PATH],
 210                 [Path to kernel build objects]),
 211                 [kernelbuild="$withval"])
 212
 213         AC_MSG_CHECKING([kernel source directory])
 214         AS_IF([test -z "$kernelsrc"], [
 215                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 216                         headersdir="/lib/modules/$(uname -r)/source"
 217                         sourcelink=$(readlink -f "$headersdir")
 218                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 219                         headersdir="/lib/modules/$(uname -r)/build"
 220                         sourcelink=$(readlink -f "$headersdir")
 221                 ], [
 222                         sourcelink=$(ls -1d /usr/src/kernels/* \
 223                                      /usr/src/linux-* \
 224                                      2>/dev/null | grep -v obj | tail -1)
 225                 ])
 226
 227                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 228                         kernelsrc=`readlink -f ${sourcelink}`
 229                 ], [
 230                         kernelsrc="[Not found]"
 231                 ])
 232         ], [
 233                 AS_IF([test "$kernelsrc" = "NONE"], [
 234                         kernsrcver=NONE
 235                 ])
 236                 withlinux=yes
 237         ])
 238
 239         AC_MSG_RESULT([$kernelsrc])
 240         AS_IF([test ! -d "$kernelsrc"], [
 241                 AC_MSG_ERROR([
 242         *** Please make sure the kernel devel package for your distribution
 243         *** is installed and then try again.  If that fails, you can specify the
 244         *** location of the kernel source with the '--with-linux=PATH' option.])
 245         ])
 246
 247         AC_MSG_CHECKING([kernel build directory])
 248         AS_IF([test -z "$kernelbuild"], [
 249                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 250                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 251                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 252                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 253                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 254                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 255                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 256                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 257                 ], [
 258                         kernelbuild=${kernelsrc}
 259                 ])
 260         ])
 261         AC_MSG_RESULT([$kernelbuild])
 262
 263         AC_MSG_CHECKING([kernel source version])
 264         utsrelease1=$kernelbuild/include/linux/version.h
 265         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 266         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 267         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 268                 utsrelease=linux/version.h
 269         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 270                 utsrelease=linux/utsrelease.h
 271         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 272                 utsrelease=generated/utsrelease.h
 273         ])
 274
 275         AS_IF([test "$utsrelease"], [
 276                 kernsrcver=`(echo "#include <$utsrelease>";
 277                              echo "kernsrcver=UTS_RELEASE") |
 278                              ${CPP} -I $kernelbuild/include - |
 279                              grep "^kernsrcver=" | cut -d \" -f 2`
 280
 281                 AS_IF([test -z "$kernsrcver"], [
 282                         AC_MSG_RESULT([Not found])
 283                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 284                 ])
 285         ], [
 286                 AC_MSG_RESULT([Not found])
 287                 if test "x$enable_linux_builtin" != xyes; then
 288                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 289                 else
 290                         AC_MSG_ERROR([
 291         *** Cannot find UTS_RELEASE definition.
 292         *** Please run 'make prepare' inside the kernel source tree.])
 293                 fi
 294         ])
 295
 296         AC_MSG_RESULT([$kernsrcver])
 297
 298         LINUX=${kernelsrc}
 299         LINUX_OBJ=${kernelbuild}
 300         LINUX_VERSION=${kernsrcver}
 301
 302         AC_SUBST(LINUX)
 303         AC_SUBST(LINUX_OBJ)
 304         AC_SUBST(LINUX_VERSION)
 305
 306         ZFS_AC_MODULE_SYMVERS
 307 ])
 308
 309 dnl #
 310 dnl # Detect the QAT module to be built against
 311 dnl # QAT provides hardware acceleration for data compression:
 312 dnl #   https://01.org/intel-quickassist-technology
 313 dnl # * Download and install QAT driver from the above link
 314 dnl # * Start QAT driver in your system:
 315 dnl #   service qat_service start
 316 dnl # * Enable QAT in ZFS, e.g.:
 317 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 318 dnl #   make
 319 dnl # * Set GZIP compression in ZFS dataset:
 320 dnl #   zfs set compression = gzip <dataset>
 321 dnl # Then the data written to this ZFS pool is compressed
 322 dnl # by QAT accelerator automatically, and de-compressed by
 323 dnl # QAT when read from the pool.
 324 dnl # * Get QAT hardware statistics by:
 325 dnl #   cat /proc/icp_dh895xcc_dev/qat
 326 dnl # * To disable QAT:
 327 dnl #   insmod zfs.ko zfs_qat_disable=1
 328 dnl #
 329 AC_DEFUN([ZFS_AC_QAT], [
 330         AC_ARG_WITH([qat],
 331                 AS_HELP_STRING([--with-qat=PATH],
 332                 [Path to qat source]),
 333                 AS_IF([test "$withval" = "yes"],
 334                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 335                         [qatsrc="$withval"]))
 336
 337         AC_ARG_WITH([qat-obj],
 338                 AS_HELP_STRING([--with-qat-obj=PATH],
 339                 [Path to qat build objects]),
 340                 [qatbuild="$withval"])
 341
 342         AS_IF([test ! -z "${qatsrc}"], [
 343                 AC_MSG_CHECKING([qat source directory])
 344                 AC_MSG_RESULT([$qatsrc])
 345                 QAT_SRC="${qatsrc}/quickassist"
 346                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 347                         AC_MSG_ERROR([
 348                 *** Please make sure the qat driver package is installed
 349                 *** and specify the location of the qat source with the
 350                 *** '--with-qat=PATH' option then try again. Failed to
 351                 *** find cpa.h in:
 352                 ${QAT_SRC}/include])
 353                 ])
 354         ])
 355
 356         AS_IF([test ! -z "${qatsrc}"], [
 357                 AC_MSG_CHECKING([qat build directory])
 358                 AS_IF([test -z "$qatbuild"], [
 359                         qatbuild="${qatsrc}/build"
 360                 ])
 361
 362                 AC_MSG_RESULT([$qatbuild])
 363                 QAT_OBJ=${qatbuild}
 364                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 365                         AC_MSG_ERROR([
 366                 *** Please make sure the qat driver is installed then try again.
 367                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 368                 $QAT_OBJ])
 369                 ])
 370
 371                 AC_SUBST(QAT_SRC)
 372                 AC_SUBST(QAT_OBJ)
 373
 374                 AC_DEFINE(HAVE_QAT, 1,
 375                 [qat is enabled and existed])
 376         ])
 377
 378         dnl #
 379         dnl # Detect the name used for the QAT Module.symvers file.
 380         dnl #
 381         AS_IF([test ! -z "${qatsrc}"], [
 382                 AC_MSG_CHECKING([qat file for module symbols])
 383                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 384
 385                 AS_IF([test -r $QAT_SYMBOLS], [
 386                         AC_MSG_RESULT([$QAT_SYMBOLS])
 387                         AC_SUBST(QAT_SYMBOLS)
 388                 ],[
 389                        AC_MSG_ERROR([
 390                         *** Please make sure the qat driver is installed then try again.
 391                         *** Failed to find Module.symvers in:
 392                         $QAT_SYMBOLS])
 393                         ])
 394                 ])
 395         ])
 396 ])
 397
 398 dnl #
 399 dnl # Basic toolchain sanity check.
 400 dnl #
 401 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 402         AC_MSG_CHECKING([whether modules can be built])
 403         ZFS_LINUX_TRY_COMPILE([],[],[
 404                 AC_MSG_RESULT([yes])
 405         ],[
 406                 AC_MSG_RESULT([no])
 407                 if test "x$enable_linux_builtin" != xyes; then
 408                         AC_MSG_ERROR([*** Unable to build an empty module.])
 409                 else
 410                         AC_MSG_ERROR([
 411         *** Unable to build an empty module.
 412         *** Please run 'make scripts' inside the kernel source tree.])
 413                 fi
 414         ])
 415 ])
 416
 417 dnl #
 418 dnl # Certain kernel build options are not supported.  These must be
 419 dnl # detected at configure time and cause a build failure.  Otherwise
 420 dnl # modules may be successfully built that behave incorrectly.
 421 dnl #
 422 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 423         AS_IF([test "x$cross_compiling" != xyes], [
 424                 AC_RUN_IFELSE([
 425                         AC_LANG_PROGRAM([
 426                                 #include "$LINUX/include/linux/license.h"
 427                         ], [
 428                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 429                         ])
 430                 ], [
 431                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 432                             [Define to 1 if GPL-only symbols can be used])
 433                 ], [
 434                 ])
 435         ])
 436
 437         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 438         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 439         ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS
 440         ZFS_AC_KERNEL_CONFIG_ZLIB_INFLATE
 441         ZFS_AC_KERNEL_CONFIG_ZLIB_DEFLATE
 442 ])
 443
 444 dnl #
 445 dnl # Check configured THREAD_SIZE
 446 dnl #
 447 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 448 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 449 dnl # on newer kernels and some architectures stack usage optimizations can be
 450 dnl # conditionally applied to improve performance without negatively impacting
 451 dnl # stability.
 452 dnl #
 453 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 454         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 455         ZFS_LINUX_TRY_COMPILE([
 456                 #include <linux/module.h>
 457         ],[
 458                 #if (THREAD_SIZE < 16384)
 459                 #error "THREAD_SIZE is less than 16K"
 460                 #endif
 461         ],[
 462                 AC_MSG_RESULT([yes])
 463                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 464         ],[
 465                 AC_MSG_RESULT([no])
 466         ])
 467 ])
 468
 469 dnl #
 470 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 471 dnl #
 472 dnl # This is typically only set for debug kernels because it comes with
 473 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 474 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 475 dnl # This will cause a failure at link time which we'd rather know about
 476 dnl # at compile time.
 477 dnl #
 478 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 479 dnl # with the upstream community we add a check to detect this case.
 480 dnl #
 481 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 482
 483         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 484                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 485                 tmp_flags="$EXTRA_KCFLAGS"
 486                 ZFS_LINUX_TRY_COMPILE([
 487                         #include <linux/module.h>
 488                         #include <linux/mutex.h>
 489
 490                         MODULE_LICENSE("$ZFS_META_LICENSE");
 491                 ],[
 492                         struct mutex lock;
 493
 494                         mutex_init(&lock);
 495                         mutex_lock(&lock);
 496                         mutex_unlock(&lock);
 497                 ],[
 498                         AC_MSG_RESULT(no)
 499                 ],[
 500                         AC_MSG_RESULT(yes)
 501                         AC_MSG_ERROR([
 502         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 503         *** with the CDDL license and will prevent the module linking stage
 504         *** from succeeding.  You must rebuild your kernel without this
 505         *** option enabled.])
 506                 ])
 507                 EXTRA_KCFLAGS="$tmp_flags"
 508         ], [])
 509 ])
 510
 511 dnl #
 512 dnl # Check CONFIG_TRIM_UNUSED_KSYMS
 513 dnl #
 514 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS disabled.
 515 dnl #
 516 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS], [
 517         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
 518         ZFS_LINUX_TRY_COMPILE([
 519                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
 520                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
 521                 #endif
 522         ],[ ],[
 523                 AC_MSG_RESULT([yes])
 524         ],[
 525                 AC_MSG_RESULT([no])
 526                 AC_MSG_ERROR([
 527         *** This kernel has unused symbols trimming enabled, please disable.
 528         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
 529         ])
 530 ])
 531
 532 dnl #
 533 dnl # ZFS_LINUX_CONFTEST_H
 534 dnl #
 535 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 536 cat - <<_ACEOF >conftest.h
 537 $1
 538 _ACEOF
 539 ])
 540
 541 dnl #
 542 dnl # ZFS_LINUX_CONFTEST_C
 543 dnl #
 544 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 545 cat confdefs.h - <<_ACEOF >conftest.c
 546 $1
 547 _ACEOF
 548 ])
 549
 550 dnl #
 551 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 552 dnl #
 553 m4_define([ZFS_LANG_PROGRAM], [
 554 $1
 555 int
 556 main (void)
 557 {
 558 dnl Do *not* indent the following line: there may be CPP directives.
 559 dnl Don't move the `;' right after for the same reason.
 560 $2
 561   ;
 562   return 0;
 563 }
 564 ])
 565
 566 dnl #
 567 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 568 dnl #
 569 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 570         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 571         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 572         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 573         echo "obj-m := conftest.o" >build/Makefile
 574         modpost_flag=''
 575         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 576         AS_IF(
 577                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $FRAME_LARGER_THAN $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 578                 [$4],
 579                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 580         )
 581         rm -Rf build
 582 ])
 583
 584 dnl #
 585 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 586 dnl #
 587 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 588         [ZFS_LINUX_COMPILE_IFELSE(
 589         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 590         [modules],
 591         [test -s build/conftest.o],
 592         [$3], [$4])
 593 ])
 594
 595 dnl #
 596 dnl # ZFS_LINUX_CONFIG
 597 dnl #
 598 AC_DEFUN([ZFS_LINUX_CONFIG],
 599         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 600         ZFS_LINUX_TRY_COMPILE([
 601                 #include <linux/module.h>
 602         ],[
 603                 #ifndef CONFIG_$1
 604                 #error CONFIG_$1 not #defined
 605                 #endif
 606         ],[
 607                 AC_MSG_RESULT([yes])
 608                 $2
 609         ],[
 610                 AC_MSG_RESULT([no])
 611                 $3
 612         ])
 613 ])
 614
 615 dnl #
 616 dnl # ZFS_CHECK_SYMBOL_EXPORT
 617 dnl # check symbol exported or not
 618 dnl #
 619 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 620         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 621                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 622         rc=$?
 623         if test $rc -ne 0; then
 624                 export=0
 625                 for file in $2; do
 626                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 627                                 "$LINUX/$file" 2>/dev/null
 628                         rc=$?
 629                         if test $rc -eq 0; then
 630                                 export=1
 631                                 break;
 632                         fi
 633                 done
 634                 if test $export -eq 0; then :
 635                         $4
 636                 else :
 637                         $3
 638                 fi
 639         else :
 640                 $3
 641         fi
 642 ])
 643
 644 dnl #
 645 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 646 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 647 dnl # is called if not compiling for builtin
 648 dnl #
 649 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 650         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 651         if test $rc -ne 0; then :
 652                 $6
 653         else
 654                 if test "x$enable_linux_builtin" != xyes; then
 655                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 656                 fi
 657                 if test $rc -ne 0; then :
 658                         $6
 659                 else :
 660                         $5
 661                 fi
 662         fi
 663 ])
 664
 665 dnl #
 666 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 667 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 668 dnl # provided via the fifth parameter
 669 dnl #
 670 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 671         [ZFS_LINUX_COMPILE_IFELSE(
 672         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 673         [modules],
 674         [test -s build/conftest.o],
 675         [$3], [$4], [$5])
 676 ])