]> git.proxmox.com Git - mirror_zfs-debian.git/blob - config/kernel.m4
Merge branch 'clopez'
[mirror_zfs-debian.git] / config / kernel.m4
1 dnl #
2 dnl # Default ZFS kernel configuration
3 dnl #
4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
5 ZFS_AC_KERNEL
6 ZFS_AC_SPL
7 ZFS_AC_TEST_MODULE
8 ZFS_AC_KERNEL_CONFIG
9 ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
10 ZFS_AC_KERNEL_TYPE_FMODE_T
11 ZFS_AC_KERNEL_KOBJ_NAME_LEN
12 ZFS_AC_KERNEL_3ARG_BLKDEV_GET
13 ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
14 ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
15 ZFS_AC_KERNEL_LOOKUP_BDEV
16 ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
17 ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
18 ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
19 ZFS_AC_KERNEL_BIO_FAILFAST
20 ZFS_AC_KERNEL_BIO_FAILFAST_DTD
21 ZFS_AC_KERNEL_REQ_FAILFAST_MASK
22 ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
23 ZFS_AC_KERNEL_BIO_RW_SYNC
24 ZFS_AC_KERNEL_BIO_RW_SYNCIO
25 ZFS_AC_KERNEL_REQ_SYNC
26 ZFS_AC_KERNEL_BLK_END_REQUEST
27 ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
28 ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
29 ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
30 ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
31 ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
32 ZFS_AC_KERNEL_BLK_QUEUE_NONROT
33 ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
34 ZFS_AC_KERNEL_BLK_FETCH_REQUEST
35 ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
36 ZFS_AC_KERNEL_BLK_RQ_BYTES
37 ZFS_AC_KERNEL_BLK_RQ_POS
38 ZFS_AC_KERNEL_BLK_RQ_SECTORS
39 ZFS_AC_KERNEL_GET_DISK_RO
40 ZFS_AC_KERNEL_GET_GENDISK
41 ZFS_AC_KERNEL_RQ_IS_SYNC
42 ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
43 ZFS_AC_KERNEL_DISCARD_GRANULARITY
44 ZFS_AC_KERNEL_CONST_XATTR_HANDLER
45 ZFS_AC_KERNEL_XATTR_HANDLER_GET
46 ZFS_AC_KERNEL_XATTR_HANDLER_SET
47 ZFS_AC_KERNEL_SHOW_OPTIONS
48 ZFS_AC_KERNEL_FSYNC
49 ZFS_AC_KERNEL_EVICT_INODE
50 ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
51 ZFS_AC_KERNEL_NR_CACHED_OBJECTS
52 ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
53 ZFS_AC_KERNEL_FALLOCATE
54 ZFS_AC_KERNEL_MKDIR_UMODE_T
55 ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
56 ZFS_AC_KERNEL_CREATE_NAMEIDATA
57 ZFS_AC_KERNEL_TRUNCATE_RANGE
58 ZFS_AC_KERNEL_AUTOMOUNT
59 ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
60 ZFS_AC_KERNEL_COMMIT_METADATA
61 ZFS_AC_KERNEL_CLEAR_INODE
62 ZFS_AC_KERNEL_INSERT_INODE_LOCKED
63 ZFS_AC_KERNEL_D_MAKE_ROOT
64 ZFS_AC_KERNEL_D_OBTAIN_ALIAS
65 ZFS_AC_KERNEL_D_SET_D_OP
66 ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
67 ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
68 ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
69 ZFS_AC_KERNEL_TRUNCATE_SETSIZE
70 ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
71 ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
72 ZFS_AC_KERNEL_MOUNT_NODEV
73 ZFS_AC_KERNEL_SHRINK
74 ZFS_AC_KERNEL_S_D_OP
75 ZFS_AC_KERNEL_BDI
76 ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
77 ZFS_AC_KERNEL_SET_NLINK
78 ZFS_AC_KERNEL_ELEVATOR_CHANGE
79 ZFS_AC_KERNEL_5ARG_SGET
80
81 AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
82 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
83 ])
84 AC_SUBST(KERNELMAKE_PARAMS)
85
86
87 dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
88 dnl # compiler options are added by the kernel build system.
89 KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
90 KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
91 KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
92
93 AC_SUBST(KERNELCPPFLAGS)
94 ])
95
96 dnl #
97 dnl # Detect name used for Module.symvers file in kernel
98 dnl #
99 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
100 modpost=$LINUX/scripts/Makefile.modpost
101 AC_MSG_CHECKING([kernel file name for module symbols])
102 AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
103 AS_IF([grep -q Modules.symvers $modpost], [
104 LINUX_SYMBOLS=Modules.symvers
105 ], [
106 LINUX_SYMBOLS=Module.symvers
107 ])
108
109 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
110 AC_MSG_ERROR([
111 *** Please make sure the kernel devel package for your distribution
112 *** is installed. If your building with a custom kernel make sure the
113 *** kernel is configured, built, and the '--with-linux=PATH' configure
114 *** option refers to the location of the kernel source.])
115 ])
116 ], [
117 LINUX_SYMBOLS=NONE
118 ])
119 AC_MSG_RESULT($LINUX_SYMBOLS)
120 AC_SUBST(LINUX_SYMBOLS)
121 ])
122
123 dnl #
124 dnl # Detect the kernel to be built against
125 dnl #
126 AC_DEFUN([ZFS_AC_KERNEL], [
127 AC_ARG_WITH([linux],
128 AS_HELP_STRING([--with-linux=PATH],
129 [Path to kernel source]),
130 [kernelsrc="$withval"])
131
132 AC_ARG_WITH(linux-obj,
133 AS_HELP_STRING([--with-linux-obj=PATH],
134 [Path to kernel build objects]),
135 [kernelbuild="$withval"])
136
137 AC_MSG_CHECKING([kernel source directory])
138 AS_IF([test -z "$kernelsrc"], [
139 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
140 headersdir="/lib/modules/$(uname -r)/source"
141 sourcelink=$(readlink -f "$headersdir")
142 ], [test -e "/lib/modules/$(uname -r)/build"], [
143 headersdir="/lib/modules/$(uname -r)/build"
144 sourcelink=$(readlink -f "$headersdir")
145 ], [
146 sourcelink=$(ls -1d /usr/src/kernels/* \
147 /usr/src/linux-* \
148 2>/dev/null | grep -v obj | tail -1)
149 ])
150
151 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
152 kernelsrc=`readlink -f ${sourcelink}`
153 ], [
154 kernelsrc="[Not found]"
155 ])
156 ], [
157 AS_IF([test "$kernelsrc" = "NONE"], [
158 kernsrcver=NONE
159 ])
160 ])
161
162 AC_MSG_RESULT([$kernelsrc])
163 AS_IF([test ! -d "$kernelsrc"], [
164 AC_MSG_ERROR([
165 *** Please make sure the kernel devel package for your distribution
166 *** is installed then try again. If that fails you can specify the
167 *** location of the kernel source with the '--with-linux=PATH' option.])
168 ])
169
170 AC_MSG_CHECKING([kernel build directory])
171 AS_IF([test -z "$kernelbuild"], [
172 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
173 kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
174 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
175 kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
176 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
177 kernelbuild=${kernelsrc}-obj/${target_cpu}/default
178 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
179 kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
180 ], [
181 kernelbuild=${kernelsrc}
182 ])
183 ])
184 AC_MSG_RESULT([$kernelbuild])
185
186 AC_MSG_CHECKING([kernel source version])
187 utsrelease1=$kernelbuild/include/linux/version.h
188 utsrelease2=$kernelbuild/include/linux/utsrelease.h
189 utsrelease3=$kernelbuild/include/generated/utsrelease.h
190 AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
191 utsrelease=linux/version.h
192 ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
193 utsrelease=linux/utsrelease.h
194 ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
195 utsrelease=generated/utsrelease.h
196 ])
197
198 AS_IF([test "$utsrelease"], [
199 kernsrcver=`(echo "#include <$utsrelease>";
200 echo "kernsrcver=UTS_RELEASE") |
201 cpp -I $kernelbuild/include |
202 grep "^kernsrcver=" | cut -d \" -f 2`
203
204 AS_IF([test -z "$kernsrcver"], [
205 AC_MSG_RESULT([Not found])
206 AC_MSG_ERROR([*** Cannot determine kernel version.])
207 ])
208 ], [
209 AC_MSG_RESULT([Not found])
210 if test "x$enable_linux_builtin" != xyes; then
211 AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
212 else
213 AC_MSG_ERROR([
214 *** Cannot find UTS_RELEASE definition.
215 *** Please run 'make prepare' inside the kernel source tree.])
216 fi
217 ])
218
219 AC_MSG_RESULT([$kernsrcver])
220
221 LINUX=${kernelsrc}
222 LINUX_OBJ=${kernelbuild}
223 LINUX_VERSION=${kernsrcver}
224
225 AC_SUBST(LINUX)
226 AC_SUBST(LINUX_OBJ)
227 AC_SUBST(LINUX_VERSION)
228
229 ZFS_AC_MODULE_SYMVERS
230 ])
231
232 dnl #
233 dnl # Detect name used for the additional SPL Module.symvers file. If one
234 dnl # does not exist this is likely because the SPL has been configured
235 dnl # but not built. The '--with-spl-timeout' option can be passed
236 dnl # to pause here, waiting for the file to appear from a concurrently
237 dnl # building SPL package. If the file does not appear in time, a good
238 dnl # guess is made as to what this file will be named based on what it
239 dnl # is named in the kernel build products. This file will first be
240 dnl # used at link time so if the guess is wrong the build will fail
241 dnl # then. This unfortunately means the ZFS package does not contain a
242 dnl # reliable mechanism to detect symbols exported by the SPL at
243 dnl # configure time.
244 dnl #
245 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
246 AC_ARG_WITH([spl-timeout],
247 AS_HELP_STRING([--with-spl-timeout=SECS],
248 [Wait SECS for symvers file to appear @<:@default=0@:>@]),
249 [timeout="$withval"], [timeout=0])
250
251 AC_MSG_CHECKING([spl file name for module symbols])
252 SPL_SYMBOLS=NONE
253
254 while true; do
255 AS_IF([test -r $SPL_OBJ/Module.symvers], [
256 SPL_SYMBOLS=Module.symvers
257 ], [test -r $SPL_OBJ/Modules.symvers], [
258 SPL_SYMBOLS=Modules.symvers
259 ], [test -r $SPL_OBJ/module/Module.symvers], [
260 SPL_SYMBOLS=Module.symvers
261 ], [test -r $SPL_OBJ/module/Modules.symvers], [
262 SPL_SYMBOLS=Modules.symvers
263 ])
264
265 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
266 break;
267 ], [
268 sleep 1
269 timeout=$((timeout-1))
270 ])
271 done
272
273 AS_IF([test "$SPL_SYMBOLS" = NONE], [
274 SPL_SYMBOLS=$LINUX_SYMBOLS
275 ])
276
277 AC_MSG_RESULT([$SPL_SYMBOLS])
278 AC_SUBST(SPL_SYMBOLS)
279 ])
280
281 dnl #
282 dnl # Detect the SPL module to be built against
283 dnl #
284 AC_DEFUN([ZFS_AC_SPL], [
285 AC_ARG_WITH([spl],
286 AS_HELP_STRING([--with-spl=PATH],
287 [Path to spl source]),
288 [splsrc="$withval"])
289
290 AC_ARG_WITH([spl-obj],
291 AS_HELP_STRING([--with-spl-obj=PATH],
292 [Path to spl build objects]),
293 [splbuild="$withval"])
294
295 dnl #
296 dnl # The existence of spl.release.in is used to identify a valid
297 dnl # source directory. In order of preference:
298 dnl #
299 splsrc0="/var/lib/dkms/spl/${VERSION}/build"
300 splsrc1="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
301 splsrc2="/usr/src/spl-${VERSION}"
302 splsrc3="../spl/"
303 splsrc4="$LINUX"
304
305 AC_MSG_CHECKING([spl source directory])
306 AS_IF([test -z "${splsrc}"], [
307 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
308 splsrc=${splsrc0}
309 ], [ test -e "${splsrc1}/spl.release.in"], [
310 splsrc=${splsrc1}
311 ], [ test -e "${splsrc2}/spl.release.in"], [
312 splsrc=${splsrc2}
313 ], [ test -e "${splsrc3}/spl.release.in"], [
314 splsrc=$(readlink -f "${splsrc3}")
315 ], [ test -e "${splsrc4}/spl.release.in" ], [
316 splsrc=${splsrc4}
317 ], [
318 splsrc="[Not found]"
319 ])
320 ], [
321 AS_IF([test "$splsrc" = "NONE"], [
322 splbuild=NONE
323 splsrcver=NONE
324 ])
325 ])
326
327 AC_MSG_RESULT([$splsrc])
328 AS_IF([ test ! -e "$splsrc/spl.release.in"], [
329 AC_MSG_ERROR([
330 *** Please make sure the kmod spl devel package for your distribution
331 *** is installed then try again. If that fails you can specify the
332 *** location of the spl source with the '--with-spl=PATH' option.])
333 ])
334
335 dnl #
336 dnl # The existence of the spl_config.h is used to identify a valid
337 dnl # spl object directory. In many cases the object and source
338 dnl # directory are the same, however the objects may also reside
339 dnl # is a subdirectory named after the kernel version.
340 dnl #
341 AC_MSG_CHECKING([spl build directory])
342 AS_IF([test -z "$splbuild"], [
343 AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
344 splbuild="${splsrc}/${LINUX_VERSION}"
345 ], [ test -e "${splsrc}/spl_config.h" ], [
346 splbuild="${splsrc}"
347 ], [
348 splbuild="[Not found]"
349 ])
350 ])
351
352 AC_MSG_RESULT([$splbuild])
353 AS_IF([ ! test -e "$splbuild/spl_config.h"], [
354 AC_MSG_ERROR([
355 *** Please make sure the kmod spl devel <kernel> package for your
356 *** distribution is installed then try again. If that fails you
357 *** can specify the location of the spl objects with the
358 *** '--with-spl-obj=PATH' option.])
359 ])
360
361 AC_MSG_CHECKING([spl source version])
362 AS_IF([test -r $splbuild/spl_config.h &&
363 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
364
365 splsrcver=`(echo "#include <spl_config.h>";
366 echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
367 cpp -I $splbuild |
368 grep "^splsrcver=" | tr -d \" | cut -d= -f2`
369 ])
370
371 AS_IF([test -z "$splsrcver"], [
372 AC_MSG_RESULT([Not found])
373 AC_MSG_ERROR([
374 *** Cannot determine the version of the spl source.
375 *** Please prepare the spl source before running this script])
376 ])
377
378 AC_MSG_RESULT([$splsrcver])
379
380 SPL=${splsrc}
381 SPL_OBJ=${splbuild}
382 SPL_VERSION=${splsrcver}
383
384 AC_SUBST(SPL)
385 AC_SUBST(SPL_OBJ)
386 AC_SUBST(SPL_VERSION)
387
388 ZFS_AC_SPL_MODULE_SYMVERS
389 ])
390
391 dnl #
392 dnl # Basic toolchain sanity check.
393 dnl #
394 AC_DEFUN([ZFS_AC_TEST_MODULE],
395 [AC_MSG_CHECKING([whether modules can be built])
396 ZFS_LINUX_TRY_COMPILE([],[],[
397 AC_MSG_RESULT([yes])
398 ],[
399 AC_MSG_RESULT([no])
400 if test "x$enable_linux_builtin" != xyes; then
401 AC_MSG_ERROR([*** Unable to build an empty module.])
402 else
403 AC_MSG_ERROR([
404 *** Unable to build an empty module.
405 *** Please run 'make scripts' inside the kernel source tree.])
406 fi
407 ])
408 ])
409
410 dnl #
411 dnl # Certain kernel build options are not supported. These must be
412 dnl # detected at configure time and cause a build failure. Otherwise
413 dnl # modules may be successfully built that behave incorrectly.
414 dnl #
415 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
416
417 AS_IF([test "$ZFS_META_LICENSE" = GPL], [
418 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
419 [Define to 1 if licensed under the GPL])
420 ])
421
422 ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
423 ])
424
425 dnl #
426 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
427 dnl #
428 dnl # This is typically only set for debug kernels because it comes with
429 dnl # a performance penalty. However, when it is set it maps the non-GPL
430 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
431 dnl # This will cause a failure at link time which we'd rather know about
432 dnl # at compile time.
433 dnl #
434 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
435 dnl # with the upstream community we add a check to detect this case.
436 dnl #
437 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
438
439 ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
440 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
441 tmp_flags="$EXTRA_KCFLAGS"
442 ZFS_LINUX_TRY_COMPILE([
443 #include <linux/module.h>
444 #include <linux/mutex.h>
445
446 MODULE_LICENSE("$ZFS_META_LICENSE");
447 ],[
448 struct mutex lock;
449
450 mutex_init(&lock);
451 mutex_lock(&lock);
452 mutex_unlock(&lock);
453 ],[
454 AC_MSG_RESULT(no)
455 ],[
456 AC_MSG_RESULT(yes)
457 AC_MSG_ERROR([
458 *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
459 *** with the CDDL license and will prevent the module linking stage
460 *** from succeeding. You must rebuild your kernel without this
461 *** option enabled.])
462 ])
463 EXTRA_KCFLAGS="$tmp_flags"
464 ], [])
465 ])
466
467 dnl #
468 dnl # ZFS_LINUX_CONFTEST
469 dnl #
470 AC_DEFUN([ZFS_LINUX_CONFTEST], [
471 cat confdefs.h - <<_ACEOF >conftest.c
472 $1
473 _ACEOF
474 ])
475
476 dnl #
477 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
478 dnl #
479 m4_define([ZFS_LANG_PROGRAM], [
480 $1
481 int
482 main (void)
483 {
484 dnl Do *not* indent the following line: there may be CPP directives.
485 dnl Don't move the `;' right after for the same reason.
486 $2
487 ;
488 return 0;
489 }
490 ])
491
492 dnl #
493 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
494 dnl #
495 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
496 m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
497 rm -Rf build && mkdir -p build && touch build/conftest.mod.c
498 echo "obj-m := conftest.o" >build/Makefile
499 modpost_flag=''
500 test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
501 AS_IF(
502 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
503 [$4],
504 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
505 )
506 rm -Rf build
507 ])
508
509 dnl #
510 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
511 dnl #
512 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
513 [ZFS_LINUX_COMPILE_IFELSE(
514 [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
515 [modules],
516 [test -s build/conftest.o],
517 [$3], [$4])
518 ])
519
520 dnl #
521 dnl # ZFS_LINUX_CONFIG
522 dnl #
523 AC_DEFUN([ZFS_LINUX_CONFIG],
524 [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
525 ZFS_LINUX_TRY_COMPILE([
526 #include <linux/module.h>
527 ],[
528 #ifndef CONFIG_$1
529 #error CONFIG_$1 not #defined
530 #endif
531 ],[
532 AC_MSG_RESULT([yes])
533 $2
534 ],[
535 AC_MSG_RESULT([no])
536 $3
537 ])
538 ])
539
540 dnl #
541 dnl # ZFS_CHECK_SYMBOL_EXPORT
542 dnl # check symbol exported or not
543 dnl #
544 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
545 grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
546 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
547 rc=$?
548 if test $rc -ne 0; then
549 export=0
550 for file in $2; do
551 grep -q -E "EXPORT_SYMBOL.*($1)" \
552 "$LINUX/$file" 2>/dev/null
553 rc=$?
554 if test $rc -eq 0; then
555 export=1
556 break;
557 fi
558 done
559 if test $export -eq 0; then :
560 $4
561 else :
562 $3
563 fi
564 else :
565 $3
566 fi
567 ])
568
569 dnl #
570 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
571 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
572 dnl # is called if not compiling for builtin
573 dnl #
574 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
575 ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
576 if test $rc -ne 0; then :
577 $6
578 else
579 if test "x$enable_linux_builtin" != xyes; then
580 ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
581 fi
582 if test $rc -ne 0; then :
583 $6
584 else :
585 $5
586 fi
587 fi
588 ])