config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         AM_COND_IF([BUILD_LINUX], [
   6                 dnl # Setup the kernel build environment.
   7                 ZFS_AC_KERNEL
   8                 ZFS_AC_QAT
   9
  10                 dnl # Sanity checks for module building and CONFIG_* defines
  11                 ZFS_AC_KERNEL_CONFIG_DEFINED
  12                 ZFS_AC_MODULE_SYMVERS
  13
  14                 dnl # Sequential ZFS_LINUX_TRY_COMPILE tests
  15                 ZFS_AC_KERNEL_FPU_HEADER
  16                 ZFS_AC_KERNEL_OBJTOOL_HEADER
  17                 ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  18                 ZFS_AC_KERNEL_MISC_MINOR
  19                 ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  20
  21                 dnl # Parallel ZFS_LINUX_TEST_SRC / ZFS_LINUX_TEST_RESULT tests
  22                 ZFS_AC_KERNEL_TEST_SRC
  23                 ZFS_AC_KERNEL_TEST_RESULT
  24
  25                 AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  26                         KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
  27                 ])
  28
  29                 AC_SUBST(KERNEL_MAKE)
  30         ])
  31 ])
  32
  33 dnl #
  34 dnl # Generate and compile all of the kernel API test cases to determine
  35 dnl # which interfaces are available.  By invoking the kernel build system
  36 dnl # only once the compilation can be done in parallel significantly
  37 dnl # speeding up the process.
  38 dnl #
  39 AC_DEFUN([ZFS_AC_KERNEL_TEST_SRC], [
  40         ZFS_AC_KERNEL_SRC_OBJTOOL
  41         ZFS_AC_KERNEL_SRC_GLOBAL_PAGE_STATE
  42         ZFS_AC_KERNEL_SRC_ACCESS_OK_TYPE
  43         ZFS_AC_KERNEL_SRC_PDE_DATA
  44         ZFS_AC_KERNEL_SRC_FALLOCATE
  45         ZFS_AC_KERNEL_SRC_FADVISE
  46         ZFS_AC_KERNEL_SRC_GENERIC_FADVISE
  47         ZFS_AC_KERNEL_SRC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  48         ZFS_AC_KERNEL_SRC_RWSEM
  49         ZFS_AC_KERNEL_SRC_SCHED
  50         ZFS_AC_KERNEL_SRC_USLEEP_RANGE
  51         ZFS_AC_KERNEL_SRC_KMEM_CACHE
  52         ZFS_AC_KERNEL_SRC_KVMALLOC
  53         ZFS_AC_KERNEL_SRC_VMALLOC_PAGE_KERNEL
  54         ZFS_AC_KERNEL_SRC_WAIT
  55         ZFS_AC_KERNEL_SRC_INODE_TIMES
  56         ZFS_AC_KERNEL_SRC_INODE_LOCK
  57         ZFS_AC_KERNEL_SRC_GROUP_INFO_GID
  58         ZFS_AC_KERNEL_SRC_RW
  59         ZFS_AC_KERNEL_SRC_TIMER_SETUP
  60         ZFS_AC_KERNEL_SRC_SUPER_USER_NS
  61         ZFS_AC_KERNEL_SRC_PROC_OPERATIONS
  62         ZFS_AC_KERNEL_SRC_BLOCK_DEVICE_OPERATIONS
  63         ZFS_AC_KERNEL_SRC_BIO
  64         ZFS_AC_KERNEL_SRC_BLKDEV
  65         ZFS_AC_KERNEL_SRC_BLK_QUEUE
  66         ZFS_AC_KERNEL_SRC_GENHD_FLAGS
  67         ZFS_AC_KERNEL_SRC_REVALIDATE_DISK
  68         ZFS_AC_KERNEL_SRC_GET_DISK_RO
  69         ZFS_AC_KERNEL_SRC_GENERIC_READLINK_GLOBAL
  70         ZFS_AC_KERNEL_SRC_DISCARD_GRANULARITY
  71         ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE
  72         ZFS_AC_KERNEL_SRC_XATTR
  73         ZFS_AC_KERNEL_SRC_ACL
  74         ZFS_AC_KERNEL_SRC_INODE_GETATTR
  75         ZFS_AC_KERNEL_SRC_INODE_SET_FLAGS
  76         ZFS_AC_KERNEL_SRC_INODE_SET_IVERSION
  77         ZFS_AC_KERNEL_SRC_SHOW_OPTIONS
  78         ZFS_AC_KERNEL_SRC_FILE_INODE
  79         ZFS_AC_KERNEL_SRC_FILE_DENTRY
  80         ZFS_AC_KERNEL_SRC_FSYNC
  81         ZFS_AC_KERNEL_SRC_AIO_FSYNC
  82         ZFS_AC_KERNEL_SRC_EVICT_INODE
  83         ZFS_AC_KERNEL_SRC_DIRTY_INODE
  84         ZFS_AC_KERNEL_SRC_SHRINKER
  85         ZFS_AC_KERNEL_SRC_MKDIR
  86         ZFS_AC_KERNEL_SRC_LOOKUP_FLAGS
  87         ZFS_AC_KERNEL_SRC_CREATE
  88         ZFS_AC_KERNEL_SRC_PERMISSION
  89         ZFS_AC_KERNEL_SRC_GET_LINK
  90         ZFS_AC_KERNEL_SRC_PUT_LINK
  91         ZFS_AC_KERNEL_SRC_TMPFILE
  92         ZFS_AC_KERNEL_SRC_AUTOMOUNT
  93         ZFS_AC_KERNEL_SRC_ENCODE_FH_WITH_INODE
  94         ZFS_AC_KERNEL_SRC_COMMIT_METADATA
  95         ZFS_AC_KERNEL_SRC_CLEAR_INODE
  96         ZFS_AC_KERNEL_SRC_SETATTR_PREPARE
  97         ZFS_AC_KERNEL_SRC_INSERT_INODE_LOCKED
  98         ZFS_AC_KERNEL_SRC_DENTRY
  99         ZFS_AC_KERNEL_SRC_TRUNCATE_SETSIZE
 100         ZFS_AC_KERNEL_SRC_SECURITY_INODE
 101         ZFS_AC_KERNEL_SRC_FST_MOUNT
 102         ZFS_AC_KERNEL_SRC_BDI
 103         ZFS_AC_KERNEL_SRC_SET_NLINK
 104         ZFS_AC_KERNEL_SRC_SGET
 105         ZFS_AC_KERNEL_SRC_LSEEK_EXECUTE
 106         ZFS_AC_KERNEL_SRC_VFS_FILEMAP_DIRTY_FOLIO
 107         ZFS_AC_KERNEL_SRC_VFS_READ_FOLIO
 108         ZFS_AC_KERNEL_SRC_VFS_GETATTR
 109         ZFS_AC_KERNEL_SRC_VFS_FSYNC_2ARGS
 110         ZFS_AC_KERNEL_SRC_VFS_ITERATE
 111         ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO
 112         ZFS_AC_KERNEL_SRC_VFS_READPAGES
 113         ZFS_AC_KERNEL_SRC_VFS_SET_PAGE_DIRTY_NOBUFFERS
 114         ZFS_AC_KERNEL_SRC_VFS_RW_ITERATE
 115         ZFS_AC_KERNEL_SRC_VFS_GENERIC_WRITE_CHECKS
 116         ZFS_AC_KERNEL_SRC_VFS_IOV_ITER
 117         ZFS_AC_KERNEL_SRC_KMAP_ATOMIC_ARGS
 118         ZFS_AC_KERNEL_SRC_FOLLOW_DOWN_ONE
 119         ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN
 120         ZFS_AC_KERNEL_SRC_GENERIC_IO_ACCT
 121         ZFS_AC_KERNEL_SRC_FPU
 122         ZFS_AC_KERNEL_SRC_FMODE_T
 123         ZFS_AC_KERNEL_SRC_KUIDGID_T
 124         ZFS_AC_KERNEL_SRC_KUID_HELPERS
 125         ZFS_AC_KERNEL_SRC_RENAME
 126         ZFS_AC_KERNEL_SRC_CURRENT_TIME
 127         ZFS_AC_KERNEL_SRC_USERNS_CAPABILITIES
 128         ZFS_AC_KERNEL_SRC_IN_COMPAT_SYSCALL
 129         ZFS_AC_KERNEL_SRC_KTIME
 130         ZFS_AC_KERNEL_SRC_TOTALRAM_PAGES_FUNC
 131         ZFS_AC_KERNEL_SRC_TOTALHIGH_PAGES
 132         ZFS_AC_KERNEL_SRC_KSTRTOUL
 133         ZFS_AC_KERNEL_SRC_PERCPU
 134         ZFS_AC_KERNEL_SRC_CPU_HOTPLUG
 135         ZFS_AC_KERNEL_SRC_GENERIC_FILLATTR_USERNS
 136         ZFS_AC_KERNEL_SRC_MKNOD
 137         ZFS_AC_KERNEL_SRC_SYMLINK
 138         ZFS_AC_KERNEL_SRC_BIO_MAX_SEGS
 139         ZFS_AC_KERNEL_SRC_SIGNAL_STOP
 140         ZFS_AC_KERNEL_SRC_SIGINFO
 141         ZFS_AC_KERNEL_SRC_SYSFS
 142         ZFS_AC_KERNEL_SRC_SET_SPECIAL_STATE
 143         ZFS_AC_KERNEL_SRC_STANDALONE_LINUX_STDARG
 144         ZFS_AC_KERNEL_SRC_PAGEMAP_FOLIO_WAIT_BIT
 145         ZFS_AC_KERNEL_SRC_ADD_DISK
 146         ZFS_AC_KERNEL_SRC_KTHREAD
 147         ZFS_AC_KERNEL_SRC_ZERO_PAGE
 148         ZFS_AC_KERNEL_SRC___COPY_FROM_USER_INATOMIC
 149         ZFS_AC_KERNEL_SRC_USER_NS_COMMON_INUM
 150
 151         AC_MSG_CHECKING([for available kernel interfaces])
 152         ZFS_LINUX_TEST_COMPILE_ALL([kabi])
 153         AC_MSG_RESULT([done])
 154 ])
 155
 156 dnl #
 157 dnl # Check results of kernel interface tests.
 158 dnl #
 159 AC_DEFUN([ZFS_AC_KERNEL_TEST_RESULT], [
 160         ZFS_AC_KERNEL_ACCESS_OK_TYPE
 161         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 162         ZFS_AC_KERNEL_OBJTOOL
 163         ZFS_AC_KERNEL_PDE_DATA
 164         ZFS_AC_KERNEL_FALLOCATE
 165         ZFS_AC_KERNEL_FADVISE
 166         ZFS_AC_KERNEL_GENERIC_FADVISE
 167         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
 168         ZFS_AC_KERNEL_RWSEM
 169         ZFS_AC_KERNEL_SCHED
 170         ZFS_AC_KERNEL_USLEEP_RANGE
 171         ZFS_AC_KERNEL_KMEM_CACHE
 172         ZFS_AC_KERNEL_KVMALLOC
 173         ZFS_AC_KERNEL_VMALLOC_PAGE_KERNEL
 174         ZFS_AC_KERNEL_WAIT
 175         ZFS_AC_KERNEL_INODE_TIMES
 176         ZFS_AC_KERNEL_INODE_LOCK
 177         ZFS_AC_KERNEL_GROUP_INFO_GID
 178         ZFS_AC_KERNEL_RW
 179         ZFS_AC_KERNEL_TIMER_SETUP
 180         ZFS_AC_KERNEL_SUPER_USER_NS
 181         ZFS_AC_KERNEL_PROC_OPERATIONS
 182         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS
 183         ZFS_AC_KERNEL_BIO
 184         ZFS_AC_KERNEL_BLKDEV
 185         ZFS_AC_KERNEL_BLK_QUEUE
 186         ZFS_AC_KERNEL_GENHD_FLAGS
 187         ZFS_AC_KERNEL_REVALIDATE_DISK
 188         ZFS_AC_KERNEL_GET_DISK_RO
 189         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
 190         ZFS_AC_KERNEL_DISCARD_GRANULARITY
 191         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
 192         ZFS_AC_KERNEL_XATTR
 193         ZFS_AC_KERNEL_ACL
 194         ZFS_AC_KERNEL_INODE_GETATTR
 195         ZFS_AC_KERNEL_INODE_SET_FLAGS
 196         ZFS_AC_KERNEL_INODE_SET_IVERSION
 197         ZFS_AC_KERNEL_SHOW_OPTIONS
 198         ZFS_AC_KERNEL_FILE_INODE
 199         ZFS_AC_KERNEL_FILE_DENTRY
 200         ZFS_AC_KERNEL_FSYNC
 201         ZFS_AC_KERNEL_AIO_FSYNC
 202         ZFS_AC_KERNEL_EVICT_INODE
 203         ZFS_AC_KERNEL_DIRTY_INODE
 204         ZFS_AC_KERNEL_SHRINKER
 205         ZFS_AC_KERNEL_MKDIR
 206         ZFS_AC_KERNEL_LOOKUP_FLAGS
 207         ZFS_AC_KERNEL_CREATE
 208         ZFS_AC_KERNEL_PERMISSION
 209         ZFS_AC_KERNEL_GET_LINK
 210         ZFS_AC_KERNEL_PUT_LINK
 211         ZFS_AC_KERNEL_TMPFILE
 212         ZFS_AC_KERNEL_AUTOMOUNT
 213         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 214         ZFS_AC_KERNEL_COMMIT_METADATA
 215         ZFS_AC_KERNEL_CLEAR_INODE
 216         ZFS_AC_KERNEL_SETATTR_PREPARE
 217         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 218         ZFS_AC_KERNEL_DENTRY
 219         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 220         ZFS_AC_KERNEL_SECURITY_INODE
 221         ZFS_AC_KERNEL_FST_MOUNT
 222         ZFS_AC_KERNEL_BDI
 223         ZFS_AC_KERNEL_SET_NLINK
 224         ZFS_AC_KERNEL_SGET
 225         ZFS_AC_KERNEL_LSEEK_EXECUTE
 226         ZFS_AC_KERNEL_VFS_FILEMAP_DIRTY_FOLIO
 227         ZFS_AC_KERNEL_VFS_READ_FOLIO
 228         ZFS_AC_KERNEL_VFS_GETATTR
 229         ZFS_AC_KERNEL_VFS_FSYNC_2ARGS
 230         ZFS_AC_KERNEL_VFS_ITERATE
 231         ZFS_AC_KERNEL_VFS_DIRECT_IO
 232         ZFS_AC_KERNEL_VFS_READPAGES
 233         ZFS_AC_KERNEL_VFS_SET_PAGE_DIRTY_NOBUFFERS
 234         ZFS_AC_KERNEL_VFS_RW_ITERATE
 235         ZFS_AC_KERNEL_VFS_GENERIC_WRITE_CHECKS
 236         ZFS_AC_KERNEL_VFS_IOV_ITER
 237         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 238         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 239         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 240         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 241         ZFS_AC_KERNEL_FPU
 242         ZFS_AC_KERNEL_FMODE_T
 243         ZFS_AC_KERNEL_KUIDGID_T
 244         ZFS_AC_KERNEL_KUID_HELPERS
 245         ZFS_AC_KERNEL_RENAME
 246         ZFS_AC_KERNEL_CURRENT_TIME
 247         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 248         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 249         ZFS_AC_KERNEL_KTIME
 250         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 251         ZFS_AC_KERNEL_TOTALHIGH_PAGES
 252         ZFS_AC_KERNEL_KSTRTOUL
 253         ZFS_AC_KERNEL_PERCPU
 254         ZFS_AC_KERNEL_CPU_HOTPLUG
 255         ZFS_AC_KERNEL_GENERIC_FILLATTR_USERNS
 256         ZFS_AC_KERNEL_MKNOD
 257         ZFS_AC_KERNEL_SYMLINK
 258         ZFS_AC_KERNEL_BIO_MAX_SEGS
 259         ZFS_AC_KERNEL_SIGNAL_STOP
 260         ZFS_AC_KERNEL_SIGINFO
 261         ZFS_AC_KERNEL_SYSFS
 262         ZFS_AC_KERNEL_SET_SPECIAL_STATE
 263         ZFS_AC_KERNEL_STANDALONE_LINUX_STDARG
 264         ZFS_AC_KERNEL_PAGEMAP_FOLIO_WAIT_BIT
 265         ZFS_AC_KERNEL_ADD_DISK
 266         ZFS_AC_KERNEL_KTHREAD
 267         ZFS_AC_KERNEL_ZERO_PAGE
 268         ZFS_AC_KERNEL___COPY_FROM_USER_INATOMIC
 269         ZFS_AC_KERNEL_USER_NS_COMMON_INUM
 270 ])
 271
 272 dnl #
 273 dnl # Detect name used for Module.symvers file in kernel
 274 dnl #
 275 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 276         modpost=$LINUX/scripts/Makefile.modpost
 277         AC_MSG_CHECKING([kernel file name for module symbols])
 278         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 279                 AS_IF([grep -q Modules.symvers $modpost], [
 280                         LINUX_SYMBOLS=Modules.symvers
 281                 ], [
 282                         LINUX_SYMBOLS=Module.symvers
 283                 ])
 284
 285                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 286                         AC_MSG_ERROR([
 287         *** Please make sure the kernel devel package for your distribution
 288         *** is installed.  If you are building with a custom kernel, make sure
 289         *** the kernel is configured, built, and the '--with-linux=PATH'
 290         *** configure option refers to the location of the kernel source.
 291                         ])
 292                 ])
 293         ], [
 294                 LINUX_SYMBOLS=NONE
 295         ])
 296         AC_MSG_RESULT($LINUX_SYMBOLS)
 297         AC_SUBST(LINUX_SYMBOLS)
 298 ])
 299
 300 dnl #
 301 dnl # Detect the kernel to be built against
 302 dnl #
 303 dnl # Most modern Linux distributions have separate locations for bare
 304 dnl # source (source) and prebuilt (build) files. Additionally, there are
 305 dnl # `source` and `build` symlinks in `/lib/modules/$(KERNEL_VERSION)`
 306 dnl # pointing to them. The directory search order is now:
 307 dnl #
 308 dnl # - `configure` command line values if both `--with-linux` and
 309 dnl #   `--with-linux-obj` were defined
 310 dnl #
 311 dnl # - If only `--with-linux` was defined, `--with-linux-obj` is assumed
 312 dnl #   to have the same value as `--with-linux`
 313 dnl #
 314 dnl # - If neither `--with-linux` nor `--with-linux-obj` were defined
 315 dnl #   autodetection is used:
 316 dnl #
 317 dnl #   - `/lib/modules/$(uname -r)/{source,build}` respectively, if exist.
 318 dnl #
 319 dnl #   - If only `/lib/modules/$(uname -r)/build` exists, it is assumed
 320 dnl #     to be both source and build directory.
 321 dnl #
 322 dnl #   - The first directory in `/lib/modules` with the highest version
 323 dnl #     number according to `sort -V` which contains both `source` and
 324 dnl #     `build` symlinks/directories. If module directory contains only
 325 dnl #     `build` component, it is assumed to be both source and build
 326 dnl #     directory.
 327 dnl #
 328 dnl #   - Last resort: the first directory matching `/usr/src/kernels/*`
 329 dnl #     and `/usr/src/linux-*` with the highest version number according
 330 dnl #     to `sort -V` is assumed to be both source and build directory.
 331 dnl #
 332 AC_DEFUN([ZFS_AC_KERNEL], [
 333         AC_ARG_WITH([linux],
 334                 AS_HELP_STRING([--with-linux=PATH],
 335                 [Path to kernel source]),
 336                 [kernelsrc="$withval"])
 337
 338         AC_ARG_WITH(linux-obj,
 339                 AS_HELP_STRING([--with-linux-obj=PATH],
 340                 [Path to kernel build objects]),
 341                 [kernelbuild="$withval"])
 342
 343         AC_MSG_CHECKING([kernel source and build directories])
 344         AS_IF([test -n "$kernelsrc" && test -z "$kernelbuild"], [
 345                 kernelbuild="$kernelsrc"
 346         ], [test -z "$kernelsrc"], [
 347                 AS_IF([test -e "/lib/modules/$(uname -r)/source" && \
 348                        test -e "/lib/modules/$(uname -r)/build"], [
 349                         src="/lib/modules/$(uname -r)/source"
 350                         build="/lib/modules/$(uname -r)/build"
 351                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 352                         build="/lib/modules/$(uname -r)/build"
 353                         src="$build"
 354                 ], [
 355                         src=
 356
 357                         for d in $(ls -1d /lib/modules/* 2>/dev/null | sort -Vr); do
 358                                 if test -e "$d/source" && test -e "$d/build"; then
 359                                         src="$d/source"
 360                                         build="$d/build"
 361                                         break
 362                                 fi
 363
 364                                 if test -e "$d/build"; then
 365                                         src="$d/build"
 366                                         build="$d/build"
 367                                         break
 368                                 fi
 369                         done
 370
 371                         # the least reliable method
 372                         if test -z "$src"; then
 373                                 src=$(ls -1d /usr/src/kernels/* /usr/src/linux-* \
 374                                       2>/dev/null | grep -v obj | sort -Vr | head -1)
 375                                 build="$src"
 376                         fi
 377                 ])
 378
 379                 AS_IF([test -n "$src" && test -e "$src"], [
 380                         kernelsrc=$(readlink -e "$src")
 381                 ], [
 382                         kernelsrc="[Not found]"
 383                 ])
 384                 AS_IF([test -n "$build" && test -e "$build"], [
 385                         kernelbuild=$(readlink -e "$build")
 386                 ], [
 387                         kernelbuild="[Not found]"
 388                 ])
 389         ], [
 390                 AS_IF([test "$kernelsrc" = "NONE"], [
 391                         kernsrcver=NONE
 392                 ])
 393                 withlinux=yes
 394         ])
 395
 396         AC_MSG_RESULT([done])
 397         AC_MSG_CHECKING([kernel source directory])
 398         AC_MSG_RESULT([$kernelsrc])
 399         AC_MSG_CHECKING([kernel build directory])
 400         AC_MSG_RESULT([$kernelbuild])
 401         AS_IF([test ! -d "$kernelsrc" || test ! -d "$kernelbuild"], [
 402                 AC_MSG_ERROR([
 403         *** Please make sure the kernel devel package for your distribution
 404         *** is installed and then try again.  If that fails, you can specify the
 405         *** location of the kernel source and build with the '--with-linux=PATH' and
 406         *** '--with-linux-obj=PATH' options respectively.])
 407         ])
 408
 409         AC_MSG_CHECKING([kernel source version])
 410         utsrelease1=$kernelbuild/include/linux/version.h
 411         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 412         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 413         AS_IF([test -r $utsrelease1 && grep -qF UTS_RELEASE $utsrelease1], [
 414                 utsrelease=$utsrelease1
 415         ], [test -r $utsrelease2 && grep -qF UTS_RELEASE $utsrelease2], [
 416                 utsrelease=$utsrelease2
 417         ], [test -r $utsrelease3 && grep -qF UTS_RELEASE $utsrelease3], [
 418                 utsrelease=$utsrelease3
 419         ])
 420
 421         AS_IF([test -n "$utsrelease"], [
 422                 kernsrcver=$($AWK '/UTS_RELEASE/ { gsub(/"/, "", $[3]); print $[3] }' $utsrelease)
 423                 AS_IF([test -z "$kernsrcver"], [
 424                         AC_MSG_RESULT([Not found])
 425                         AC_MSG_ERROR([
 426         *** Cannot determine kernel version.
 427                         ])
 428                 ])
 429         ], [
 430                 AC_MSG_RESULT([Not found])
 431                 if test "x$enable_linux_builtin" != xyes; then
 432                         AC_MSG_ERROR([
 433         *** Cannot find UTS_RELEASE definition.
 434                         ])
 435                 else
 436                         AC_MSG_ERROR([
 437         *** Cannot find UTS_RELEASE definition.
 438         *** Please run 'make prepare' inside the kernel source tree.])
 439                 fi
 440         ])
 441
 442         AC_MSG_RESULT([$kernsrcver])
 443
 444         AS_VERSION_COMPARE([$kernsrcver], [$ZFS_META_KVER_MIN], [
 445                  AC_MSG_ERROR([
 446         *** Cannot build against kernel version $kernsrcver.
 447         *** The minimum supported kernel version is $ZFS_META_KVER_MIN.
 448                 ])
 449         ])
 450
 451         LINUX=${kernelsrc}
 452         LINUX_OBJ=${kernelbuild}
 453         LINUX_VERSION=${kernsrcver}
 454
 455         AC_SUBST(LINUX)
 456         AC_SUBST(LINUX_OBJ)
 457         AC_SUBST(LINUX_VERSION)
 458 ])
 459
 460 dnl #
 461 dnl # Detect the QAT module to be built against, QAT provides hardware
 462 dnl # acceleration for data compression:
 463 dnl #
 464 dnl # https://01.org/intel-quickassist-technology
 465 dnl #
 466 dnl # 1) Download and install QAT driver from the above link
 467 dnl # 2) Start QAT driver in your system:
 468 dnl #    service qat_service start
 469 dnl # 3) Enable QAT in ZFS, e.g.:
 470 dnl #    ./configure --with-qat=<qat-driver-path>/QAT1.6
 471 dnl #    make
 472 dnl # 4) Set GZIP compression in ZFS dataset:
 473 dnl #    zfs set compression = gzip <dataset>
 474 dnl #
 475 dnl # Then the data written to this ZFS pool is compressed by QAT accelerator
 476 dnl # automatically, and de-compressed by QAT when read from the pool.
 477 dnl #
 478 dnl # 1) Get QAT hardware statistics with:
 479 dnl #    cat /proc/icp_dh895xcc_dev/qat
 480 dnl # 2) To disable QAT:
 481 dnl #    insmod zfs.ko zfs_qat_disable=1
 482 dnl #
 483 AC_DEFUN([ZFS_AC_QAT], [
 484         AC_ARG_WITH([qat],
 485                 AS_HELP_STRING([--with-qat=PATH],
 486                 [Path to qat source]),
 487                 AS_IF([test "$withval" = "yes"],
 488                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 489                         [qatsrc="$withval"]))
 490
 491         AC_ARG_WITH([qat-obj],
 492                 AS_HELP_STRING([--with-qat-obj=PATH],
 493                 [Path to qat build objects]),
 494                 [qatbuild="$withval"])
 495
 496         AS_IF([test ! -z "${qatsrc}"], [
 497                 AC_MSG_CHECKING([qat source directory])
 498                 AC_MSG_RESULT([$qatsrc])
 499                 QAT_SRC="${qatsrc}/quickassist"
 500                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 501                         AC_MSG_ERROR([
 502         *** Please make sure the qat driver package is installed
 503         *** and specify the location of the qat source with the
 504         *** '--with-qat=PATH' option then try again. Failed to
 505         *** find cpa.h in:
 506         ${QAT_SRC}/include])
 507                 ])
 508         ])
 509
 510         AS_IF([test ! -z "${qatsrc}"], [
 511                 AC_MSG_CHECKING([qat build directory])
 512                 AS_IF([test -z "$qatbuild"], [
 513                         qatbuild="${qatsrc}/build"
 514                 ])
 515
 516                 AC_MSG_RESULT([$qatbuild])
 517                 QAT_OBJ=${qatbuild}
 518                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 519                         AC_MSG_ERROR([
 520         *** Please make sure the qat driver is installed then try again.
 521         *** Failed to find icp_qa_al.ko or qat_api.ko in:
 522         $QAT_OBJ])
 523                 ])
 524
 525                 AC_SUBST(QAT_SRC)
 526                 AC_SUBST(QAT_OBJ)
 527
 528                 AC_DEFINE(HAVE_QAT, 1,
 529                 [qat is enabled and existed])
 530         ])
 531
 532         dnl #
 533         dnl # Detect the name used for the QAT Module.symvers file.
 534         dnl #
 535         AS_IF([test ! -z "${qatsrc}"], [
 536                 AC_MSG_CHECKING([qat file for module symbols])
 537                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 538
 539                 AS_IF([test -r $QAT_SYMBOLS], [
 540                         AC_MSG_RESULT([$QAT_SYMBOLS])
 541                         AC_SUBST(QAT_SYMBOLS)
 542                 ],[
 543                         AC_MSG_ERROR([
 544         *** Please make sure the qat driver is installed then try again.
 545         *** Failed to find Module.symvers in:
 546         $QAT_SYMBOLS
 547                         ])
 548                 ])
 549         ])
 550 ])
 551
 552 dnl #
 553 dnl # ZFS_LINUX_CONFTEST_H
 554 dnl #
 555 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 556 test -d build/$2 || mkdir -p build/$2
 557 cat - <<_ACEOF >build/$2/$2.h
 558 $1
 559 _ACEOF
 560 ])
 561
 562 dnl #
 563 dnl # ZFS_LINUX_CONFTEST_C
 564 dnl #
 565 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 566 test -d build/$2 || mkdir -p build/$2
 567 cat confdefs.h - <<_ACEOF >build/$2/$2.c
 568 $1
 569 _ACEOF
 570 ])
 571
 572 dnl #
 573 dnl # ZFS_LINUX_CONFTEST_MAKEFILE
 574 dnl #
 575 dnl # $1 - test case name
 576 dnl # $2 - add to top-level Makefile
 577 dnl # $3 - additional build flags
 578 dnl #
 579 AC_DEFUN([ZFS_LINUX_CONFTEST_MAKEFILE], [
 580         test -d build || mkdir -p build
 581         test -d build/$1 || mkdir -p build/$1
 582
 583         file=build/$1/Makefile
 584
 585         dnl # Example command line to manually build source.
 586         cat - <<_ACEOF >$file
 587 # Example command line to manually build source
 588 # make modules -C $LINUX_OBJ $ARCH_UM M=$PWD/build/$1
 589
 590 ccflags-y := -Werror $FRAME_LARGER_THAN
 591 _ACEOF
 592
 593         dnl # Additional custom CFLAGS as requested.
 594         m4_ifval($3, [echo "ccflags-y += $3" >>$file], [])
 595
 596         dnl # Test case source
 597         echo "obj-m := $1.o" >>$file
 598
 599         AS_IF([test "x$2" = "xyes"], [echo "obj-m += $1/" >>build/Makefile], [])
 600 ])
 601
 602 dnl #
 603 dnl # ZFS_LINUX_TEST_PROGRAM(C)([PROLOGUE], [BODY])
 604 dnl #
 605 m4_define([ZFS_LINUX_TEST_PROGRAM], [
 606 #include <linux/module.h>
 607 $1
 608
 609 int
 610 main (void)
 611 {
 612 $2
 613         ;
 614         return 0;
 615 }
 616
 617 MODULE_DESCRIPTION("conftest");
 618 MODULE_AUTHOR(ZFS_META_AUTHOR);
 619 MODULE_VERSION(ZFS_META_VERSION "-" ZFS_META_RELEASE);
 620 MODULE_LICENSE($3);
 621 ])
 622
 623 dnl #
 624 dnl # ZFS_LINUX_TEST_REMOVE
 625 dnl #
 626 dnl # Removes the specified test source and results.
 627 dnl #
 628 AC_DEFUN([ZFS_LINUX_TEST_REMOVE], [
 629         test -d build/$1 && rm -Rf build/$1
 630         test -f build/Makefile && sed '/$1/d' build/Makefile
 631 ])
 632
 633 dnl #
 634 dnl # ZFS_LINUX_COMPILE
 635 dnl #
 636 dnl # $1 - build dir
 637 dnl # $2 - test command
 638 dnl # $3 - pass command
 639 dnl # $4 - fail command
 640 dnl # $5 - set KBUILD_MODPOST_NOFINAL='yes'
 641 dnl # $6 - set KBUILD_MODPOST_WARN='yes'
 642 dnl #
 643 dnl # Used internally by ZFS_LINUX_TEST_{COMPILE,MODPOST}
 644 dnl #
 645 AC_DEFUN([ZFS_LINUX_COMPILE], [
 646         AC_ARG_VAR([KERNEL_CC], [C compiler for
 647                 building kernel modules])
 648         AC_ARG_VAR([KERNEL_LD], [Linker for
 649                 building kernel modules])
 650         AC_ARG_VAR([KERNEL_LLVM], [Binary option to
 651                 build kernel modules with LLVM/CLANG toolchain])
 652         AC_TRY_COMMAND([
 653             KBUILD_MODPOST_NOFINAL="$5" KBUILD_MODPOST_WARN="$6"
 654             make modules -k -j$TEST_JOBS ${KERNEL_CC:+CC=$KERNEL_CC}
 655             ${KERNEL_LD:+LD=$KERNEL_LD} ${KERNEL_LLVM:+LLVM=$KERNEL_LLVM}
 656             CONFIG_MODULES=y CFLAGS_MODULE=-DCONFIG_MODULES
 657             -C $LINUX_OBJ $ARCH_UM M=$PWD/$1 >$1/build.log 2>&1])
 658         AS_IF([AC_TRY_COMMAND([$2])], [$3], [$4])
 659 ])
 660
 661 dnl #
 662 dnl # ZFS_LINUX_TEST_COMPILE
 663 dnl #
 664 dnl # Perform a full compile excluding the final modpost phase.
 665 dnl #
 666 AC_DEFUN([ZFS_LINUX_TEST_COMPILE], [
 667         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 668                 mv $2/Makefile $2/Makefile.compile.$1
 669                 mv $2/build.log $2/build.log.$1
 670         ],[
 671                 AC_MSG_ERROR([
 672         *** Unable to compile test source to determine kernel interfaces.])
 673         ], [yes], [])
 674 ])
 675
 676 dnl #
 677 dnl # ZFS_LINUX_TEST_MODPOST
 678 dnl #
 679 dnl # Perform a full compile including the modpost phase.  This may
 680 dnl # be an incremental build if the objects have already been built.
 681 dnl #
 682 AC_DEFUN([ZFS_LINUX_TEST_MODPOST], [
 683         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 684                 mv $2/Makefile $2/Makefile.modpost.$1
 685                 cat $2/build.log >>build/build.log.$1
 686         ],[
 687                 AC_MSG_ERROR([
 688         *** Unable to modpost test source to determine kernel interfaces.])
 689         ], [], [yes])
 690 ])
 691
 692 dnl #
 693 dnl # Perform the compilation of the test cases in two phases.
 694 dnl #
 695 dnl # Phase 1) attempt to build the object files for all of the tests
 696 dnl #          defined by the ZFS_LINUX_TEST_SRC macro.  But do not
 697 dnl #          perform the final modpost stage.
 698 dnl #
 699 dnl # Phase 2) disable all tests which failed the initial compilation,
 700 dnl #          then invoke the final modpost step for the remaining tests.
 701 dnl #
 702 dnl # This allows us efficiently build the test cases in parallel while
 703 dnl # remaining resilient to build failures which are expected when
 704 dnl # detecting the available kernel interfaces.
 705 dnl #
 706 dnl # The maximum allowed parallelism can be controlled by setting the
 707 dnl # TEST_JOBS environment variable.  Otherwise, it default to $(nproc).
 708 dnl #
 709 AC_DEFUN([ZFS_LINUX_TEST_COMPILE_ALL], [
 710         dnl # Phase 1 - Compilation only, final linking is skipped.
 711         ZFS_LINUX_TEST_COMPILE([$1], [build])
 712
 713         dnl #
 714         dnl # Phase 2 - When building external modules disable test cases
 715         dnl # which failed to compile and invoke modpost to verify the
 716         dnl # final linking.
 717         dnl #
 718         dnl # Test names suffixed with '_license' call modpost independently
 719         dnl # to ensure that a single incompatibility does not result in the
 720         dnl # modpost phase exiting early.  This check is not performed on
 721         dnl # every symbol since the majority are compatible and doing so
 722         dnl # would significantly slow down this phase.
 723         dnl #
 724         dnl # When configuring for builtin (--enable-linux-builtin)
 725         dnl # fake the linking step artificially create the expected .ko
 726         dnl # files for tests which did compile.  This is required for
 727         dnl # kernels which do not have loadable module support or have
 728         dnl # not yet been built.
 729         dnl #
 730         AS_IF([test "x$enable_linux_builtin" = "xno"], [
 731                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 732                     build/Makefile.compile.$1); do
 733                         name=${dir%/}
 734                         AS_IF([test -f build/$name/$name.o], [
 735                                 AS_IF([test "${name##*_}" = "license"], [
 736                                         ZFS_LINUX_TEST_MODPOST([$1],
 737                                             [build/$name])
 738                                         echo "obj-n += $dir" >>build/Makefile
 739                                 ], [
 740                                         echo "obj-m += $dir" >>build/Makefile
 741                                 ])
 742                         ], [
 743                                 echo "obj-n += $dir" >>build/Makefile
 744                         ])
 745                 done
 746
 747                 ZFS_LINUX_TEST_MODPOST([$1], [build])
 748         ], [
 749                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 750                     build/Makefile.compile.$1); do
 751                         name=${dir%/}
 752                         AS_IF([test -f build/$name/$name.o], [
 753                                 touch build/$name/$name.ko
 754                         ])
 755                 done
 756         ])
 757 ])
 758
 759 dnl #
 760 dnl # ZFS_LINUX_TEST_SRC
 761 dnl #
 762 dnl # $1 - name
 763 dnl # $2 - global
 764 dnl # $3 - source
 765 dnl # $4 - extra cflags
 766 dnl # $5 - check license-compatibility
 767 dnl #
 768 dnl # Check if the test source is buildable at all and then if it is
 769 dnl # license compatible.
 770 dnl #
 771 dnl # N.B because all of the test cases are compiled in parallel they
 772 dnl # must never depend on the results of previous tests.  Each test
 773 dnl # needs to be entirely independent.
 774 dnl #
 775 AC_DEFUN([ZFS_LINUX_TEST_SRC], [
 776         ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM([[$2]], [[$3]],
 777             [["Dual BSD/GPL"]])], [$1])
 778         ZFS_LINUX_CONFTEST_MAKEFILE([$1], [yes], [$4])
 779
 780         AS_IF([ test -n "$5" ], [
 781                 ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM(
 782                     [[$2]], [[$3]], [[$5]])], [$1_license])
 783                 ZFS_LINUX_CONFTEST_MAKEFILE([$1_license], [yes], [$4])
 784         ])
 785 ])
 786
 787 dnl #
 788 dnl # ZFS_LINUX_TEST_RESULT
 789 dnl #
 790 dnl # $1 - name of a test source (ZFS_LINUX_TEST_SRC)
 791 dnl # $2 - run on success (valid .ko generated)
 792 dnl # $3 - run on failure (unable to compile)
 793 dnl #
 794 AC_DEFUN([ZFS_LINUX_TEST_RESULT], [
 795         AS_IF([test -d build/$1], [
 796                 AS_IF([test -f build/$1/$1.ko], [$2], [$3])
 797         ], [
 798                 AC_MSG_ERROR([
 799         *** No matching source for the "$1" test, check that
 800         *** both the test source and result macros refer to the same name.
 801                 ])
 802         ])
 803 ])
 804
 805 dnl #
 806 dnl # ZFS_LINUX_TEST_ERROR
 807 dnl #
 808 dnl # Generic error message which can be used when none of the expected
 809 dnl # kernel interfaces were detected.
 810 dnl #
 811 AC_DEFUN([ZFS_LINUX_TEST_ERROR], [
 812         AC_MSG_ERROR([
 813         *** None of the expected "$1" interfaces were detected.
 814         *** This may be because your kernel version is newer than what is
 815         *** supported, or you are using a patched custom kernel with
 816         *** incompatible modifications.
 817         ***
 818         *** ZFS Version: $ZFS_META_ALIAS
 819         *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
 820         ])
 821 ])
 822
 823 dnl #
 824 dnl # ZFS_LINUX_TEST_RESULT_SYMBOL
 825 dnl #
 826 dnl # Like ZFS_LINUX_TEST_RESULT except ZFS_CHECK_SYMBOL_EXPORT is called to
 827 dnl # verify symbol exports, unless --enable-linux-builtin was provided to
 828 dnl # configure.
 829 dnl #
 830 AC_DEFUN([ZFS_LINUX_TEST_RESULT_SYMBOL], [
 831         AS_IF([ ! test -f build/$1/$1.ko], [
 832                 $5
 833         ], [
 834                 AS_IF([test "x$enable_linux_builtin" != "xyes"], [
 835                         ZFS_CHECK_SYMBOL_EXPORT([$2], [$3], [$4], [$5])
 836                 ], [
 837                         $4
 838                 ])
 839         ])
 840 ])
 841
 842 dnl #
 843 dnl # ZFS_LINUX_COMPILE_IFELSE
 844 dnl #
 845 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 846         ZFS_LINUX_TEST_REMOVE([conftest])
 847
 848         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1], [conftest])])
 849         m4_ifvaln([$5], [ZFS_LINUX_CONFTEST_H([$5], [conftest])],
 850             [ZFS_LINUX_CONFTEST_H([], [conftest])])
 851
 852         ZFS_LINUX_CONFTEST_MAKEFILE([conftest], [no],
 853             [m4_ifvaln([$5], [-I$PWD/build/conftest], [])])
 854         ZFS_LINUX_COMPILE([build/conftest], [$2], [$3], [$4], [], [])
 855 ])
 856
 857 dnl #
 858 dnl # ZFS_LINUX_TRY_COMPILE
 859 dnl #
 860 dnl # $1 - global
 861 dnl # $2 - source
 862 dnl # $3 - run on success (valid .ko generated)
 863 dnl # $4 - run on failure (unable to compile)
 864 dnl #
 865 dnl # When configuring as builtin (--enable-linux-builtin) for kernels
 866 dnl # without loadable module support (CONFIG_MODULES=n) only the object
 867 dnl # file is created.  See ZFS_LINUX_TEST_COMPILE_ALL for details.
 868 dnl #
 869 AC_DEFUN([ZFS_LINUX_TRY_COMPILE], [
 870         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
 871                 ZFS_LINUX_COMPILE_IFELSE(
 872                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 873                     [[ZFS_META_LICENSE]])],
 874                     [test -f build/conftest/conftest.o], [$3], [$4])
 875         ], [
 876                 ZFS_LINUX_COMPILE_IFELSE(
 877                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 878                     [[ZFS_META_LICENSE]])],
 879                     [test -f build/conftest/conftest.ko], [$3], [$4])
 880         ])
 881 ])
 882
 883 dnl #
 884 dnl # ZFS_CHECK_SYMBOL_EXPORT
 885 dnl #
 886 dnl # Check if a symbol is exported on not by consulting the symbols
 887 dnl # file, or optionally the source code.
 888 dnl #
 889 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 890         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 891                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 892         rc=$?
 893         if test $rc -ne 0; then
 894                 export=0
 895                 for file in $2; do
 896                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 897                                 "$LINUX/$file" 2>/dev/null
 898                         rc=$?
 899                         if test $rc -eq 0; then
 900                                 export=1
 901                                 break;
 902                         fi
 903                 done
 904                 if test $export -eq 0; then :
 905                         $4
 906                 else :
 907                         $3
 908                 fi
 909         else :
 910                 $3
 911         fi
 912 ])
 913
 914 dnl #
 915 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 916 dnl #
 917 dnl # Like ZFS_LINUX_TRY_COMPILER except ZFS_CHECK_SYMBOL_EXPORT is called
 918 dnl # to verify symbol exports, unless --enable-linux-builtin was provided
 919 dnl # to configure.
 920 dnl #
 921 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 922         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 923         if test $rc -ne 0; then :
 924                 $6
 925         else
 926                 if test "x$enable_linux_builtin" != xyes; then
 927                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 928                 fi
 929                 if test $rc -ne 0; then :
 930                         $6
 931                 else :
 932                         $5
 933                 fi
 934         fi
 935 ])
 936
 937 dnl #
 938 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 939 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 940 dnl # provided via the fifth parameter
 941 dnl #
 942 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], [
 943         ZFS_LINUX_COMPILE_IFELSE(
 944             [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]], [[ZFS_META_LICENSE]])],
 945             [test -f build/conftest/conftest.ko],
 946             [$3], [$4], [$5])
 947 ])