config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  10         ZFS_AC_KERNEL_TYPE_FMODE_T
  11         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  12         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  13         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  14         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  15         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  16         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  17         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  18         ZFS_AC_KERNEL_BIO_EMPTY_BARRIER
  19         ZFS_AC_KERNEL_BIO_FAILFAST
  20         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  21         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  22         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  23         ZFS_AC_KERNEL_BIO_RW_SYNC
  24         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  25         ZFS_AC_KERNEL_REQ_SYNC
  26         ZFS_AC_KERNEL_BLK_END_REQUEST
  27         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  28         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  29         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  30         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  31         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  32         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  33         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  34         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  35         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_RQ_IS_SYNC
  42         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_SHOW_OPTIONS
  48         ZFS_AC_KERNEL_FSYNC
  49         ZFS_AC_KERNEL_EVICT_INODE
  50         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  51         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  52         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  53         ZFS_AC_KERNEL_FALLOCATE
  54         ZFS_AC_KERNEL_MKDIR_UMODE_T
  55         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  56         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  57         ZFS_AC_KERNEL_TRUNCATE_RANGE
  58         ZFS_AC_KERNEL_AUTOMOUNT
  59         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  60         ZFS_AC_KERNEL_COMMIT_METADATA
  61         ZFS_AC_KERNEL_CLEAR_INODE
  62         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  63         ZFS_AC_KERNEL_D_MAKE_ROOT
  64         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  65         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  66         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  67         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  68         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  69         ZFS_AC_KERNEL_MOUNT_NODEV
  70         ZFS_AC_KERNEL_SHRINK
  71         ZFS_AC_KERNEL_BDI
  72         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  73         ZFS_AC_KERNEL_SET_NLINK
  74         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  75         ZFS_AC_KERNEL_5ARG_SGET
  76
  77         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  78                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
  79         ])
  80         AC_SUBST(KERNELMAKE_PARAMS)
  81
  82
  83         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
  84         dnl # compiler options are added by the kernel build system.
  85         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
  86         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
  87         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
  88
  89         AC_SUBST(KERNELCPPFLAGS)
  90 ])
  91
  92 dnl #
  93 dnl # Detect name used for Module.symvers file in kernel
  94 dnl #
  95 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
  96         modpost=$LINUX/scripts/Makefile.modpost
  97         AC_MSG_CHECKING([kernel file name for module symbols])
  98         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
  99                 AS_IF([grep -q Modules.symvers $modpost], [
 100                         LINUX_SYMBOLS=Modules.symvers
 101                 ], [
 102                         LINUX_SYMBOLS=Module.symvers
 103                 ])
 104
 105                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 106                         AC_MSG_ERROR([
 107         *** Please make sure the kernel devel package for your distribution
 108         *** is installed.  If your building with a custom kernel make sure the
 109         *** kernel is configured, built, and the '--with-linux=PATH' configure
 110         *** option refers to the location of the kernel source.])
 111                 ])
 112         ], [
 113                 LINUX_SYMBOLS=NONE
 114         ])
 115         AC_MSG_RESULT($LINUX_SYMBOLS)
 116         AC_SUBST(LINUX_SYMBOLS)
 117 ])
 118
 119 dnl #
 120 dnl # Detect the kernel to be built against
 121 dnl #
 122 AC_DEFUN([ZFS_AC_KERNEL], [
 123         AC_ARG_WITH([linux],
 124                 AS_HELP_STRING([--with-linux=PATH],
 125                 [Path to kernel source]),
 126                 [kernelsrc="$withval"])
 127
 128         AC_ARG_WITH(linux-obj,
 129                 AS_HELP_STRING([--with-linux-obj=PATH],
 130                 [Path to kernel build objects]),
 131                 [kernelbuild="$withval"])
 132
 133         AC_MSG_CHECKING([kernel source directory])
 134         AS_IF([test -z "$kernelsrc"], [
 135                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 136                         headersdir="/lib/modules/$(uname -r)/source"
 137                         sourcelink=$(readlink -f "$headersdir")
 138                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 139                         headersdir="/lib/modules/$(uname -r)/build"
 140                         sourcelink=$(readlink -f "$headersdir")
 141                 ], [
 142                         sourcelink=$(ls -1d /usr/src/kernels/* \
 143                                      /usr/src/linux-* \
 144                                      2>/dev/null | grep -v obj | tail -1)
 145                 ])
 146
 147                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 148                         kernelsrc=`readlink -f ${sourcelink}`
 149                 ], [
 150                         kernelsrc="[Not found]"
 151                 ])
 152         ], [
 153                 AS_IF([test "$kernelsrc" = "NONE"], [
 154                         kernsrcver=NONE
 155                 ])
 156         ])
 157
 158         AC_MSG_RESULT([$kernelsrc])
 159         AS_IF([test ! -d "$kernelsrc"], [
 160                 AC_MSG_ERROR([
 161         *** Please make sure the kernel devel package for your distribution
 162         *** is installed then try again.  If that fails you can specify the
 163         *** location of the kernel source with the '--with-linux=PATH' option.])
 164         ])
 165
 166         AC_MSG_CHECKING([kernel build directory])
 167         AS_IF([test -z "$kernelbuild"], [
 168                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 169                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 170                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 171                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 172                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 173                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 174                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 175                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 176                 ], [
 177                         kernelbuild=${kernelsrc}
 178                 ])
 179         ])
 180         AC_MSG_RESULT([$kernelbuild])
 181
 182         AC_MSG_CHECKING([kernel source version])
 183         utsrelease1=$kernelbuild/include/linux/version.h
 184         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 185         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 186         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 187                 utsrelease=linux/version.h
 188         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 189                 utsrelease=linux/utsrelease.h
 190         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 191                 utsrelease=generated/utsrelease.h
 192         ])
 193
 194         AS_IF([test "$utsrelease"], [
 195                 kernsrcver=`(echo "#include <$utsrelease>";
 196                              echo "kernsrcver=UTS_RELEASE") |
 197                              cpp -I $kernelbuild/include |
 198                              grep "^kernsrcver=" | cut -d \" -f 2`
 199
 200                 AS_IF([test -z "$kernsrcver"], [
 201                         AC_MSG_RESULT([Not found])
 202                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 203                 ])
 204         ], [
 205                 AC_MSG_RESULT([Not found])
 206                 if test "x$enable_linux_builtin" != xyes; then
 207                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 208                 else
 209                         AC_MSG_ERROR([
 210         *** Cannot find UTS_RELEASE definition.
 211         *** Please run 'make prepare' inside the kernel source tree.])
 212                 fi
 213         ])
 214
 215         AC_MSG_RESULT([$kernsrcver])
 216
 217         LINUX=${kernelsrc}
 218         LINUX_OBJ=${kernelbuild}
 219         LINUX_VERSION=${kernsrcver}
 220
 221         AC_SUBST(LINUX)
 222         AC_SUBST(LINUX_OBJ)
 223         AC_SUBST(LINUX_VERSION)
 224
 225         ZFS_AC_MODULE_SYMVERS
 226 ])
 227
 228 dnl #
 229 dnl # Detect name used for the additional SPL Module.symvers file.  If one
 230 dnl # does not exist this is likely because the SPL has been configured
 231 dnl # but not built.  The '--with-spl-timeout' option can be passed
 232 dnl # to pause here, waiting for the file to appear from a concurrently
 233 dnl # building SPL package.  If the file does not appear in time, a good
 234 dnl # guess is made as to what this file will be named based on what it
 235 dnl # is named in the kernel build products.  This file will first be
 236 dnl # used at link time so if the guess is wrong the build will fail
 237 dnl # then.  This unfortunately means the ZFS package does not contain a
 238 dnl # reliable mechanism to detect symbols exported by the SPL at
 239 dnl # configure time.
 240 dnl #
 241 AC_DEFUN([ZFS_AC_SPL_MODULE_SYMVERS], [
 242         AC_ARG_WITH([spl-timeout],
 243                 AS_HELP_STRING([--with-spl-timeout=SECS],
 244                 [Wait SECS for symvers file to appear  @<:@default=0@:>@]),
 245                 [timeout="$withval"], [timeout=0])
 246
 247         AC_MSG_CHECKING([spl file name for module symbols])
 248         SPL_SYMBOLS=NONE
 249
 250         while true; do
 251                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 252                         SPL_SYMBOLS=Module.symvers
 253                 ], [test -r $SPL_OBJ/Modules.symvers], [
 254                         SPL_SYMBOLS=Modules.symvers
 255                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 256                         SPL_SYMBOLS=Module.symvers
 257                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 258                         SPL_SYMBOLS=Modules.symvers
 259                 ])
 260
 261                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 262                         break;
 263                 ], [
 264                         sleep 1
 265                         timeout=$((timeout-1))
 266                 ])
 267         done
 268
 269         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 270                 SPL_SYMBOLS=$LINUX_SYMBOLS
 271         ])
 272
 273         AC_MSG_RESULT([$SPL_SYMBOLS])
 274         AC_SUBST(SPL_SYMBOLS)
 275 ])
 276
 277 dnl #
 278 dnl # Detect the SPL module to be built against
 279 dnl #
 280 AC_DEFUN([ZFS_AC_SPL], [
 281         AC_ARG_WITH([spl],
 282                 AS_HELP_STRING([--with-spl=PATH],
 283                 [Path to spl source]),
 284                 [splsrc="$withval"])
 285
 286         AC_ARG_WITH([spl-obj],
 287                 AS_HELP_STRING([--with-spl-obj=PATH],
 288                 [Path to spl build objects]),
 289                 [splbuild="$withval"])
 290
 291
 292         AC_MSG_CHECKING([spl source directory])
 293         AS_IF([test -z "$splsrc"], [
 294                 dnl #
 295                 dnl # Look in the standard development package location
 296                 dnl #
 297                 sourcelink=`ls -1d /usr/src/spl-*/${LINUX_VERSION} \
 298                             2>/dev/null | tail -1`
 299
 300                 dnl #
 301                 dnl # Look in the DKMS source location
 302                 dnl #
 303                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 304                         sourcelink=`ls -1d /var/lib/dkms/spl/*/build \
 305                                     2>/dev/null | tail -1`
 306                 ])
 307
 308                 dnl #
 309                 dnl # Look in the parent directory
 310                 dnl #
 311                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 312                         sourcelink=../spl
 313                 ])
 314
 315                 dnl #
 316                 dnl # Look in the kernel directory
 317                 dnl #
 318                 AS_IF([test -z "$sourcelink" || test ! -e $sourcelink/spl_config.h], [
 319                         sourcelink="$LINUX"
 320                 ])
 321
 322                 AS_IF([test -e $sourcelink/spl_config.h], [
 323                         splsrc=`readlink -f ${sourcelink}`
 324                 ], [
 325                         AC_MSG_RESULT([Not found])
 326                         AC_MSG_ERROR([
 327         *** Please make sure the spl devel package for your distribution
 328         *** is installed then try again.  If that fails you can specify the
 329         *** location of the spl source with the '--with-spl=PATH' option.])
 330                 ])
 331         ], [
 332                 AS_IF([test "$splsrc" = "NONE"], [
 333                         splbuild=NONE
 334                         splsrcver=NONE
 335                 ])
 336         ])
 337
 338         AC_MSG_RESULT([$splsrc])
 339         AC_MSG_CHECKING([spl build directory])
 340         AS_IF([test -z "$splbuild"], [
 341                 splbuild=${splsrc}
 342         ])
 343         AC_MSG_RESULT([$splbuild])
 344
 345         AC_MSG_CHECKING([spl source version])
 346         AS_IF([test -r $splbuild/spl_config.h &&
 347                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 348
 349                 splsrcver=`(echo "#include <spl_config.h>";
 350                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 351                             cpp -I $splbuild |
 352                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 353         ])
 354
 355         AS_IF([test -z "$splsrcver"], [
 356                 AC_MSG_RESULT([Not found])
 357                 AC_MSG_ERROR([
 358         *** Cannot determine the version of the spl source.
 359         *** Please prepare the spl source before running this script])
 360         ])
 361
 362         AC_MSG_RESULT([$splsrcver])
 363
 364         SPL=${splsrc}
 365         SPL_OBJ=${splbuild}
 366         SPL_VERSION=${splsrcver}
 367
 368         AC_SUBST(SPL)
 369         AC_SUBST(SPL_OBJ)
 370         AC_SUBST(SPL_VERSION)
 371
 372         ZFS_AC_SPL_MODULE_SYMVERS
 373 ])
 374
 375 dnl #
 376 dnl # Basic toolchain sanity check.
 377 dnl #
 378 AC_DEFUN([ZFS_AC_TEST_MODULE],
 379         [AC_MSG_CHECKING([whether modules can be built])
 380         ZFS_LINUX_TRY_COMPILE([],[],[
 381                 AC_MSG_RESULT([yes])
 382         ],[
 383                 AC_MSG_RESULT([no])
 384                 if test "x$enable_linux_builtin" != xyes; then
 385                         AC_MSG_ERROR([*** Unable to build an empty module.])
 386                 else
 387                         AC_MSG_ERROR([
 388         *** Unable to build an empty module.
 389         *** Please run 'make scripts' inside the kernel source tree.])
 390                 fi
 391         ])
 392 ])
 393
 394 dnl #
 395 dnl # Certain kernel build options are not supported.  These must be
 396 dnl # detected at configure time and cause a build failure.  Otherwise
 397 dnl # modules may be successfully built that behave incorrectly.
 398 dnl #
 399 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 400
 401         AS_IF([test "$ZFS_META_LICENSE" = GPL], [
 402                 AC_DEFINE([HAVE_GPL_ONLY_SYMBOLS], [1],
 403                         [Define to 1 if licensed under the GPL])
 404         ])
 405
 406         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 407 ])
 408
 409 dnl #
 410 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 411 dnl #
 412 dnl # This is typically only set for debug kernels because it comes with
 413 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 414 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 415 dnl # This will cause a failure at link time which we'd rather know about
 416 dnl # at compile time.
 417 dnl #
 418 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 419 dnl # with the upstream community we add a check to detect this case.
 420 dnl #
 421 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 422
 423         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 424                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 425                 tmp_flags="$EXTRA_KCFLAGS"
 426                 ZFS_LINUX_TRY_COMPILE([
 427                         #include <linux/module.h>
 428                         #include <linux/mutex.h>
 429
 430                         MODULE_LICENSE("$ZFS_META_LICENSE");
 431                 ],[
 432                         struct mutex lock;
 433
 434                         mutex_init(&lock);
 435                         mutex_lock(&lock);
 436                         mutex_unlock(&lock);
 437                 ],[
 438                         AC_MSG_RESULT(no)
 439                 ],[
 440                         AC_MSG_RESULT(yes)
 441                         AC_MSG_ERROR([
 442         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 443         *** with the CDDL license and will prevent the module linking stage
 444         *** from succeeding.  You must rebuild your kernel without this
 445         *** option enabled.])
 446                 ])
 447                 EXTRA_KCFLAGS="$tmp_flags"
 448         ], [])
 449 ])
 450
 451 dnl #
 452 dnl # ZFS_LINUX_CONFTEST
 453 dnl #
 454 AC_DEFUN([ZFS_LINUX_CONFTEST], [
 455 cat confdefs.h - <<_ACEOF >conftest.c
 456 $1
 457 _ACEOF
 458 ])
 459
 460 dnl #
 461 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 462 dnl #
 463 m4_define([ZFS_LANG_PROGRAM], [
 464 $1
 465 int
 466 main (void)
 467 {
 468 dnl Do *not* indent the following line: there may be CPP directives.
 469 dnl Don't move the `;' right after for the same reason.
 470 $2
 471   ;
 472   return 0;
 473 }
 474 ])
 475
 476 dnl #
 477 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 478 dnl #
 479 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 480         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST([$1])])
 481         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 482         echo "obj-m := conftest.o" >build/Makefile
 483         modpost_flag=''
 484         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 485         AS_IF(
 486                 [AC_TRY_COMMAND(cp conftest.c build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror-implicit-function-declaration $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 487                 [$4],
 488                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 489         )
 490         rm -Rf build
 491 ])
 492
 493 dnl #
 494 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 495 dnl #
 496 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 497         [ZFS_LINUX_COMPILE_IFELSE(
 498         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 499         [modules],
 500         [test -s build/conftest.o],
 501         [$3], [$4])
 502 ])
 503
 504 dnl #
 505 dnl # ZFS_LINUX_CONFIG
 506 dnl #
 507 AC_DEFUN([ZFS_LINUX_CONFIG],
 508         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 509         ZFS_LINUX_TRY_COMPILE([
 510                 #include <linux/module.h>
 511         ],[
 512                 #ifndef CONFIG_$1
 513                 #error CONFIG_$1 not #defined
 514                 #endif
 515         ],[
 516                 AC_MSG_RESULT([yes])
 517                 $2
 518         ],[
 519                 AC_MSG_RESULT([no])
 520                 $3
 521         ])
 522 ])
 523
 524 dnl #
 525 dnl # ZFS_CHECK_SYMBOL_EXPORT
 526 dnl # check symbol exported or not
 527 dnl #
 528 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 529         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 530                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 531         rc=$?
 532         if test $rc -ne 0; then
 533                 export=0
 534                 for file in $2; do
 535                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 536                                 "$LINUX/$file" 2>/dev/null
 537                         rc=$?
 538                         if test $rc -eq 0; then
 539                                 export=1
 540                                 break;
 541                         fi
 542                 done
 543                 if test $export -eq 0; then :
 544                         $4
 545                 else :
 546                         $3
 547                 fi
 548         else :
 549                 $3
 550         fi
 551 ])
 552
 553 dnl #
 554 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 555 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 556 dnl # is called if not compiling for builtin
 557 dnl #
 558 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 559         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 560         if test $rc -ne 0; then :
 561                 $6
 562         else
 563                 if test "x$enable_linux_builtin" != xyes; then
 564                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 565                 fi
 566                 if test $rc -ne 0; then :
 567                         $6
 568                 else :
 569                         $5
 570                 fi
 571         fi
 572 ])