config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         AM_COND_IF([BUILD_LINUX], [
   6                 dnl # Setup the kernel build environment.
   7                 ZFS_AC_KERNEL
   8                 ZFS_AC_QAT
   9
  10                 dnl # Sanity checks for module building and CONFIG_* defines
  11                 ZFS_AC_KERNEL_CONFIG_DEFINED
  12                 ZFS_AC_MODULE_SYMVERS
  13
  14                 dnl # Sequential ZFS_LINUX_TRY_COMPILE tests
  15                 ZFS_AC_KERNEL_FPU_HEADER
  16                 ZFS_AC_KERNEL_OBJTOOL_HEADER
  17                 ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  18                 ZFS_AC_KERNEL_MISC_MINOR
  19                 ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  20
  21                 dnl # Parallel ZFS_LINUX_TEST_SRC / ZFS_LINUX_TEST_RESULT tests
  22                 ZFS_AC_KERNEL_TEST_SRC
  23                 ZFS_AC_KERNEL_TEST_RESULT
  24
  25                 AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
  26                         KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
  27                 ])
  28
  29                 AC_SUBST(KERNEL_MAKE)
  30         ])
  31 ])
  32
  33 dnl #
  34 dnl # Generate and compile all of the kernel API test cases to determine
  35 dnl # which interfaces are available.  By invoking the kernel build system
  36 dnl # only once the compilation can be done in parallel significantly
  37 dnl # speeding up the process.
  38 dnl #
  39 AC_DEFUN([ZFS_AC_KERNEL_TEST_SRC], [
  40         ZFS_AC_KERNEL_SRC_OBJTOOL
  41         ZFS_AC_KERNEL_SRC_GLOBAL_PAGE_STATE
  42         ZFS_AC_KERNEL_SRC_ACCESS_OK_TYPE
  43         ZFS_AC_KERNEL_SRC_PDE_DATA
  44         ZFS_AC_KERNEL_SRC_FALLOCATE
  45         ZFS_AC_KERNEL_SRC_FADVISE
  46         ZFS_AC_KERNEL_SRC_GENERIC_FADVISE
  47         ZFS_AC_KERNEL_SRC_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  48         ZFS_AC_KERNEL_SRC_RWSEM
  49         ZFS_AC_KERNEL_SRC_SCHED
  50         ZFS_AC_KERNEL_SRC_USLEEP_RANGE
  51         ZFS_AC_KERNEL_SRC_KMEM_CACHE
  52         ZFS_AC_KERNEL_SRC_KVMALLOC
  53         ZFS_AC_KERNEL_SRC_VMALLOC_PAGE_KERNEL
  54         ZFS_AC_KERNEL_SRC_WAIT
  55         ZFS_AC_KERNEL_SRC_INODE_TIMES
  56         ZFS_AC_KERNEL_SRC_INODE_LOCK
  57         ZFS_AC_KERNEL_SRC_GROUP_INFO_GID
  58         ZFS_AC_KERNEL_SRC_RW
  59         ZFS_AC_KERNEL_SRC_TIMER_SETUP
  60         ZFS_AC_KERNEL_SRC_SUPER_USER_NS
  61         ZFS_AC_KERNEL_SRC_PROC_OPERATIONS
  62         ZFS_AC_KERNEL_SRC_BLOCK_DEVICE_OPERATIONS
  63         ZFS_AC_KERNEL_SRC_BIO
  64         ZFS_AC_KERNEL_SRC_BLKDEV
  65         ZFS_AC_KERNEL_SRC_BLK_QUEUE
  66         ZFS_AC_KERNEL_SRC_GENHD_FLAGS
  67         ZFS_AC_KERNEL_SRC_REVALIDATE_DISK
  68         ZFS_AC_KERNEL_SRC_GET_DISK_RO
  69         ZFS_AC_KERNEL_SRC_GENERIC_READLINK_GLOBAL
  70         ZFS_AC_KERNEL_SRC_DISCARD_GRANULARITY
  71         ZFS_AC_KERNEL_SRC_INODE_OWNER_OR_CAPABLE
  72         ZFS_AC_KERNEL_SRC_XATTR
  73         ZFS_AC_KERNEL_SRC_ACL
  74         ZFS_AC_KERNEL_SRC_INODE_SETATTR
  75         ZFS_AC_KERNEL_SRC_INODE_GETATTR
  76         ZFS_AC_KERNEL_SRC_INODE_SET_FLAGS
  77         ZFS_AC_KERNEL_SRC_INODE_SET_IVERSION
  78         ZFS_AC_KERNEL_SRC_SHOW_OPTIONS
  79         ZFS_AC_KERNEL_SRC_FILE_INODE
  80         ZFS_AC_KERNEL_SRC_FILE_DENTRY
  81         ZFS_AC_KERNEL_SRC_FSYNC
  82         ZFS_AC_KERNEL_SRC_AIO_FSYNC
  83         ZFS_AC_KERNEL_SRC_EVICT_INODE
  84         ZFS_AC_KERNEL_SRC_DIRTY_INODE
  85         ZFS_AC_KERNEL_SRC_SHRINKER
  86         ZFS_AC_KERNEL_SRC_MKDIR
  87         ZFS_AC_KERNEL_SRC_LOOKUP_FLAGS
  88         ZFS_AC_KERNEL_SRC_CREATE
  89         ZFS_AC_KERNEL_SRC_PERMISSION
  90         ZFS_AC_KERNEL_SRC_GET_LINK
  91         ZFS_AC_KERNEL_SRC_PUT_LINK
  92         ZFS_AC_KERNEL_SRC_TMPFILE
  93         ZFS_AC_KERNEL_SRC_AUTOMOUNT
  94         ZFS_AC_KERNEL_SRC_ENCODE_FH_WITH_INODE
  95         ZFS_AC_KERNEL_SRC_COMMIT_METADATA
  96         ZFS_AC_KERNEL_SRC_CLEAR_INODE
  97         ZFS_AC_KERNEL_SRC_SETATTR_PREPARE
  98         ZFS_AC_KERNEL_SRC_INSERT_INODE_LOCKED
  99         ZFS_AC_KERNEL_SRC_DENTRY
 100         ZFS_AC_KERNEL_SRC_DENTRY_ALIAS_D_U
 101         ZFS_AC_KERNEL_SRC_TRUNCATE_SETSIZE
 102         ZFS_AC_KERNEL_SRC_SECURITY_INODE
 103         ZFS_AC_KERNEL_SRC_FST_MOUNT
 104         ZFS_AC_KERNEL_SRC_BDI
 105         ZFS_AC_KERNEL_SRC_SET_NLINK
 106         ZFS_AC_KERNEL_SRC_SGET
 107         ZFS_AC_KERNEL_SRC_LSEEK_EXECUTE
 108         ZFS_AC_KERNEL_SRC_VFS_FILEMAP_DIRTY_FOLIO
 109         ZFS_AC_KERNEL_SRC_VFS_READ_FOLIO
 110         ZFS_AC_KERNEL_SRC_VFS_GETATTR
 111         ZFS_AC_KERNEL_SRC_VFS_FSYNC_2ARGS
 112         ZFS_AC_KERNEL_SRC_VFS_ITERATE
 113         ZFS_AC_KERNEL_SRC_VFS_DIRECT_IO
 114         ZFS_AC_KERNEL_SRC_VFS_READPAGES
 115         ZFS_AC_KERNEL_SRC_VFS_SET_PAGE_DIRTY_NOBUFFERS
 116         ZFS_AC_KERNEL_SRC_VFS_RW_ITERATE
 117         ZFS_AC_KERNEL_SRC_VFS_GENERIC_WRITE_CHECKS
 118         ZFS_AC_KERNEL_SRC_VFS_IOV_ITER
 119         ZFS_AC_KERNEL_SRC_VFS_COPY_FILE_RANGE
 120         ZFS_AC_KERNEL_SRC_VFS_GENERIC_COPY_FILE_RANGE
 121         ZFS_AC_KERNEL_SRC_VFS_REMAP_FILE_RANGE
 122         ZFS_AC_KERNEL_SRC_VFS_CLONE_FILE_RANGE
 123         ZFS_AC_KERNEL_SRC_VFS_DEDUPE_FILE_RANGE
 124         ZFS_AC_KERNEL_SRC_VFS_FILE_OPERATIONS_EXTEND
 125         ZFS_AC_KERNEL_SRC_KMAP_ATOMIC_ARGS
 126         ZFS_AC_KERNEL_SRC_FOLLOW_DOWN_ONE
 127         ZFS_AC_KERNEL_SRC_MAKE_REQUEST_FN
 128         ZFS_AC_KERNEL_SRC_GENERIC_IO_ACCT
 129         ZFS_AC_KERNEL_SRC_FPU
 130         ZFS_AC_KERNEL_SRC_FMODE_T
 131         ZFS_AC_KERNEL_SRC_KUIDGID_T
 132         ZFS_AC_KERNEL_SRC_KUID_HELPERS
 133         ZFS_AC_KERNEL_SRC_RENAME
 134         ZFS_AC_KERNEL_SRC_CURRENT_TIME
 135         ZFS_AC_KERNEL_SRC_USERNS_CAPABILITIES
 136         ZFS_AC_KERNEL_SRC_IN_COMPAT_SYSCALL
 137         ZFS_AC_KERNEL_SRC_KTIME
 138         ZFS_AC_KERNEL_SRC_TOTALRAM_PAGES_FUNC
 139         ZFS_AC_KERNEL_SRC_TOTALHIGH_PAGES
 140         ZFS_AC_KERNEL_SRC_KSTRTOUL
 141         ZFS_AC_KERNEL_SRC_PERCPU
 142         ZFS_AC_KERNEL_SRC_CPU_HOTPLUG
 143         ZFS_AC_KERNEL_SRC_GENERIC_FILLATTR
 144         ZFS_AC_KERNEL_SRC_MKNOD
 145         ZFS_AC_KERNEL_SRC_SYMLINK
 146         ZFS_AC_KERNEL_SRC_BIO_MAX_SEGS
 147         ZFS_AC_KERNEL_SRC_SIGNAL_STOP
 148         ZFS_AC_KERNEL_SRC_SIGINFO
 149         ZFS_AC_KERNEL_SRC_SYSFS
 150         ZFS_AC_KERNEL_SRC_SET_SPECIAL_STATE
 151         ZFS_AC_KERNEL_SRC_STANDALONE_LINUX_STDARG
 152         ZFS_AC_KERNEL_SRC_STRLCPY
 153         ZFS_AC_KERNEL_SRC_STRSCPY
 154         ZFS_AC_KERNEL_SRC_PAGEMAP_FOLIO_WAIT_BIT
 155         ZFS_AC_KERNEL_SRC_ADD_DISK
 156         ZFS_AC_KERNEL_SRC_KTHREAD
 157         ZFS_AC_KERNEL_SRC_ZERO_PAGE
 158         ZFS_AC_KERNEL_SRC___COPY_FROM_USER_INATOMIC
 159         ZFS_AC_KERNEL_SRC_USER_NS_COMMON_INUM
 160         ZFS_AC_KERNEL_SRC_IDMAP_MNT_API
 161         ZFS_AC_KERNEL_SRC_IDMAP_NO_USERNS
 162         ZFS_AC_KERNEL_SRC_IATTR_VFSID
 163         ZFS_AC_KERNEL_SRC_FILEMAP
 164         ZFS_AC_KERNEL_SRC_WRITEPAGE_T
 165         ZFS_AC_KERNEL_SRC_RECLAIMED
 166         ZFS_AC_KERNEL_SRC_REGISTER_SYSCTL_TABLE
 167         ZFS_AC_KERNEL_SRC_COPY_SPLICE_READ
 168         ZFS_AC_KERNEL_SRC_SYNC_BDEV
 169         case "$host_cpu" in
 170                 powerpc*)
 171                         ZFS_AC_KERNEL_SRC_CPU_HAS_FEATURE
 172                         ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
 173                         ;;
 174                 riscv*)
 175                         ZFS_AC_KERNEL_SRC_FLUSH_DCACHE_PAGE
 176                         ;;
 177         esac
 178
 179         AC_MSG_CHECKING([for available kernel interfaces])
 180         ZFS_LINUX_TEST_COMPILE_ALL([kabi])
 181         AC_MSG_RESULT([done])
 182 ])
 183
 184 dnl #
 185 dnl # Check results of kernel interface tests.
 186 dnl #
 187 AC_DEFUN([ZFS_AC_KERNEL_TEST_RESULT], [
 188         ZFS_AC_KERNEL_ACCESS_OK_TYPE
 189         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 190         ZFS_AC_KERNEL_OBJTOOL
 191         ZFS_AC_KERNEL_PDE_DATA
 192         ZFS_AC_KERNEL_FALLOCATE
 193         ZFS_AC_KERNEL_FADVISE
 194         ZFS_AC_KERNEL_GENERIC_FADVISE
 195         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
 196         ZFS_AC_KERNEL_RWSEM
 197         ZFS_AC_KERNEL_SCHED
 198         ZFS_AC_KERNEL_USLEEP_RANGE
 199         ZFS_AC_KERNEL_KMEM_CACHE
 200         ZFS_AC_KERNEL_KVMALLOC
 201         ZFS_AC_KERNEL_VMALLOC_PAGE_KERNEL
 202         ZFS_AC_KERNEL_WAIT
 203         ZFS_AC_KERNEL_INODE_TIMES
 204         ZFS_AC_KERNEL_INODE_LOCK
 205         ZFS_AC_KERNEL_GROUP_INFO_GID
 206         ZFS_AC_KERNEL_RW
 207         ZFS_AC_KERNEL_TIMER_SETUP
 208         ZFS_AC_KERNEL_SUPER_USER_NS
 209         ZFS_AC_KERNEL_PROC_OPERATIONS
 210         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS
 211         ZFS_AC_KERNEL_BIO
 212         ZFS_AC_KERNEL_BLKDEV
 213         ZFS_AC_KERNEL_BLK_QUEUE
 214         ZFS_AC_KERNEL_GENHD_FLAGS
 215         ZFS_AC_KERNEL_REVALIDATE_DISK
 216         ZFS_AC_KERNEL_GET_DISK_RO
 217         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
 218         ZFS_AC_KERNEL_DISCARD_GRANULARITY
 219         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
 220         ZFS_AC_KERNEL_XATTR
 221         ZFS_AC_KERNEL_ACL
 222         ZFS_AC_KERNEL_INODE_SETATTR
 223         ZFS_AC_KERNEL_INODE_GETATTR
 224         ZFS_AC_KERNEL_INODE_SET_FLAGS
 225         ZFS_AC_KERNEL_INODE_SET_IVERSION
 226         ZFS_AC_KERNEL_SHOW_OPTIONS
 227         ZFS_AC_KERNEL_FILE_INODE
 228         ZFS_AC_KERNEL_FILE_DENTRY
 229         ZFS_AC_KERNEL_FSYNC
 230         ZFS_AC_KERNEL_AIO_FSYNC
 231         ZFS_AC_KERNEL_EVICT_INODE
 232         ZFS_AC_KERNEL_DIRTY_INODE
 233         ZFS_AC_KERNEL_SHRINKER
 234         ZFS_AC_KERNEL_MKDIR
 235         ZFS_AC_KERNEL_LOOKUP_FLAGS
 236         ZFS_AC_KERNEL_CREATE
 237         ZFS_AC_KERNEL_PERMISSION
 238         ZFS_AC_KERNEL_GET_LINK
 239         ZFS_AC_KERNEL_PUT_LINK
 240         ZFS_AC_KERNEL_TMPFILE
 241         ZFS_AC_KERNEL_AUTOMOUNT
 242         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 243         ZFS_AC_KERNEL_COMMIT_METADATA
 244         ZFS_AC_KERNEL_CLEAR_INODE
 245         ZFS_AC_KERNEL_SETATTR_PREPARE
 246         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 247         ZFS_AC_KERNEL_DENTRY
 248         ZFS_AC_KERNEL_DENTRY_ALIAS_D_U
 249         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 250         ZFS_AC_KERNEL_SECURITY_INODE
 251         ZFS_AC_KERNEL_FST_MOUNT
 252         ZFS_AC_KERNEL_BDI
 253         ZFS_AC_KERNEL_SET_NLINK
 254         ZFS_AC_KERNEL_SGET
 255         ZFS_AC_KERNEL_LSEEK_EXECUTE
 256         ZFS_AC_KERNEL_VFS_FILEMAP_DIRTY_FOLIO
 257         ZFS_AC_KERNEL_VFS_READ_FOLIO
 258         ZFS_AC_KERNEL_VFS_GETATTR
 259         ZFS_AC_KERNEL_VFS_FSYNC_2ARGS
 260         ZFS_AC_KERNEL_VFS_ITERATE
 261         ZFS_AC_KERNEL_VFS_DIRECT_IO
 262         ZFS_AC_KERNEL_VFS_READPAGES
 263         ZFS_AC_KERNEL_VFS_SET_PAGE_DIRTY_NOBUFFERS
 264         ZFS_AC_KERNEL_VFS_RW_ITERATE
 265         ZFS_AC_KERNEL_VFS_GENERIC_WRITE_CHECKS
 266         ZFS_AC_KERNEL_VFS_IOV_ITER
 267         ZFS_AC_KERNEL_VFS_COPY_FILE_RANGE
 268         ZFS_AC_KERNEL_VFS_GENERIC_COPY_FILE_RANGE
 269         ZFS_AC_KERNEL_VFS_REMAP_FILE_RANGE
 270         ZFS_AC_KERNEL_VFS_CLONE_FILE_RANGE
 271         ZFS_AC_KERNEL_VFS_DEDUPE_FILE_RANGE
 272         ZFS_AC_KERNEL_VFS_FILE_OPERATIONS_EXTEND
 273         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 274         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 275         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 276         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 277         ZFS_AC_KERNEL_FPU
 278         ZFS_AC_KERNEL_FMODE_T
 279         ZFS_AC_KERNEL_KUIDGID_T
 280         ZFS_AC_KERNEL_KUID_HELPERS
 281         ZFS_AC_KERNEL_RENAME
 282         ZFS_AC_KERNEL_CURRENT_TIME
 283         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 284         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 285         ZFS_AC_KERNEL_KTIME
 286         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 287         ZFS_AC_KERNEL_TOTALHIGH_PAGES
 288         ZFS_AC_KERNEL_KSTRTOUL
 289         ZFS_AC_KERNEL_PERCPU
 290         ZFS_AC_KERNEL_CPU_HOTPLUG
 291         ZFS_AC_KERNEL_GENERIC_FILLATTR
 292         ZFS_AC_KERNEL_MKNOD
 293         ZFS_AC_KERNEL_SYMLINK
 294         ZFS_AC_KERNEL_BIO_MAX_SEGS
 295         ZFS_AC_KERNEL_SIGNAL_STOP
 296         ZFS_AC_KERNEL_SIGINFO
 297         ZFS_AC_KERNEL_SYSFS
 298         ZFS_AC_KERNEL_SET_SPECIAL_STATE
 299         ZFS_AC_KERNEL_STANDALONE_LINUX_STDARG
 300         ZFS_AC_KERNEL_STRLCPY
 301         ZFS_AC_KERNEL_STRSCPY
 302         ZFS_AC_KERNEL_PAGEMAP_FOLIO_WAIT_BIT
 303         ZFS_AC_KERNEL_ADD_DISK
 304         ZFS_AC_KERNEL_KTHREAD
 305         ZFS_AC_KERNEL_ZERO_PAGE
 306         ZFS_AC_KERNEL___COPY_FROM_USER_INATOMIC
 307         ZFS_AC_KERNEL_USER_NS_COMMON_INUM
 308         ZFS_AC_KERNEL_IDMAP_MNT_API
 309         ZFS_AC_KERNEL_IDMAP_NO_USERNS
 310         ZFS_AC_KERNEL_IATTR_VFSID
 311         ZFS_AC_KERNEL_FILEMAP
 312         ZFS_AC_KERNEL_WRITEPAGE_T
 313         ZFS_AC_KERNEL_RECLAIMED
 314         ZFS_AC_KERNEL_REGISTER_SYSCTL_TABLE
 315         ZFS_AC_KERNEL_COPY_SPLICE_READ
 316         ZFS_AC_KERNEL_SYNC_BDEV
 317         case "$host_cpu" in
 318                 powerpc*)
 319                         ZFS_AC_KERNEL_CPU_HAS_FEATURE
 320                         ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
 321                         ;;
 322                 riscv*)
 323                         ZFS_AC_KERNEL_FLUSH_DCACHE_PAGE
 324                         ;;
 325         esac
 326 ])
 327
 328 dnl #
 329 dnl # Detect name used for Module.symvers file in kernel
 330 dnl #
 331 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 332         modpost=$LINUX/scripts/Makefile.modpost
 333         AC_MSG_CHECKING([kernel file name for module symbols])
 334         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 335                 AS_IF([grep -q Modules.symvers $modpost], [
 336                         LINUX_SYMBOLS=Modules.symvers
 337                 ], [
 338                         LINUX_SYMBOLS=Module.symvers
 339                 ])
 340
 341                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 342                         AC_MSG_ERROR([
 343         *** Please make sure the kernel devel package for your distribution
 344         *** is installed.  If you are building with a custom kernel, make sure
 345         *** the kernel is configured, built, and the '--with-linux=PATH'
 346         *** configure option refers to the location of the kernel source.
 347                         ])
 348                 ])
 349         ], [
 350                 LINUX_SYMBOLS=NONE
 351         ])
 352         AC_MSG_RESULT($LINUX_SYMBOLS)
 353         AC_SUBST(LINUX_SYMBOLS)
 354 ])
 355
 356 dnl #
 357 dnl # Detect the kernel to be built against
 358 dnl #
 359 dnl # Most modern Linux distributions have separate locations for bare
 360 dnl # source (source) and prebuilt (build) files. Additionally, there are
 361 dnl # `source` and `build` symlinks in `/lib/modules/$(KERNEL_VERSION)`
 362 dnl # pointing to them. The directory search order is now:
 363 dnl #
 364 dnl # - `configure` command line values if both `--with-linux` and
 365 dnl #   `--with-linux-obj` were defined
 366 dnl #
 367 dnl # - If only `--with-linux` was defined, `--with-linux-obj` is assumed
 368 dnl #   to have the same value as `--with-linux`
 369 dnl #
 370 dnl # - If neither `--with-linux` nor `--with-linux-obj` were defined
 371 dnl #   autodetection is used:
 372 dnl #
 373 dnl #   - `/lib/modules/$(uname -r)/{source,build}` respectively, if exist.
 374 dnl #
 375 dnl #   - If only `/lib/modules/$(uname -r)/build` exists, it is assumed
 376 dnl #     to be both source and build directory.
 377 dnl #
 378 dnl #   - The first directory in `/lib/modules` with the highest version
 379 dnl #     number according to `sort -V` which contains both `source` and
 380 dnl #     `build` symlinks/directories. If module directory contains only
 381 dnl #     `build` component, it is assumed to be both source and build
 382 dnl #     directory.
 383 dnl #
 384 dnl #   - Last resort: the first directory matching `/usr/src/kernels/*`
 385 dnl #     and `/usr/src/linux-*` with the highest version number according
 386 dnl #     to `sort -V` is assumed to be both source and build directory.
 387 dnl #
 388 AC_DEFUN([ZFS_AC_KERNEL], [
 389         AC_ARG_WITH([linux],
 390                 AS_HELP_STRING([--with-linux=PATH],
 391                 [Path to kernel source]),
 392                 [kernelsrc="$withval"])
 393
 394         AC_ARG_WITH(linux-obj,
 395                 AS_HELP_STRING([--with-linux-obj=PATH],
 396                 [Path to kernel build objects]),
 397                 [kernelbuild="$withval"])
 398
 399         AC_MSG_CHECKING([kernel source and build directories])
 400         AS_IF([test -n "$kernelsrc" && test -z "$kernelbuild"], [
 401                 kernelbuild="$kernelsrc"
 402         ], [test -z "$kernelsrc"], [
 403                 AS_IF([test -e "/lib/modules/$(uname -r)/source" && \
 404                        test -e "/lib/modules/$(uname -r)/build"], [
 405                         src="/lib/modules/$(uname -r)/source"
 406                         build="/lib/modules/$(uname -r)/build"
 407                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 408                         build="/lib/modules/$(uname -r)/build"
 409                         src="$build"
 410                 ], [
 411                         src=
 412
 413                         for d in $(ls -1d /lib/modules/* 2>/dev/null | sort -Vr); do
 414                                 if test -e "$d/source" && test -e "$d/build"; then
 415                                         src="$d/source"
 416                                         build="$d/build"
 417                                         break
 418                                 fi
 419
 420                                 if test -e "$d/build"; then
 421                                         src="$d/build"
 422                                         build="$d/build"
 423                                         break
 424                                 fi
 425                         done
 426
 427                         # the least reliable method
 428                         if test -z "$src"; then
 429                                 src=$(ls -1d /usr/src/kernels/* /usr/src/linux-* \
 430                                       2>/dev/null | grep -v obj | sort -Vr | head -1)
 431                                 build="$src"
 432                         fi
 433                 ])
 434
 435                 AS_IF([test -n "$src" && test -e "$src"], [
 436                         kernelsrc=$(readlink -e "$src")
 437                 ], [
 438                         kernelsrc="[Not found]"
 439                 ])
 440                 AS_IF([test -n "$build" && test -e "$build"], [
 441                         kernelbuild=$(readlink -e "$build")
 442                 ], [
 443                         kernelbuild="[Not found]"
 444                 ])
 445         ], [
 446                 AS_IF([test "$kernelsrc" = "NONE"], [
 447                         kernsrcver=NONE
 448                 ])
 449                 withlinux=yes
 450         ])
 451
 452         AC_MSG_RESULT([done])
 453         AC_MSG_CHECKING([kernel source directory])
 454         AC_MSG_RESULT([$kernelsrc])
 455         AC_MSG_CHECKING([kernel build directory])
 456         AC_MSG_RESULT([$kernelbuild])
 457         AS_IF([test ! -d "$kernelsrc" || test ! -d "$kernelbuild"], [
 458                 AC_MSG_ERROR([
 459         *** Please make sure the kernel devel package for your distribution
 460         *** is installed and then try again.  If that fails, you can specify the
 461         *** location of the kernel source and build with the '--with-linux=PATH' and
 462         *** '--with-linux-obj=PATH' options respectively.])
 463         ])
 464
 465         AC_MSG_CHECKING([kernel source version])
 466         utsrelease1=$kernelbuild/include/linux/version.h
 467         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 468         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 469         AS_IF([test -r $utsrelease1 && grep -qF UTS_RELEASE $utsrelease1], [
 470                 utsrelease=$utsrelease1
 471         ], [test -r $utsrelease2 && grep -qF UTS_RELEASE $utsrelease2], [
 472                 utsrelease=$utsrelease2
 473         ], [test -r $utsrelease3 && grep -qF UTS_RELEASE $utsrelease3], [
 474                 utsrelease=$utsrelease3
 475         ])
 476
 477         AS_IF([test -n "$utsrelease"], [
 478                 kernsrcver=$($AWK '/UTS_RELEASE/ { gsub(/"/, "", $[3]); print $[3] }' $utsrelease)
 479                 AS_IF([test -z "$kernsrcver"], [
 480                         AC_MSG_RESULT([Not found])
 481                         AC_MSG_ERROR([
 482         *** Cannot determine kernel version.
 483                         ])
 484                 ])
 485         ], [
 486                 AC_MSG_RESULT([Not found])
 487                 if test "x$enable_linux_builtin" != xyes; then
 488                         AC_MSG_ERROR([
 489         *** Cannot find UTS_RELEASE definition.
 490                         ])
 491                 else
 492                         AC_MSG_ERROR([
 493         *** Cannot find UTS_RELEASE definition.
 494         *** Please run 'make prepare' inside the kernel source tree.])
 495                 fi
 496         ])
 497
 498         AC_MSG_RESULT([$kernsrcver])
 499
 500         AS_VERSION_COMPARE([$kernsrcver], [$ZFS_META_KVER_MIN], [
 501                  AC_MSG_ERROR([
 502         *** Cannot build against kernel version $kernsrcver.
 503         *** The minimum supported kernel version is $ZFS_META_KVER_MIN.
 504                 ])
 505         ])
 506
 507         LINUX=${kernelsrc}
 508         LINUX_OBJ=${kernelbuild}
 509         LINUX_VERSION=${kernsrcver}
 510
 511         AC_SUBST(LINUX)
 512         AC_SUBST(LINUX_OBJ)
 513         AC_SUBST(LINUX_VERSION)
 514 ])
 515
 516 dnl #
 517 dnl # Detect the QAT module to be built against, QAT provides hardware
 518 dnl # acceleration for data compression:
 519 dnl #
 520 dnl # https://01.org/intel-quickassist-technology
 521 dnl #
 522 dnl # 1) Download and install QAT driver from the above link
 523 dnl # 2) Start QAT driver in your system:
 524 dnl #    service qat_service start
 525 dnl # 3) Enable QAT in ZFS, e.g.:
 526 dnl #    ./configure --with-qat=<qat-driver-path>/QAT1.6
 527 dnl #    make
 528 dnl # 4) Set GZIP compression in ZFS dataset:
 529 dnl #    zfs set compression = gzip <dataset>
 530 dnl #
 531 dnl # Then the data written to this ZFS pool is compressed by QAT accelerator
 532 dnl # automatically, and de-compressed by QAT when read from the pool.
 533 dnl #
 534 dnl # 1) Get QAT hardware statistics with:
 535 dnl #    cat /proc/icp_dh895xcc_dev/qat
 536 dnl # 2) To disable QAT:
 537 dnl #    insmod zfs.ko zfs_qat_disable=1
 538 dnl #
 539 AC_DEFUN([ZFS_AC_QAT], [
 540         AC_ARG_WITH([qat],
 541                 AS_HELP_STRING([--with-qat=PATH],
 542                 [Path to qat source]),
 543                 AS_IF([test "$withval" = "yes"],
 544                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 545                         [qatsrc="$withval"]))
 546
 547         AC_ARG_WITH([qat-obj],
 548                 AS_HELP_STRING([--with-qat-obj=PATH],
 549                 [Path to qat build objects]),
 550                 [qatbuild="$withval"])
 551
 552         AS_IF([test ! -z "${qatsrc}"], [
 553                 AC_MSG_CHECKING([qat source directory])
 554                 AC_MSG_RESULT([$qatsrc])
 555                 QAT_SRC="${qatsrc}/quickassist"
 556                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 557                         AC_MSG_ERROR([
 558         *** Please make sure the qat driver package is installed
 559         *** and specify the location of the qat source with the
 560         *** '--with-qat=PATH' option then try again. Failed to
 561         *** find cpa.h in:
 562         ${QAT_SRC}/include])
 563                 ])
 564         ])
 565
 566         AS_IF([test ! -z "${qatsrc}"], [
 567                 AC_MSG_CHECKING([qat build directory])
 568                 AS_IF([test -z "$qatbuild"], [
 569                         qatbuild="${qatsrc}/build"
 570                 ])
 571
 572                 AC_MSG_RESULT([$qatbuild])
 573                 QAT_OBJ=${qatbuild}
 574                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 575                         AC_MSG_ERROR([
 576         *** Please make sure the qat driver is installed then try again.
 577         *** Failed to find icp_qa_al.ko or qat_api.ko in:
 578         $QAT_OBJ])
 579                 ])
 580
 581                 AC_SUBST(QAT_SRC)
 582                 AC_SUBST(QAT_OBJ)
 583
 584                 AC_DEFINE(HAVE_QAT, 1,
 585                 [qat is enabled and existed])
 586         ])
 587
 588         dnl #
 589         dnl # Detect the name used for the QAT Module.symvers file.
 590         dnl #
 591         AS_IF([test ! -z "${qatsrc}"], [
 592                 AC_MSG_CHECKING([qat file for module symbols])
 593                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 594
 595                 AS_IF([test -r $QAT_SYMBOLS], [
 596                         AC_MSG_RESULT([$QAT_SYMBOLS])
 597                         AC_SUBST(QAT_SYMBOLS)
 598                 ],[
 599                         AC_MSG_ERROR([
 600         *** Please make sure the qat driver is installed then try again.
 601         *** Failed to find Module.symvers in:
 602         $QAT_SYMBOLS
 603                         ])
 604                 ])
 605         ])
 606 ])
 607
 608 dnl #
 609 dnl # ZFS_LINUX_CONFTEST_H
 610 dnl #
 611 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 612 test -d build/$2 || mkdir -p build/$2
 613 cat - <<_ACEOF >build/$2/$2.h
 614 $1
 615 _ACEOF
 616 ])
 617
 618 dnl #
 619 dnl # ZFS_LINUX_CONFTEST_C
 620 dnl #
 621 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 622 test -d build/$2 || mkdir -p build/$2
 623 cat confdefs.h - <<_ACEOF >build/$2/$2.c
 624 $1
 625 _ACEOF
 626 ])
 627
 628 dnl #
 629 dnl # ZFS_LINUX_CONFTEST_MAKEFILE
 630 dnl #
 631 dnl # $1 - test case name
 632 dnl # $2 - add to top-level Makefile
 633 dnl # $3 - additional build flags
 634 dnl #
 635 AC_DEFUN([ZFS_LINUX_CONFTEST_MAKEFILE], [
 636         test -d build || mkdir -p build
 637         test -d build/$1 || mkdir -p build/$1
 638
 639         file=build/$1/Makefile
 640
 641         dnl # Example command line to manually build source.
 642         cat - <<_ACEOF >$file
 643 # Example command line to manually build source
 644 # make modules -C $LINUX_OBJ $ARCH_UM M=$PWD/build/$1
 645
 646 ccflags-y := -Werror $FRAME_LARGER_THAN
 647 _ACEOF
 648
 649         dnl # Additional custom CFLAGS as requested.
 650         m4_ifval($3, [echo "ccflags-y += $3" >>$file], [])
 651
 652         dnl # Test case source
 653         echo "obj-m := $1.o" >>$file
 654
 655         AS_IF([test "x$2" = "xyes"], [echo "obj-m += $1/" >>build/Makefile], [])
 656 ])
 657
 658 dnl #
 659 dnl # ZFS_LINUX_TEST_PROGRAM(C)([PROLOGUE], [BODY])
 660 dnl #
 661 m4_define([ZFS_LINUX_TEST_PROGRAM], [
 662 #include <linux/module.h>
 663 $1
 664
 665 int
 666 main (void)
 667 {
 668 $2
 669         ;
 670         return 0;
 671 }
 672
 673 MODULE_DESCRIPTION("conftest");
 674 MODULE_AUTHOR(ZFS_META_AUTHOR);
 675 MODULE_VERSION(ZFS_META_VERSION "-" ZFS_META_RELEASE);
 676 MODULE_LICENSE($3);
 677 ])
 678
 679 dnl #
 680 dnl # ZFS_LINUX_TEST_REMOVE
 681 dnl #
 682 dnl # Removes the specified test source and results.
 683 dnl #
 684 AC_DEFUN([ZFS_LINUX_TEST_REMOVE], [
 685         test -d build/$1 && rm -Rf build/$1
 686         test -f build/Makefile && sed '/$1/d' build/Makefile
 687 ])
 688
 689 dnl #
 690 dnl # ZFS_LINUX_COMPILE
 691 dnl #
 692 dnl # $1 - build dir
 693 dnl # $2 - test command
 694 dnl # $3 - pass command
 695 dnl # $4 - fail command
 696 dnl # $5 - set KBUILD_MODPOST_NOFINAL='yes'
 697 dnl # $6 - set KBUILD_MODPOST_WARN='yes'
 698 dnl #
 699 dnl # Used internally by ZFS_LINUX_TEST_{COMPILE,MODPOST}
 700 dnl #
 701 AC_DEFUN([ZFS_LINUX_COMPILE], [
 702         AC_ARG_VAR([KERNEL_CC], [C compiler for
 703                 building kernel modules])
 704         AC_ARG_VAR([KERNEL_LD], [Linker for
 705                 building kernel modules])
 706         AC_ARG_VAR([KERNEL_LLVM], [Binary option to
 707                 build kernel modules with LLVM/CLANG toolchain])
 708         AC_TRY_COMMAND([
 709             KBUILD_MODPOST_NOFINAL="$5" KBUILD_MODPOST_WARN="$6"
 710             make modules -k -j$TEST_JOBS ${KERNEL_CC:+CC=$KERNEL_CC}
 711             ${KERNEL_LD:+LD=$KERNEL_LD} ${KERNEL_LLVM:+LLVM=$KERNEL_LLVM}
 712             CONFIG_MODULES=y CFLAGS_MODULE=-DCONFIG_MODULES
 713             -C $LINUX_OBJ $ARCH_UM M=$PWD/$1 >$1/build.log 2>&1])
 714         AS_IF([AC_TRY_COMMAND([$2])], [$3], [$4])
 715 ])
 716
 717 dnl #
 718 dnl # ZFS_LINUX_TEST_COMPILE
 719 dnl #
 720 dnl # Perform a full compile excluding the final modpost phase.
 721 dnl #
 722 AC_DEFUN([ZFS_LINUX_TEST_COMPILE], [
 723         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 724                 mv $2/Makefile $2/Makefile.compile.$1
 725                 mv $2/build.log $2/build.log.$1
 726         ],[
 727                 AC_MSG_ERROR([
 728         *** Unable to compile test source to determine kernel interfaces.])
 729         ], [yes], [])
 730 ])
 731
 732 dnl #
 733 dnl # ZFS_LINUX_TEST_MODPOST
 734 dnl #
 735 dnl # Perform a full compile including the modpost phase.  This may
 736 dnl # be an incremental build if the objects have already been built.
 737 dnl #
 738 AC_DEFUN([ZFS_LINUX_TEST_MODPOST], [
 739         ZFS_LINUX_COMPILE([$2], [test -f $2/build.log], [
 740                 mv $2/Makefile $2/Makefile.modpost.$1
 741                 cat $2/build.log >>build/build.log.$1
 742         ],[
 743                 AC_MSG_ERROR([
 744         *** Unable to modpost test source to determine kernel interfaces.])
 745         ], [], [yes])
 746 ])
 747
 748 dnl #
 749 dnl # Perform the compilation of the test cases in two phases.
 750 dnl #
 751 dnl # Phase 1) attempt to build the object files for all of the tests
 752 dnl #          defined by the ZFS_LINUX_TEST_SRC macro.  But do not
 753 dnl #          perform the final modpost stage.
 754 dnl #
 755 dnl # Phase 2) disable all tests which failed the initial compilation,
 756 dnl #          then invoke the final modpost step for the remaining tests.
 757 dnl #
 758 dnl # This allows us efficiently build the test cases in parallel while
 759 dnl # remaining resilient to build failures which are expected when
 760 dnl # detecting the available kernel interfaces.
 761 dnl #
 762 dnl # The maximum allowed parallelism can be controlled by setting the
 763 dnl # TEST_JOBS environment variable.  Otherwise, it default to $(nproc).
 764 dnl #
 765 AC_DEFUN([ZFS_LINUX_TEST_COMPILE_ALL], [
 766         dnl # Phase 1 - Compilation only, final linking is skipped.
 767         ZFS_LINUX_TEST_COMPILE([$1], [build])
 768
 769         dnl #
 770         dnl # Phase 2 - When building external modules disable test cases
 771         dnl # which failed to compile and invoke modpost to verify the
 772         dnl # final linking.
 773         dnl #
 774         dnl # Test names suffixed with '_license' call modpost independently
 775         dnl # to ensure that a single incompatibility does not result in the
 776         dnl # modpost phase exiting early.  This check is not performed on
 777         dnl # every symbol since the majority are compatible and doing so
 778         dnl # would significantly slow down this phase.
 779         dnl #
 780         dnl # When configuring for builtin (--enable-linux-builtin)
 781         dnl # fake the linking step artificially create the expected .ko
 782         dnl # files for tests which did compile.  This is required for
 783         dnl # kernels which do not have loadable module support or have
 784         dnl # not yet been built.
 785         dnl #
 786         AS_IF([test "x$enable_linux_builtin" = "xno"], [
 787                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 788                     build/Makefile.compile.$1); do
 789                         name=${dir%/}
 790                         AS_IF([test -f build/$name/$name.o], [
 791                                 AS_IF([test "${name##*_}" = "license"], [
 792                                         ZFS_LINUX_TEST_MODPOST([$1],
 793                                             [build/$name])
 794                                         echo "obj-n += $dir" >>build/Makefile
 795                                 ], [
 796                                         echo "obj-m += $dir" >>build/Makefile
 797                                 ])
 798                         ], [
 799                                 echo "obj-n += $dir" >>build/Makefile
 800                         ])
 801                 done
 802
 803                 ZFS_LINUX_TEST_MODPOST([$1], [build])
 804         ], [
 805                 for dir in $(awk '/^obj-m/ { print [$]3 }' \
 806                     build/Makefile.compile.$1); do
 807                         name=${dir%/}
 808                         AS_IF([test -f build/$name/$name.o], [
 809                                 touch build/$name/$name.ko
 810                         ])
 811                 done
 812         ])
 813 ])
 814
 815 dnl #
 816 dnl # ZFS_LINUX_TEST_SRC
 817 dnl #
 818 dnl # $1 - name
 819 dnl # $2 - global
 820 dnl # $3 - source
 821 dnl # $4 - extra cflags
 822 dnl # $5 - check license-compatibility
 823 dnl #
 824 dnl # Check if the test source is buildable at all and then if it is
 825 dnl # license compatible.
 826 dnl #
 827 dnl # N.B because all of the test cases are compiled in parallel they
 828 dnl # must never depend on the results of previous tests.  Each test
 829 dnl # needs to be entirely independent.
 830 dnl #
 831 AC_DEFUN([ZFS_LINUX_TEST_SRC], [
 832         ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM([[$2]], [[$3]],
 833             [["Dual BSD/GPL"]])], [$1])
 834         ZFS_LINUX_CONFTEST_MAKEFILE([$1], [yes], [$4])
 835
 836         AS_IF([ test -n "$5" ], [
 837                 ZFS_LINUX_CONFTEST_C([ZFS_LINUX_TEST_PROGRAM(
 838                     [[$2]], [[$3]], [[$5]])], [$1_license])
 839                 ZFS_LINUX_CONFTEST_MAKEFILE([$1_license], [yes], [$4])
 840         ])
 841 ])
 842
 843 dnl #
 844 dnl # ZFS_LINUX_TEST_RESULT
 845 dnl #
 846 dnl # $1 - name of a test source (ZFS_LINUX_TEST_SRC)
 847 dnl # $2 - run on success (valid .ko generated)
 848 dnl # $3 - run on failure (unable to compile)
 849 dnl #
 850 AC_DEFUN([ZFS_LINUX_TEST_RESULT], [
 851         AS_IF([test -d build/$1], [
 852                 AS_IF([test -f build/$1/$1.ko], [$2], [$3])
 853         ], [
 854                 AC_MSG_ERROR([
 855         *** No matching source for the "$1" test, check that
 856         *** both the test source and result macros refer to the same name.
 857                 ])
 858         ])
 859 ])
 860
 861 dnl #
 862 dnl # ZFS_LINUX_TEST_ERROR
 863 dnl #
 864 dnl # Generic error message which can be used when none of the expected
 865 dnl # kernel interfaces were detected.
 866 dnl #
 867 AC_DEFUN([ZFS_LINUX_TEST_ERROR], [
 868         AC_MSG_ERROR([
 869         *** None of the expected "$1" interfaces were detected.
 870         *** This may be because your kernel version is newer than what is
 871         *** supported, or you are using a patched custom kernel with
 872         *** incompatible modifications.
 873         ***
 874         *** ZFS Version: $ZFS_META_ALIAS
 875         *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
 876         ])
 877 ])
 878
 879 dnl #
 880 dnl # ZFS_LINUX_TEST_RESULT_SYMBOL
 881 dnl #
 882 dnl # Like ZFS_LINUX_TEST_RESULT except ZFS_CHECK_SYMBOL_EXPORT is called to
 883 dnl # verify symbol exports, unless --enable-linux-builtin was provided to
 884 dnl # configure.
 885 dnl #
 886 AC_DEFUN([ZFS_LINUX_TEST_RESULT_SYMBOL], [
 887         AS_IF([ ! test -f build/$1/$1.ko], [
 888                 $5
 889         ], [
 890                 AS_IF([test "x$enable_linux_builtin" != "xyes"], [
 891                         ZFS_CHECK_SYMBOL_EXPORT([$2], [$3], [$4], [$5])
 892                 ], [
 893                         $4
 894                 ])
 895         ])
 896 ])
 897
 898 dnl #
 899 dnl # ZFS_LINUX_COMPILE_IFELSE
 900 dnl #
 901 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 902         ZFS_LINUX_TEST_REMOVE([conftest])
 903
 904         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1], [conftest])])
 905         m4_ifvaln([$5], [ZFS_LINUX_CONFTEST_H([$5], [conftest])],
 906             [ZFS_LINUX_CONFTEST_H([], [conftest])])
 907
 908         ZFS_LINUX_CONFTEST_MAKEFILE([conftest], [no],
 909             [m4_ifvaln([$5], [-I$PWD/build/conftest], [])])
 910         ZFS_LINUX_COMPILE([build/conftest], [$2], [$3], [$4], [], [])
 911 ])
 912
 913 dnl #
 914 dnl # ZFS_LINUX_TRY_COMPILE
 915 dnl #
 916 dnl # $1 - global
 917 dnl # $2 - source
 918 dnl # $3 - run on success (valid .ko generated)
 919 dnl # $4 - run on failure (unable to compile)
 920 dnl #
 921 dnl # When configuring as builtin (--enable-linux-builtin) for kernels
 922 dnl # without loadable module support (CONFIG_MODULES=n) only the object
 923 dnl # file is created.  See ZFS_LINUX_TEST_COMPILE_ALL for details.
 924 dnl #
 925 AC_DEFUN([ZFS_LINUX_TRY_COMPILE], [
 926         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
 927                 ZFS_LINUX_COMPILE_IFELSE(
 928                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 929                     [[ZFS_META_LICENSE]])],
 930                     [test -f build/conftest/conftest.o], [$3], [$4])
 931         ], [
 932                 ZFS_LINUX_COMPILE_IFELSE(
 933                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
 934                     [[ZFS_META_LICENSE]])],
 935                     [test -f build/conftest/conftest.ko], [$3], [$4])
 936         ])
 937 ])
 938
 939 dnl #
 940 dnl # ZFS_CHECK_SYMBOL_EXPORT
 941 dnl #
 942 dnl # Check if a symbol is exported on not by consulting the symbols
 943 dnl # file, or optionally the source code.
 944 dnl #
 945 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 946         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 947                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 948         rc=$?
 949         if test $rc -ne 0; then
 950                 export=0
 951                 for file in $2; do
 952                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 953                                 "$LINUX/$file" 2>/dev/null
 954                         rc=$?
 955                         if test $rc -eq 0; then
 956                                 export=1
 957                                 break;
 958                         fi
 959                 done
 960                 if test $export -eq 0; then :
 961                         $4
 962                 else :
 963                         $3
 964                 fi
 965         else :
 966                 $3
 967         fi
 968 ])
 969
 970 dnl #
 971 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 972 dnl #
 973 dnl # Like ZFS_LINUX_TRY_COMPILER except ZFS_CHECK_SYMBOL_EXPORT is called
 974 dnl # to verify symbol exports, unless --enable-linux-builtin was provided
 975 dnl # to configure.
 976 dnl #
 977 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 978         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 979         if test $rc -ne 0; then :
 980                 $6
 981         else
 982                 if test "x$enable_linux_builtin" != xyes; then
 983                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 984                 fi
 985                 if test $rc -ne 0; then :
 986                         $6
 987                 else :
 988                         $5
 989                 fi
 990         fi
 991 ])
 992
 993 dnl #
 994 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 995 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 996 dnl # provided via the fifth parameter
 997 dnl #
 998 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER], [
 999         AS_IF([test "x$enable_linux_builtin" = "xyes"], [
1000                 ZFS_LINUX_COMPILE_IFELSE(
1001                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
1002                     [[ZFS_META_LICENSE]])],
1003                     [test -f build/conftest/conftest.o], [$3], [$4], [$5])
1004         ], [
1005                 ZFS_LINUX_COMPILE_IFELSE(
1006                     [ZFS_LINUX_TEST_PROGRAM([[$1]], [[$2]],
1007                     [[ZFS_META_LICENSE]])],
1008                     [test -f build/conftest/conftest.ko], [$3], [$4], [$5])
1009         ])
1010 ])
1011
1012 dnl #
1013 dnl # AS_VERSION_COMPARE_LE
1014 dnl # like AS_VERSION_COMPARE_LE, but runs $3 if (and only if) $1 <= $2
1015 dnl # AS_VERSION_COMPARE_LE (version-1, version-2, [action-if-less-or-equal], [action-if-greater])
1016 dnl #
1017 AC_DEFUN([AS_VERSION_COMPARE_LE], [
1018         AS_VERSION_COMPARE([$1], [$2], [$3], [$3], [$4])
1019 ])
1020
1021 dnl #
1022 dnl # ZFS_LINUX_REQUIRE_API
1023 dnl # like ZFS_LINUX_TEST_ERROR, except only fails if the kernel is
1024 dnl # at least some specified version.
1025 dnl #
1026 AC_DEFUN([ZFS_LINUX_REQUIRE_API], [
1027         AS_VERSION_COMPARE_LE([$2], [$kernsrcver], [
1028                 AC_MSG_ERROR([
1029                 *** None of the expected "$1" interfaces were detected. This
1030                 *** interface is expected for kernels version "$2" and above.
1031                 *** This may be because your kernel version is newer than what is
1032                 *** supported, or you are using a patched custom kernel with
1033                 *** incompatible modifications.  Newer kernels may have incompatible
1034                 *** APIs.
1035                 ***
1036                 *** ZFS Version: $ZFS_META_ALIAS
1037                 *** Compatible Kernels: $ZFS_META_KVER_MIN - $ZFS_META_KVER_MAX
1038                 ])
1039         ], [
1040                 AC_MSG_RESULT(no)
1041         ])
1042 ])