config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_QAT
   7         ZFS_AC_KERNEL_ACCESS_OK_TYPE
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_MISC_MINOR
  10         ZFS_AC_KERNEL_OBJTOOL
  11         ZFS_AC_KERNEL_CONFIG
  12         ZFS_AC_KERNEL_CTL_NAME
  13         ZFS_AC_KERNEL_PDE_DATA
  14         ZFS_AC_KERNEL_SET_FS_PWD_WITH_CONST
  15         ZFS_AC_KERNEL_2ARGS_VFS_FSYNC
  16         ZFS_AC_KERNEL_FS_STRUCT_SPINLOCK
  17         ZFS_AC_KERNEL_KUIDGID_T
  18         ZFS_AC_KERNEL_FALLOCATE
  19         ZFS_AC_KERNEL_2ARGS_ZLIB_DEFLATE_WORKSPACESIZE
  20         ZFS_AC_KERNEL_RWSEM_SPINLOCK_IS_RAW
  21         ZFS_AC_KERNEL_RWSEM_ACTIVITY
  22         ZFS_AC_KERNEL_RWSEM_ATOMIC_LONG_COUNT
  23         ZFS_AC_KERNEL_SCHED_RT_HEADER
  24         ZFS_AC_KERNEL_SCHED_SIGNAL_HEADER
  25         ZFS_AC_KERNEL_IO_SCHEDULE_TIMEOUT
  26         ZFS_AC_KERNEL_4ARGS_VFS_GETATTR
  27         ZFS_AC_KERNEL_3ARGS_VFS_GETATTR
  28         ZFS_AC_KERNEL_2ARGS_VFS_GETATTR
  29         ZFS_AC_KERNEL_USLEEP_RANGE
  30         ZFS_AC_KERNEL_KMEM_CACHE_ALLOCFLAGS
  31         ZFS_AC_KERNEL_KMEM_CACHE_CREATE_USERCOPY
  32         ZFS_AC_KERNEL_WAIT_ON_BIT
  33         ZFS_AC_KERNEL_WAIT_QUEUE_ENTRY_T
  34         ZFS_AC_KERNEL_WAIT_QUEUE_HEAD_ENTRY
  35         ZFS_AC_KERNEL_INODE_TIMES
  36         ZFS_AC_KERNEL_INODE_LOCK
  37         ZFS_AC_KERNEL_GROUP_INFO_GID
  38         ZFS_AC_KERNEL_WRITE
  39         ZFS_AC_KERNEL_READ
  40         ZFS_AC_KERNEL_TIMER_FUNCTION_TIMER_LIST
  41         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  42         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  43         ZFS_AC_KERNEL_SUPER_USER_NS
  44         ZFS_AC_KERNEL_SUBMIT_BIO
  45         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_CHECK_EVENTS
  46         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  47         ZFS_AC_KERNEL_TYPE_FMODE_T
  48         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  49         ZFS_AC_KERNEL_BLKDEV_REREAD_PART
  50         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  51         ZFS_AC_KERNEL_LOOKUP_BDEV
  52         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  53         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  54         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  55         ZFS_AC_KERNEL_BIO_BVEC_ITER
  56         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  57         ZFS_AC_KERNEL_BIO_SET_DEV
  58         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  59         ZFS_AC_KERNEL_REQ_OP_DISCARD
  60         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  61         ZFS_AC_KERNEL_REQ_OP_FLUSH
  62         ZFS_AC_KERNEL_BIO_BI_OPF
  63         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  64         ZFS_AC_KERNEL_BIO_BI_STATUS
  65         ZFS_AC_KERNEL_BIO_RW_BARRIER
  66         ZFS_AC_KERNEL_BIO_RW_DISCARD
  67         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  68         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_CLEAR
  69         ZFS_AC_KERNEL_BLK_QUEUE_FLAG_SET
  70         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  71         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  72         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  73         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  74         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  75         ZFS_AC_KERNEL_GET_DISK_AND_MODULE
  76         ZFS_AC_KERNEL_GET_DISK_RO
  77         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  78         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  79         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  80         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  81         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  82         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  83         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  84         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  85         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  86         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  87         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  88         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  89         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  90         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  91         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  92         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  93         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  94         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  95         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  96         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  97         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  98         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  99         ZFS_AC_KERNEL_INODE_SET_FLAGS
 100         ZFS_AC_KERNEL_INODE_SET_IVERSION
 101         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
 102         ZFS_AC_KERNEL_SHOW_OPTIONS
 103         ZFS_AC_KERNEL_FILE_INODE
 104         ZFS_AC_KERNEL_FILE_DENTRY
 105         ZFS_AC_KERNEL_FSYNC
 106         ZFS_AC_KERNEL_EVICT_INODE
 107         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
 108         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
 109         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
 110         ZFS_AC_KERNEL_FALLOCATE
 111         ZFS_AC_KERNEL_AIO_FSYNC
 112         ZFS_AC_KERNEL_MKDIR_UMODE_T
 113         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
 114         ZFS_AC_KERNEL_CREATE_NAMEIDATA
 115         ZFS_AC_KERNEL_GET_LINK
 116         ZFS_AC_KERNEL_PUT_LINK
 117         ZFS_AC_KERNEL_TMPFILE
 118         ZFS_AC_KERNEL_TRUNCATE_RANGE
 119         ZFS_AC_KERNEL_AUTOMOUNT
 120         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
 121         ZFS_AC_KERNEL_COMMIT_METADATA
 122         ZFS_AC_KERNEL_CLEAR_INODE
 123         ZFS_AC_KERNEL_SETATTR_PREPARE
 124         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
 125         ZFS_AC_KERNEL_D_MAKE_ROOT
 126         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
 127         ZFS_AC_KERNEL_D_PRUNE_ALIASES
 128         ZFS_AC_KERNEL_D_SET_D_OP
 129         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
 130         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
 131         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
 132         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 133         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 134         ZFS_AC_KERNEL_FST_MOUNT
 135         ZFS_AC_KERNEL_SHRINK
 136         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 137         ZFS_AC_KERNEL_SHRINK_CONTROL_STRUCT
 138         ZFS_AC_KERNEL_SHRINKER_CALLBACK
 139         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 140         ZFS_AC_KERNEL_S_D_OP
 141         ZFS_AC_KERNEL_BDI
 142         ZFS_AC_KERNEL_SET_NLINK
 143         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 144         ZFS_AC_KERNEL_5ARG_SGET
 145         ZFS_AC_KERNEL_LSEEK_EXECUTE
 146         ZFS_AC_KERNEL_VFS_ITERATE
 147         ZFS_AC_KERNEL_VFS_RW_ITERATE
 148         ZFS_AC_KERNEL_VFS_DIRECT_IO
 149         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 150         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 151         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 152         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 153         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 154         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 155         ZFS_AC_KERNEL_FPU
 156         ZFS_AC_KERNEL_KUID_HELPERS
 157         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 158         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 159         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 160         ZFS_AC_KERNEL_CURRENT_TIME
 161         ZFS_AC_KERNEL_GLOBAL_PAGE_STATE
 162         ZFS_AC_KERNEL_ACL_HAS_REFCOUNT
 163         ZFS_AC_KERNEL_USERNS_CAPABILITIES
 164         ZFS_AC_KERNEL_IN_COMPAT_SYSCALL
 165         ZFS_AC_KERNEL_KTIME_GET_COARSE_REAL_TS64
 166         ZFS_AC_KERNEL_TOTALRAM_PAGES_FUNC
 167         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
 168         ZFS_AC_KERNEL_BLK_QUEUE_SECURE_ERASE
 169
 170         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 171                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 172         ])
 173
 174         AC_SUBST(KERNEL_MAKE)
 175 ])
 176
 177 dnl #
 178 dnl # Detect name used for Module.symvers file in kernel
 179 dnl #
 180 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 181         modpost=$LINUX/scripts/Makefile.modpost
 182         AC_MSG_CHECKING([kernel file name for module symbols])
 183         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 184                 AS_IF([grep -q Modules.symvers $modpost], [
 185                         LINUX_SYMBOLS=Modules.symvers
 186                 ], [
 187                         LINUX_SYMBOLS=Module.symvers
 188                 ])
 189
 190                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 191                         AC_MSG_ERROR([
 192         *** Please make sure the kernel devel package for your distribution
 193         *** is installed.  If you are building with a custom kernel, make sure the
 194         *** kernel is configured, built, and the '--with-linux=PATH' configure
 195         *** option refers to the location of the kernel source.])
 196                 ])
 197         ], [
 198                 LINUX_SYMBOLS=NONE
 199         ])
 200         AC_MSG_RESULT($LINUX_SYMBOLS)
 201         AC_SUBST(LINUX_SYMBOLS)
 202 ])
 203
 204 dnl #
 205 dnl # Detect the kernel to be built against
 206 dnl #
 207 AC_DEFUN([ZFS_AC_KERNEL], [
 208         AC_ARG_WITH([linux],
 209                 AS_HELP_STRING([--with-linux=PATH],
 210                 [Path to kernel source]),
 211                 [kernelsrc="$withval"])
 212
 213         AC_ARG_WITH(linux-obj,
 214                 AS_HELP_STRING([--with-linux-obj=PATH],
 215                 [Path to kernel build objects]),
 216                 [kernelbuild="$withval"])
 217
 218         AC_MSG_CHECKING([kernel source directory])
 219         AS_IF([test -z "$kernelsrc"], [
 220                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 221                         headersdir="/lib/modules/$(uname -r)/source"
 222                         sourcelink=$(readlink -f "$headersdir")
 223                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 224                         headersdir="/lib/modules/$(uname -r)/build"
 225                         sourcelink=$(readlink -f "$headersdir")
 226                 ], [
 227                         sourcelink=$(ls -1d /usr/src/kernels/* \
 228                                      /usr/src/linux-* \
 229                                      2>/dev/null | grep -v obj | tail -1)
 230                 ])
 231
 232                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 233                         kernelsrc=`readlink -f ${sourcelink}`
 234                 ], [
 235                         kernelsrc="[Not found]"
 236                 ])
 237         ], [
 238                 AS_IF([test "$kernelsrc" = "NONE"], [
 239                         kernsrcver=NONE
 240                 ])
 241                 withlinux=yes
 242         ])
 243
 244         AC_MSG_RESULT([$kernelsrc])
 245         AS_IF([test ! -d "$kernelsrc"], [
 246                 AC_MSG_ERROR([
 247         *** Please make sure the kernel devel package for your distribution
 248         *** is installed and then try again.  If that fails, you can specify the
 249         *** location of the kernel source with the '--with-linux=PATH' option.])
 250         ])
 251
 252         AC_MSG_CHECKING([kernel build directory])
 253         AS_IF([test -z "$kernelbuild"], [
 254                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 255                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 256                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 257                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 258                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 259                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 260                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 261                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 262                 ], [
 263                         kernelbuild=${kernelsrc}
 264                 ])
 265         ])
 266         AC_MSG_RESULT([$kernelbuild])
 267
 268         AC_MSG_CHECKING([kernel source version])
 269         utsrelease1=$kernelbuild/include/linux/version.h
 270         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 271         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 272         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 273                 utsrelease=linux/version.h
 274         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 275                 utsrelease=linux/utsrelease.h
 276         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 277                 utsrelease=generated/utsrelease.h
 278         ])
 279
 280         AS_IF([test "$utsrelease"], [
 281                 kernsrcver=`(echo "#include <$utsrelease>";
 282                              echo "kernsrcver=UTS_RELEASE") |
 283                              ${CPP} -I $kernelbuild/include - |
 284                              grep "^kernsrcver=" | cut -d \" -f 2`
 285
 286                 AS_IF([test -z "$kernsrcver"], [
 287                         AC_MSG_RESULT([Not found])
 288                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 289                 ])
 290         ], [
 291                 AC_MSG_RESULT([Not found])
 292                 if test "x$enable_linux_builtin" != xyes; then
 293                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 294                 else
 295                         AC_MSG_ERROR([
 296         *** Cannot find UTS_RELEASE definition.
 297         *** Please run 'make prepare' inside the kernel source tree.])
 298                 fi
 299         ])
 300
 301         AC_MSG_RESULT([$kernsrcver])
 302
 303         LINUX=${kernelsrc}
 304         LINUX_OBJ=${kernelbuild}
 305         LINUX_VERSION=${kernsrcver}
 306
 307         AC_SUBST(LINUX)
 308         AC_SUBST(LINUX_OBJ)
 309         AC_SUBST(LINUX_VERSION)
 310
 311         ZFS_AC_MODULE_SYMVERS
 312 ])
 313
 314 dnl #
 315 dnl # Detect the QAT module to be built against
 316 dnl # QAT provides hardware acceleration for data compression:
 317 dnl #   https://01.org/intel-quickassist-technology
 318 dnl # * Download and install QAT driver from the above link
 319 dnl # * Start QAT driver in your system:
 320 dnl #   service qat_service start
 321 dnl # * Enable QAT in ZFS, e.g.:
 322 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 323 dnl #   make
 324 dnl # * Set GZIP compression in ZFS dataset:
 325 dnl #   zfs set compression = gzip <dataset>
 326 dnl # Then the data written to this ZFS pool is compressed
 327 dnl # by QAT accelerator automatically, and de-compressed by
 328 dnl # QAT when read from the pool.
 329 dnl # * Get QAT hardware statistics by:
 330 dnl #   cat /proc/icp_dh895xcc_dev/qat
 331 dnl # * To disable QAT:
 332 dnl #   insmod zfs.ko zfs_qat_disable=1
 333 dnl #
 334 AC_DEFUN([ZFS_AC_QAT], [
 335         AC_ARG_WITH([qat],
 336                 AS_HELP_STRING([--with-qat=PATH],
 337                 [Path to qat source]),
 338                 AS_IF([test "$withval" = "yes"],
 339                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 340                         [qatsrc="$withval"]))
 341
 342         AC_ARG_WITH([qat-obj],
 343                 AS_HELP_STRING([--with-qat-obj=PATH],
 344                 [Path to qat build objects]),
 345                 [qatbuild="$withval"])
 346
 347         AS_IF([test ! -z "${qatsrc}"], [
 348                 AC_MSG_CHECKING([qat source directory])
 349                 AC_MSG_RESULT([$qatsrc])
 350                 QAT_SRC="${qatsrc}/quickassist"
 351                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 352                         AC_MSG_ERROR([
 353                 *** Please make sure the qat driver package is installed
 354                 *** and specify the location of the qat source with the
 355                 *** '--with-qat=PATH' option then try again. Failed to
 356                 *** find cpa.h in:
 357                 ${QAT_SRC}/include])
 358                 ])
 359         ])
 360
 361         AS_IF([test ! -z "${qatsrc}"], [
 362                 AC_MSG_CHECKING([qat build directory])
 363                 AS_IF([test -z "$qatbuild"], [
 364                         qatbuild="${qatsrc}/build"
 365                 ])
 366
 367                 AC_MSG_RESULT([$qatbuild])
 368                 QAT_OBJ=${qatbuild}
 369                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 370                         AC_MSG_ERROR([
 371                 *** Please make sure the qat driver is installed then try again.
 372                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 373                 $QAT_OBJ])
 374                 ])
 375
 376                 AC_SUBST(QAT_SRC)
 377                 AC_SUBST(QAT_OBJ)
 378
 379                 AC_DEFINE(HAVE_QAT, 1,
 380                 [qat is enabled and existed])
 381         ])
 382
 383         dnl #
 384         dnl # Detect the name used for the QAT Module.symvers file.
 385         dnl #
 386         AS_IF([test ! -z "${qatsrc}"], [
 387                 AC_MSG_CHECKING([qat file for module symbols])
 388                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 389
 390                 AS_IF([test -r $QAT_SYMBOLS], [
 391                         AC_MSG_RESULT([$QAT_SYMBOLS])
 392                         AC_SUBST(QAT_SYMBOLS)
 393                 ],[
 394                        AC_MSG_ERROR([
 395                         *** Please make sure the qat driver is installed then try again.
 396                         *** Failed to find Module.symvers in:
 397                         $QAT_SYMBOLS])
 398                         ])
 399                 ])
 400         ])
 401 ])
 402
 403 dnl #
 404 dnl # Basic toolchain sanity check.
 405 dnl #
 406 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 407         AC_MSG_CHECKING([whether modules can be built])
 408         ZFS_LINUX_TRY_COMPILE([],[],[
 409                 AC_MSG_RESULT([yes])
 410         ],[
 411                 AC_MSG_RESULT([no])
 412                 if test "x$enable_linux_builtin" != xyes; then
 413                         AC_MSG_ERROR([*** Unable to build an empty module.])
 414                 else
 415                         AC_MSG_ERROR([
 416         *** Unable to build an empty module.
 417         *** Please run 'make scripts' inside the kernel source tree.])
 418                 fi
 419         ])
 420 ])
 421
 422 dnl #
 423 dnl # Certain kernel build options are not supported.  These must be
 424 dnl # detected at configure time and cause a build failure.  Otherwise
 425 dnl # modules may be successfully built that behave incorrectly.
 426 dnl #
 427 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 428         AS_IF([test "x$cross_compiling" != xyes], [
 429                 AC_RUN_IFELSE([
 430                         AC_LANG_PROGRAM([
 431                                 #include "$LINUX/include/linux/license.h"
 432                         ], [
 433                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 434                         ])
 435                 ], [
 436                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 437                             [Define to 1 if GPL-only symbols can be used])
 438                 ], [
 439                 ])
 440         ])
 441
 442         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 443         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 444         ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS
 445         ZFS_AC_KERNEL_CONFIG_ZLIB_INFLATE
 446         ZFS_AC_KERNEL_CONFIG_ZLIB_DEFLATE
 447 ])
 448
 449 dnl #
 450 dnl # Check configured THREAD_SIZE
 451 dnl #
 452 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 453 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 454 dnl # on newer kernels and some architectures stack usage optimizations can be
 455 dnl # conditionally applied to improve performance without negatively impacting
 456 dnl # stability.
 457 dnl #
 458 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 459         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 460         ZFS_LINUX_TRY_COMPILE([
 461                 #include <linux/module.h>
 462         ],[
 463                 #if (THREAD_SIZE < 16384)
 464                 #error "THREAD_SIZE is less than 16K"
 465                 #endif
 466         ],[
 467                 AC_MSG_RESULT([yes])
 468                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 469         ],[
 470                 AC_MSG_RESULT([no])
 471         ])
 472 ])
 473
 474 dnl #
 475 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 476 dnl #
 477 dnl # This is typically only set for debug kernels because it comes with
 478 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 479 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 480 dnl # This will cause a failure at link time which we'd rather know about
 481 dnl # at compile time.
 482 dnl #
 483 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 484 dnl # with the upstream community we add a check to detect this case.
 485 dnl #
 486 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 487
 488         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 489                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 490                 tmp_flags="$EXTRA_KCFLAGS"
 491                 ZFS_LINUX_TRY_COMPILE([
 492                         #include <linux/module.h>
 493                         #include <linux/mutex.h>
 494
 495                         MODULE_LICENSE("$ZFS_META_LICENSE");
 496                 ],[
 497                         struct mutex lock;
 498
 499                         mutex_init(&lock);
 500                         mutex_lock(&lock);
 501                         mutex_unlock(&lock);
 502                 ],[
 503                         AC_MSG_RESULT(no)
 504                 ],[
 505                         AC_MSG_RESULT(yes)
 506                         AC_MSG_ERROR([
 507         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 508         *** with the CDDL license and will prevent the module linking stage
 509         *** from succeeding.  You must rebuild your kernel without this
 510         *** option enabled.])
 511                 ])
 512                 EXTRA_KCFLAGS="$tmp_flags"
 513         ], [])
 514 ])
 515
 516 dnl #
 517 dnl # Check CONFIG_TRIM_UNUSED_KSYMS
 518 dnl #
 519 dnl # Verify the kernel has CONFIG_TRIM_UNUSED_KSYMS disabled.
 520 dnl #
 521 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_TRIM_UNUSED_KSYMS], [
 522         AC_MSG_CHECKING([whether CONFIG_TRIM_UNUSED_KSYM is disabled])
 523         ZFS_LINUX_TRY_COMPILE([
 524                 #if defined(CONFIG_TRIM_UNUSED_KSYMS)
 525                 #error CONFIG_TRIM_UNUSED_KSYMS not defined
 526                 #endif
 527         ],[ ],[
 528                 AC_MSG_RESULT([yes])
 529         ],[
 530                 AC_MSG_RESULT([no])
 531                 AC_MSG_ERROR([
 532         *** This kernel has unused symbols trimming enabled, please disable.
 533         *** Rebuild the kernel with CONFIG_TRIM_UNUSED_KSYMS=n set.])
 534         ])
 535 ])
 536
 537 dnl #
 538 dnl # ZFS_LINUX_CONFTEST_H
 539 dnl #
 540 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 541 cat - <<_ACEOF >conftest.h
 542 $1
 543 _ACEOF
 544 ])
 545
 546 dnl #
 547 dnl # ZFS_LINUX_CONFTEST_C
 548 dnl #
 549 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 550 cat confdefs.h - <<_ACEOF >conftest.c
 551 $1
 552 _ACEOF
 553 ])
 554
 555 dnl #
 556 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 557 dnl #
 558 m4_define([ZFS_LANG_PROGRAM], [
 559 $1
 560 int
 561 main (void)
 562 {
 563 dnl Do *not* indent the following line: there may be CPP directives.
 564 dnl Don't move the `;' right after for the same reason.
 565 $2
 566   ;
 567   return 0;
 568 }
 569 ])
 570
 571 dnl #
 572 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 573 dnl #
 574 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 575         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 576         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 577         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 578         echo "obj-m := conftest.o" >build/Makefile
 579         modpost_flag=''
 580         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 581         AS_IF(
 582                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $FRAME_LARGER_THAN $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 583                 [$4],
 584                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 585         )
 586         rm -Rf build
 587 ])
 588
 589 dnl #
 590 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 591 dnl #
 592 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 593         [ZFS_LINUX_COMPILE_IFELSE(
 594         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 595         [modules],
 596         [test -s build/conftest.o],
 597         [$3], [$4])
 598 ])
 599
 600 dnl #
 601 dnl # ZFS_LINUX_CONFIG
 602 dnl #
 603 AC_DEFUN([ZFS_LINUX_CONFIG],
 604         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 605         ZFS_LINUX_TRY_COMPILE([
 606                 #include <linux/module.h>
 607         ],[
 608                 #ifndef CONFIG_$1
 609                 #error CONFIG_$1 not #defined
 610                 #endif
 611         ],[
 612                 AC_MSG_RESULT([yes])
 613                 $2
 614         ],[
 615                 AC_MSG_RESULT([no])
 616                 $3
 617         ])
 618 ])
 619
 620 dnl #
 621 dnl # ZFS_CHECK_SYMBOL_EXPORT
 622 dnl # check symbol exported or not
 623 dnl #
 624 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 625         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 626                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 627         rc=$?
 628         if test $rc -ne 0; then
 629                 export=0
 630                 for file in $2; do
 631                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 632                                 "$LINUX/$file" 2>/dev/null
 633                         rc=$?
 634                         if test $rc -eq 0; then
 635                                 export=1
 636                                 break;
 637                         fi
 638                 done
 639                 if test $export -eq 0; then :
 640                         $4
 641                 else :
 642                         $3
 643                 fi
 644         else :
 645                 $3
 646         fi
 647 ])
 648
 649 dnl #
 650 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 651 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 652 dnl # is called if not compiling for builtin
 653 dnl #
 654 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 655         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 656         if test $rc -ne 0; then :
 657                 $6
 658         else
 659                 if test "x$enable_linux_builtin" != xyes; then
 660                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 661                 fi
 662                 if test $rc -ne 0; then :
 663                         $6
 664                 else :
 665                         $5
 666                 fi
 667         fi
 668 ])
 669
 670 dnl #
 671 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 672 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 673 dnl # provided via the fifth parameter
 674 dnl #
 675 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 676         [ZFS_LINUX_COMPILE_IFELSE(
 677         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 678         [modules],
 679         [test -s build/conftest.o],
 680         [$3], [$4], [$5])
 681 ])