config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  11         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  12         ZFS_AC_KERNEL_TYPE_FMODE_T
  13         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  14         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  15         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  16         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  17         ZFS_AC_KERNEL_LOOKUP_BDEV
  18         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  19         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  20         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BIO_BVEC_ITER
  22         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  23         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  24         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  25         ZFS_AC_KERNEL_BIO_RW_SYNC
  26         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  27         ZFS_AC_KERNEL_REQ_SYNC
  28         ZFS_AC_KERNEL_BLK_END_REQUEST
  29         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  30         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  31         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  32         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
  33         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
  34         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  35         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  36         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
  37         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
  38         ZFS_AC_KERNEL_BLK_RQ_BYTES
  39         ZFS_AC_KERNEL_BLK_RQ_POS
  40         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  41         ZFS_AC_KERNEL_GET_DISK_RO
  42         ZFS_AC_KERNEL_GET_GENDISK
  43         ZFS_AC_KERNEL_RQ_IS_SYNC
  44         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
  45         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  46         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  47         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  48         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  49         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  50         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  51         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  52         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  53         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  54         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  55         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  61         ZFS_AC_KERNEL_CURRENT_UMASK
  62         ZFS_AC_KERNEL_SHOW_OPTIONS
  63         ZFS_AC_KERNEL_FILE_INODE
  64         ZFS_AC_KERNEL_FSYNC
  65         ZFS_AC_KERNEL_EVICT_INODE
  66         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  67         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  68         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  69         ZFS_AC_KERNEL_FALLOCATE
  70         ZFS_AC_KERNEL_MKDIR_UMODE_T
  71         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  72         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  73         ZFS_AC_KERNEL_TRUNCATE_RANGE
  74         ZFS_AC_KERNEL_AUTOMOUNT
  75         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  76         ZFS_AC_KERNEL_COMMIT_METADATA
  77         ZFS_AC_KERNEL_CLEAR_INODE
  78         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  79         ZFS_AC_KERNEL_D_MAKE_ROOT
  80         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  81         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  82         ZFS_AC_KERNEL_D_SET_D_OP
  83         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  84         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  85         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  86         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  87         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  88         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  89         ZFS_AC_KERNEL_MOUNT_NODEV
  90         ZFS_AC_KERNEL_SHRINK
  91         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  92         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  93         ZFS_AC_KERNEL_S_D_OP
  94         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  95         ZFS_AC_KERNEL_SET_NLINK
  96         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  97         ZFS_AC_KERNEL_5ARG_SGET
  98         ZFS_AC_KERNEL_LSEEK_EXECUTE
  99         ZFS_AC_KERNEL_VFS_ITERATE
 100         ZFS_AC_KERNEL_VFS_RW_ITERATE
 101
 102         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 103                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 104         ])
 105         AC_SUBST(KERNELMAKE_PARAMS)
 106
 107
 108         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 109         dnl # compiler options are added by the kernel build system.
 110         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 111         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 112         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 113
 114         AC_SUBST(KERNELCPPFLAGS)
 115 ])
 116
 117 dnl #
 118 dnl # Detect name used for Module.symvers file in kernel
 119 dnl #
 120 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 121         modpost=$LINUX/scripts/Makefile.modpost
 122         AC_MSG_CHECKING([kernel file name for module symbols])
 123         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 124                 AS_IF([grep -q Modules.symvers $modpost], [
 125                         LINUX_SYMBOLS=Modules.symvers
 126                 ], [
 127                         LINUX_SYMBOLS=Module.symvers
 128                 ])
 129
 130                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 131                         AC_MSG_ERROR([
 132         *** Please make sure the kernel devel package for your distribution
 133         *** is installed.  If you are building with a custom kernel, make sure the
 134         *** kernel is configured, built, and the '--with-linux=PATH' configure
 135         *** option refers to the location of the kernel source.])
 136                 ])
 137         ], [
 138                 LINUX_SYMBOLS=NONE
 139         ])
 140         AC_MSG_RESULT($LINUX_SYMBOLS)
 141         AC_SUBST(LINUX_SYMBOLS)
 142 ])
 143
 144 dnl #
 145 dnl # Detect the kernel to be built against
 146 dnl #
 147 AC_DEFUN([ZFS_AC_KERNEL], [
 148         AC_ARG_WITH([linux],
 149                 AS_HELP_STRING([--with-linux=PATH],
 150                 [Path to kernel source]),
 151                 [kernelsrc="$withval"])
 152
 153         AC_ARG_WITH(linux-obj,
 154                 AS_HELP_STRING([--with-linux-obj=PATH],
 155                 [Path to kernel build objects]),
 156                 [kernelbuild="$withval"])
 157
 158         AC_MSG_CHECKING([kernel source directory])
 159         AS_IF([test -z "$kernelsrc"], [
 160                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 161                         headersdir="/lib/modules/$(uname -r)/source"
 162                         sourcelink=$(readlink -f "$headersdir")
 163                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 164                         headersdir="/lib/modules/$(uname -r)/build"
 165                         sourcelink=$(readlink -f "$headersdir")
 166                 ], [
 167                         sourcelink=$(ls -1d /usr/src/kernels/* \
 168                                      /usr/src/linux-* \
 169                                      2>/dev/null | grep -v obj | tail -1)
 170                 ])
 171
 172                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 173                         kernelsrc=`readlink -f ${sourcelink}`
 174                 ], [
 175                         kernelsrc="[Not found]"
 176                 ])
 177         ], [
 178                 AS_IF([test "$kernelsrc" = "NONE"], [
 179                         kernsrcver=NONE
 180                 ])
 181         ])
 182
 183         AC_MSG_RESULT([$kernelsrc])
 184         AS_IF([test ! -d "$kernelsrc"], [
 185                 AC_MSG_ERROR([
 186         *** Please make sure the kernel devel package for your distribution
 187         *** is installed and then try again.  If that fails, you can specify the
 188         *** location of the kernel source with the '--with-linux=PATH' option.])
 189         ])
 190
 191         AC_MSG_CHECKING([kernel build directory])
 192         AS_IF([test -z "$kernelbuild"], [
 193                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 194                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 195                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 196                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 197                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 198                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 199                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 200                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 201                 ], [
 202                         kernelbuild=${kernelsrc}
 203                 ])
 204         ])
 205         AC_MSG_RESULT([$kernelbuild])
 206
 207         AC_MSG_CHECKING([kernel source version])
 208         utsrelease1=$kernelbuild/include/linux/version.h
 209         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 210         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 211         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 212                 utsrelease=linux/version.h
 213         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 214                 utsrelease=linux/utsrelease.h
 215         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 216                 utsrelease=generated/utsrelease.h
 217         ])
 218
 219         AS_IF([test "$utsrelease"], [
 220                 kernsrcver=`(echo "#include <$utsrelease>";
 221                              echo "kernsrcver=UTS_RELEASE") |
 222                              cpp -I $kernelbuild/include |
 223                              grep "^kernsrcver=" | cut -d \" -f 2`
 224
 225                 AS_IF([test -z "$kernsrcver"], [
 226                         AC_MSG_RESULT([Not found])
 227                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 228                 ])
 229         ], [
 230                 AC_MSG_RESULT([Not found])
 231                 if test "x$enable_linux_builtin" != xyes; then
 232                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 233                 else
 234                         AC_MSG_ERROR([
 235         *** Cannot find UTS_RELEASE definition.
 236         *** Please run 'make prepare' inside the kernel source tree.])
 237                 fi
 238         ])
 239
 240         AC_MSG_RESULT([$kernsrcver])
 241
 242         LINUX=${kernelsrc}
 243         LINUX_OBJ=${kernelbuild}
 244         LINUX_VERSION=${kernsrcver}
 245
 246         AC_SUBST(LINUX)
 247         AC_SUBST(LINUX_OBJ)
 248         AC_SUBST(LINUX_VERSION)
 249
 250         ZFS_AC_MODULE_SYMVERS
 251 ])
 252
 253
 254 dnl #
 255 dnl # Detect the SPL module to be built against
 256 dnl #
 257 AC_DEFUN([ZFS_AC_SPL], [
 258         AC_ARG_WITH([spl],
 259                 AS_HELP_STRING([--with-spl=PATH],
 260                 [Path to spl source]),
 261                 [splsrc="$withval"])
 262
 263         AC_ARG_WITH([spl-obj],
 264                 AS_HELP_STRING([--with-spl-obj=PATH],
 265                 [Path to spl build objects]),
 266                 [splbuild="$withval"])
 267
 268         AC_ARG_WITH([spl-timeout],
 269                 AS_HELP_STRING([--with-spl-timeout=SECS],
 270                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 271                 [timeout="$withval"], [timeout=0])
 272
 273         dnl #
 274         dnl # The existence of spl.release.in is used to identify a valid
 275         dnl # source directory.  In order of preference:
 276         dnl #
 277         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 278         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 279         splsrc2="/usr/local/src/spl-${VERSION}"
 280         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 281         splsrc4="/usr/src/spl-${VERSION}"
 282         splsrc5="../spl/"
 283         splsrc6="$LINUX"
 284
 285         AC_MSG_CHECKING([spl source directory])
 286         AS_IF([test -z "${splsrc}"], [
 287                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 288                         splsrc=${splsrc0}
 289                 ], [ test -e "${splsrc1}/spl.release.in"], [
 290                         splsrc=${splsrc1}
 291                 ], [ test -e "${splsrc2}/spl.release.in"], [
 292                         splsrc=${splsrc2}
 293                 ], [ test -e "${splsrc3}/spl.release.in"], [
 294                         splsrc=$(readlink -f "${splsrc3}")
 295                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 296                         splsrc=${splsrc4}
 297                 ], [ test -e "${splsrc5}/spl.release.in"], [
 298                         splsrc=$(readlink -f "${splsrc5}")
 299                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 300                         splsrc=${splsrc6}
 301                 ], [
 302                         splsrc="[Not found]"
 303                 ])
 304         ], [
 305                 AS_IF([test "$splsrc" = "NONE"], [
 306                         splbuild=NONE
 307                         splsrcver=NONE
 308                 ])
 309         ])
 310
 311         AC_MSG_RESULT([$splsrc])
 312         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 313                 AC_MSG_ERROR([
 314         *** Please make sure the kmod spl devel package for your distribution
 315         *** is installed then try again.  If that fails you can specify the
 316         *** location of the spl source with the '--with-spl=PATH' option.])
 317         ])
 318
 319         dnl #
 320         dnl # The existence of the spl_config.h is used to identify a valid
 321         dnl # spl object directory.  In many cases the object and source
 322         dnl # directory are the same, however the objects may also reside
 323         dnl # is a subdirectory named after the kernel version.
 324         dnl #
 325         dnl # This file is supposed to be available after DKMS finishes
 326         dnl # building the SPL kernel module for the target kernel.  The
 327         dnl # '--with-spl-timeout' option can be passed to pause here,
 328         dnl # waiting for the file to appear from a concurrently building
 329         dnl # SPL package.
 330         dnl #
 331         AC_MSG_CHECKING([spl build directory])
 332         while true; do
 333                 AS_IF([test -z "$splbuild"], [
 334                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 335                                 splbuild="${splsrc}/${LINUX_VERSION}"
 336                         ], [ test -e "${splsrc}/spl_config.h" ], [
 337                                 splbuild="${splsrc}"
 338                         ], [
 339                                 splbuild="[Not found]"
 340                         ])
 341                 ])
 342                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 343                         break;
 344                 ], [
 345                         sleep 1
 346                         timeout=$((timeout-1))
 347                 ])
 348         done
 349
 350         AC_MSG_RESULT([$splbuild])
 351         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 352                 AC_MSG_ERROR([
 353         *** Please make sure the kmod spl devel <kernel> package for your
 354         *** distribution is installed then try again.  If that fails you
 355         *** can specify the location of the spl objects with the
 356         *** '--with-spl-obj=PATH' option.])
 357         ])
 358
 359         AC_MSG_CHECKING([spl source version])
 360         AS_IF([test -r $splbuild/spl_config.h &&
 361                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 362
 363                 splsrcver=`(echo "#include <spl_config.h>";
 364                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 365                             cpp -I $splbuild |
 366                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 367         ])
 368
 369         AS_IF([test -z "$splsrcver"], [
 370                 AC_MSG_RESULT([Not found])
 371                 AC_MSG_ERROR([
 372         *** Cannot determine the version of the spl source.
 373         *** Please prepare the spl source before running this script])
 374         ])
 375
 376         AC_MSG_RESULT([$splsrcver])
 377
 378         SPL=${splsrc}
 379         SPL_OBJ=${splbuild}
 380         SPL_VERSION=${splsrcver}
 381
 382         AC_SUBST(SPL)
 383         AC_SUBST(SPL_OBJ)
 384         AC_SUBST(SPL_VERSION)
 385
 386         dnl #
 387         dnl # Detect the name used for the SPL Module.symvers file.  If one
 388         dnl # does not exist this is likely because the SPL has been configured
 389         dnl # but not built.  The '--with-spl-timeout' option can be passed
 390         dnl # to pause here, waiting for the file to appear from a concurrently
 391         dnl # building SPL package.  If the file does not appear in time, a good
 392         dnl # guess is made as to what this file will be named based on what it
 393         dnl # is named in the kernel build products.  This file will first be
 394         dnl # used at link time so if the guess is wrong the build will fail
 395         dnl # then.  This unfortunately means the ZFS package does not contain a
 396         dnl # reliable mechanism to detect symbols exported by the SPL at
 397         dnl # configure time.
 398         dnl #
 399         AC_MSG_CHECKING([spl file name for module symbols])
 400         SPL_SYMBOLS=NONE
 401
 402         while true; do
 403                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 404                         SPL_SYMBOLS=Module.symvers
 405                 ], [test -r $SPL_OBJ/Modules.symvers], [
 406                         SPL_SYMBOLS=Modules.symvers
 407                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 408                         SPL_SYMBOLS=Module.symvers
 409                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 410                         SPL_SYMBOLS=Modules.symvers
 411                 ])
 412
 413                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 414                         break;
 415                 ], [
 416                         sleep 1
 417                         timeout=$((timeout-1))
 418                 ])
 419         done
 420
 421         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 422                 SPL_SYMBOLS=$LINUX_SYMBOLS
 423         ])
 424
 425         AC_MSG_RESULT([$SPL_SYMBOLS])
 426         AC_SUBST(SPL_SYMBOLS)
 427 ])
 428
 429 dnl #
 430 dnl # Basic toolchain sanity check.
 431 dnl #
 432 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 433         AC_MSG_CHECKING([whether modules can be built])
 434         ZFS_LINUX_TRY_COMPILE([],[],[
 435                 AC_MSG_RESULT([yes])
 436         ],[
 437                 AC_MSG_RESULT([no])
 438                 if test "x$enable_linux_builtin" != xyes; then
 439                         AC_MSG_ERROR([*** Unable to build an empty module.])
 440                 else
 441                         AC_MSG_ERROR([
 442         *** Unable to build an empty module.
 443         *** Please run 'make scripts' inside the kernel source tree.])
 444                 fi
 445         ])
 446 ])
 447
 448 dnl #
 449 dnl # Certain kernel build options are not supported.  These must be
 450 dnl # detected at configure time and cause a build failure.  Otherwise
 451 dnl # modules may be successfully built that behave incorrectly.
 452 dnl #
 453 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 454         AC_RUN_IFELSE([
 455                 AC_LANG_PROGRAM([
 456                         #include "$LINUX/include/linux/license.h"
 457                 ], [
 458                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 459                 ])
 460         ], [
 461                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 462                     [Define to 1 if GPL-only symbols can be used])
 463         ], [
 464         ])
 465
 466         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 467 ])
 468
 469 dnl #
 470 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 471 dnl #
 472 dnl # This is typically only set for debug kernels because it comes with
 473 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 474 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 475 dnl # This will cause a failure at link time which we'd rather know about
 476 dnl # at compile time.
 477 dnl #
 478 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 479 dnl # with the upstream community we add a check to detect this case.
 480 dnl #
 481 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 482
 483         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 484                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 485                 tmp_flags="$EXTRA_KCFLAGS"
 486                 ZFS_LINUX_TRY_COMPILE([
 487                         #include <linux/module.h>
 488                         #include <linux/mutex.h>
 489
 490                         MODULE_LICENSE("$ZFS_META_LICENSE");
 491                 ],[
 492                         struct mutex lock;
 493
 494                         mutex_init(&lock);
 495                         mutex_lock(&lock);
 496                         mutex_unlock(&lock);
 497                 ],[
 498                         AC_MSG_RESULT(no)
 499                 ],[
 500                         AC_MSG_RESULT(yes)
 501                         AC_MSG_ERROR([
 502         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 503         *** with the CDDL license and will prevent the module linking stage
 504         *** from succeeding.  You must rebuild your kernel without this
 505         *** option enabled.])
 506                 ])
 507                 EXTRA_KCFLAGS="$tmp_flags"
 508         ], [])
 509 ])
 510
 511 dnl #
 512 dnl # ZFS_LINUX_CONFTEST_H
 513 dnl #
 514 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 515 cat - <<_ACEOF >conftest.h
 516 $1
 517 _ACEOF
 518 ])
 519
 520 dnl #
 521 dnl # ZFS_LINUX_CONFTEST_C
 522 dnl #
 523 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 524 cat confdefs.h - <<_ACEOF >conftest.c
 525 $1
 526 _ACEOF
 527 ])
 528
 529 dnl #
 530 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 531 dnl #
 532 m4_define([ZFS_LANG_PROGRAM], [
 533 $1
 534 int
 535 main (void)
 536 {
 537 dnl Do *not* indent the following line: there may be CPP directives.
 538 dnl Don't move the `;' right after for the same reason.
 539 $2
 540   ;
 541   return 0;
 542 }
 543 ])
 544
 545 dnl #
 546 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 547 dnl #
 548 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 549         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 550         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 551         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 552         echo "obj-m := conftest.o" >build/Makefile
 553         modpost_flag=''
 554         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 555         AS_IF(
 556                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 557                 [$4],
 558                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 559         )
 560         rm -Rf build
 561 ])
 562
 563 dnl #
 564 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 565 dnl #
 566 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 567         [ZFS_LINUX_COMPILE_IFELSE(
 568         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 569         [modules],
 570         [test -s build/conftest.o],
 571         [$3], [$4])
 572 ])
 573
 574 dnl #
 575 dnl # ZFS_LINUX_CONFIG
 576 dnl #
 577 AC_DEFUN([ZFS_LINUX_CONFIG],
 578         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 579         ZFS_LINUX_TRY_COMPILE([
 580                 #include <linux/module.h>
 581         ],[
 582                 #ifndef CONFIG_$1
 583                 #error CONFIG_$1 not #defined
 584                 #endif
 585         ],[
 586                 AC_MSG_RESULT([yes])
 587                 $2
 588         ],[
 589                 AC_MSG_RESULT([no])
 590                 $3
 591         ])
 592 ])
 593
 594 dnl #
 595 dnl # ZFS_CHECK_SYMBOL_EXPORT
 596 dnl # check symbol exported or not
 597 dnl #
 598 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 599         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 600                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 601         rc=$?
 602         if test $rc -ne 0; then
 603                 export=0
 604                 for file in $2; do
 605                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 606                                 "$LINUX/$file" 2>/dev/null
 607                         rc=$?
 608                         if test $rc -eq 0; then
 609                                 export=1
 610                                 break;
 611                         fi
 612                 done
 613                 if test $export -eq 0; then :
 614                         $4
 615                 else :
 616                         $3
 617                 fi
 618         else :
 619                 $3
 620         fi
 621 ])
 622
 623 dnl #
 624 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 625 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 626 dnl # is called if not compiling for builtin
 627 dnl #
 628 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 629         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 630         if test $rc -ne 0; then :
 631                 $6
 632         else
 633                 if test "x$enable_linux_builtin" != xyes; then
 634                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 635                 fi
 636                 if test $rc -ne 0; then :
 637                         $6
 638                 else :
 639                         $5
 640                 fi
 641         fi
 642 ])
 643
 644 dnl #
 645 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 646 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 647 dnl # provided via the fifth parameter
 648 dnl #
 649 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 650         [ZFS_LINUX_COMPILE_IFELSE(
 651         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 652         [modules],
 653         [test -s build/conftest.o],
 654         [$3], [$4], [$5])
 655 ])