config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_QAT
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  12         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  13         ZFS_AC_KERNEL_SUPER_USER_NS
  14         ZFS_AC_KERNEL_SUBMIT_BIO
  15         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  16         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  17         ZFS_AC_KERNEL_TYPE_FMODE_T
  18         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  19         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  20         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  21         ZFS_AC_KERNEL_LOOKUP_BDEV
  22         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  23         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  24         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  25         ZFS_AC_KERNEL_BIO_BVEC_ITER
  26         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  27         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  28         ZFS_AC_KERNEL_REQ_OP_DISCARD
  29         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  30         ZFS_AC_KERNEL_REQ_OP_FLUSH
  31         ZFS_AC_KERNEL_BIO_BI_OPF
  32         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  33         ZFS_AC_KERNEL_BIO_BI_STATUS
  34         ZFS_AC_KERNEL_BIO_RW_BARRIER
  35         ZFS_AC_KERNEL_BIO_RW_DISCARD
  36         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  37         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  38         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  39         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  40         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  41         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  42         ZFS_AC_KERNEL_GET_DISK_RO
  43         ZFS_AC_KERNEL_GET_GENDISK
  44         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  45         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  46         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  47         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  48         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  49         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  50         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  51         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  52         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  53         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  54         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  55         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  56         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  57         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  58         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  63         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  64         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  65         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  66         ZFS_AC_KERNEL_INODE_SET_FLAGS
  67         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  68         ZFS_AC_KERNEL_SHOW_OPTIONS
  69         ZFS_AC_KERNEL_FILE_INODE
  70         ZFS_AC_KERNEL_FILE_DENTRY
  71         ZFS_AC_KERNEL_FSYNC
  72         ZFS_AC_KERNEL_EVICT_INODE
  73         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  74         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  75         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  76         ZFS_AC_KERNEL_FALLOCATE
  77         ZFS_AC_KERNEL_AIO_FSYNC
  78         ZFS_AC_KERNEL_MKDIR_UMODE_T
  79         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  80         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  81         ZFS_AC_KERNEL_GET_LINK
  82         ZFS_AC_KERNEL_PUT_LINK
  83         ZFS_AC_KERNEL_TMPFILE
  84         ZFS_AC_KERNEL_TRUNCATE_RANGE
  85         ZFS_AC_KERNEL_AUTOMOUNT
  86         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  87         ZFS_AC_KERNEL_COMMIT_METADATA
  88         ZFS_AC_KERNEL_CLEAR_INODE
  89         ZFS_AC_KERNEL_SETATTR_PREPARE
  90         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  91         ZFS_AC_KERNEL_D_MAKE_ROOT
  92         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  93         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  94         ZFS_AC_KERNEL_D_SET_D_OP
  95         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  96         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  97         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  98         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  99         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 100         ZFS_AC_KERNEL_MOUNT_NODEV
 101         ZFS_AC_KERNEL_SHRINK
 102         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 103         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 104         ZFS_AC_KERNEL_S_D_OP
 105         ZFS_AC_KERNEL_BDI
 106         ZFS_AC_KERNEL_SET_NLINK
 107         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 108         ZFS_AC_KERNEL_5ARG_SGET
 109         ZFS_AC_KERNEL_LSEEK_EXECUTE
 110         ZFS_AC_KERNEL_VFS_ITERATE
 111         ZFS_AC_KERNEL_VFS_RW_ITERATE
 112         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 113         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 114         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 115         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 116         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 117         ZFS_AC_KERNEL_FPU
 118         ZFS_AC_KERNEL_KUID_HELPERS
 119         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 120         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 121         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 122         ZFS_AC_KERNEL_CURRENT_TIME
 123
 124         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 125                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 126         ])
 127         AC_SUBST(KERNELMAKE_PARAMS)
 128
 129
 130         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 131         dnl # compiler options are added by the kernel build system.
 132         KERNELCPPFLAGS="$KERNELCPPFLAGS -std=gnu99"
 133         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wno-declaration-after-statement"
 134         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 135         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 136         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 137         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 138
 139         AC_SUBST(KERNELCPPFLAGS)
 140 ])
 141
 142 dnl #
 143 dnl # Detect name used for Module.symvers file in kernel
 144 dnl #
 145 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 146         modpost=$LINUX/scripts/Makefile.modpost
 147         AC_MSG_CHECKING([kernel file name for module symbols])
 148         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 149                 AS_IF([grep -q Modules.symvers $modpost], [
 150                         LINUX_SYMBOLS=Modules.symvers
 151                 ], [
 152                         LINUX_SYMBOLS=Module.symvers
 153                 ])
 154
 155                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 156                         AC_MSG_ERROR([
 157         *** Please make sure the kernel devel package for your distribution
 158         *** is installed.  If you are building with a custom kernel, make sure the
 159         *** kernel is configured, built, and the '--with-linux=PATH' configure
 160         *** option refers to the location of the kernel source.])
 161                 ])
 162         ], [
 163                 LINUX_SYMBOLS=NONE
 164         ])
 165         AC_MSG_RESULT($LINUX_SYMBOLS)
 166         AC_SUBST(LINUX_SYMBOLS)
 167 ])
 168
 169 dnl #
 170 dnl # Detect the kernel to be built against
 171 dnl #
 172 AC_DEFUN([ZFS_AC_KERNEL], [
 173         AC_ARG_WITH([linux],
 174                 AS_HELP_STRING([--with-linux=PATH],
 175                 [Path to kernel source]),
 176                 [kernelsrc="$withval"])
 177
 178         AC_ARG_WITH(linux-obj,
 179                 AS_HELP_STRING([--with-linux-obj=PATH],
 180                 [Path to kernel build objects]),
 181                 [kernelbuild="$withval"])
 182
 183         AC_MSG_CHECKING([kernel source directory])
 184         AS_IF([test -z "$kernelsrc"], [
 185                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 186                         headersdir="/lib/modules/$(uname -r)/source"
 187                         sourcelink=$(readlink -f "$headersdir")
 188                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 189                         headersdir="/lib/modules/$(uname -r)/build"
 190                         sourcelink=$(readlink -f "$headersdir")
 191                 ], [
 192                         sourcelink=$(ls -1d /usr/src/kernels/* \
 193                                      /usr/src/linux-* \
 194                                      2>/dev/null | grep -v obj | tail -1)
 195                 ])
 196
 197                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 198                         kernelsrc=`readlink -f ${sourcelink}`
 199                 ], [
 200                         kernelsrc="[Not found]"
 201                 ])
 202         ], [
 203                 AS_IF([test "$kernelsrc" = "NONE"], [
 204                         kernsrcver=NONE
 205                 ])
 206                 withlinux=yes
 207         ])
 208
 209         AC_MSG_RESULT([$kernelsrc])
 210         AS_IF([test ! -d "$kernelsrc"], [
 211                 AC_MSG_ERROR([
 212         *** Please make sure the kernel devel package for your distribution
 213         *** is installed and then try again.  If that fails, you can specify the
 214         *** location of the kernel source with the '--with-linux=PATH' option.])
 215         ])
 216
 217         AC_MSG_CHECKING([kernel build directory])
 218         AS_IF([test -z "$kernelbuild"], [
 219                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 220                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 221                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 222                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 223                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 224                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 225                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 226                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 227                 ], [
 228                         kernelbuild=${kernelsrc}
 229                 ])
 230         ])
 231         AC_MSG_RESULT([$kernelbuild])
 232
 233         AC_MSG_CHECKING([kernel source version])
 234         utsrelease1=$kernelbuild/include/linux/version.h
 235         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 236         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 237         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 238                 utsrelease=linux/version.h
 239         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 240                 utsrelease=linux/utsrelease.h
 241         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 242                 utsrelease=generated/utsrelease.h
 243         ])
 244
 245         AS_IF([test "$utsrelease"], [
 246                 kernsrcver=`(echo "#include <$utsrelease>";
 247                              echo "kernsrcver=UTS_RELEASE") |
 248                              cpp -I $kernelbuild/include |
 249                              grep "^kernsrcver=" | cut -d \" -f 2`
 250
 251                 AS_IF([test -z "$kernsrcver"], [
 252                         AC_MSG_RESULT([Not found])
 253                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 254                 ])
 255         ], [
 256                 AC_MSG_RESULT([Not found])
 257                 if test "x$enable_linux_builtin" != xyes; then
 258                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 259                 else
 260                         AC_MSG_ERROR([
 261         *** Cannot find UTS_RELEASE definition.
 262         *** Please run 'make prepare' inside the kernel source tree.])
 263                 fi
 264         ])
 265
 266         AC_MSG_RESULT([$kernsrcver])
 267
 268         LINUX=${kernelsrc}
 269         LINUX_OBJ=${kernelbuild}
 270         LINUX_VERSION=${kernsrcver}
 271
 272         AC_SUBST(LINUX)
 273         AC_SUBST(LINUX_OBJ)
 274         AC_SUBST(LINUX_VERSION)
 275
 276         ZFS_AC_MODULE_SYMVERS
 277 ])
 278
 279
 280 dnl #
 281 dnl # Detect the SPL module to be built against
 282 dnl #
 283 AC_DEFUN([ZFS_AC_SPL], [
 284         AC_ARG_WITH([spl],
 285                 AS_HELP_STRING([--with-spl=PATH],
 286                 [Path to spl source]),
 287                 AS_IF([test "$withval" = "yes"],
 288                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 289                         [splsrc="$withval"]))
 290
 291         AC_ARG_WITH([spl-obj],
 292                 AS_HELP_STRING([--with-spl-obj=PATH],
 293                 [Path to spl build objects]),
 294                 [splbuild="$withval"])
 295
 296         AC_ARG_WITH([spl-timeout],
 297                 AS_HELP_STRING([--with-spl-timeout=SECS],
 298                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 299                 [timeout="$withval"], [timeout=0])
 300
 301         dnl #
 302         dnl # The existence of spl.release.in is used to identify a valid
 303         dnl # source directory.  In order of preference:
 304         dnl #
 305         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 306         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 307         splsrc2="/usr/local/src/spl-${VERSION}"
 308         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 309         splsrc4="/usr/src/spl-${VERSION}"
 310         splsrc5="../spl/"
 311         splsrc6="$LINUX"
 312
 313         AC_MSG_CHECKING([spl source directory])
 314         AS_IF([test -z "${splsrc}"], [
 315                 [all_spl_sources="
 316                 ${splsrc0}
 317                 ${splsrc1}
 318                 ${splsrc2}
 319                 ${splsrc3}
 320                 ${splsrc4}
 321                 ${splsrc5}
 322                 ${splsrc6}"],
 323                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 324                         splsrc=${splsrc0}
 325                 ], [ test -e "${splsrc1}/spl.release.in"], [
 326                         splsrc=${splsrc1}
 327                 ], [ test -e "${splsrc2}/spl.release.in"], [
 328                         splsrc=${splsrc2}
 329                 ], [ test -e "${splsrc3}/spl.release.in"], [
 330                         splsrc=$(readlink -f "${splsrc3}")
 331                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 332                         splsrc=${splsrc4}
 333                 ], [ test -e "${splsrc5}/spl.release.in"], [
 334                         splsrc=$(readlink -f "${splsrc5}")
 335                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 336                         splsrc=${splsrc6}
 337                 ], [
 338                         splsrc="[Not found]"
 339                 ])
 340         ], [
 341                 [all_spl_sources="$withval"],
 342                 AS_IF([test "$splsrc" = "NONE"], [
 343                         splbuild=NONE
 344                         splsrcver=NONE
 345                 ])
 346         ])
 347
 348         AC_MSG_RESULT([$splsrc])
 349         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 350                 AC_MSG_ERROR([
 351         *** Please make sure the kmod spl devel package for your distribution
 352         *** is installed then try again.  If that fails you can specify the
 353         *** location of the spl source with the '--with-spl=PATH' option.
 354         *** The spl version must match the version of ZFS you are building,
 355         *** ${VERSION}.  Failed to find spl.release.in in the following:
 356         $all_spl_sources])
 357         ])
 358
 359         dnl #
 360         dnl # The existence of the spl_config.h is used to identify a valid
 361         dnl # spl object directory.  In many cases the object and source
 362         dnl # directory are the same, however the objects may also reside
 363         dnl # is a subdirectory named after the kernel version.
 364         dnl #
 365         dnl # This file is supposed to be available after DKMS finishes
 366         dnl # building the SPL kernel module for the target kernel.  The
 367         dnl # '--with-spl-timeout' option can be passed to pause here,
 368         dnl # waiting for the file to appear from a concurrently building
 369         dnl # SPL package.
 370         dnl #
 371         AC_MSG_CHECKING([spl build directory])
 372
 373         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 374         ${splsrc}"
 375
 376         while true; do
 377                 AS_IF([test -z "$splbuild"], [
 378                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 379                                 splbuild="${splsrc}/${LINUX_VERSION}"
 380                         ], [ test -e "${splsrc}/spl_config.h" ], [
 381                                 splbuild="${splsrc}"
 382                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 383                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 384                         ], [
 385                                 splbuild="[Not found]"
 386                         ])
 387                 ])
 388                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 389                         break;
 390                 ], [
 391                         sleep 1
 392                         timeout=$((timeout-1))
 393                 ])
 394         done
 395
 396         AC_MSG_RESULT([$splbuild])
 397         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 398                 AC_MSG_ERROR([
 399         *** Please make sure the kmod spl devel <kernel> package for your
 400         *** distribution is installed then try again.  If that fails you
 401         *** can specify the location of the spl objects with the
 402         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 403         *** any of the following:
 404         $all_spl_config_locs])
 405         ])
 406
 407         AC_MSG_CHECKING([spl source version])
 408         AS_IF([test -r $splbuild/spl_config.h &&
 409                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 410
 411                 splsrcver=`(echo "#include <spl_config.h>";
 412                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 413                             cpp -I $splbuild |
 414                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 415         ])
 416
 417         AS_IF([test -z "$splsrcver"], [
 418                 AC_MSG_RESULT([Not found])
 419                 AC_MSG_ERROR([
 420         *** Cannot determine the version of the spl source.
 421         *** Please prepare the spl source before running this script])
 422         ])
 423
 424         AC_MSG_RESULT([$splsrcver])
 425
 426         SPL=${splsrc}
 427         SPL_OBJ=${splbuild}
 428         SPL_VERSION=${splsrcver}
 429
 430         AC_SUBST(SPL)
 431         AC_SUBST(SPL_OBJ)
 432         AC_SUBST(SPL_VERSION)
 433
 434         dnl #
 435         dnl # Detect the name used for the SPL Module.symvers file.  If one
 436         dnl # does not exist this is likely because the SPL has been configured
 437         dnl # but not built.  The '--with-spl-timeout' option can be passed
 438         dnl # to pause here, waiting for the file to appear from a concurrently
 439         dnl # building SPL package.  If the file does not appear in time, a good
 440         dnl # guess is made as to what this file will be named based on what it
 441         dnl # is named in the kernel build products.  This file will first be
 442         dnl # used at link time so if the guess is wrong the build will fail
 443         dnl # then.  This unfortunately means the ZFS package does not contain a
 444         dnl # reliable mechanism to detect symbols exported by the SPL at
 445         dnl # configure time.
 446         dnl #
 447         AC_MSG_CHECKING([spl file name for module symbols])
 448         SPL_SYMBOLS=NONE
 449
 450         while true; do
 451                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 452                         SPL_SYMBOLS=Module.symvers
 453                 ], [test -r $SPL_OBJ/Modules.symvers], [
 454                         SPL_SYMBOLS=Modules.symvers
 455                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 456                         SPL_SYMBOLS=Module.symvers
 457                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 458                         SPL_SYMBOLS=Modules.symvers
 459                 ])
 460
 461                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 462                         break;
 463                 ], [
 464                         sleep 1
 465                         timeout=$((timeout-1))
 466                 ])
 467         done
 468
 469         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 470                 SPL_SYMBOLS=$LINUX_SYMBOLS
 471         ])
 472
 473         AC_MSG_RESULT([$SPL_SYMBOLS])
 474         AC_SUBST(SPL_SYMBOLS)
 475 ])
 476
 477 dnl #
 478 dnl # Detect the QAT module to be built against
 479 dnl # QAT provides hardware acceleration for data compression:
 480 dnl #   https://01.org/intel-quickassist-technology
 481 dnl # * Download and install QAT driver from the above link
 482 dnl # * Start QAT driver in your system:
 483 dnl #   service qat_service start
 484 dnl # * Enable QAT in ZFS, e.g.:
 485 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 486 dnl #   make
 487 dnl # * Set GZIP compression in ZFS dataset:
 488 dnl #   zfs set compression = gzip <dataset>
 489 dnl # Then the data written to this ZFS pool is compressed
 490 dnl # by QAT accelerator automatically, and de-compressed by
 491 dnl # QAT when read from the pool.
 492 dnl # * Get QAT hardware statistics by:
 493 dnl #   cat /proc/icp_dh895xcc_dev/qat
 494 dnl # * To disable QAT:
 495 dnl #   insmod zfs.ko zfs_qat_disable=1
 496 dnl #
 497 AC_DEFUN([ZFS_AC_QAT], [
 498         AC_ARG_WITH([qat],
 499                 AS_HELP_STRING([--with-qat=PATH],
 500                 [Path to qat source]),
 501                 AS_IF([test "$withval" = "yes"],
 502                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 503                         [qatsrc="$withval"]))
 504
 505         AC_ARG_WITH([qat-obj],
 506                 AS_HELP_STRING([--with-qat-obj=PATH],
 507                 [Path to qat build objects]),
 508                 [qatbuild="$withval"])
 509
 510         AS_IF([test ! -z "${qatsrc}"], [
 511                 AC_MSG_CHECKING([qat source directory])
 512                 AC_MSG_RESULT([$qatsrc])
 513                 QAT_SRC="${qatsrc}/quickassist"
 514                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 515                         AC_MSG_ERROR([
 516                 *** Please make sure the qat driver package is installed
 517                 *** and specify the location of the qat source with the
 518                 *** '--with-qat=PATH' option then try again. Failed to
 519                 *** find cpa.h in:
 520                 ${QAT_SRC}/include])
 521                 ])
 522         ])
 523
 524         AS_IF([test ! -z "${qatsrc}"], [
 525                 AC_MSG_CHECKING([qat build directory])
 526                 AS_IF([test -z "$qatbuild"], [
 527                         qatbuild="${qatsrc}/build"
 528                 ])
 529
 530                 AC_MSG_RESULT([$qatbuild])
 531                 QAT_OBJ=${qatbuild}
 532                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko"], [
 533                         AC_MSG_ERROR([
 534                 *** Please make sure the qat driver is installed then try again.
 535                 *** Failed to find icp_qa_al.ko in:
 536                 $QAT_OBJ])
 537                 ])
 538
 539                 AC_SUBST(QAT_SRC)
 540                 AC_SUBST(QAT_OBJ)
 541
 542                 AC_DEFINE(HAVE_QAT, 1,
 543                 [qat is enabled and existed])
 544         ])
 545
 546         dnl #
 547         dnl # Detect the name used for the QAT Module.symvers file.
 548         dnl #
 549         AS_IF([test ! -z "${qatsrc}"], [
 550                 AC_MSG_CHECKING([qat file for module symbols])
 551                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 552
 553                 AS_IF([test -r $QAT_SYMBOLS], [
 554                         AC_MSG_RESULT([$QAT_SYMBOLS])
 555                         AC_SUBST(QAT_SYMBOLS)
 556                 ],[
 557                        AC_MSG_ERROR([
 558                         *** Please make sure the qat driver is installed then try again.
 559                         *** Failed to find Module.symvers in:
 560                         $QAT_SYMBOLS])
 561                         ])
 562                 ])
 563         ])
 564 ])
 565
 566 dnl #
 567 dnl # Basic toolchain sanity check.
 568 dnl #
 569 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 570         AC_MSG_CHECKING([whether modules can be built])
 571         ZFS_LINUX_TRY_COMPILE([],[],[
 572                 AC_MSG_RESULT([yes])
 573         ],[
 574                 AC_MSG_RESULT([no])
 575                 if test "x$enable_linux_builtin" != xyes; then
 576                         AC_MSG_ERROR([*** Unable to build an empty module.])
 577                 else
 578                         AC_MSG_ERROR([
 579         *** Unable to build an empty module.
 580         *** Please run 'make scripts' inside the kernel source tree.])
 581                 fi
 582         ])
 583 ])
 584
 585 dnl #
 586 dnl # Certain kernel build options are not supported.  These must be
 587 dnl # detected at configure time and cause a build failure.  Otherwise
 588 dnl # modules may be successfully built that behave incorrectly.
 589 dnl #
 590 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 591         AS_IF([test "x$cross_compiling" != xyes], [
 592                 AC_RUN_IFELSE([
 593                         AC_LANG_PROGRAM([
 594                                 #include "$LINUX/include/linux/license.h"
 595                         ], [
 596                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 597                         ])
 598                 ], [
 599                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 600                             [Define to 1 if GPL-only symbols can be used])
 601                 ], [
 602                 ])
 603         ])
 604
 605         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 606         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 607 ])
 608
 609 dnl #
 610 dnl # Check configured THREAD_SIZE
 611 dnl #
 612 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 613 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 614 dnl # on newer kernels and some architectures stack usage optimizations can be
 615 dnl # conditionally applied to improve performance without negatively impacting
 616 dnl # stability.
 617 dnl #
 618 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 619         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 620         ZFS_LINUX_TRY_COMPILE([
 621                 #include <linux/module.h>
 622         ],[
 623                 #if (THREAD_SIZE < 16384)
 624                 #error "THREAD_SIZE is less than 16K"
 625                 #endif
 626         ],[
 627                 AC_MSG_RESULT([yes])
 628                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 629         ],[
 630                 AC_MSG_RESULT([no])
 631         ])
 632 ])
 633
 634 dnl #
 635 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 636 dnl #
 637 dnl # This is typically only set for debug kernels because it comes with
 638 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 639 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 640 dnl # This will cause a failure at link time which we'd rather know about
 641 dnl # at compile time.
 642 dnl #
 643 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 644 dnl # with the upstream community we add a check to detect this case.
 645 dnl #
 646 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 647
 648         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 649                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 650                 tmp_flags="$EXTRA_KCFLAGS"
 651                 ZFS_LINUX_TRY_COMPILE([
 652                         #include <linux/module.h>
 653                         #include <linux/mutex.h>
 654
 655                         MODULE_LICENSE("$ZFS_META_LICENSE");
 656                 ],[
 657                         struct mutex lock;
 658
 659                         mutex_init(&lock);
 660                         mutex_lock(&lock);
 661                         mutex_unlock(&lock);
 662                 ],[
 663                         AC_MSG_RESULT(no)
 664                 ],[
 665                         AC_MSG_RESULT(yes)
 666                         AC_MSG_ERROR([
 667         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 668         *** with the CDDL license and will prevent the module linking stage
 669         *** from succeeding.  You must rebuild your kernel without this
 670         *** option enabled.])
 671                 ])
 672                 EXTRA_KCFLAGS="$tmp_flags"
 673         ], [])
 674 ])
 675
 676 dnl #
 677 dnl # ZFS_LINUX_CONFTEST_H
 678 dnl #
 679 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 680 cat - <<_ACEOF >conftest.h
 681 $1
 682 _ACEOF
 683 ])
 684
 685 dnl #
 686 dnl # ZFS_LINUX_CONFTEST_C
 687 dnl #
 688 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 689 cat confdefs.h - <<_ACEOF >conftest.c
 690 $1
 691 _ACEOF
 692 ])
 693
 694 dnl #
 695 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 696 dnl #
 697 m4_define([ZFS_LANG_PROGRAM], [
 698 $1
 699 int
 700 main (void)
 701 {
 702 dnl Do *not* indent the following line: there may be CPP directives.
 703 dnl Don't move the `;' right after for the same reason.
 704 $2
 705   ;
 706   return 0;
 707 }
 708 ])
 709
 710 dnl #
 711 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 712 dnl #
 713 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 714         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 715         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 716         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 717         echo "obj-m := conftest.o" >build/Makefile
 718         modpost_flag=''
 719         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 720         AS_IF(
 721                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 722                 [$4],
 723                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 724         )
 725         rm -Rf build
 726 ])
 727
 728 dnl #
 729 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 730 dnl #
 731 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 732         [ZFS_LINUX_COMPILE_IFELSE(
 733         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 734         [modules],
 735         [test -s build/conftest.o],
 736         [$3], [$4])
 737 ])
 738
 739 dnl #
 740 dnl # ZFS_LINUX_CONFIG
 741 dnl #
 742 AC_DEFUN([ZFS_LINUX_CONFIG],
 743         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 744         ZFS_LINUX_TRY_COMPILE([
 745                 #include <linux/module.h>
 746         ],[
 747                 #ifndef CONFIG_$1
 748                 #error CONFIG_$1 not #defined
 749                 #endif
 750         ],[
 751                 AC_MSG_RESULT([yes])
 752                 $2
 753         ],[
 754                 AC_MSG_RESULT([no])
 755                 $3
 756         ])
 757 ])
 758
 759 dnl #
 760 dnl # ZFS_CHECK_SYMBOL_EXPORT
 761 dnl # check symbol exported or not
 762 dnl #
 763 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 764         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 765                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 766         rc=$?
 767         if test $rc -ne 0; then
 768                 export=0
 769                 for file in $2; do
 770                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 771                                 "$LINUX/$file" 2>/dev/null
 772                         rc=$?
 773                         if test $rc -eq 0; then
 774                                 export=1
 775                                 break;
 776                         fi
 777                 done
 778                 if test $export -eq 0; then :
 779                         $4
 780                 else :
 781                         $3
 782                 fi
 783         else :
 784                 $3
 785         fi
 786 ])
 787
 788 dnl #
 789 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 790 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 791 dnl # is called if not compiling for builtin
 792 dnl #
 793 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 794         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 795         if test $rc -ne 0; then :
 796                 $6
 797         else
 798                 if test "x$enable_linux_builtin" != xyes; then
 799                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 800                 fi
 801                 if test $rc -ne 0; then :
 802                         $6
 803                 else :
 804                         $5
 805                 fi
 806         fi
 807 ])
 808
 809 dnl #
 810 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 811 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 812 dnl # provided via the fifth parameter
 813 dnl #
 814 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 815         [ZFS_LINUX_COMPILE_IFELSE(
 816         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 817         [modules],
 818         [test -s build/conftest.o],
 819         [$3], [$4], [$5])
 820 ])