config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  46         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  47         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  48         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  49         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  50         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  51         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  57         ZFS_AC_KERNE_GET_ACL_HANDLE_CACHE
  58         ZFS_AC_KERNEL_SHOW_OPTIONS
  59         ZFS_AC_KERNEL_FILE_INODE
  60         ZFS_AC_KERNEL_FILE_DENTRY
  61         ZFS_AC_KERNEL_FSYNC
  62         ZFS_AC_KERNEL_EVICT_INODE
  63         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  64         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  66         ZFS_AC_KERNEL_FALLOCATE
  67         ZFS_AC_KERNEL_MKDIR_UMODE_T
  68         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  69         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  70         ZFS_AC_KERNEL_GET_LINK
  71         ZFS_AC_KERNEL_PUT_LINK
  72         ZFS_AC_KERNEL_TRUNCATE_RANGE
  73         ZFS_AC_KERNEL_AUTOMOUNT
  74         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  75         ZFS_AC_KERNEL_COMMIT_METADATA
  76         ZFS_AC_KERNEL_CLEAR_INODE
  77         ZFS_AC_KERNEL_SETATTR_PREPARE
  78         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  79         ZFS_AC_KERNEL_D_MAKE_ROOT
  80         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  81         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  82         ZFS_AC_KERNEL_D_SET_D_OP
  83         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  84         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  85         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  86         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  87         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  88         ZFS_AC_KERNEL_MOUNT_NODEV
  89         ZFS_AC_KERNEL_SHRINK
  90         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  91         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  92         ZFS_AC_KERNEL_S_D_OP
  93         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  94         ZFS_AC_KERNEL_SET_NLINK
  95         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  96         ZFS_AC_KERNEL_5ARG_SGET
  97         ZFS_AC_KERNEL_LSEEK_EXECUTE
  98         ZFS_AC_KERNEL_VFS_ITERATE
  99         ZFS_AC_KERNEL_VFS_RW_ITERATE
 100         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 101         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 102         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 103         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 104         ZFS_AC_KERNEL_FPU
 105         ZFS_AC_KERNEL_KUID_HELPERS
 106         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 107         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 108         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 109
 110         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 111                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 112         ])
 113         AC_SUBST(KERNELMAKE_PARAMS)
 114
 115
 116         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 117         dnl # compiler options are added by the kernel build system.
 118         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 119         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 120         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 121         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 122
 123         AC_SUBST(KERNELCPPFLAGS)
 124 ])
 125
 126 dnl #
 127 dnl # Detect name used for Module.symvers file in kernel
 128 dnl #
 129 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 130         modpost=$LINUX/scripts/Makefile.modpost
 131         AC_MSG_CHECKING([kernel file name for module symbols])
 132         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 133                 AS_IF([grep -q Modules.symvers $modpost], [
 134                         LINUX_SYMBOLS=Modules.symvers
 135                 ], [
 136                         LINUX_SYMBOLS=Module.symvers
 137                 ])
 138
 139                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 140                         AC_MSG_ERROR([
 141         *** Please make sure the kernel devel package for your distribution
 142         *** is installed.  If you are building with a custom kernel, make sure the
 143         *** kernel is configured, built, and the '--with-linux=PATH' configure
 144         *** option refers to the location of the kernel source.])
 145                 ])
 146         ], [
 147                 LINUX_SYMBOLS=NONE
 148         ])
 149         AC_MSG_RESULT($LINUX_SYMBOLS)
 150         AC_SUBST(LINUX_SYMBOLS)
 151 ])
 152
 153 dnl #
 154 dnl # Detect the kernel to be built against
 155 dnl #
 156 AC_DEFUN([ZFS_AC_KERNEL], [
 157         AC_ARG_WITH([linux],
 158                 AS_HELP_STRING([--with-linux=PATH],
 159                 [Path to kernel source]),
 160                 [kernelsrc="$withval"])
 161
 162         AC_ARG_WITH(linux-obj,
 163                 AS_HELP_STRING([--with-linux-obj=PATH],
 164                 [Path to kernel build objects]),
 165                 [kernelbuild="$withval"])
 166
 167         AC_MSG_CHECKING([kernel source directory])
 168         AS_IF([test -z "$kernelsrc"], [
 169                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 170                         headersdir="/lib/modules/$(uname -r)/source"
 171                         sourcelink=$(readlink -f "$headersdir")
 172                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 173                         headersdir="/lib/modules/$(uname -r)/build"
 174                         sourcelink=$(readlink -f "$headersdir")
 175                 ], [
 176                         sourcelink=$(ls -1d /usr/src/kernels/* \
 177                                      /usr/src/linux-* \
 178                                      2>/dev/null | grep -v obj | tail -1)
 179                 ])
 180
 181                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 182                         kernelsrc=`readlink -f ${sourcelink}`
 183                 ], [
 184                         kernelsrc="[Not found]"
 185                 ])
 186         ], [
 187                 AS_IF([test "$kernelsrc" = "NONE"], [
 188                         kernsrcver=NONE
 189                 ])
 190         ])
 191
 192         AC_MSG_RESULT([$kernelsrc])
 193         AS_IF([test ! -d "$kernelsrc"], [
 194                 AC_MSG_ERROR([
 195         *** Please make sure the kernel devel package for your distribution
 196         *** is installed and then try again.  If that fails, you can specify the
 197         *** location of the kernel source with the '--with-linux=PATH' option.])
 198         ])
 199
 200         AC_MSG_CHECKING([kernel build directory])
 201         AS_IF([test -z "$kernelbuild"], [
 202                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 203                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 204                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 205                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 206                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 207                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 208                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 209                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 210                 ], [
 211                         kernelbuild=${kernelsrc}
 212                 ])
 213         ])
 214         AC_MSG_RESULT([$kernelbuild])
 215
 216         AC_MSG_CHECKING([kernel source version])
 217         utsrelease1=$kernelbuild/include/linux/version.h
 218         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 219         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 220         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 221                 utsrelease=linux/version.h
 222         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 223                 utsrelease=linux/utsrelease.h
 224         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 225                 utsrelease=generated/utsrelease.h
 226         ])
 227
 228         AS_IF([test "$utsrelease"], [
 229                 kernsrcver=`(echo "#include <$utsrelease>";
 230                              echo "kernsrcver=UTS_RELEASE") |
 231                              cpp -I $kernelbuild/include |
 232                              grep "^kernsrcver=" | cut -d \" -f 2`
 233
 234                 AS_IF([test -z "$kernsrcver"], [
 235                         AC_MSG_RESULT([Not found])
 236                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 237                 ])
 238         ], [
 239                 AC_MSG_RESULT([Not found])
 240                 if test "x$enable_linux_builtin" != xyes; then
 241                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 242                 else
 243                         AC_MSG_ERROR([
 244         *** Cannot find UTS_RELEASE definition.
 245         *** Please run 'make prepare' inside the kernel source tree.])
 246                 fi
 247         ])
 248
 249         AC_MSG_RESULT([$kernsrcver])
 250
 251         LINUX=${kernelsrc}
 252         LINUX_OBJ=${kernelbuild}
 253         LINUX_VERSION=${kernsrcver}
 254
 255         AC_SUBST(LINUX)
 256         AC_SUBST(LINUX_OBJ)
 257         AC_SUBST(LINUX_VERSION)
 258
 259         ZFS_AC_MODULE_SYMVERS
 260 ])
 261
 262
 263 dnl #
 264 dnl # Detect the SPL module to be built against
 265 dnl #
 266 AC_DEFUN([ZFS_AC_SPL], [
 267         AC_ARG_WITH([spl],
 268                 AS_HELP_STRING([--with-spl=PATH],
 269                 [Path to spl source]),
 270                 AS_IF([test "$withval" = "yes"],
 271                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 272                         [splsrc="$withval"]))
 273
 274         AC_ARG_WITH([spl-obj],
 275                 AS_HELP_STRING([--with-spl-obj=PATH],
 276                 [Path to spl build objects]),
 277                 [splbuild="$withval"])
 278
 279         AC_ARG_WITH([spl-timeout],
 280                 AS_HELP_STRING([--with-spl-timeout=SECS],
 281                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 282                 [timeout="$withval"], [timeout=0])
 283
 284         dnl #
 285         dnl # The existence of spl.release.in is used to identify a valid
 286         dnl # source directory.  In order of preference:
 287         dnl #
 288         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 289         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 290         splsrc2="/usr/local/src/spl-${VERSION}"
 291         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 292         splsrc4="/usr/src/spl-${VERSION}"
 293         splsrc5="../spl/"
 294         splsrc6="$LINUX"
 295
 296         AC_MSG_CHECKING([spl source directory])
 297         AS_IF([test -z "${splsrc}"], [
 298                 [all_spl_sources="
 299                 ${splsrc0}
 300                 ${splsrc1}
 301                 ${splsrc2}
 302                 ${splsrc3}
 303                 ${splsrc4}
 304                 ${splsrc5}
 305                 ${splsrc6}"],
 306                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 307                         splsrc=${splsrc0}
 308                 ], [ test -e "${splsrc1}/spl.release.in"], [
 309                         splsrc=${splsrc1}
 310                 ], [ test -e "${splsrc2}/spl.release.in"], [
 311                         splsrc=${splsrc2}
 312                 ], [ test -e "${splsrc3}/spl.release.in"], [
 313                         splsrc=$(readlink -f "${splsrc3}")
 314                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 315                         splsrc=${splsrc4}
 316                 ], [ test -e "${splsrc5}/spl.release.in"], [
 317                         splsrc=$(readlink -f "${splsrc5}")
 318                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 319                         splsrc=${splsrc6}
 320                 ], [
 321                         splsrc="[Not found]"
 322                 ])
 323         ], [
 324                 [all_spl_sources="$withval"],
 325                 AS_IF([test "$splsrc" = "NONE"], [
 326                         splbuild=NONE
 327                         splsrcver=NONE
 328                 ])
 329         ])
 330
 331         AC_MSG_RESULT([$splsrc])
 332         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 333                 AC_MSG_ERROR([
 334         *** Please make sure the kmod spl devel package for your distribution
 335         *** is installed then try again.  If that fails you can specify the
 336         *** location of the spl source with the '--with-spl=PATH' option.
 337         *** The spl version must match the version of ZFS you are building,
 338         *** ${VERSION}.  Failed to find spl.release.in in the following:
 339         $all_spl_sources])
 340         ])
 341
 342         dnl #
 343         dnl # The existence of the spl_config.h is used to identify a valid
 344         dnl # spl object directory.  In many cases the object and source
 345         dnl # directory are the same, however the objects may also reside
 346         dnl # is a subdirectory named after the kernel version.
 347         dnl #
 348         dnl # This file is supposed to be available after DKMS finishes
 349         dnl # building the SPL kernel module for the target kernel.  The
 350         dnl # '--with-spl-timeout' option can be passed to pause here,
 351         dnl # waiting for the file to appear from a concurrently building
 352         dnl # SPL package.
 353         dnl #
 354         AC_MSG_CHECKING([spl build directory])
 355
 356         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 357         ${splsrc}"
 358
 359         while true; do
 360                 AS_IF([test -z "$splbuild"], [
 361                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 362                                 splbuild="${splsrc}/${LINUX_VERSION}"
 363                         ], [ test -e "${splsrc}/spl_config.h" ], [
 364                                 splbuild="${splsrc}"
 365                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 366                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 367                         ], [
 368                                 splbuild="[Not found]"
 369                         ])
 370                 ])
 371                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 372                         break;
 373                 ], [
 374                         sleep 1
 375                         timeout=$((timeout-1))
 376                 ])
 377         done
 378
 379         AC_MSG_RESULT([$splbuild])
 380         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 381                 AC_MSG_ERROR([
 382         *** Please make sure the kmod spl devel <kernel> package for your
 383         *** distribution is installed then try again.  If that fails you
 384         *** can specify the location of the spl objects with the
 385         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 386         *** any of the following:
 387         $all_spl_config_locs])
 388         ])
 389
 390         AC_MSG_CHECKING([spl source version])
 391         AS_IF([test -r $splbuild/spl_config.h &&
 392                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 393
 394                 splsrcver=`(echo "#include <spl_config.h>";
 395                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 396                             cpp -I $splbuild |
 397                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 398         ])
 399
 400         AS_IF([test -z "$splsrcver"], [
 401                 AC_MSG_RESULT([Not found])
 402                 AC_MSG_ERROR([
 403         *** Cannot determine the version of the spl source.
 404         *** Please prepare the spl source before running this script])
 405         ])
 406
 407         AC_MSG_RESULT([$splsrcver])
 408
 409         SPL=${splsrc}
 410         SPL_OBJ=${splbuild}
 411         SPL_VERSION=${splsrcver}
 412
 413         AC_SUBST(SPL)
 414         AC_SUBST(SPL_OBJ)
 415         AC_SUBST(SPL_VERSION)
 416
 417         dnl #
 418         dnl # Detect the name used for the SPL Module.symvers file.  If one
 419         dnl # does not exist this is likely because the SPL has been configured
 420         dnl # but not built.  The '--with-spl-timeout' option can be passed
 421         dnl # to pause here, waiting for the file to appear from a concurrently
 422         dnl # building SPL package.  If the file does not appear in time, a good
 423         dnl # guess is made as to what this file will be named based on what it
 424         dnl # is named in the kernel build products.  This file will first be
 425         dnl # used at link time so if the guess is wrong the build will fail
 426         dnl # then.  This unfortunately means the ZFS package does not contain a
 427         dnl # reliable mechanism to detect symbols exported by the SPL at
 428         dnl # configure time.
 429         dnl #
 430         AC_MSG_CHECKING([spl file name for module symbols])
 431         SPL_SYMBOLS=NONE
 432
 433         while true; do
 434                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 435                         SPL_SYMBOLS=Module.symvers
 436                 ], [test -r $SPL_OBJ/Modules.symvers], [
 437                         SPL_SYMBOLS=Modules.symvers
 438                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 439                         SPL_SYMBOLS=Module.symvers
 440                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 441                         SPL_SYMBOLS=Modules.symvers
 442                 ])
 443
 444                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 445                         break;
 446                 ], [
 447                         sleep 1
 448                         timeout=$((timeout-1))
 449                 ])
 450         done
 451
 452         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 453                 SPL_SYMBOLS=$LINUX_SYMBOLS
 454         ])
 455
 456         AC_MSG_RESULT([$SPL_SYMBOLS])
 457         AC_SUBST(SPL_SYMBOLS)
 458 ])
 459
 460 dnl #
 461 dnl # Basic toolchain sanity check.
 462 dnl #
 463 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 464         AC_MSG_CHECKING([whether modules can be built])
 465         ZFS_LINUX_TRY_COMPILE([],[],[
 466                 AC_MSG_RESULT([yes])
 467         ],[
 468                 AC_MSG_RESULT([no])
 469                 if test "x$enable_linux_builtin" != xyes; then
 470                         AC_MSG_ERROR([*** Unable to build an empty module.])
 471                 else
 472                         AC_MSG_ERROR([
 473         *** Unable to build an empty module.
 474         *** Please run 'make scripts' inside the kernel source tree.])
 475                 fi
 476         ])
 477 ])
 478
 479 dnl #
 480 dnl # Certain kernel build options are not supported.  These must be
 481 dnl # detected at configure time and cause a build failure.  Otherwise
 482 dnl # modules may be successfully built that behave incorrectly.
 483 dnl #
 484 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 485         AS_IF([test "x$cross_compiling" != xyes], [
 486                 AC_RUN_IFELSE([
 487                         AC_LANG_PROGRAM([
 488                                 #include "$LINUX/include/linux/license.h"
 489                         ], [
 490                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 491                         ])
 492                 ], [
 493                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 494                             [Define to 1 if GPL-only symbols can be used])
 495                 ], [
 496                 ])
 497         ])
 498
 499         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 500         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 501 ])
 502
 503 dnl #
 504 dnl # Check configured THREAD_SIZE
 505 dnl #
 506 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 507 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 508 dnl # on newer kernels and some architectures stack usage optimizations can be
 509 dnl # conditionally applied to improve performance without negatively impacting
 510 dnl # stability.
 511 dnl #
 512 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 513         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 514         ZFS_LINUX_TRY_COMPILE([
 515                 #include <linux/module.h>
 516         ],[
 517                 #if (THREAD_SIZE < 16384)
 518                 #error "THREAD_SIZE is less than 16K"
 519                 #endif
 520         ],[
 521                 AC_MSG_RESULT([yes])
 522                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 523         ],[
 524                 AC_MSG_RESULT([no])
 525         ])
 526 ])
 527
 528 dnl #
 529 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 530 dnl #
 531 dnl # This is typically only set for debug kernels because it comes with
 532 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 533 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 534 dnl # This will cause a failure at link time which we'd rather know about
 535 dnl # at compile time.
 536 dnl #
 537 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 538 dnl # with the upstream community we add a check to detect this case.
 539 dnl #
 540 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 541
 542         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 543                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 544                 tmp_flags="$EXTRA_KCFLAGS"
 545                 ZFS_LINUX_TRY_COMPILE([
 546                         #include <linux/module.h>
 547                         #include <linux/mutex.h>
 548
 549                         MODULE_LICENSE("$ZFS_META_LICENSE");
 550                 ],[
 551                         struct mutex lock;
 552
 553                         mutex_init(&lock);
 554                         mutex_lock(&lock);
 555                         mutex_unlock(&lock);
 556                 ],[
 557                         AC_MSG_RESULT(no)
 558                 ],[
 559                         AC_MSG_RESULT(yes)
 560                         AC_MSG_ERROR([
 561         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 562         *** with the CDDL license and will prevent the module linking stage
 563         *** from succeeding.  You must rebuild your kernel without this
 564         *** option enabled.])
 565                 ])
 566                 EXTRA_KCFLAGS="$tmp_flags"
 567         ], [])
 568 ])
 569
 570 dnl #
 571 dnl # ZFS_LINUX_CONFTEST_H
 572 dnl #
 573 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 574 cat - <<_ACEOF >conftest.h
 575 $1
 576 _ACEOF
 577 ])
 578
 579 dnl #
 580 dnl # ZFS_LINUX_CONFTEST_C
 581 dnl #
 582 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 583 cat confdefs.h - <<_ACEOF >conftest.c
 584 $1
 585 _ACEOF
 586 ])
 587
 588 dnl #
 589 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 590 dnl #
 591 m4_define([ZFS_LANG_PROGRAM], [
 592 $1
 593 int
 594 main (void)
 595 {
 596 dnl Do *not* indent the following line: there may be CPP directives.
 597 dnl Don't move the `;' right after for the same reason.
 598 $2
 599   ;
 600   return 0;
 601 }
 602 ])
 603
 604 dnl #
 605 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 606 dnl #
 607 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 608         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 609         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 610         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 611         echo "obj-m := conftest.o" >build/Makefile
 612         modpost_flag=''
 613         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 614         AS_IF(
 615                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 616                 [$4],
 617                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 618         )
 619         rm -Rf build
 620 ])
 621
 622 dnl #
 623 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 624 dnl #
 625 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 626         [ZFS_LINUX_COMPILE_IFELSE(
 627         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 628         [modules],
 629         [test -s build/conftest.o],
 630         [$3], [$4])
 631 ])
 632
 633 dnl #
 634 dnl # ZFS_LINUX_CONFIG
 635 dnl #
 636 AC_DEFUN([ZFS_LINUX_CONFIG],
 637         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 638         ZFS_LINUX_TRY_COMPILE([
 639                 #include <linux/module.h>
 640         ],[
 641                 #ifndef CONFIG_$1
 642                 #error CONFIG_$1 not #defined
 643                 #endif
 644         ],[
 645                 AC_MSG_RESULT([yes])
 646                 $2
 647         ],[
 648                 AC_MSG_RESULT([no])
 649                 $3
 650         ])
 651 ])
 652
 653 dnl #
 654 dnl # ZFS_CHECK_SYMBOL_EXPORT
 655 dnl # check symbol exported or not
 656 dnl #
 657 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 658         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 659                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 660         rc=$?
 661         if test $rc -ne 0; then
 662                 export=0
 663                 for file in $2; do
 664                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 665                                 "$LINUX/$file" 2>/dev/null
 666                         rc=$?
 667                         if test $rc -eq 0; then
 668                                 export=1
 669                                 break;
 670                         fi
 671                 done
 672                 if test $export -eq 0; then :
 673                         $4
 674                 else :
 675                         $3
 676                 fi
 677         else :
 678                 $3
 679         fi
 680 ])
 681
 682 dnl #
 683 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 684 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 685 dnl # is called if not compiling for builtin
 686 dnl #
 687 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 688         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 689         if test $rc -ne 0; then :
 690                 $6
 691         else
 692                 if test "x$enable_linux_builtin" != xyes; then
 693                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 694                 fi
 695                 if test $rc -ne 0; then :
 696                         $6
 697                 else :
 698                         $5
 699                 fi
 700         fi
 701 ])
 702
 703 dnl #
 704 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 705 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 706 dnl # provided via the fifth parameter
 707 dnl #
 708 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 709         [ZFS_LINUX_COMPILE_IFELSE(
 710         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 711         [modules],
 712         [test -s build/conftest.o],
 713         [$3], [$4], [$5])
 714 ])