config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  41         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  48         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  49         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  50         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  51         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  52         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  53         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  54         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  61         ZFS_AC_KERNEL_INODE_SET_FLAGS
  62         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  63         ZFS_AC_KERNEL_SHOW_OPTIONS
  64         ZFS_AC_KERNEL_FILE_INODE
  65         ZFS_AC_KERNEL_FILE_DENTRY
  66         ZFS_AC_KERNEL_FSYNC
  67         ZFS_AC_KERNEL_EVICT_INODE
  68         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  69         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  70         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  71         ZFS_AC_KERNEL_FALLOCATE
  72         ZFS_AC_KERNEL_AIO_FSYNC
  73         ZFS_AC_KERNEL_MKDIR_UMODE_T
  74         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  75         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  76         ZFS_AC_KERNEL_GET_LINK
  77         ZFS_AC_KERNEL_PUT_LINK
  78         ZFS_AC_KERNEL_TMPFILE
  79         ZFS_AC_KERNEL_TRUNCATE_RANGE
  80         ZFS_AC_KERNEL_AUTOMOUNT
  81         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  82         ZFS_AC_KERNEL_COMMIT_METADATA
  83         ZFS_AC_KERNEL_CLEAR_INODE
  84         ZFS_AC_KERNEL_SETATTR_PREPARE
  85         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  86         ZFS_AC_KERNEL_D_MAKE_ROOT
  87         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  88         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  89         ZFS_AC_KERNEL_D_SET_D_OP
  90         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  91         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  92         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  93         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  94         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  95         ZFS_AC_KERNEL_MOUNT_NODEV
  96         ZFS_AC_KERNEL_SHRINK
  97         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  98         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  99         ZFS_AC_KERNEL_S_D_OP
 100         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
 101         ZFS_AC_KERNEL_SET_NLINK
 102         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 103         ZFS_AC_KERNEL_5ARG_SGET
 104         ZFS_AC_KERNEL_LSEEK_EXECUTE
 105         ZFS_AC_KERNEL_VFS_ITERATE
 106         ZFS_AC_KERNEL_VFS_RW_ITERATE
 107         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 108         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 109         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 110         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 111         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 112         ZFS_AC_KERNEL_FPU
 113         ZFS_AC_KERNEL_KUID_HELPERS
 114         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 115         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 116         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 117
 118         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 119                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 120         ])
 121         AC_SUBST(KERNELMAKE_PARAMS)
 122
 123
 124         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 125         dnl # compiler options are added by the kernel build system.
 126         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 127         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 128         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 129         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 130
 131         AC_SUBST(KERNELCPPFLAGS)
 132 ])
 133
 134 dnl #
 135 dnl # Detect name used for Module.symvers file in kernel
 136 dnl #
 137 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 138         modpost=$LINUX/scripts/Makefile.modpost
 139         AC_MSG_CHECKING([kernel file name for module symbols])
 140         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 141                 AS_IF([grep -q Modules.symvers $modpost], [
 142                         LINUX_SYMBOLS=Modules.symvers
 143                 ], [
 144                         LINUX_SYMBOLS=Module.symvers
 145                 ])
 146
 147                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 148                         AC_MSG_ERROR([
 149         *** Please make sure the kernel devel package for your distribution
 150         *** is installed.  If you are building with a custom kernel, make sure the
 151         *** kernel is configured, built, and the '--with-linux=PATH' configure
 152         *** option refers to the location of the kernel source.])
 153                 ])
 154         ], [
 155                 LINUX_SYMBOLS=NONE
 156         ])
 157         AC_MSG_RESULT($LINUX_SYMBOLS)
 158         AC_SUBST(LINUX_SYMBOLS)
 159 ])
 160
 161 dnl #
 162 dnl # Detect the kernel to be built against
 163 dnl #
 164 AC_DEFUN([ZFS_AC_KERNEL], [
 165         AC_ARG_WITH([linux],
 166                 AS_HELP_STRING([--with-linux=PATH],
 167                 [Path to kernel source]),
 168                 [kernelsrc="$withval"])
 169
 170         AC_ARG_WITH(linux-obj,
 171                 AS_HELP_STRING([--with-linux-obj=PATH],
 172                 [Path to kernel build objects]),
 173                 [kernelbuild="$withval"])
 174
 175         AC_MSG_CHECKING([kernel source directory])
 176         AS_IF([test -z "$kernelsrc"], [
 177                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 178                         headersdir="/lib/modules/$(uname -r)/source"
 179                         sourcelink=$(readlink -f "$headersdir")
 180                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 181                         headersdir="/lib/modules/$(uname -r)/build"
 182                         sourcelink=$(readlink -f "$headersdir")
 183                 ], [
 184                         sourcelink=$(ls -1d /usr/src/kernels/* \
 185                                      /usr/src/linux-* \
 186                                      2>/dev/null | grep -v obj | tail -1)
 187                 ])
 188
 189                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 190                         kernelsrc=`readlink -f ${sourcelink}`
 191                 ], [
 192                         kernelsrc="[Not found]"
 193                 ])
 194         ], [
 195                 AS_IF([test "$kernelsrc" = "NONE"], [
 196                         kernsrcver=NONE
 197                 ])
 198         ])
 199
 200         AC_MSG_RESULT([$kernelsrc])
 201         AS_IF([test ! -d "$kernelsrc"], [
 202                 AC_MSG_ERROR([
 203         *** Please make sure the kernel devel package for your distribution
 204         *** is installed and then try again.  If that fails, you can specify the
 205         *** location of the kernel source with the '--with-linux=PATH' option.])
 206         ])
 207
 208         AC_MSG_CHECKING([kernel build directory])
 209         AS_IF([test -z "$kernelbuild"], [
 210                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 211                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 212                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 213                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 214                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 215                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 216                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 217                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 218                 ], [
 219                         kernelbuild=${kernelsrc}
 220                 ])
 221         ])
 222         AC_MSG_RESULT([$kernelbuild])
 223
 224         AC_MSG_CHECKING([kernel source version])
 225         utsrelease1=$kernelbuild/include/linux/version.h
 226         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 227         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 228         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 229                 utsrelease=linux/version.h
 230         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 231                 utsrelease=linux/utsrelease.h
 232         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 233                 utsrelease=generated/utsrelease.h
 234         ])
 235
 236         AS_IF([test "$utsrelease"], [
 237                 kernsrcver=`(echo "#include <$utsrelease>";
 238                              echo "kernsrcver=UTS_RELEASE") |
 239                              cpp -I $kernelbuild/include |
 240                              grep "^kernsrcver=" | cut -d \" -f 2`
 241
 242                 AS_IF([test -z "$kernsrcver"], [
 243                         AC_MSG_RESULT([Not found])
 244                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 245                 ])
 246         ], [
 247                 AC_MSG_RESULT([Not found])
 248                 if test "x$enable_linux_builtin" != xyes; then
 249                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 250                 else
 251                         AC_MSG_ERROR([
 252         *** Cannot find UTS_RELEASE definition.
 253         *** Please run 'make prepare' inside the kernel source tree.])
 254                 fi
 255         ])
 256
 257         AC_MSG_RESULT([$kernsrcver])
 258
 259         LINUX=${kernelsrc}
 260         LINUX_OBJ=${kernelbuild}
 261         LINUX_VERSION=${kernsrcver}
 262
 263         AC_SUBST(LINUX)
 264         AC_SUBST(LINUX_OBJ)
 265         AC_SUBST(LINUX_VERSION)
 266
 267         ZFS_AC_MODULE_SYMVERS
 268 ])
 269
 270
 271 dnl #
 272 dnl # Detect the SPL module to be built against
 273 dnl #
 274 AC_DEFUN([ZFS_AC_SPL], [
 275         AC_ARG_WITH([spl],
 276                 AS_HELP_STRING([--with-spl=PATH],
 277                 [Path to spl source]),
 278                 AS_IF([test "$withval" = "yes"],
 279                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 280                         [splsrc="$withval"]))
 281
 282         AC_ARG_WITH([spl-obj],
 283                 AS_HELP_STRING([--with-spl-obj=PATH],
 284                 [Path to spl build objects]),
 285                 [splbuild="$withval"])
 286
 287         AC_ARG_WITH([spl-timeout],
 288                 AS_HELP_STRING([--with-spl-timeout=SECS],
 289                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 290                 [timeout="$withval"], [timeout=0])
 291
 292         dnl #
 293         dnl # The existence of spl.release.in is used to identify a valid
 294         dnl # source directory.  In order of preference:
 295         dnl #
 296         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 297         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 298         splsrc2="/usr/local/src/spl-${VERSION}"
 299         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 300         splsrc4="/usr/src/spl-${VERSION}"
 301         splsrc5="../spl/"
 302         splsrc6="$LINUX"
 303
 304         AC_MSG_CHECKING([spl source directory])
 305         AS_IF([test -z "${splsrc}"], [
 306                 [all_spl_sources="
 307                 ${splsrc0}
 308                 ${splsrc1}
 309                 ${splsrc2}
 310                 ${splsrc3}
 311                 ${splsrc4}
 312                 ${splsrc5}
 313                 ${splsrc6}"],
 314                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 315                         splsrc=${splsrc0}
 316                 ], [ test -e "${splsrc1}/spl.release.in"], [
 317                         splsrc=${splsrc1}
 318                 ], [ test -e "${splsrc2}/spl.release.in"], [
 319                         splsrc=${splsrc2}
 320                 ], [ test -e "${splsrc3}/spl.release.in"], [
 321                         splsrc=$(readlink -f "${splsrc3}")
 322                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 323                         splsrc=${splsrc4}
 324                 ], [ test -e "${splsrc5}/spl.release.in"], [
 325                         splsrc=$(readlink -f "${splsrc5}")
 326                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 327                         splsrc=${splsrc6}
 328                 ], [
 329                         splsrc="[Not found]"
 330                 ])
 331         ], [
 332                 [all_spl_sources="$withval"],
 333                 AS_IF([test "$splsrc" = "NONE"], [
 334                         splbuild=NONE
 335                         splsrcver=NONE
 336                 ])
 337         ])
 338
 339         AC_MSG_RESULT([$splsrc])
 340         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 341                 AC_MSG_ERROR([
 342         *** Please make sure the kmod spl devel package for your distribution
 343         *** is installed then try again.  If that fails you can specify the
 344         *** location of the spl source with the '--with-spl=PATH' option.
 345         *** The spl version must match the version of ZFS you are building,
 346         *** ${VERSION}.  Failed to find spl.release.in in the following:
 347         $all_spl_sources])
 348         ])
 349
 350         dnl #
 351         dnl # The existence of the spl_config.h is used to identify a valid
 352         dnl # spl object directory.  In many cases the object and source
 353         dnl # directory are the same, however the objects may also reside
 354         dnl # is a subdirectory named after the kernel version.
 355         dnl #
 356         dnl # This file is supposed to be available after DKMS finishes
 357         dnl # building the SPL kernel module for the target kernel.  The
 358         dnl # '--with-spl-timeout' option can be passed to pause here,
 359         dnl # waiting for the file to appear from a concurrently building
 360         dnl # SPL package.
 361         dnl #
 362         AC_MSG_CHECKING([spl build directory])
 363
 364         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 365         ${splsrc}"
 366
 367         while true; do
 368                 AS_IF([test -z "$splbuild"], [
 369                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 370                                 splbuild="${splsrc}/${LINUX_VERSION}"
 371                         ], [ test -e "${splsrc}/spl_config.h" ], [
 372                                 splbuild="${splsrc}"
 373                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 374                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 375                         ], [
 376                                 splbuild="[Not found]"
 377                         ])
 378                 ])
 379                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 380                         break;
 381                 ], [
 382                         sleep 1
 383                         timeout=$((timeout-1))
 384                 ])
 385         done
 386
 387         AC_MSG_RESULT([$splbuild])
 388         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 389                 AC_MSG_ERROR([
 390         *** Please make sure the kmod spl devel <kernel> package for your
 391         *** distribution is installed then try again.  If that fails you
 392         *** can specify the location of the spl objects with the
 393         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 394         *** any of the following:
 395         $all_spl_config_locs])
 396         ])
 397
 398         AC_MSG_CHECKING([spl source version])
 399         AS_IF([test -r $splbuild/spl_config.h &&
 400                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 401
 402                 splsrcver=`(echo "#include <spl_config.h>";
 403                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 404                             cpp -I $splbuild |
 405                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 406         ])
 407
 408         AS_IF([test -z "$splsrcver"], [
 409                 AC_MSG_RESULT([Not found])
 410                 AC_MSG_ERROR([
 411         *** Cannot determine the version of the spl source.
 412         *** Please prepare the spl source before running this script])
 413         ])
 414
 415         AC_MSG_RESULT([$splsrcver])
 416
 417         SPL=${splsrc}
 418         SPL_OBJ=${splbuild}
 419         SPL_VERSION=${splsrcver}
 420
 421         AC_SUBST(SPL)
 422         AC_SUBST(SPL_OBJ)
 423         AC_SUBST(SPL_VERSION)
 424
 425         dnl #
 426         dnl # Detect the name used for the SPL Module.symvers file.  If one
 427         dnl # does not exist this is likely because the SPL has been configured
 428         dnl # but not built.  The '--with-spl-timeout' option can be passed
 429         dnl # to pause here, waiting for the file to appear from a concurrently
 430         dnl # building SPL package.  If the file does not appear in time, a good
 431         dnl # guess is made as to what this file will be named based on what it
 432         dnl # is named in the kernel build products.  This file will first be
 433         dnl # used at link time so if the guess is wrong the build will fail
 434         dnl # then.  This unfortunately means the ZFS package does not contain a
 435         dnl # reliable mechanism to detect symbols exported by the SPL at
 436         dnl # configure time.
 437         dnl #
 438         AC_MSG_CHECKING([spl file name for module symbols])
 439         SPL_SYMBOLS=NONE
 440
 441         while true; do
 442                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 443                         SPL_SYMBOLS=Module.symvers
 444                 ], [test -r $SPL_OBJ/Modules.symvers], [
 445                         SPL_SYMBOLS=Modules.symvers
 446                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 447                         SPL_SYMBOLS=Module.symvers
 448                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 449                         SPL_SYMBOLS=Modules.symvers
 450                 ])
 451
 452                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 453                         break;
 454                 ], [
 455                         sleep 1
 456                         timeout=$((timeout-1))
 457                 ])
 458         done
 459
 460         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 461                 SPL_SYMBOLS=$LINUX_SYMBOLS
 462         ])
 463
 464         AC_MSG_RESULT([$SPL_SYMBOLS])
 465         AC_SUBST(SPL_SYMBOLS)
 466 ])
 467
 468 dnl #
 469 dnl # Basic toolchain sanity check.
 470 dnl #
 471 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 472         AC_MSG_CHECKING([whether modules can be built])
 473         ZFS_LINUX_TRY_COMPILE([],[],[
 474                 AC_MSG_RESULT([yes])
 475         ],[
 476                 AC_MSG_RESULT([no])
 477                 if test "x$enable_linux_builtin" != xyes; then
 478                         AC_MSG_ERROR([*** Unable to build an empty module.])
 479                 else
 480                         AC_MSG_ERROR([
 481         *** Unable to build an empty module.
 482         *** Please run 'make scripts' inside the kernel source tree.])
 483                 fi
 484         ])
 485 ])
 486
 487 dnl #
 488 dnl # Certain kernel build options are not supported.  These must be
 489 dnl # detected at configure time and cause a build failure.  Otherwise
 490 dnl # modules may be successfully built that behave incorrectly.
 491 dnl #
 492 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 493         AS_IF([test "x$cross_compiling" != xyes], [
 494                 AC_RUN_IFELSE([
 495                         AC_LANG_PROGRAM([
 496                                 #include "$LINUX/include/linux/license.h"
 497                         ], [
 498                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 499                         ])
 500                 ], [
 501                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 502                             [Define to 1 if GPL-only symbols can be used])
 503                 ], [
 504                 ])
 505         ])
 506
 507         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 508         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 509 ])
 510
 511 dnl #
 512 dnl # Check configured THREAD_SIZE
 513 dnl #
 514 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 515 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 516 dnl # on newer kernels and some architectures stack usage optimizations can be
 517 dnl # conditionally applied to improve performance without negatively impacting
 518 dnl # stability.
 519 dnl #
 520 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 521         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 522         ZFS_LINUX_TRY_COMPILE([
 523                 #include <linux/module.h>
 524         ],[
 525                 #if (THREAD_SIZE < 16384)
 526                 #error "THREAD_SIZE is less than 16K"
 527                 #endif
 528         ],[
 529                 AC_MSG_RESULT([yes])
 530                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 531         ],[
 532                 AC_MSG_RESULT([no])
 533         ])
 534 ])
 535
 536 dnl #
 537 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 538 dnl #
 539 dnl # This is typically only set for debug kernels because it comes with
 540 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 541 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 542 dnl # This will cause a failure at link time which we'd rather know about
 543 dnl # at compile time.
 544 dnl #
 545 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 546 dnl # with the upstream community we add a check to detect this case.
 547 dnl #
 548 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 549
 550         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 551                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 552                 tmp_flags="$EXTRA_KCFLAGS"
 553                 ZFS_LINUX_TRY_COMPILE([
 554                         #include <linux/module.h>
 555                         #include <linux/mutex.h>
 556
 557                         MODULE_LICENSE("$ZFS_META_LICENSE");
 558                 ],[
 559                         struct mutex lock;
 560
 561                         mutex_init(&lock);
 562                         mutex_lock(&lock);
 563                         mutex_unlock(&lock);
 564                 ],[
 565                         AC_MSG_RESULT(no)
 566                 ],[
 567                         AC_MSG_RESULT(yes)
 568                         AC_MSG_ERROR([
 569         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 570         *** with the CDDL license and will prevent the module linking stage
 571         *** from succeeding.  You must rebuild your kernel without this
 572         *** option enabled.])
 573                 ])
 574                 EXTRA_KCFLAGS="$tmp_flags"
 575         ], [])
 576 ])
 577
 578 dnl #
 579 dnl # ZFS_LINUX_CONFTEST_H
 580 dnl #
 581 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 582 cat - <<_ACEOF >conftest.h
 583 $1
 584 _ACEOF
 585 ])
 586
 587 dnl #
 588 dnl # ZFS_LINUX_CONFTEST_C
 589 dnl #
 590 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 591 cat confdefs.h - <<_ACEOF >conftest.c
 592 $1
 593 _ACEOF
 594 ])
 595
 596 dnl #
 597 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 598 dnl #
 599 m4_define([ZFS_LANG_PROGRAM], [
 600 $1
 601 int
 602 main (void)
 603 {
 604 dnl Do *not* indent the following line: there may be CPP directives.
 605 dnl Don't move the `;' right after for the same reason.
 606 $2
 607   ;
 608   return 0;
 609 }
 610 ])
 611
 612 dnl #
 613 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 614 dnl #
 615 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 616         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 617         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 618         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 619         echo "obj-m := conftest.o" >build/Makefile
 620         modpost_flag=''
 621         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 622         AS_IF(
 623                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 624                 [$4],
 625                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 626         )
 627         rm -Rf build
 628 ])
 629
 630 dnl #
 631 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 632 dnl #
 633 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 634         [ZFS_LINUX_COMPILE_IFELSE(
 635         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 636         [modules],
 637         [test -s build/conftest.o],
 638         [$3], [$4])
 639 ])
 640
 641 dnl #
 642 dnl # ZFS_LINUX_CONFIG
 643 dnl #
 644 AC_DEFUN([ZFS_LINUX_CONFIG],
 645         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 646         ZFS_LINUX_TRY_COMPILE([
 647                 #include <linux/module.h>
 648         ],[
 649                 #ifndef CONFIG_$1
 650                 #error CONFIG_$1 not #defined
 651                 #endif
 652         ],[
 653                 AC_MSG_RESULT([yes])
 654                 $2
 655         ],[
 656                 AC_MSG_RESULT([no])
 657                 $3
 658         ])
 659 ])
 660
 661 dnl #
 662 dnl # ZFS_CHECK_SYMBOL_EXPORT
 663 dnl # check symbol exported or not
 664 dnl #
 665 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 666         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 667                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 668         rc=$?
 669         if test $rc -ne 0; then
 670                 export=0
 671                 for file in $2; do
 672                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 673                                 "$LINUX/$file" 2>/dev/null
 674                         rc=$?
 675                         if test $rc -eq 0; then
 676                                 export=1
 677                                 break;
 678                         fi
 679                 done
 680                 if test $export -eq 0; then :
 681                         $4
 682                 else :
 683                         $3
 684                 fi
 685         else :
 686                 $3
 687         fi
 688 ])
 689
 690 dnl #
 691 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 692 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 693 dnl # is called if not compiling for builtin
 694 dnl #
 695 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 696         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 697         if test $rc -ne 0; then :
 698                 $6
 699         else
 700                 if test "x$enable_linux_builtin" != xyes; then
 701                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 702                 fi
 703                 if test $rc -ne 0; then :
 704                         $6
 705                 else :
 706                         $5
 707                 fi
 708         fi
 709 ])
 710
 711 dnl #
 712 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 713 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 714 dnl # provided via the fifth parameter
 715 dnl #
 716 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 717         [ZFS_LINUX_COMPILE_IFELSE(
 718         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 719         [modules],
 720         [test -s build/conftest.o],
 721         [$3], [$4], [$5])
 722 ])